e30d958a14261337a9d9f48934e7f0828aad6c87
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / gamemodes / gamemode / lms / sv_lms.qc
1 #include "sv_lms.qh"
2
3 #include <common/mutators/mutator/instagib/items.qh>
4 #include <server/campaign.qh>
5 #include <server/command/_mod.qh>
6
7 int autocvar_g_lms_extra_lives;
8 bool autocvar_g_lms_join_anytime;
9 int autocvar_g_lms_last_join;
10 bool autocvar_g_lms_regenerate;
11
12 // main functions
13 float LMS_NewPlayerLives()
14 {
15         float fl;
16         fl = autocvar_fraglimit;
17         if(fl == 0)
18                 fl = 999;
19
20         // first player has left the game for dying too much? Nobody else can get in.
21         if(lms_lowest_lives < 1)
22                 return 0;
23
24         if(!autocvar_g_lms_join_anytime)
25                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
26                         return 0;
27
28         return bound(1, lms_lowest_lives, fl);
29 }
30
31 void ClearWinners();
32
33 // LMS winning condition: game terminates if and only if there's at most one
34 // one player who's living lives. Top two scores being equal cancels the time
35 // limit.
36 int WinningCondition_LMS()
37 {
38         entity first_player = NULL;
39         int totalplayers = 0;
40         FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_LMS_LOSER, {
41                 if (!totalplayers)
42                         first_player = it;
43                 ++totalplayers;
44         });
45
46         if (totalplayers)
47         {
48                 if (totalplayers > 1)
49                 {
50                         // two or more active players - continue with the game
51
52                         if (autocvar_g_campaign)
53                         {
54                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
55                                         float pl_lives = GameRules_scoring_add(it, LMS_LIVES, 0);
56                                         if (!pl_lives)
57                                                 return WINNING_YES; // human player lost, game over
58                                         break;
59                                 });
60                         }
61                 }
62                 else
63                 {
64                         // exactly one player?
65
66                         ClearWinners();
67                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
68
69                         if (LMS_NewPlayerLives())
70                         {
71                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
72                                 return WINNING_NO;
73                         }
74                         else
75                         {
76                                 // a winner!
77                                 // and assign him his first place
78                                 GameRules_scoring_add(first_player, LMS_RANK, 1);
79                                 if(warmup_stage)
80                                         return WINNING_NO;
81                                 else
82                                         return WINNING_YES;
83                         }
84                 }
85         }
86         else
87         {
88                 // nobody is playing at all...
89                 if (LMS_NewPlayerLives())
90                 {
91                         // wait for players...
92                 }
93                 else
94                 {
95                         // SNAFU (maybe a draw game?)
96                         ClearWinners();
97                         LOG_TRACE("No players, ending game.");
98                         return WINNING_YES;
99                 }
100         }
101
102         // When we get here, we have at least two players who are actually LIVING,
103         // now check if the top two players have equal score.
104         WinningConditionHelper(NULL);
105
106         ClearWinners();
107         if(WinningConditionHelper_winner)
108                 WinningConditionHelper_winner.winning = true;
109         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
110                 return WINNING_NEVER;
111
112         // Top two have different scores? Way to go for our beloved TIMELIMIT!
113         return WINNING_NO;
114 }
115
116 // mutator hooks
117 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
118 {
119         lms_lowest_lives = 999;
120 }
121
122 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
123 {
124         FOREACH_CLIENT(true, {
125                 TRANSMUTE(Player, it);
126                 it.frags = FRAGS_PLAYER;
127                 GameRules_scoring_add(it, LMS_LIVES, LMS_NewPlayerLives());
128                 PutClientInServer(it);
129         });
130 }
131
132 // FIXME add support for sv_ready_restart_after_countdown
133 // that is find a way to respawn/reset players IN GAME without setting lives to 0
134 MUTATOR_HOOKFUNCTION(lms, ReadLevelCvars)
135 {
136         // incompatible
137         sv_ready_restart_after_countdown = 0;
138 }
139
140 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
141 {
142         entity player = M_ARGV(0, entity);
143
144         if(player.frags == FRAGS_SPECTATOR)
145                 TRANSMUTE(Observer, player);
146         else
147         {
148                 float tl = GameRules_scoring_add(player, LMS_LIVES, 0);
149                 if(tl < lms_lowest_lives)
150                         lms_lowest_lives = tl;
151                 if(tl <= 0)
152                         TRANSMUTE(Observer, player);
153                 if(warmup_stage)
154                         GameRules_scoring_add(player, LMS_RANK, -GameRules_scoring_add(player, LMS_RANK, 0));
155         }
156 }
157
158 MUTATOR_HOOKFUNCTION(lms, ForbidSpawn)
159 {
160         entity player = M_ARGV(0, entity);
161
162         if(warmup_stage)
163                 return false;
164         if(player.frags == FRAGS_SPECTATOR)
165                 return true;
166         if(GameRules_scoring_add(player, LMS_LIVES, 0) <= 0)
167         {
168                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_LMS_NOLIVES);
169                 return true;
170         }
171         return false;
172 }
173
174 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
175 {
176         entity frag_target = M_ARGV(2, entity);
177
178         frag_target.respawn_flags |= RESPAWN_FORCE;
179 }
180
181 void lms_RemovePlayer(entity player)
182 {
183         static int quitters = 0;
184         float player_rank = GameRules_scoring_add(player, LMS_RANK, 0);
185         if (!player_rank)
186         {
187                 int pl_cnt = 0;
188                 FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_LMS_LOSER, {
189                         pl_cnt++;
190                 });
191                 if (player.lms_spectate_warning < 2)
192                 {
193                         if(IS_BOT_CLIENT(player))
194                                 bot_clear(player);
195                         player.frags = FRAGS_LMS_LOSER;
196                         GameRules_scoring_add(player, LMS_RANK, pl_cnt + 1);
197                 }
198                 else
199                 {
200                         lms_lowest_lives = 999;
201                         FOREACH_CLIENT(true, {
202                                 if (it.frags == FRAGS_LMS_LOSER)
203                                 {
204                                         float it_rank = GameRules_scoring_add(it, LMS_RANK, 0);
205                                         if (it_rank > player_rank && it_rank <= 256)
206                                                 GameRules_scoring_add(it, LMS_RANK, -1);
207                                         lms_lowest_lives = 0;
208                                 }
209                                 else if (it.frags != FRAGS_SPECTATOR)
210                                 {
211                                         float tl = GameRules_scoring_add(it, LMS_LIVES, 0);
212                                         if(tl < lms_lowest_lives)
213                                                 lms_lowest_lives = tl;
214                                 }
215                         });
216                         GameRules_scoring_add(player, LMS_RANK, 665 - quitters); // different from 666
217                         if(!warmup_stage)
218                         {
219                                 GameRules_scoring_add(player, LMS_LIVES, -GameRules_scoring_add(player, LMS_LIVES, 0));
220                                 ++quitters;
221                         }
222                         player.frags = FRAGS_LMS_LOSER;
223                         TRANSMUTE(Observer, player);
224                 }
225         }
226
227         if (CS(player).killcount != FRAGS_SPECTATOR && player.lms_spectate_warning < 3)
228         {
229                 if (GameRules_scoring_add(player, LMS_RANK, 0) > 0 && player.lms_spectate_warning < 2)
230                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
231                 else
232                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
233         }
234 }
235
236 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
237 {
238         entity player = M_ARGV(0, entity);
239
240         // no further message other than the disconnect message
241         player.lms_spectate_warning = 3;
242
243         lms_RemovePlayer(player);
244 }
245
246 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
247 {
248         entity player = M_ARGV(0, entity);
249
250         if (!IS_PLAYER(player))
251                 return true;
252
253         lms_RemovePlayer(player);
254         return true;  // prevent team reset
255 }
256
257 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
258 {
259         entity player = M_ARGV(0, entity);
260
261         if(GameRules_scoring_add(player, LMS_LIVES, LMS_NewPlayerLives()) <= 0)
262         {
263                 GameRules_scoring_add(player, LMS_RANK, 666); // mark as forced spectator for the hud code
264                 player.frags = FRAGS_SPECTATOR;
265         }
266 }
267
268 // FIXME LMS doesn't allow clients to spectate due to its particular implementation
269 MUTATOR_HOOKFUNCTION(lms, AutoJoinOnConnection)
270 {
271         if(autocvar_g_campaign)
272                 return false;
273         return true;
274 }
275
276 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
277 {
278         entity player = M_ARGV(0, entity);
279
280         if(player.deadflag == DEAD_DYING)
281                 player.deadflag = DEAD_RESPAWNING;
282 }
283
284 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
285 {
286         if(autocvar_g_lms_regenerate)
287                 return false;
288         return true;
289 }
290
291 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
292 {
293         // forbode!
294         return true;
295 }
296
297 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
298 {
299         entity frag_target = M_ARGV(1, entity);
300
301         if (!warmup_stage)
302         {
303                 // remove a life
304                 int tl = GameRules_scoring_add(frag_target, LMS_LIVES, -1);
305                 if(tl < lms_lowest_lives)
306                         lms_lowest_lives = tl;
307                 if(tl <= 0)
308                 {
309                         int pl_cnt = 0;
310                         FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_LMS_LOSER, {
311                                 pl_cnt++;
312                         });
313                         if(IS_BOT_CLIENT(frag_target))
314                                 bot_clear(frag_target);
315                         frag_target.frags = FRAGS_LMS_LOSER;
316                         GameRules_scoring_add(frag_target, LMS_RANK, pl_cnt);
317                 }
318         }
319         M_ARGV(2, float) = 0; // frag score
320
321         return true;
322 }
323
324 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
325 {
326         start_items &= ~IT_UNLIMITED_AMMO;
327         start_health       = warmup_start_health       = cvar("g_lms_start_health");
328         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
329         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
330         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
331         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
332         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
333         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
334         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
335 }
336
337 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
338 {
339         // don't clear player score
340         return true;
341 }
342
343 MUTATOR_HOOKFUNCTION(lms, FilterItemDefinition)
344 {
345         entity definition = M_ARGV(0, entity);
346
347         if (autocvar_g_lms_extra_lives && definition == ITEM_ExtraLife)
348         {
349                 return false;
350         }
351         return true;
352 }
353
354 void lms_extralife(entity this)
355 {
356         StartItem(this, ITEM_ExtraLife);
357 }
358
359 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
360 {
361         if (!autocvar_g_powerups) return false;
362         if (!autocvar_g_lms_extra_lives) return false;
363
364         entity ent = M_ARGV(0, entity);
365
366         // Can't use .itemdef here
367         if (ent.classname != "item_health_mega") return false;
368
369         entity e = spawn();
370         setthink(e, lms_extralife);
371
372         e.nextthink = time + 0.1;
373         e.spawnflags = ent.spawnflags;
374         e.noalign = ent.noalign;
375         setorigin(e, ent.origin);
376
377         return true;
378 }
379
380 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
381 {
382         entity item = M_ARGV(0, entity);
383         entity toucher = M_ARGV(1, entity);
384
385         if(item.itemdef == ITEM_ExtraLife)
386         {
387                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_EXTRALIVES);
388                 GameRules_scoring_add(toucher, LMS_LIVES, autocvar_g_lms_extra_lives);
389                 return MUT_ITEMTOUCH_PICKUP;
390         }
391
392         return MUT_ITEMTOUCH_CONTINUE;
393 }
394
395 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
396 {
397         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
398                 ++M_ARGV(0, int); // activerealplayers
399                 ++M_ARGV(1, int); // realplayers
400         });
401
402         return true;
403 }
404
405 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
406 {
407         entity player = M_ARGV(0, entity);
408
409         if(warmup_stage || player.lms_spectate_warning)
410         {
411                 // for the forfeit message...
412                 player.lms_spectate_warning = 2;
413         }
414         else
415         {
416                 if(player.frags != FRAGS_SPECTATOR && player.frags != FRAGS_LMS_LOSER)
417                 {
418                         player.lms_spectate_warning = 1;
419                         sprint(player, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
420                 }
421                 return MUT_SPECCMD_RETURN;
422         }
423         return MUT_SPECCMD_CONTINUE;
424 }
425
426 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
427 {
428         M_ARGV(0, float) = WinningCondition_LMS();
429         return true;
430 }
431
432 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
433 {
434         M_ARGV(2, bool) = true; // all weapons
435 }
436
437 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
438 {
439         return true;
440 }
441
442 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
443 {
444         if(game_stopped)
445         if(M_ARGV(0, entity) == SP_LMS_RANK) // score field
446                 return true; // allow writing to this field in intermission as it is needed for newly joining players
447 }
448
449 void lms_Initialize()
450 {
451         lms_lowest_lives = 9999;
452 }