qcsrc/common/gamemodes/gamemode/keyhunt/sv_keyhunt.qc

   1 #include "sv_keyhunt.qh"
   2
   3 float autocvar_g_balance_keyhunt_damageforcescale;
   4 float autocvar_g_balance_keyhunt_delay_collect;
   5 float autocvar_g_balance_keyhunt_delay_damage_return;
   6 float autocvar_g_balance_keyhunt_delay_return;
   7 float autocvar_g_balance_keyhunt_delay_round;
   8 float autocvar_g_balance_keyhunt_delay_tracking;
   9 float autocvar_g_balance_keyhunt_return_when_unreachable;
  10 float autocvar_g_balance_keyhunt_dropvelocity;
  11 float autocvar_g_balance_keyhunt_maxdist;
  12 float autocvar_g_balance_keyhunt_protecttime;
  13
  14 int autocvar_g_balance_keyhunt_score_capture;
  15 int autocvar_g_balance_keyhunt_score_carrierfrag;
  16 int autocvar_g_balance_keyhunt_score_collect;
  17 int autocvar_g_balance_keyhunt_score_destroyed;
  18 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  19 int autocvar_g_balance_keyhunt_score_push;
  20 float autocvar_g_balance_keyhunt_throwvelocity;
  21
  22 //int autocvar_g_keyhunt_teams;
  23 int autocvar_g_keyhunt_teams_override;
  24
  25 // #define KH_PLAYER_USE_ATTACHMENT
  26 // TODO? no model exists for this
  27 // #define KH_PLAYER_USE_CARRIEDMODEL
  28
  29 #ifdef KH_PLAYER_USE_ATTACHMENT
  30 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  31 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  32 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  33 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  34 const string KH_PLAYER_ATTACHMENT_BONE = "";
  35 #else
  36 const float KH_KEY_ZSHIFT = 22;
  37 const float KH_KEY_XYDIST = 24;
  38 const float KH_KEY_XYSPEED = 45;
  39 #endif
  40 const float KH_KEY_WP_ZSHIFT = 20;
  41
  42 const vector KH_KEY_MIN = '-10 -10 -46';
  43 const vector KH_KEY_MAX = '10 10 3';
  44 const float KH_KEY_BRIGHTNESS = 2;
  45
  46 bool kh_no_radar_circles;
  47
  48 // kh_state
  49 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  50 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  51 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  52 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  53 .float siren_time;  //  time delay the siren
  54 //.float stuff_time;  //  time delay to stuffcmd a cvar
  55
  56 int kh_Team_ByID(int t)
  57 {
  58         if(t == 0) return NUM_TEAM_1;
  59         if(t == 1) return NUM_TEAM_2;
  60         if(t == 2) return NUM_TEAM_3;
  61         if(t == 3) return NUM_TEAM_4;
  62         return 0;
  63 }
  64
  65 entity kh_controller;
  66 //bool kh_tracking_enabled;
  67 int kh_teams;
  68 int kh_interferemsg_team;
  69 float kh_interferemsg_time;
  70 .entity kh_next, kh_prev; // linked list
  71 .float kh_droptime;
  72 .int kh_dropperteam;
  73 .entity kh_previous_owner;
  74 .int kh_previous_owner_playerid;
  75
  76 int kh_key_dropped, kh_key_carried;
  77
  78 int kh_Key_AllOwnedByWhichTeam();
  79
  80 const int ST_KH_CAPS = 1;
  81 void kh_ScoreRules(int teams)
  82 {
  83         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
  84         field_team(ST_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  85         field(SP_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  86         field(SP_KH_PUSHES, "pushes", 0);
  87         field(SP_KH_DESTROYS, "destroyed", SFL_LOWER_IS_BETTER);
  88         field(SP_KH_PICKUPS, "pickups", 0);
  89         field(SP_KH_KCKILLS, "kckills", 0);
  90         field(SP_KH_LOSSES, "losses", SFL_LOWER_IS_BETTER);
  91         });
  92 }
  93
  94 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
  95 {
  96         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
  97                 if(!kh_tracking_enabled)
  98                         return false;
  99
 100         return true;
 101 }
 102
 103 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 104 {
 105         if(!kh_tracking_enabled)
 106                 return false;
 107         if(!this.owner)
 108                 return true;
 109         if(!this.owner.owner)
 110                 return true;
 111         return false;  // draw only when key is not owned
 112 }
 113
 114 void kh_update_state()
 115 {
 116         entity key;
 117         int f;
 118         int s = 0;
 119         FOR_EACH_KH_KEY(key)
 120         {
 121                 if(key.owner)
 122                         f = key.team;
 123                 else
 124                         f = 30;
 125                 s |= (32 ** key.count) * f;
 126         }
 127
 128         FOREACH_CLIENT(true, { STAT(KH_KEYS, it) = s; });
 129
 130         FOR_EACH_KH_KEY(key)
 131         {
 132                 if(key.owner)
 133                         STAT(KH_KEYS, key.owner) |= (32 ** key.count) * 31;
 134         }
 135         //print(ftos((nextent(NULL)).kh_state), "\n");
 136 }
 137
 138
 139
 140
 141 var kh_Think_t kh_Controller_Thinkfunc;
 142 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 143 {
 144         kh_Controller_Thinkfunc = func;
 145         kh_controller.cnt = ceil(t);
 146         if(t == 0)
 147                 kh_controller.nextthink = time; // force
 148 }
 149 void kh_WaitForPlayers();
 150 void kh_Controller_Think(entity this)  // called a lot
 151 {
 152         if(game_stopped)
 153                 return;
 154         if(this.cnt > 0)
 155         {
 156                 if(getthink(this) != kh_WaitForPlayers)
 157                         this.cnt -= 1;
 158         }
 159         else if(this.cnt == 0)
 160         {
 161                 this.cnt -= 1;
 162                 kh_Controller_Thinkfunc();
 163         }
 164         this.nextthink = time + 1;
 165 }
 166
 167 // frags f: take from cvar * f
 168 // frags 0: no frags
 169 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 170 {
 171         string s;
 172         if(game_stopped)
 173                 return;
 174
 175         if(frags_player)
 176                 UpdateFrags(player, frags_player);
 177
 178         if(key && key.owner && frags_owner)
 179                 UpdateFrags(key.owner, frags_owner);
 180
 181         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 182                 return;
 183
 184         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 185
 186         if(key && key.owner)
 187                 s = strcat(s, ":", ftos(key.owner.playerid));
 188         else
 189                 s = strcat(s, ":0");
 190
 191         s = strcat(s, ":", ftos(frags_owner), ":");
 192
 193         if(key)
 194                 s = strcat(s, key.netname);
 195
 196         GameLogEcho(s);
 197 }
 198
 199 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 200 {
 201         if(e.tag_entity)
 202         {
 203                 makevectors(e.tag_entity.angles);
 204                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 205         }
 206         else
 207                 return e.origin;
 208 }
 209
 210 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 211 {
 212 #ifdef KH_PLAYER_USE_ATTACHMENT
 213         entity first = key.owner.kh_next;
 214         if(key == first)
 215         {
 216                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 217                 if(key.kh_next)
 218                 {
 219                         setattachment(key.kh_next, key, "");
 220                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 221                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 222                         key.kh_next.angles = '0 0 0';
 223                 }
 224                 else
 225                         setorigin(key, KH_PLAYER_ATTACHMENT);
 226                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 227         }
 228         else
 229         {
 230                 setattachment(key, key.kh_prev, "");
 231                 if(key.kh_next)
 232                         setattachment(key.kh_next, key, "");
 233                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 234                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 235                 key.angles = '0 0 0';
 236         }
 237 #else
 238         setattachment(key, key.owner, "");
 239         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 240         key.angles_y -= key.owner.angles.y;
 241 #endif
 242         key.flags = 0;
 243         if(IL_CONTAINS(g_items, key))
 244                 IL_REMOVE(g_items, key);
 245         key.solid = SOLID_NOT;
 246         set_movetype(key, MOVETYPE_NONE);
 247         key.team = key.owner.team;
 248         key.nextthink = time;
 249         key.damageforcescale = 0;
 250         key.takedamage = DAMAGE_NO;
 251         key.modelindex = kh_key_carried;
 252         navigation_dynamicgoal_unset(key);
 253 }
 254
 255 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 256 {
 257 #ifdef KH_PLAYER_USE_ATTACHMENT
 258         entity first = key.owner.kh_next;
 259         if(key == first)
 260         {
 261                 if(key.kh_next)
 262                 {
 263                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 264                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 265                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 266                 }
 267         }
 268         else
 269         {
 270                 if(key.kh_next)
 271                         setattachment(key.kh_next, key.kh_prev, "");
 272                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 273         }
 274         // in any case:
 275         setattachment(key, NULL, "");
 276         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, key.owner).z - KH_KEY_MIN_z));
 277         key.angles = key.owner.angles;
 278 #else
 279         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 280         setattachment(key, NULL, "");
 281         key.angles_y += key.owner.angles.y;
 282 #endif
 283         key.flags = FL_ITEM;
 284         if(!IL_CONTAINS(g_items, key))
 285                 IL_PUSH(g_items, key);
 286         key.solid = SOLID_TRIGGER;
 287         set_movetype(key, MOVETYPE_TOSS);
 288         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 289         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 290         key.takedamage = DAMAGE_YES;
 291         // let key.team stay
 292         key.modelindex = kh_key_dropped;
 293         navigation_dynamicgoal_set(key, key.owner);
 294         key.kh_previous_owner = key.owner;
 295         key.kh_previous_owner_playerid = key.owner.playerid;
 296 }
 297
 298 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 299 {
 300         if(key.owner == player)
 301                 return;
 302
 303         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 304
 305         if(key.owner)
 306         {
 307                 kh_Key_Detach(key);
 308
 309                 // remove from linked list
 310                 if(key.kh_next)
 311                         key.kh_next.kh_prev = key.kh_prev;
 312                 key.kh_prev.kh_next = key.kh_next;
 313                 key.kh_next = NULL;
 314                 key.kh_prev = NULL;
 315
 316                 if(key.owner.kh_next == NULL)
 317                 {
 318                         // No longer a key carrier
 319                         if(!kh_no_radar_circles)
 320                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 321                         WaypointSprite_DetachCarrier(key.owner);
 322                 }
 323         }
 324
 325         key.owner = player;
 326
 327         if(player)
 328         {
 329                 // insert into linked list
 330                 key.kh_next = player.kh_next;
 331                 key.kh_prev = player;
 332                 player.kh_next = key;
 333                 if(key.kh_next)
 334                         key.kh_next.kh_prev = key;
 335
 336                 kh_Key_Attach(key);
 337
 338                 if(key.kh_next == NULL)
 339                 {
 340                         // player is now a key carrier
 341                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 342                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 343                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 344                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 345                         if(player.team == NUM_TEAM_1)
 346                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 347                         else if(player.team == NUM_TEAM_2)
 348                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 349                         else if(player.team == NUM_TEAM_3)
 350                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 351                         else if(player.team == NUM_TEAM_4)
 352                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 353                         if(!kh_no_radar_circles)
 354                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 355                 }
 356         }
 357
 358         // moved that here, also update if there's no player
 359         kh_update_state();
 360
 361         key.pusher = NULL;
 362
 363         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 364         if(ownerteam != ownerteam0)
 365         {
 366                 entity k;
 367                 if(ownerteam != -1)
 368                 {
 369                         kh_interferemsg_time = time + 0.2;
 370                         kh_interferemsg_team = player.team;
 371
 372                         // audit all key carrier sprites, update them to "Run here"
 373                         FOR_EACH_KH_KEY(k)
 374                         {
 375                                 if (!k.owner) continue;
 376                                 entity first = WP_Null;
 377                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 378                                 entity third = WP_Null;
 379                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 380                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 381                         }
 382                 }
 383                 else
 384                 {
 385                         kh_interferemsg_time = 0;
 386
 387                         // audit all key carrier sprites, update them to "Key Carrier"
 388                         FOR_EACH_KH_KEY(k)
 389                         {
 390                                 if (!k.owner) continue;
 391                                 entity first = WP_Null;
 392                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 393                                 entity third = WP_Null;
 394                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 395                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 396                         }
 397                 }
 398         }
 399 }
 400
 401 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 402 {
 403         if(this.owner)
 404                 return;
 405         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 406         {
 407                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 408                 return;
 409         }
 410         if(force == '0 0 0')
 411                 return;
 412         if(time > this.pushltime)
 413                 if(IS_PLAYER(attacker))
 414                         this.team = attacker.team;
 415 }
 416
 417 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 418 {
 419         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 420
 421         if(key.kh_dropperteam != player.team)
 422         {
 423                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 424                 GameRules_scoring_add(player, KH_PICKUPS, 1);
 425         }
 426         key.kh_dropperteam = 0;
 427         int realteam = kh_Team_ByID(key.count);
 428         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 429
 430         kh_Key_AssignTo(key, player); // this also updates .kh_state
 431 }
 432
 433 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 434 {
 435         if(game_stopped)
 436                 return;
 437
 438         if(this.owner) // already carried
 439                 return;
 440
 441         if(ITEM_TOUCH_NEEDKILL())
 442         {
 443                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 444                 return;
 445         }
 446
 447         if (!IS_PLAYER(toucher))
 448                 return;
 449         if(IS_DEAD(toucher))
 450                 return;
 451         if(toucher == this.enemy)
 452                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 453                         return;  // you just dropped it!
 454         kh_Key_Collect(this, toucher);
 455 }
 456
 457 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 458 {
 459         entity o = key.owner;
 460         kh_Key_AssignTo(key, NULL);
 461         if(o) // it was attached
 462                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 463         else // it was dropped
 464                 WaypointSprite_DetachCarrier(key);
 465
 466         // remove key from key list
 467         if (kh_worldkeylist == key)
 468                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 469         else
 470         {
 471                 o = kh_worldkeylist;
 472                 while (o)
 473                 {
 474                         if (o.kh_worldkeynext == key)
 475                         {
 476                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 477                                 break;
 478                         }
 479                         o = o.kh_worldkeynext;
 480                 }
 481         }
 482
 483         delete(key);
 484
 485         kh_update_state();
 486 }
 487
 488 void kh_FinishRound()  // runs when a team captures the keys
 489 {
 490         // prepare next round
 491         kh_interferemsg_time = 0;
 492         entity key;
 493
 494         kh_no_radar_circles = true;
 495         FOR_EACH_KH_KEY(key)
 496                 kh_Key_Remove(key);
 497         kh_no_radar_circles = false;
 498
 499         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 500         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 501 }
 502
 503 void nades_GiveBonus(entity player, float score);
 504
 505 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 506 {
 507         // all key carriers get some points
 508         entity key;
 509         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 510         DistributeEvenly_Init(score, NumTeams(kh_teams));
 511         // twice the score for 3 team games, three times the score for 4 team games!
 512         // note: for a win by destroying the key, this should NOT be applied
 513         FOR_EACH_KH_KEY(key)
 514         {
 515                 float f = DistributeEvenly_Get(1);
 516                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 517                 GameRules_scoring_add_team(key.owner, KH_CAPS, 1);
 518                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 519         }
 520
 521         bool first = true;
 522         string keyowner = "";
 523         FOR_EACH_KH_KEY(key)
 524                 if(key.owner.kh_next == key)
 525                 {
 526                         if(!first)
 527                                 keyowner = strcat(keyowner, ", ");
 528                         keyowner = key.owner.netname;
 529                         first = false;
 530                 }
 531
 532         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 533         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 534
 535         first = true;
 536         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 537         FOR_EACH_KH_KEY(key)
 538         {
 539                 vector thisorigin = kh_AttachedOrigin(key);
 540                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 541                 midpoint += thisorigin;
 542
 543                 if(!first)
 544                         te_lightning2(NULL, lastorigin, thisorigin);
 545                 lastorigin = thisorigin;
 546                 if(first)
 547                         firstorigin = thisorigin;
 548                 first = false;
 549         }
 550         if(NumTeams(kh_teams) > 2)
 551         {
 552                 te_lightning2(NULL, lastorigin, firstorigin);
 553         }
 554         midpoint = midpoint * (1 / NumTeams(kh_teams));
 555         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 556
 557         play2all(SND(KH_CAPTURE));
 558         kh_FinishRound();
 559 }
 560
 561 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 562 {
 563         float f;
 564         entity attacker = NULL;
 565         if(lostkey.pusher)
 566                 if(lostkey.pusher.team != loser_team)
 567                         if(IS_PLAYER(lostkey.pusher))
 568                                 attacker = lostkey.pusher;
 569
 570         if(attacker)
 571         {
 572                 if(lostkey.kh_previous_owner)
 573                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 574                         // don't actually GIVE him the -nn points, just log
 575                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 576                 GameRules_scoring_add(attacker, KH_PUSHES, 1);
 577                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 578         }
 579         else
 580         {
 581                 int players = 0;
 582                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 583
 584                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, { ++players; });
 585
 586                 entity key;
 587                 int keys = 0;
 588                 FOR_EACH_KH_KEY(key)
 589                         if(key.owner && key.team != loser_team)
 590                                 ++keys;
 591
 592                 if(lostkey.kh_previous_owner)
 593                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 594                         // don't actually GIVE him the -nn points, just log
 595
 596                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 597                         GameRules_scoring_add(lostkey.kh_previous_owner, KH_DESTROYS, 1);
 598
 599                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 600
 601                 FOR_EACH_KH_KEY(key)
 602                         if(key.owner && key.team != loser_team)
 603                         {
 604                                 f = DistributeEvenly_Get(of);
 605                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 606                         }
 607
 608                 int fragsleft = DistributeEvenly_Get(players);
 609
 610                 // Now distribute these among all other teams...
 611                 int j = NumTeams(kh_teams) - 1;
 612                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 613                 {
 614                         int thisteam = kh_Team_ByID(i);
 615                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 616                                 continue;
 617
 618                         players = 0;
 619                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, { ++players; });
 620
 621                         DistributeEvenly_Init(fragsleft, j);
 622                         fragsleft = DistributeEvenly_Get(j - 1);
 623                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 624
 625                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, {
 626                                 f = DistributeEvenly_Get(1);
 627                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 628                         });
 629
 630                         --j;
 631                 }
 632         }
 633
 634         int realteam = kh_Team_ByID(lostkey.count);
 635         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 636         if(attacker)
 637                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 638         else
 639                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 640
 641         play2all(SND(KH_DESTROY));
 642         te_tarexplosion(lostkey.origin);
 643
 644         kh_FinishRound();
 645 }
 646
 647 void kh_Key_Think(entity this)  // runs all the time
 648 {
 649         if(game_stopped)
 650                 return;
 651
 652         if(this.owner)
 653         {
 654 #ifndef KH_PLAYER_USE_ATTACHMENT
 655                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 656                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 657 #endif
 658         }
 659
 660         // if in nodrop or time over, end the round
 661         if(!this.owner)
 662                 if(time > this.pain_finished)
 663                         kh_LoserTeam(this.team, this);
 664
 665         if(this.owner)
 666         if(kh_Key_AllOwnedByWhichTeam() != -1)
 667         {
 668                 if(this.siren_time < time)
 669                 {
 670                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 671                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 672                 }
 673
 674                 entity key;
 675                 vector p = this.owner.origin;
 676                 FOR_EACH_KH_KEY(key)
 677                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 678                                 goto not_winning;
 679                 kh_WinnerTeam(this.team);
 680 LABEL(not_winning)
 681         }
 682
 683         if(kh_interferemsg_time && time > kh_interferemsg_time)
 684         {
 685                 kh_interferemsg_time = 0;
 686                 FOREACH_CLIENT(IS_PLAYER(it), {
 687                         if(it.team == kh_interferemsg_team)
 688                         {
 689                                 if(it.kh_next)
 690                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 691                                 else
 692                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 693                         }
 694                         else
 695                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 696                 });
 697         }
 698
 699         this.nextthink = time + 0.05;
 700 }
 701
 702 void key_reset(entity this)
 703 {
 704         kh_Key_AssignTo(this, NULL);
 705         kh_Key_Remove(this);
 706 }
 707
 708 const string STR_ITEM_KH_KEY = "item_kh_key";
 709 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 710 {
 711         entity key = spawn();
 712         key.count = i;
 713         key.classname = STR_ITEM_KH_KEY;
 714         settouch(key, kh_Key_Touch);
 715         setthink(key, kh_Key_Think);
 716         key.nextthink = time;
 717         key.items = IT_KEY1 | IT_KEY2;
 718         key.cnt = _angle;
 719         key.angles = '0 360 0' * random();
 720         key.event_damage = kh_Key_Damage;
 721         key.takedamage = DAMAGE_YES;
 722         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 723         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 724         key.modelindex = kh_key_dropped;
 725         key.model = "key";
 726         key.kh_dropperteam = 0;
 727         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 728         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 729         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 730         key.reset = key_reset;
 731         navigation_dynamicgoal_init(key, false);
 732
 733         switch(initial_owner.team)
 734         {
 735                 case NUM_TEAM_1:
 736                         key.netname = "^1red key";
 737                         break;
 738                 case NUM_TEAM_2:
 739                         key.netname = "^4blue key";
 740                         break;
 741                 case NUM_TEAM_3:
 742                         key.netname = "^3yellow key";
 743                         break;
 744                 case NUM_TEAM_4:
 745                         key.netname = "^6pink key";
 746                         break;
 747                 default:
 748                         key.netname = "NETGIER key";
 749                         break;
 750         }
 751
 752         // link into key list
 753         key.kh_worldkeynext = kh_worldkeylist;
 754         kh_worldkeylist = key;
 755
 756         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 757
 758         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 759         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 760
 761         kh_Key_AssignTo(key, initial_owner);
 762 }
 763
 764 // -1 when no team completely owns all keys yet
 765 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 766 {
 767         entity key;
 768         int teem = -1;
 769         int keys = NumTeams(kh_teams);
 770         FOR_EACH_KH_KEY(key)
 771         {
 772                 if(!key.owner)
 773                         return -1;
 774                 if(teem == -1)
 775                         teem = key.team;
 776                 else if(teem != key.team)
 777                         return -1;
 778                 --keys;
 779         }
 780         if(keys != 0)
 781                 return -1;
 782         return teem;
 783 }
 784
 785 void kh_Key_DropOne(entity key)
 786 {
 787         // prevent collecting this one for some time
 788         entity player = key.owner;
 789
 790         key.kh_droptime = time;
 791         key.enemy = player;
 792
 793         kh_Scores_Event(player, key, "dropkey", 0, 0);
 794         GameRules_scoring_add(player, KH_LOSSES, 1);
 795         int realteam = kh_Team_ByID(key.count);
 796         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 797
 798         kh_Key_AssignTo(key, NULL);
 799         makevectors(player.v_angle);
 800         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 801         key.pusher = NULL;
 802         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 803         key.kh_dropperteam = key.team;
 804
 805         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 806 }
 807
 808 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 809 {
 810         if(player.kh_next)
 811         {
 812                 entity mypusher = NULL;
 813                 if(player.pusher)
 814                         if(time < player.pushltime)
 815                                 mypusher = player.pusher;
 816
 817                 entity key;
 818                 while((key = player.kh_next))
 819                 {
 820                         kh_Scores_Event(player, key, "losekey", 0, 0);
 821                         GameRules_scoring_add(player, KH_LOSSES, 1);
 822                         int realteam = kh_Team_ByID(key.count);
 823                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 824                         kh_Key_AssignTo(key, NULL);
 825                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 826                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 827                         key.pusher = mypusher;
 828                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 829                         if(suicide)
 830                                 key.kh_dropperteam = player.team;
 831                 }
 832                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 833         }
 834 }
 835
 836 int kh_GetMissingTeams()
 837 {
 838         int missing_teams = 0;
 839         for(int i = 0; i < NumTeams(kh_teams); ++i)
 840         {
 841                 int teem = kh_Team_ByID(i);
 842                 int players = 0;
 843                 FOREACH_CLIENT(IS_PLAYER(it), {
 844                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 845                                 ++players;
 846                 });
 847                 if (!players)
 848                         missing_teams |= (2 ** i);
 849         }
 850         return missing_teams;
 851 }
 852
 853 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 854 {
 855         static int prev_missing_teams_mask;
 856         if(time < game_starttime)
 857         {
 858                 if (prev_missing_teams_mask > 0)
 859                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 860                 prev_missing_teams_mask = -1;
 861                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 862                 return;
 863         }
 864
 865         int missing_teams_mask = kh_GetMissingTeams();
 866         if(!missing_teams_mask)
 867         {
 868                 if(prev_missing_teams_mask > 0)
 869                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 870                 prev_missing_teams_mask = -1;
 871                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 872                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 873         }
 874         else
 875         {
 876                 if(player_count == 0)
 877                 {
 878                         if(prev_missing_teams_mask > 0)
 879                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 880                         prev_missing_teams_mask = -1;
 881                 }
 882                 else
 883                 {
 884                         if(prev_missing_teams_mask != missing_teams_mask)
 885                         {
 886                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 887                                 prev_missing_teams_mask = missing_teams_mask;
 888                         }
 889                 }
 890                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 891         }
 892 }
 893
 894 void kh_EnableTrackingDevice()  // runs after each round
 895 {
 896         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 897         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 898
 899         kh_tracking_enabled = true;
 900 }
 901
 902 void kh_StartRound()  // runs at the start of each round
 903 {
 904         if(time < game_starttime)
 905         {
 906                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 907                 return;
 908         }
 909
 910         if(kh_GetMissingTeams())
 911         {
 912                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 913                 return;
 914         }
 915
 916         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 917         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 918
 919         for(int i = 0; i < NumTeams(kh_teams); ++i)
 920         {
 921                 int teem = kh_Team_ByID(i);
 922                 int players = 0;
 923                 entity my_player = NULL;
 924                 FOREACH_CLIENT(IS_PLAYER(it), {
 925                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 926                         {
 927                                 ++players;
 928                                 if(random() * players <= 1)
 929                                         my_player = it;
 930                         }
 931                 });
 932                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 933         }
 934
 935         kh_tracking_enabled = false;
 936         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 937         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 938 }
 939
 940 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 941 {
 942         if(attacker == targ)
 943                 return f;
 944
 945         if(targ.kh_next)
 946         {
 947                 if(attacker.team == targ.team)
 948                 {
 949                         int nk = 0;
 950                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 951                                 ++nk;
 952                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 953                 }
 954                 else
 955                 {
 956                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 957                         GameRules_scoring_add(attacker, KH_KCKILLS, 1);
 958                         // the frag gets added later
 959                 }
 960         }
 961
 962         return f;
 963 }
 964
 965 void kh_Initialize()  // sets up th KH environment
 966 {
 967         // setup variables
 968         kh_teams = autocvar_g_keyhunt_teams_override;
 969         if(kh_teams < 2)
 970                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 971         kh_teams = BITS(bound(2, kh_teams, 4));
 972
 973         // make a KH entity for controlling the game
 974         kh_controller = spawn();
 975         setthink(kh_controller, kh_Controller_Think);
 976         kh_Controller_SetThink(0, kh_WaitForPlayers);
 977
 978         setmodel(kh_controller, MDL_KH_KEY);
 979         kh_key_dropped = kh_controller.modelindex;
 980         /*
 981         dprint(vtos(kh_controller.mins));
 982         dprint(vtos(kh_controller.maxs));
 983         dprint("\n");
 984         */
 985 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 986         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
 987         kh_key_carried = kh_controller.modelindex;
 988 #else
 989         kh_key_carried = kh_key_dropped;
 990 #endif
 991
 992         kh_controller.model = "";
 993         kh_controller.modelindex = 0;
 994
 995         kh_ScoreRules(kh_teams);
 996 }
 997
 998 void kh_finalize()
 999 {
1000         // to be called before intermission
1001         kh_FinishRound();
1002         delete(kh_controller);
1003         kh_controller = NULL;
1004 }
1005
1006 // legacy bot role
1007
1008 void(entity this) havocbot_role_kh_carrier;
1009 void(entity this) havocbot_role_kh_defense;
1010 void(entity this) havocbot_role_kh_offense;
1011 void(entity this) havocbot_role_kh_freelancer;
1012
1013
1014 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1015 {
1016         entity head;
1017         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1018         {
1019                 if(head.owner == this)
1020                         continue;
1021                 if(!kh_tracking_enabled)
1022                 {
1023                         // if it's carried by our team we know about it
1024                         // otherwise we have to see it to know about it
1025                         if(!head.owner || head.team != this.team)
1026                         {
1027                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1028                                 if (trace_fraction < 1 && trace_ent != head)
1029                                         continue; // skip what I can't see
1030                         }
1031                 }
1032                 if(!head.owner)
1033                         navigation_routerating(this, head, ratingscale_dropped * 10000, 100000);
1034                 else if(head.team == this.team)
1035                         navigation_routerating(this, head.owner, ratingscale_team * 10000, 100000);
1036                 else
1037                         navigation_routerating(this, head.owner, ratingscale_enemy * 10000, 100000);
1038         }
1039
1040         havocbot_goalrating_items(this, 1, this.origin, 10000);
1041 }
1042
1043 void havocbot_role_kh_carrier(entity this)
1044 {
1045         if(IS_DEAD(this))
1046                 return;
1047
1048         if (!(this.kh_next))
1049         {
1050                 LOG_TRACE("changing role to freelancer");
1051                 this.havocbot_role = havocbot_role_kh_freelancer;
1052                 this.havocbot_role_timeout = 0;
1053                 return;
1054         }
1055
1056         if (navigation_goalrating_timeout(this))
1057         {
1058                 navigation_goalrating_start(this);
1059
1060                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1061                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // bring home
1062                 else
1063                         havocbot_goalrating_kh(this, 4, 4, 0.5); // play defensively
1064
1065                 navigation_goalrating_end(this);
1066
1067                 navigation_goalrating_timeout_set(this);
1068         }
1069 }
1070
1071 void havocbot_role_kh_defense(entity this)
1072 {
1073         if(IS_DEAD(this))
1074                 return;
1075
1076         if (this.kh_next)
1077         {
1078                 LOG_TRACE("changing role to carrier");
1079                 this.havocbot_role = havocbot_role_kh_carrier;
1080                 this.havocbot_role_timeout = 0;
1081                 return;
1082         }
1083
1084         if (!this.havocbot_role_timeout)
1085                 this.havocbot_role_timeout = time + random() * 10 + 20;
1086         if (time > this.havocbot_role_timeout)
1087         {
1088                 LOG_TRACE("changing role to freelancer");
1089                 this.havocbot_role = havocbot_role_kh_freelancer;
1090                 this.havocbot_role_timeout = 0;
1091                 return;
1092         }
1093
1094         if (navigation_goalrating_timeout(this))
1095         {
1096                 float key_owner_team;
1097                 navigation_goalrating_start(this);
1098
1099                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1100                 if(key_owner_team == this.team)
1101                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend key carriers
1102                 else if(key_owner_team == -1)
1103                         havocbot_goalrating_kh(this, 4, 1, 0.05); // play defensively
1104                 else
1105                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1106
1107                 navigation_goalrating_end(this);
1108
1109                 navigation_goalrating_timeout_set(this);
1110         }
1111 }
1112
1113 void havocbot_role_kh_offense(entity this)
1114 {
1115         if(IS_DEAD(this))
1116                 return;
1117
1118         if (this.kh_next)
1119         {
1120                 LOG_TRACE("changing role to carrier");
1121                 this.havocbot_role = havocbot_role_kh_carrier;
1122                 this.havocbot_role_timeout = 0;
1123                 return;
1124         }
1125
1126         if (!this.havocbot_role_timeout)
1127                 this.havocbot_role_timeout = time + random() * 10 + 20;
1128         if (time > this.havocbot_role_timeout)
1129         {
1130                 LOG_TRACE("changing role to freelancer");
1131                 this.havocbot_role = havocbot_role_kh_freelancer;
1132                 this.havocbot_role_timeout = 0;
1133                 return;
1134         }
1135
1136         if (navigation_goalrating_timeout(this))
1137         {
1138                 float key_owner_team;
1139
1140                 navigation_goalrating_start(this);
1141
1142                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1143                 if(key_owner_team == this.team)
1144                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1145                 else if(key_owner_team == -1)
1146                         havocbot_goalrating_kh(this, 0.1, 1, 2); // play offensively
1147                 else
1148                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK! EMERGENCY!
1149
1150                 navigation_goalrating_end(this);
1151
1152                 navigation_goalrating_timeout_set(this);
1153         }
1154 }
1155
1156 void havocbot_role_kh_freelancer(entity this)
1157 {
1158         if(IS_DEAD(this))
1159                 return;
1160
1161         if (this.kh_next)
1162         {
1163                 LOG_TRACE("changing role to carrier");
1164                 this.havocbot_role = havocbot_role_kh_carrier;
1165                 this.havocbot_role_timeout = 0;
1166                 return;
1167         }
1168
1169         if (!this.havocbot_role_timeout)
1170                 this.havocbot_role_timeout = time + random() * 10 + 10;
1171         if (time > this.havocbot_role_timeout)
1172         {
1173                 if (random() < 0.5)
1174                 {
1175                         LOG_TRACE("changing role to offense");
1176                         this.havocbot_role = havocbot_role_kh_offense;
1177                 }
1178                 else
1179                 {
1180                         LOG_TRACE("changing role to defense");
1181                         this.havocbot_role = havocbot_role_kh_defense;
1182                 }
1183                 this.havocbot_role_timeout = 0;
1184                 return;
1185         }
1186
1187         if (navigation_goalrating_timeout(this))
1188         {
1189                 navigation_goalrating_start(this);
1190
1191                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1192                 if(key_owner_team == this.team)
1193                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1194                 else if(key_owner_team == -1)
1195                         havocbot_goalrating_kh(this, 1, 10, 2); // prefer dropped keys
1196                 else
1197                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1198
1199                 navigation_goalrating_end(this);
1200
1201                 navigation_goalrating_timeout_set(this);
1202         }
1203 }
1204
1205
1206 // register this as a mutator
1207
1208 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1209 {
1210         entity player = M_ARGV(0, entity);
1211
1212         kh_Key_DropAll(player, true);
1213 }
1214
1215 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1216 {
1217         entity player = M_ARGV(0, entity);
1218
1219         kh_Key_DropAll(player, true);
1220 }
1221
1222 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1223 {
1224         entity frag_attacker = M_ARGV(1, entity);
1225         entity frag_target = M_ARGV(2, entity);
1226
1227         if(frag_target == frag_attacker)
1228                 kh_Key_DropAll(frag_target, true);
1229         else if(IS_PLAYER(frag_attacker))
1230                 kh_Key_DropAll(frag_target, false);
1231         else
1232                 kh_Key_DropAll(frag_target, true);
1233 }
1234
1235 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1236 {
1237         entity frag_attacker = M_ARGV(0, entity);
1238         entity frag_target = M_ARGV(1, entity);
1239         float frag_score = M_ARGV(2, float);
1240         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1241 }
1242
1243 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1244 {
1245         kh_finalize();
1246 }
1247
1248 MUTATOR_HOOKFUNCTION(kh, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1249 {
1250         M_ARGV(0, float) = kh_teams;
1251         return true;
1252 }
1253
1254 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1255 {
1256         entity spectatee = M_ARGV(0, entity);
1257         entity client = M_ARGV(1, entity);
1258
1259         STAT(KH_KEYS, client) = STAT(KH_KEYS, spectatee);
1260 }
1261
1262 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1263 {
1264         entity player = M_ARGV(0, entity);
1265
1266         if(MUTATOR_RETURNVALUE == 0)
1267         {
1268                 entity k = player.kh_next;
1269                 if(k)
1270                 {
1271                         kh_Key_DropOne(k);
1272                         return true;
1273                 }
1274         }
1275 }
1276
1277 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1278 {
1279     entity bot = M_ARGV(0, entity);
1280
1281         if(IS_DEAD(bot))
1282                 return true;
1283
1284         float r = random() * 3;
1285         if (r < 1)
1286                 bot.havocbot_role = havocbot_role_kh_offense;
1287         else if (r < 2)
1288                 bot.havocbot_role = havocbot_role_kh_defense;
1289         else
1290                 bot.havocbot_role = havocbot_role_kh_freelancer;
1291
1292         return true;
1293 }
1294
1295 MUTATOR_HOOKFUNCTION(kh, LogDeath_AppendItemCodes)
1296 {
1297         entity player = M_ARGV(0, entity);
1298         if(player.kh_next)
1299                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "K"); // item codes
1300 }
1301
1302 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1303 {
1304         entity frag_target = M_ARGV(0, entity);
1305
1306         kh_Key_DropAll(frag_target, false);
1307 }
1308
1309 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1310 {
1311         kh_WaitForPlayers(); // takes care of killing the "missing teams" message
1312 }