qcsrc/common/gamemodes/gamemode/keyhunt/sv_keyhunt.qc

   1 #include "sv_keyhunt.qh"
   2
   3 float autocvar_g_balance_keyhunt_damageforcescale;
   4 float autocvar_g_balance_keyhunt_delay_collect;
   5 float autocvar_g_balance_keyhunt_delay_damage_return;
   6 float autocvar_g_balance_keyhunt_delay_return;
   7 float autocvar_g_balance_keyhunt_delay_round;
   8 float autocvar_g_balance_keyhunt_delay_tracking;
   9 float autocvar_g_balance_keyhunt_return_when_unreachable;
  10 float autocvar_g_balance_keyhunt_dropvelocity;
  11 float autocvar_g_balance_keyhunt_maxdist;
  12 float autocvar_g_balance_keyhunt_protecttime;
  13
  14 int autocvar_g_balance_keyhunt_score_capture;
  15 int autocvar_g_balance_keyhunt_score_carrierfrag;
  16 int autocvar_g_balance_keyhunt_score_collect;
  17 int autocvar_g_balance_keyhunt_score_destroyed;
  18 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  19 int autocvar_g_balance_keyhunt_score_push;
  20 float autocvar_g_balance_keyhunt_throwvelocity;
  21
  22 //int autocvar_g_keyhunt_teams;
  23 int autocvar_g_keyhunt_teams_override;
  24
  25 // #define KH_PLAYER_USE_ATTACHMENT
  26 // #define KH_PLAYER_USE_CARRIEDMODEL
  27
  28 #ifdef KH_PLAYER_USE_ATTACHMENT
  29 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  30 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  31 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  32 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  33 const string KH_PLAYER_ATTACHMENT_BONE = "";
  34 #else
  35 const float KH_KEY_ZSHIFT = 22;
  36 const float KH_KEY_XYDIST = 24;
  37 const float KH_KEY_XYSPEED = 45;
  38 #endif
  39 const float KH_KEY_WP_ZSHIFT = 20;
  40
  41 const vector KH_KEY_MIN = '-10 -10 -46';
  42 const vector KH_KEY_MAX = '10 10 3';
  43 const float KH_KEY_BRIGHTNESS = 2;
  44
  45 bool kh_no_radar_circles;
  46
  47 // kh_state
  48 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  49 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  50 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  51 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  52 .float siren_time;  //  time delay the siren
  53 //.float stuff_time;  //  time delay to stuffcmd a cvar
  54
  55 int kh_Team_ByID(int t)
  56 {
  57         if(t == 0) return NUM_TEAM_1;
  58         if(t == 1) return NUM_TEAM_2;
  59         if(t == 2) return NUM_TEAM_3;
  60         if(t == 3) return NUM_TEAM_4;
  61         return 0;
  62 }
  63
  64 //entity kh_worldkeylist;
  65 .entity kh_worldkeynext;
  66 entity kh_controller;
  67 //bool kh_tracking_enabled;
  68 int kh_teams;
  69 int kh_interferemsg_team;
  70 float kh_interferemsg_time;
  71 .entity kh_next, kh_prev; // linked list
  72 .float kh_droptime;
  73 .int kh_dropperteam;
  74 .entity kh_previous_owner;
  75 .int kh_previous_owner_playerid;
  76
  77 int kh_key_dropped, kh_key_carried;
  78
  79 int kh_Key_AllOwnedByWhichTeam();
  80
  81 const int ST_KH_CAPS = 1;
  82 void kh_ScoreRules(int teams)
  83 {
  84         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
  85         field_team(ST_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  86         field(SP_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  87         field(SP_KH_PUSHES, "pushes", 0);
  88         field(SP_KH_DESTROYS, "destroyed", SFL_LOWER_IS_BETTER);
  89         field(SP_KH_PICKUPS, "pickups", 0);
  90         field(SP_KH_KCKILLS, "kckills", 0);
  91         field(SP_KH_LOSSES, "losses", SFL_LOWER_IS_BETTER);
  92         });
  93 }
  94
  95 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
  96 {
  97         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
  98                 if(!kh_tracking_enabled)
  99                         return false;
 100
 101         return true;
 102 }
 103
 104 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 105 {
 106         if(!kh_tracking_enabled)
 107                 return false;
 108         if(!this.owner)
 109                 return true;
 110         if(!this.owner.owner)
 111                 return true;
 112         return false;  // draw only when key is not owned
 113 }
 114
 115 void kh_update_state()
 116 {
 117         entity key;
 118         int f;
 119         int s = 0;
 120         FOR_EACH_KH_KEY(key)
 121         {
 122                 if(key.owner)
 123                         f = key.team;
 124                 else
 125                         f = 30;
 126                 s |= (32 ** key.count) * f;
 127         }
 128
 129         FOREACH_CLIENT(true, { STAT(KH_KEYS, it) = s; });
 130
 131         FOR_EACH_KH_KEY(key)
 132         {
 133                 if(key.owner)
 134                         STAT(KH_KEYS, key.owner) |= (32 ** key.count) * 31;
 135         }
 136         //print(ftos((nextent(NULL)).kh_state), "\n");
 137 }
 138
 139
 140
 141
 142 var kh_Think_t kh_Controller_Thinkfunc;
 143 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 144 {
 145         kh_Controller_Thinkfunc = func;
 146         kh_controller.cnt = ceil(t);
 147         if(t == 0)
 148                 kh_controller.nextthink = time; // force
 149 }
 150 void kh_WaitForPlayers();
 151 void kh_Controller_Think(entity this)  // called a lot
 152 {
 153         if(game_stopped)
 154                 return;
 155         if(this.cnt > 0)
 156         {
 157                 if(getthink(this) != kh_WaitForPlayers)
 158                         this.cnt -= 1;
 159         }
 160         else if(this.cnt == 0)
 161         {
 162                 this.cnt -= 1;
 163                 kh_Controller_Thinkfunc();
 164         }
 165         this.nextthink = time + 1;
 166 }
 167
 168 // frags f: take from cvar * f
 169 // frags 0: no frags
 170 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 171 {
 172         string s;
 173         if(game_stopped)
 174                 return;
 175
 176         if(frags_player)
 177                 UpdateFrags(player, frags_player);
 178
 179         if(key && key.owner && frags_owner)
 180                 UpdateFrags(key.owner, frags_owner);
 181
 182         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 183                 return;
 184
 185         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 186
 187         if(key && key.owner)
 188                 s = strcat(s, ":", ftos(key.owner.playerid));
 189         else
 190                 s = strcat(s, ":0");
 191
 192         s = strcat(s, ":", ftos(frags_owner), ":");
 193
 194         if(key)
 195                 s = strcat(s, key.netname);
 196
 197         GameLogEcho(s);
 198 }
 199
 200 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 201 {
 202         if(e.tag_entity)
 203         {
 204                 makevectors(e.tag_entity.angles);
 205                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 206         }
 207         else
 208                 return e.origin;
 209 }
 210
 211 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 212 {
 213 #ifdef KH_PLAYER_USE_ATTACHMENT
 214         entity first = key.owner.kh_next;
 215         if(key == first)
 216         {
 217                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 218                 if(key.kh_next)
 219                 {
 220                         setattachment(key.kh_next, key, "");
 221                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 222                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 223                         key.kh_next.angles = '0 0 0';
 224                 }
 225                 else
 226                         setorigin(key, KH_PLAYER_ATTACHMENT);
 227                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 228         }
 229         else
 230         {
 231                 setattachment(key, key.kh_prev, "");
 232                 if(key.kh_next)
 233                         setattachment(key.kh_next, key, "");
 234                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 235                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 236                 key.angles = '0 0 0';
 237         }
 238 #else
 239         setattachment(key, key.owner, "");
 240         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 241         key.angles_y -= key.owner.angles.y;
 242 #endif
 243         key.flags = 0;
 244         if(IL_CONTAINS(g_items, key))
 245                 IL_REMOVE(g_items, key);
 246         key.solid = SOLID_NOT;
 247         set_movetype(key, MOVETYPE_NONE);
 248         key.team = key.owner.team;
 249         key.nextthink = time;
 250         key.damageforcescale = 0;
 251         key.takedamage = DAMAGE_NO;
 252         key.modelindex = kh_key_carried;
 253         navigation_dynamicgoal_unset(key);
 254 }
 255
 256 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 257 {
 258 #ifdef KH_PLAYER_USE_ATTACHMENT
 259         entity first = key.owner.kh_next;
 260         if(key == first)
 261         {
 262                 if(key.kh_next)
 263                 {
 264                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 265                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 266                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 267                 }
 268         }
 269         else
 270         {
 271                 if(key.kh_next)
 272                         setattachment(key.kh_next, key.kh_prev, "");
 273                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 274         }
 275         // in any case:
 276         setattachment(key, NULL, "");
 277         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, key.owner).z - KH_KEY_MIN_z));
 278         key.angles = key.owner.angles;
 279 #else
 280         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 281         setattachment(key, NULL, "");
 282         key.angles_y += key.owner.angles.y;
 283 #endif
 284         key.flags = FL_ITEM;
 285         if(!IL_CONTAINS(g_items, key))
 286                 IL_PUSH(g_items, key);
 287         key.solid = SOLID_TRIGGER;
 288         set_movetype(key, MOVETYPE_TOSS);
 289         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 290         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 291         key.takedamage = DAMAGE_YES;
 292         // let key.team stay
 293         key.modelindex = kh_key_dropped;
 294         navigation_dynamicgoal_set(key, key.owner);
 295         key.kh_previous_owner = key.owner;
 296         key.kh_previous_owner_playerid = key.owner.playerid;
 297 }
 298
 299 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 300 {
 301         if(key.owner == player)
 302                 return;
 303
 304         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 305
 306         if(key.owner)
 307         {
 308                 kh_Key_Detach(key);
 309
 310                 // remove from linked list
 311                 if(key.kh_next)
 312                         key.kh_next.kh_prev = key.kh_prev;
 313                 key.kh_prev.kh_next = key.kh_next;
 314                 key.kh_next = NULL;
 315                 key.kh_prev = NULL;
 316
 317                 if(key.owner.kh_next == NULL)
 318                 {
 319                         // No longer a key carrier
 320                         if(!kh_no_radar_circles)
 321                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 322                         WaypointSprite_DetachCarrier(key.owner);
 323                 }
 324         }
 325
 326         key.owner = player;
 327
 328         if(player)
 329         {
 330                 // insert into linked list
 331                 key.kh_next = player.kh_next;
 332                 key.kh_prev = player;
 333                 player.kh_next = key;
 334                 if(key.kh_next)
 335                         key.kh_next.kh_prev = key;
 336
 337                 kh_Key_Attach(key);
 338
 339                 if(key.kh_next == NULL)
 340                 {
 341                         // player is now a key carrier
 342                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 343                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 344                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 345                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 346                         if(player.team == NUM_TEAM_1)
 347                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 348                         else if(player.team == NUM_TEAM_2)
 349                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 350                         else if(player.team == NUM_TEAM_3)
 351                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 352                         else if(player.team == NUM_TEAM_4)
 353                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 354                         if(!kh_no_radar_circles)
 355                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 356                 }
 357         }
 358
 359         // moved that here, also update if there's no player
 360         kh_update_state();
 361
 362         key.pusher = NULL;
 363
 364         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 365         if(ownerteam != ownerteam0)
 366         {
 367                 entity k;
 368                 if(ownerteam != -1)
 369                 {
 370                         kh_interferemsg_time = time + 0.2;
 371                         kh_interferemsg_team = player.team;
 372
 373                         // audit all key carrier sprites, update them to "Run here"
 374                         FOR_EACH_KH_KEY(k)
 375                         {
 376                                 if (!k.owner) continue;
 377                                 entity first = WP_Null;
 378                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 379                                 entity third = WP_Null;
 380                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 381                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 382                         }
 383                 }
 384                 else
 385                 {
 386                         kh_interferemsg_time = 0;
 387
 388                         // audit all key carrier sprites, update them to "Key Carrier"
 389                         FOR_EACH_KH_KEY(k)
 390                         {
 391                                 if (!k.owner) continue;
 392                                 entity first = WP_Null;
 393                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 394                                 entity third = WP_Null;
 395                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 396                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 397                         }
 398                 }
 399         }
 400 }
 401
 402 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 403 {
 404         if(this.owner)
 405                 return;
 406         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 407         {
 408                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 409                 return;
 410         }
 411         if(force == '0 0 0')
 412                 return;
 413         if(time > this.pushltime)
 414                 if(IS_PLAYER(attacker))
 415                         this.team = attacker.team;
 416 }
 417
 418 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 419 {
 420         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 421
 422         if(key.kh_dropperteam != player.team)
 423         {
 424                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 425                 GameRules_scoring_add(player, KH_PICKUPS, 1);
 426         }
 427         key.kh_dropperteam = 0;
 428         int realteam = kh_Team_ByID(key.count);
 429         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 430
 431         kh_Key_AssignTo(key, player); // this also updates .kh_state
 432 }
 433
 434 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 435 {
 436         if(game_stopped)
 437                 return;
 438
 439         if(this.owner) // already carried
 440                 return;
 441
 442         if(ITEM_TOUCH_NEEDKILL())
 443         {
 444                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 445                 return;
 446         }
 447
 448         if (!IS_PLAYER(toucher))
 449                 return;
 450         if(IS_DEAD(toucher))
 451                 return;
 452         if(toucher == this.enemy)
 453                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 454                         return;  // you just dropped it!
 455         kh_Key_Collect(this, toucher);
 456 }
 457
 458 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 459 {
 460         entity o = key.owner;
 461         kh_Key_AssignTo(key, NULL);
 462         if(o) // it was attached
 463                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 464         else // it was dropped
 465                 WaypointSprite_DetachCarrier(key);
 466
 467         // remove key from key list
 468         if (kh_worldkeylist == key)
 469                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 470         else
 471         {
 472                 o = kh_worldkeylist;
 473                 while (o)
 474                 {
 475                         if (o.kh_worldkeynext == key)
 476                         {
 477                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 478                                 break;
 479                         }
 480                         o = o.kh_worldkeynext;
 481                 }
 482         }
 483
 484         delete(key);
 485
 486         kh_update_state();
 487 }
 488
 489 void kh_FinishRound()  // runs when a team captures the keys
 490 {
 491         // prepare next round
 492         kh_interferemsg_time = 0;
 493         entity key;
 494
 495         kh_no_radar_circles = true;
 496         FOR_EACH_KH_KEY(key)
 497                 kh_Key_Remove(key);
 498         kh_no_radar_circles = false;
 499
 500         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 501         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 502 }
 503
 504 void nades_GiveBonus(entity player, float score);
 505
 506 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 507 {
 508         // all key carriers get some points
 509         entity key;
 510         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 511         DistributeEvenly_Init(score, NumTeams(kh_teams));
 512         // twice the score for 3 team games, three times the score for 4 team games!
 513         // note: for a win by destroying the key, this should NOT be applied
 514         FOR_EACH_KH_KEY(key)
 515         {
 516                 float f = DistributeEvenly_Get(1);
 517                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 518                 GameRules_scoring_add_team(key.owner, KH_CAPS, 1);
 519                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 520         }
 521
 522         bool first = true;
 523         string keyowner = "";
 524         FOR_EACH_KH_KEY(key)
 525                 if(key.owner.kh_next == key)
 526                 {
 527                         if(!first)
 528                                 keyowner = strcat(keyowner, ", ");
 529                         keyowner = key.owner.netname;
 530                         first = false;
 531                 }
 532
 533         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 534         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 535
 536         first = true;
 537         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 538         FOR_EACH_KH_KEY(key)
 539         {
 540                 vector thisorigin = kh_AttachedOrigin(key);
 541                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 542                 midpoint += thisorigin;
 543
 544                 if(!first)
 545                         te_lightning2(NULL, lastorigin, thisorigin);
 546                 lastorigin = thisorigin;
 547                 if(first)
 548                         firstorigin = thisorigin;
 549                 first = false;
 550         }
 551         if(NumTeams(kh_teams) > 2)
 552         {
 553                 te_lightning2(NULL, lastorigin, firstorigin);
 554         }
 555         midpoint = midpoint * (1 / NumTeams(kh_teams));
 556         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 557
 558         play2all(SND(KH_CAPTURE));
 559         kh_FinishRound();
 560 }
 561
 562 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 563 {
 564         float f;
 565         entity attacker = NULL;
 566         if(lostkey.pusher)
 567                 if(lostkey.pusher.team != loser_team)
 568                         if(IS_PLAYER(lostkey.pusher))
 569                                 attacker = lostkey.pusher;
 570
 571         if(attacker)
 572         {
 573                 if(lostkey.kh_previous_owner)
 574                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 575                         // don't actually GIVE him the -nn points, just log
 576                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 577                 GameRules_scoring_add(attacker, KH_PUSHES, 1);
 578                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 579         }
 580         else
 581         {
 582                 int players = 0;
 583                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 584
 585                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, { ++players; });
 586
 587                 entity key;
 588                 int keys = 0;
 589                 FOR_EACH_KH_KEY(key)
 590                         if(key.owner && key.team != loser_team)
 591                                 ++keys;
 592
 593                 if(lostkey.kh_previous_owner)
 594                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 595                         // don't actually GIVE him the -nn points, just log
 596
 597                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 598                         GameRules_scoring_add(lostkey.kh_previous_owner, KH_DESTROYS, 1);
 599
 600                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 601
 602                 FOR_EACH_KH_KEY(key)
 603                         if(key.owner && key.team != loser_team)
 604                         {
 605                                 f = DistributeEvenly_Get(of);
 606                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 607                         }
 608
 609                 int fragsleft = DistributeEvenly_Get(players);
 610
 611                 // Now distribute these among all other teams...
 612                 int j = NumTeams(kh_teams) - 1;
 613                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 614                 {
 615                         int thisteam = kh_Team_ByID(i);
 616                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 617                                 continue;
 618
 619                         players = 0;
 620                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, { ++players; });
 621
 622                         DistributeEvenly_Init(fragsleft, j);
 623                         fragsleft = DistributeEvenly_Get(j - 1);
 624                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 625
 626                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, {
 627                                 f = DistributeEvenly_Get(1);
 628                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 629                         });
 630
 631                         --j;
 632                 }
 633         }
 634
 635         int realteam = kh_Team_ByID(lostkey.count);
 636         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 637         if(attacker)
 638                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 639         else
 640                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 641
 642         play2all(SND(KH_DESTROY));
 643         te_tarexplosion(lostkey.origin);
 644
 645         kh_FinishRound();
 646 }
 647
 648 void kh_Key_Think(entity this)  // runs all the time
 649 {
 650         if(game_stopped)
 651                 return;
 652
 653         if(this.owner)
 654         {
 655 #ifndef KH_PLAYER_USE_ATTACHMENT
 656                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 657                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 658 #endif
 659         }
 660
 661         // if in nodrop or time over, end the round
 662         if(!this.owner)
 663                 if(time > this.pain_finished)
 664                         kh_LoserTeam(this.team, this);
 665
 666         if(this.owner)
 667         if(kh_Key_AllOwnedByWhichTeam() != -1)
 668         {
 669                 if(this.siren_time < time)
 670                 {
 671                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 672                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 673                 }
 674
 675                 entity key;
 676                 vector p = this.owner.origin;
 677                 FOR_EACH_KH_KEY(key)
 678                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 679                                 goto not_winning;
 680                 kh_WinnerTeam(this.team);
 681 LABEL(not_winning)
 682         }
 683
 684         if(kh_interferemsg_time && time > kh_interferemsg_time)
 685         {
 686                 kh_interferemsg_time = 0;
 687                 FOREACH_CLIENT(IS_PLAYER(it), {
 688                         if(it.team == kh_interferemsg_team)
 689                         {
 690                                 if(it.kh_next)
 691                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 692                                 else
 693                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 694                         }
 695                         else
 696                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 697                 });
 698         }
 699
 700         this.nextthink = time + 0.05;
 701 }
 702
 703 void key_reset(entity this)
 704 {
 705         kh_Key_AssignTo(this, NULL);
 706         kh_Key_Remove(this);
 707 }
 708
 709 const string STR_ITEM_KH_KEY = "item_kh_key";
 710 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 711 {
 712         entity key = spawn();
 713         key.count = i;
 714         key.classname = STR_ITEM_KH_KEY;
 715         settouch(key, kh_Key_Touch);
 716         setthink(key, kh_Key_Think);
 717         key.nextthink = time;
 718         key.items = IT_KEY1 | IT_KEY2;
 719         key.cnt = _angle;
 720         key.angles = '0 360 0' * random();
 721         key.event_damage = kh_Key_Damage;
 722         key.takedamage = DAMAGE_YES;
 723         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 724         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 725         key.modelindex = kh_key_dropped;
 726         key.model = "key";
 727         key.kh_dropperteam = 0;
 728         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 729         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 730         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 731         key.reset = key_reset;
 732         navigation_dynamicgoal_init(key, false);
 733
 734         switch(initial_owner.team)
 735         {
 736                 case NUM_TEAM_1:
 737                         key.netname = "^1red key";
 738                         break;
 739                 case NUM_TEAM_2:
 740                         key.netname = "^4blue key";
 741                         break;
 742                 case NUM_TEAM_3:
 743                         key.netname = "^3yellow key";
 744                         break;
 745                 case NUM_TEAM_4:
 746                         key.netname = "^6pink key";
 747                         break;
 748                 default:
 749                         key.netname = "NETGIER key";
 750                         break;
 751         }
 752
 753         // link into key list
 754         key.kh_worldkeynext = kh_worldkeylist;
 755         kh_worldkeylist = key;
 756
 757         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 758
 759         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 760         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 761
 762         kh_Key_AssignTo(key, initial_owner);
 763 }
 764
 765 // -1 when no team completely owns all keys yet
 766 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 767 {
 768         entity key;
 769         int teem = -1;
 770         int keys = NumTeams(kh_teams);
 771         FOR_EACH_KH_KEY(key)
 772         {
 773                 if(!key.owner)
 774                         return -1;
 775                 if(teem == -1)
 776                         teem = key.team;
 777                 else if(teem != key.team)
 778                         return -1;
 779                 --keys;
 780         }
 781         if(keys != 0)
 782                 return -1;
 783         return teem;
 784 }
 785
 786 void kh_Key_DropOne(entity key)
 787 {
 788         // prevent collecting this one for some time
 789         entity player = key.owner;
 790
 791         key.kh_droptime = time;
 792         key.enemy = player;
 793
 794         kh_Scores_Event(player, key, "dropkey", 0, 0);
 795         GameRules_scoring_add(player, KH_LOSSES, 1);
 796         int realteam = kh_Team_ByID(key.count);
 797         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 798
 799         kh_Key_AssignTo(key, NULL);
 800         makevectors(player.v_angle);
 801         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 802         key.pusher = NULL;
 803         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 804         key.kh_dropperteam = key.team;
 805
 806         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 807 }
 808
 809 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 810 {
 811         if(player.kh_next)
 812         {
 813                 entity mypusher = NULL;
 814                 if(player.pusher)
 815                         if(time < player.pushltime)
 816                                 mypusher = player.pusher;
 817
 818                 entity key;
 819                 while((key = player.kh_next))
 820                 {
 821                         kh_Scores_Event(player, key, "losekey", 0, 0);
 822                         GameRules_scoring_add(player, KH_LOSSES, 1);
 823                         int realteam = kh_Team_ByID(key.count);
 824                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 825                         kh_Key_AssignTo(key, NULL);
 826                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 827                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 828                         key.pusher = mypusher;
 829                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 830                         if(suicide)
 831                                 key.kh_dropperteam = player.team;
 832                 }
 833                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 834         }
 835 }
 836
 837 int kh_GetMissingTeams()
 838 {
 839         int missing_teams = 0;
 840         for(int i = 0; i < NumTeams(kh_teams); ++i)
 841         {
 842                 int teem = kh_Team_ByID(i);
 843                 int players = 0;
 844                 FOREACH_CLIENT(IS_PLAYER(it), {
 845                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 846                                 ++players;
 847                 });
 848                 if (!players)
 849                         missing_teams |= (2 ** i);
 850         }
 851         return missing_teams;
 852 }
 853
 854 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 855 {
 856         static int prev_missing_teams_mask;
 857         if(time < game_starttime)
 858         {
 859                 if (prev_missing_teams_mask > 0)
 860                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 861                 prev_missing_teams_mask = -1;
 862                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 863                 return;
 864         }
 865
 866         int missing_teams_mask = kh_GetMissingTeams();
 867         if(!missing_teams_mask)
 868         {
 869                 if(prev_missing_teams_mask > 0)
 870                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 871                 prev_missing_teams_mask = -1;
 872                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 873                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 874         }
 875         else
 876         {
 877                 if(player_count == 0)
 878                 {
 879                         if(prev_missing_teams_mask > 0)
 880                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 881                         prev_missing_teams_mask = -1;
 882                 }
 883                 else
 884                 {
 885                         if(prev_missing_teams_mask != missing_teams_mask)
 886                         {
 887                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 888                                 prev_missing_teams_mask = missing_teams_mask;
 889                         }
 890                 }
 891                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 892         }
 893 }
 894
 895 void kh_EnableTrackingDevice()  // runs after each round
 896 {
 897         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 898         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 899
 900         kh_tracking_enabled = true;
 901 }
 902
 903 void kh_StartRound()  // runs at the start of each round
 904 {
 905         if(time < game_starttime)
 906         {
 907                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 908                 return;
 909         }
 910
 911         if(kh_GetMissingTeams())
 912         {
 913                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 914                 return;
 915         }
 916
 917         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 918         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 919
 920         for(int i = 0; i < NumTeams(kh_teams); ++i)
 921         {
 922                 int teem = kh_Team_ByID(i);
 923                 int players = 0;
 924                 entity my_player = NULL;
 925                 FOREACH_CLIENT(IS_PLAYER(it), {
 926                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 927                         {
 928                                 ++players;
 929                                 if(random() * players <= 1)
 930                                         my_player = it;
 931                         }
 932                 });
 933                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 934         }
 935
 936         kh_tracking_enabled = false;
 937         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 938         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 939 }
 940
 941 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 942 {
 943         if(attacker == targ)
 944                 return f;
 945
 946         if(targ.kh_next)
 947         {
 948                 if(attacker.team == targ.team)
 949                 {
 950                         int nk = 0;
 951                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 952                                 ++nk;
 953                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 954                 }
 955                 else
 956                 {
 957                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 958                         GameRules_scoring_add(attacker, KH_KCKILLS, 1);
 959                         // the frag gets added later
 960                 }
 961         }
 962
 963         return f;
 964 }
 965
 966 void kh_Initialize()  // sets up th KH environment
 967 {
 968         // setup variables
 969         kh_teams = autocvar_g_keyhunt_teams_override;
 970         if(kh_teams < 2)
 971                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 972         kh_teams = BITS(bound(2, kh_teams, 4));
 973
 974         // make a KH entity for controlling the game
 975         kh_controller = spawn();
 976         setthink(kh_controller, kh_Controller_Think);
 977         kh_Controller_SetThink(0, kh_WaitForPlayers);
 978
 979         setmodel(kh_controller, MDL_KH_KEY);
 980         kh_key_dropped = kh_controller.modelindex;
 981         /*
 982         dprint(vtos(kh_controller.mins));
 983         dprint(vtos(kh_controller.maxs));
 984         dprint("\n");
 985         */
 986 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 987         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
 988         kh_key_carried = kh_controller.modelindex;
 989 #else
 990         kh_key_carried = kh_key_dropped;
 991 #endif
 992
 993         kh_controller.model = "";
 994         kh_controller.modelindex = 0;
 995
 996         kh_ScoreRules(kh_teams);
 997 }
 998
 999 void kh_finalize()
1000 {
1001         // to be called before intermission
1002         kh_FinishRound();
1003         delete(kh_controller);
1004         kh_controller = NULL;
1005 }
1006
1007 // legacy bot role
1008
1009 void(entity this) havocbot_role_kh_carrier;
1010 void(entity this) havocbot_role_kh_defense;
1011 void(entity this) havocbot_role_kh_offense;
1012 void(entity this) havocbot_role_kh_freelancer;
1013
1014
1015 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1016 {
1017         entity head;
1018         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1019         {
1020                 if(head.owner == this)
1021                         continue;
1022                 if(!kh_tracking_enabled)
1023                 {
1024                         // if it's carried by our team we know about it
1025                         // otherwise we have to see it to know about it
1026                         if(!head.owner || head.team != this.team)
1027                         {
1028                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1029                                 if (trace_fraction < 1 && trace_ent != head)
1030                                         continue; // skip what I can't see
1031                         }
1032                 }
1033                 if(!head.owner)
1034                         navigation_routerating(this, head, ratingscale_dropped * 10000, 100000);
1035                 else if(head.team == this.team)
1036                         navigation_routerating(this, head.owner, ratingscale_team * 10000, 100000);
1037                 else
1038                         navigation_routerating(this, head.owner, ratingscale_enemy * 10000, 100000);
1039         }
1040
1041         havocbot_goalrating_items(this, 1, this.origin, 10000);
1042 }
1043
1044 void havocbot_role_kh_carrier(entity this)
1045 {
1046         if(IS_DEAD(this))
1047                 return;
1048
1049         if (!(this.kh_next))
1050         {
1051                 LOG_TRACE("changing role to freelancer");
1052                 this.havocbot_role = havocbot_role_kh_freelancer;
1053                 this.havocbot_role_timeout = 0;
1054                 return;
1055         }
1056
1057         if (navigation_goalrating_timeout(this))
1058         {
1059                 navigation_goalrating_start(this);
1060
1061                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1062                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // bring home
1063                 else
1064                         havocbot_goalrating_kh(this, 4, 4, 0.5); // play defensively
1065
1066                 navigation_goalrating_end(this);
1067
1068                 navigation_goalrating_timeout_set(this);
1069         }
1070 }
1071
1072 void havocbot_role_kh_defense(entity this)
1073 {
1074         if(IS_DEAD(this))
1075                 return;
1076
1077         if (this.kh_next)
1078         {
1079                 LOG_TRACE("changing role to carrier");
1080                 this.havocbot_role = havocbot_role_kh_carrier;
1081                 this.havocbot_role_timeout = 0;
1082                 return;
1083         }
1084
1085         if (!this.havocbot_role_timeout)
1086                 this.havocbot_role_timeout = time + random() * 10 + 20;
1087         if (time > this.havocbot_role_timeout)
1088         {
1089                 LOG_TRACE("changing role to freelancer");
1090                 this.havocbot_role = havocbot_role_kh_freelancer;
1091                 this.havocbot_role_timeout = 0;
1092                 return;
1093         }
1094
1095         if (navigation_goalrating_timeout(this))
1096         {
1097                 float key_owner_team;
1098                 navigation_goalrating_start(this);
1099
1100                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1101                 if(key_owner_team == this.team)
1102                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend key carriers
1103                 else if(key_owner_team == -1)
1104                         havocbot_goalrating_kh(this, 4, 1, 0.05); // play defensively
1105                 else
1106                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1107
1108                 navigation_goalrating_end(this);
1109
1110                 navigation_goalrating_timeout_set(this);
1111         }
1112 }
1113
1114 void havocbot_role_kh_offense(entity this)
1115 {
1116         if(IS_DEAD(this))
1117                 return;
1118
1119         if (this.kh_next)
1120         {
1121                 LOG_TRACE("changing role to carrier");
1122                 this.havocbot_role = havocbot_role_kh_carrier;
1123                 this.havocbot_role_timeout = 0;
1124                 return;
1125         }
1126
1127         if (!this.havocbot_role_timeout)
1128                 this.havocbot_role_timeout = time + random() * 10 + 20;
1129         if (time > this.havocbot_role_timeout)
1130         {
1131                 LOG_TRACE("changing role to freelancer");
1132                 this.havocbot_role = havocbot_role_kh_freelancer;
1133                 this.havocbot_role_timeout = 0;
1134                 return;
1135         }
1136
1137         if (navigation_goalrating_timeout(this))
1138         {
1139                 float key_owner_team;
1140
1141                 navigation_goalrating_start(this);
1142
1143                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1144                 if(key_owner_team == this.team)
1145                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1146                 else if(key_owner_team == -1)
1147                         havocbot_goalrating_kh(this, 0.1, 1, 2); // play offensively
1148                 else
1149                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK! EMERGENCY!
1150
1151                 navigation_goalrating_end(this);
1152
1153                 navigation_goalrating_timeout_set(this);
1154         }
1155 }
1156
1157 void havocbot_role_kh_freelancer(entity this)
1158 {
1159         if(IS_DEAD(this))
1160                 return;
1161
1162         if (this.kh_next)
1163         {
1164                 LOG_TRACE("changing role to carrier");
1165                 this.havocbot_role = havocbot_role_kh_carrier;
1166                 this.havocbot_role_timeout = 0;
1167                 return;
1168         }
1169
1170         if (!this.havocbot_role_timeout)
1171                 this.havocbot_role_timeout = time + random() * 10 + 10;
1172         if (time > this.havocbot_role_timeout)
1173         {
1174                 if (random() < 0.5)
1175                 {
1176                         LOG_TRACE("changing role to offense");
1177                         this.havocbot_role = havocbot_role_kh_offense;
1178                 }
1179                 else
1180                 {
1181                         LOG_TRACE("changing role to defense");
1182                         this.havocbot_role = havocbot_role_kh_defense;
1183                 }
1184                 this.havocbot_role_timeout = 0;
1185                 return;
1186         }
1187
1188         if (navigation_goalrating_timeout(this))
1189         {
1190                 navigation_goalrating_start(this);
1191
1192                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1193                 if(key_owner_team == this.team)
1194                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1195                 else if(key_owner_team == -1)
1196                         havocbot_goalrating_kh(this, 1, 10, 2); // prefer dropped keys
1197                 else
1198                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1199
1200                 navigation_goalrating_end(this);
1201
1202                 navigation_goalrating_timeout_set(this);
1203         }
1204 }
1205
1206
1207 // register this as a mutator
1208
1209 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1210 {
1211         entity player = M_ARGV(0, entity);
1212
1213         kh_Key_DropAll(player, true);
1214 }
1215
1216 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1217 {
1218         entity player = M_ARGV(0, entity);
1219
1220         kh_Key_DropAll(player, true);
1221 }
1222
1223 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1224 {
1225         entity frag_attacker = M_ARGV(1, entity);
1226         entity frag_target = M_ARGV(2, entity);
1227
1228         if(frag_target == frag_attacker)
1229                 kh_Key_DropAll(frag_target, true);
1230         else if(IS_PLAYER(frag_attacker))
1231                 kh_Key_DropAll(frag_target, false);
1232         else
1233                 kh_Key_DropAll(frag_target, true);
1234 }
1235
1236 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1237 {
1238         entity frag_attacker = M_ARGV(0, entity);
1239         entity frag_target = M_ARGV(1, entity);
1240         float frag_score = M_ARGV(2, float);
1241         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1242 }
1243
1244 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1245 {
1246         kh_finalize();
1247 }
1248
1249 MUTATOR_HOOKFUNCTION(kh, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1250 {
1251         M_ARGV(0, float) = kh_teams;
1252         return true;
1253 }
1254
1255 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1256 {
1257         entity spectatee = M_ARGV(0, entity);
1258         entity client = M_ARGV(1, entity);
1259
1260         STAT(KH_KEYS, client) = STAT(KH_KEYS, spectatee);
1261 }
1262
1263 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1264 {
1265         entity player = M_ARGV(0, entity);
1266
1267         if(MUTATOR_RETURNVALUE == 0)
1268         {
1269                 entity k = player.kh_next;
1270                 if(k)
1271                 {
1272                         kh_Key_DropOne(k);
1273                         return true;
1274                 }
1275         }
1276 }
1277
1278 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1279 {
1280     entity bot = M_ARGV(0, entity);
1281
1282         if(IS_DEAD(bot))
1283                 return true;
1284
1285         float r = random() * 3;
1286         if (r < 1)
1287                 bot.havocbot_role = havocbot_role_kh_offense;
1288         else if (r < 2)
1289                 bot.havocbot_role = havocbot_role_kh_defense;
1290         else
1291                 bot.havocbot_role = havocbot_role_kh_freelancer;
1292
1293         return true;
1294 }
1295
1296 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1297 {
1298         entity frag_target = M_ARGV(0, entity);
1299
1300         kh_Key_DropAll(frag_target, false);
1301 }
1302
1303 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1304 {
1305         kh_WaitForPlayers(); // takes care of killing the "missing teams" message
1306 }