qcsrc/common/gamemodes/gamemode/nexball/nexball.qc

   1 #include "nexball.qh"
   2
   3 #ifdef CSQC
   4 int autocvar_cl_eventchase_nexball = 1;
   5
   6 REGISTER_MUTATOR(cl_nb, true);
   7
   8 MUTATOR_HOOKFUNCTION(cl_nb, WantEventchase)
   9 {
  10         if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
  11                 return true;
  12         return false;
  13 }
  14 #endif
  15 #ifdef SVQC
  16 .float metertime = _STAT(NB_METERSTART);
  17
  18 int autocvar_g_nexball_goalleadlimit;
  19 #define autocvar_g_nexball_goallimit cvar("g_nexball_goallimit")
  20
  21 bool autocvar_g_nexball_basketball_jumppad = true;
  22 float autocvar_g_nexball_basketball_bouncefactor;
  23 float autocvar_g_nexball_basketball_bouncestop;
  24 float autocvar_g_nexball_basketball_carrier_highspeed;
  25 bool autocvar_g_nexball_basketball_meter;
  26 float autocvar_g_nexball_basketball_meter_maxpower;
  27 float autocvar_g_nexball_basketball_meter_minpower;
  28 float autocvar_g_nexball_delay_collect;
  29 float autocvar_g_nexball_delay_goal;
  30 float autocvar_g_nexball_delay_start;
  31 bool autocvar_g_nexball_football_jumppad = true;
  32 float autocvar_g_nexball_football_bouncefactor;
  33 float autocvar_g_nexball_football_bouncestop;
  34 bool autocvar_g_nexball_radar_showallplayers;
  35 bool autocvar_g_nexball_sound_bounce;
  36 int autocvar_g_nexball_trail_color;
  37
  38 float autocvar_g_nexball_safepass_turnrate;
  39 float autocvar_g_nexball_safepass_maxdist;
  40 float autocvar_g_nexball_safepass_holdtime;
  41 float autocvar_g_nexball_viewmodel_scale;
  42 float autocvar_g_nexball_tackling;
  43 vector autocvar_g_nexball_viewmodel_offset;
  44
  45 float autocvar_g_balance_nexball_primary_animtime;
  46 float autocvar_g_balance_nexball_primary_refire;
  47 float autocvar_g_balance_nexball_primary_speed;
  48 float autocvar_g_balance_nexball_secondary_animtime;
  49 float autocvar_g_balance_nexball_secondary_force;
  50 float autocvar_g_balance_nexball_secondary_lifetime;
  51 float autocvar_g_balance_nexball_secondary_refire;
  52 float autocvar_g_balance_nexball_secondary_speed;
  53
  54 void basketball_touch(entity this, entity toucher);
  55 void football_touch(entity this, entity toucher);
  56 void ResetBall(entity this);
  57 const int NBM_NONE = 0;
  58 const int NBM_FOOTBALL = 2;
  59 const int NBM_BASKETBALL = 4;
  60 float nexball_mode;
  61
  62 float OtherTeam(float t)  //works only if there are two teams on the map!
  63 {
  64         entity e;
  65         e = find(NULL, classname, "nexball_team");
  66         if(e.team == t)
  67                 e = find(e, classname, "nexball_team");
  68         return e.team;
  69 }
  70
  71 const float ST_NEXBALL_GOALS = 1;
  72 void nb_ScoreRules(int teams)
  73 {
  74         ScoreRules_basics(teams, 0, 0, true);
  75         ScoreInfo_SetLabel_TeamScore(   ST_NEXBALL_GOALS,  "goals", SFL_SORT_PRIO_PRIMARY);
  76         ScoreInfo_SetLabel_PlayerScore( SP_NEXBALL_GOALS,  "goals", SFL_SORT_PRIO_PRIMARY);
  77         ScoreInfo_SetLabel_PlayerScore(SP_NEXBALL_FAULTS, "faults", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER);
  78         ScoreRules_basics_end();
  79 }
  80
  81 void LogNB(string mode, entity actor)
  82 {
  83         string s;
  84         if(!autocvar_sv_eventlog)
  85                 return;
  86         s = strcat(":nexball:", mode);
  87         if(actor != NULL)
  88                 s = strcat(s, ":", ftos(actor.playerid));
  89         GameLogEcho(s);
  90 }
  91
  92 void ball_restart(entity this)
  93 {
  94         if(this.owner)
  95                 DropBall(this, this.owner.origin, '0 0 0');
  96         ResetBall(this);
  97 }
  98
  99 void nexball_setstatus(entity this)
 100 {
 101         this.items &= ~IT_KEY1;
 102         if(this.ballcarried)
 103         {
 104                 if(this.ballcarried.teamtime && (this.ballcarried.teamtime < time))
 105                 {
 106                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_NEXBALL_RETURN_HELD));
 107                         entity e = this.ballcarried;
 108                         DropBall(this.ballcarried, this.ballcarried.owner.origin, '0 0 0');
 109                         ResetBall(e);
 110                 }
 111                 else
 112                         this.items |= IT_KEY1;
 113         }
 114 }
 115
 116 void relocate_nexball(entity this)
 117 {
 118         tracebox(this.origin, BALL_MINS, BALL_MAXS, this.origin, true, this);
 119         if(trace_startsolid)
 120         {
 121                 vector o;
 122                 o = this.origin;
 123                 if(!move_out_of_solid(this))
 124                         objerror(this, "could not get out of solid at all!");
 125                 LOG_INFO("^1NOTE: this map needs FIXING. ", this.classname, " at ", vtos(o - '0 0 1'));
 126                 LOG_INFO(" needs to be moved out of solid, e.g. by '", ftos(this.origin.x - o.x));
 127                 LOG_INFO(" ", ftos(this.origin.y - o.y));
 128                 LOG_INFO(" ", ftos(this.origin.z - o.z), "'\n");
 129                 this.origin = o;
 130         }
 131 }
 132
 133 void DropOwner(entity this)
 134 {
 135         entity ownr;
 136         ownr = this.owner;
 137         DropBall(this, ownr.origin, ownr.velocity);
 138         makevectors(ownr.v_angle.y * '0 1 0');
 139         ownr.velocity += ('0 0 0.75' - v_forward) * 1000;
 140         UNSET_ONGROUND(ownr);
 141 }
 142
 143 void GiveBall(entity plyr, entity ball)
 144 {
 145         .entity weaponentity = weaponentities[0]; // TODO: find ballstealer
 146         entity ownr = ball.owner;
 147         if(ownr)
 148         {
 149                 ownr.effects &= ~autocvar_g_nexball_basketball_effects_default;
 150                 ownr.ballcarried = NULL;
 151                 if(ownr.metertime)
 152                 {
 153                         ownr.metertime = 0;
 154                         ownr.(weaponentity).state = WS_READY;
 155                 }
 156                 WaypointSprite_Kill(ownr.waypointsprite_attachedforcarrier);
 157         }
 158         else
 159         {
 160                 WaypointSprite_Kill(ball.waypointsprite_attachedforcarrier);
 161         }
 162
 163         //setattachment(ball, plyr, "");
 164         setorigin(ball, plyr.origin + plyr.view_ofs);
 165
 166         if(ball.team != plyr.team)
 167                 ball.teamtime = time + autocvar_g_nexball_basketball_delay_hold_forteam;
 168
 169         ball.owner = ball.pusher = plyr; //"owner" is set to the player carrying, "pusher" to the last player who touched it
 170         ball.weaponentity_fld = weaponentity;
 171         ball.team = plyr.team;
 172         plyr.ballcarried = ball;
 173         ball.nb_dropper = plyr;
 174
 175         plyr.effects |= autocvar_g_nexball_basketball_effects_default;
 176         ball.effects &= ~autocvar_g_nexball_basketball_effects_default;
 177
 178         ball.velocity = '0 0 0';
 179         set_movetype(ball, MOVETYPE_NONE);
 180         settouch(ball, func_null);
 181         ball.effects |= EF_NOSHADOW;
 182         ball.scale = 1; // scale down.
 183
 184         WaypointSprite_AttachCarrier(WP_NbBall, plyr, RADARICON_FLAGCARRIER);
 185         WaypointSprite_UpdateRule(plyr.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 186
 187         if(autocvar_g_nexball_basketball_delay_hold)
 188         {
 189                 setthink(ball, DropOwner);
 190                 ball.nextthink = time + autocvar_g_nexball_basketball_delay_hold;
 191         }
 192
 193         plyr.(weaponentity).weapons = plyr.weapons;
 194         plyr.m_switchweapon = plyr.(weaponentity).m_weapon;
 195         plyr.weapons = WEPSET(NEXBALL);
 196         Weapon w = WEP_NEXBALL;
 197         w.wr_resetplayer(w, plyr);
 198         plyr.(weaponentity).m_switchweapon = WEP_NEXBALL;
 199         W_SwitchWeapon(plyr, WEP_NEXBALL, weaponentity);
 200 }
 201
 202 void DropBall(entity ball, vector org, vector vel)
 203 {
 204         ball.effects |= autocvar_g_nexball_basketball_effects_default;
 205         ball.effects &= ~EF_NOSHADOW;
 206         ball.owner.effects &= ~autocvar_g_nexball_basketball_effects_default;
 207
 208         setattachment(ball, NULL, "");
 209         setorigin(ball, org);
 210         set_movetype(ball, MOVETYPE_BOUNCE);
 211         UNSET_ONGROUND(ball);
 212         ball.scale = ball_scale;
 213         ball.velocity = vel;
 214         ball.nb_droptime = time;
 215         settouch(ball, basketball_touch);
 216         setthink(ball, ResetBall);
 217         ball.nextthink = min(time + autocvar_g_nexball_delay_idle, ball.teamtime);
 218
 219         if(ball.owner.metertime)
 220         {
 221                 ball.owner.metertime = 0;
 222                 .entity weaponentity = ball.weaponentity_fld;
 223                 ball.owner.(weaponentity).state = WS_READY;
 224         }
 225
 226         WaypointSprite_Kill(ball.owner.waypointsprite_attachedforcarrier);
 227         WaypointSprite_Spawn(WP_NbBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER); // no health bar please
 228         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 229
 230         ball.owner.ballcarried = NULL;
 231         ball.owner = NULL;
 232 }
 233
 234 void InitBall(entity this)
 235 {
 236         if(gameover) return;
 237         UNSET_ONGROUND(this);
 238         set_movetype(this, MOVETYPE_BOUNCE);
 239         if(this.classname == "nexball_basketball")
 240                 settouch(this, basketball_touch);
 241         else if(this.classname == "nexball_football")
 242                 settouch(this, football_touch);
 243         this.cnt = 0;
 244         setthink(this, ResetBall);
 245         this.nextthink = time + autocvar_g_nexball_delay_idle + 3;
 246         this.teamtime = 0;
 247         this.pusher = NULL;
 248         this.team = false;
 249         _sound(this, CH_TRIGGER, this.noise1, VOL_BASE, ATTEN_NORM);
 250         WaypointSprite_Ping(this.waypointsprite_attachedforcarrier);
 251         LogNB("init", NULL);
 252 }
 253
 254 void ResetBall(entity this)
 255 {
 256         if(this.cnt < 2)        // step 1
 257         {
 258                 if(time == this.teamtime)
 259                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_NEXBALL_RETURN_HELD));
 260
 261                 settouch(this, func_null);
 262                 set_movetype(this, MOVETYPE_NOCLIP);
 263                 this.velocity = '0 0 0'; // just in case?
 264                 if(!this.cnt)
 265                         LogNB("resetidle", NULL);
 266                 this.cnt = 2;
 267                 this.nextthink = time;
 268         }
 269         else if(this.cnt < 4)     // step 2 and 3
 270         {
 271 //              dprint("Step ", ftos(this.cnt), ": Calculated velocity: ", vtos(this.spawnorigin - this.origin), ", time: ", ftos(time), "\n");
 272                 this.velocity = (this.spawnorigin - this.origin) * (this.cnt - 1); // 1 or 0.5 second movement
 273                 this.nextthink = time + 0.5;
 274                 this.cnt += 1;
 275         }
 276         else     // step 4
 277         {
 278 //              dprint("Step 4: time: ", ftos(time), "\n");
 279                 if(vdist(this.origin - this.spawnorigin, >, 10)) // should not happen anymore
 280                         LOG_TRACE("The ball moved too far away from its spawn origin.\nOffset: ",
 281                                    vtos(this.origin - this.spawnorigin), " Velocity: ", vtos(this.velocity), "\n");
 282                 this.velocity = '0 0 0';
 283                 setorigin(this, this.spawnorigin); // make sure it's positioned correctly anyway
 284                 set_movetype(this, MOVETYPE_NONE);
 285                 setthink(this, InitBall);
 286                 this.nextthink = max(time, game_starttime) + autocvar_g_nexball_delay_start;
 287         }
 288 }
 289
 290 void football_touch(entity this, entity toucher)
 291 {
 292         if(toucher.solid == SOLID_BSP)
 293         {
 294                 if(time > this.lastground + 0.1)
 295                 {
 296                         _sound(this, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 297                         this.lastground = time;
 298                 }
 299                 if(this.velocity && !this.cnt)
 300                         this.nextthink = time + autocvar_g_nexball_delay_idle;
 301                 return;
 302         }
 303         if (!IS_PLAYER(toucher))
 304                 return;
 305         if(toucher.health < 1)
 306                 return;
 307         if(!this.cnt)
 308                 this.nextthink = time + autocvar_g_nexball_delay_idle;
 309
 310         this.pusher = toucher;
 311         this.team = toucher.team;
 312
 313         if(autocvar_g_nexball_football_physics == -1)   // MrBougo try 1, before decompiling Rev's original
 314         {
 315                 if(toucher.velocity)
 316                         this.velocity = toucher.velocity * 1.5 + '0 0 1' * autocvar_g_nexball_football_boost_up;
 317         }
 318         else if(autocvar_g_nexball_football_physics == 1)         // MrBougo's modded Rev style: partially independant of the height of the aiming point
 319         {
 320                 makevectors(toucher.v_angle);
 321                 this.velocity = toucher.velocity + v_forward * autocvar_g_nexball_football_boost_forward + '0 0 1' * autocvar_g_nexball_football_boost_up;
 322         }
 323         else if(autocvar_g_nexball_football_physics == 2)         // 2nd mod try: totally independant. Really playable!
 324         {
 325                 makevectors(toucher.v_angle.y * '0 1 0');
 326                 this.velocity = toucher.velocity + v_forward * autocvar_g_nexball_football_boost_forward + v_up * autocvar_g_nexball_football_boost_up;
 327         }
 328         else     // Revenant's original style (from the original mod's disassembly, acknowledged by Revenant)
 329         {
 330                 makevectors(toucher.v_angle);
 331                 this.velocity = toucher.velocity + v_forward * autocvar_g_nexball_football_boost_forward + v_up * autocvar_g_nexball_football_boost_up;
 332         }
 333         this.avelocity = -250 * v_forward;  // maybe there is a way to make it look better?
 334 }
 335
 336 void basketball_touch(entity this, entity toucher)
 337 {
 338         if(toucher.ballcarried)
 339         {
 340                 football_touch(this, toucher);
 341                 return;
 342         }
 343         if(!this.cnt && IS_PLAYER(toucher) && !STAT(FROZEN, toucher) && !IS_DEAD(toucher) && (toucher != this.nb_dropper || time > this.nb_droptime + autocvar_g_nexball_delay_collect))
 344         {
 345                 if(toucher.health <= 0)
 346                         return;
 347                 LogNB("caught", toucher);
 348                 GiveBall(toucher, this);
 349         }
 350         else if(toucher.solid == SOLID_BSP)
 351         {
 352                 _sound(this, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 353                 if(this.velocity && !this.cnt)
 354                         this.nextthink = min(time + autocvar_g_nexball_delay_idle, this.teamtime);
 355         }
 356 }
 357
 358 void GoalTouch(entity this, entity toucher)
 359 {
 360         entity ball;
 361         float isclient, pscore, otherteam;
 362         string pname;
 363
 364         if(gameover) return;
 365         if((this.spawnflags & GOAL_TOUCHPLAYER) && toucher.ballcarried)
 366                 ball = toucher.ballcarried;
 367         else
 368                 ball = toucher;
 369         if(ball.classname != "nexball_basketball")
 370                 if(ball.classname != "nexball_football")
 371                         return;
 372         if((!ball.pusher && this.team != GOAL_OUT) || ball.cnt)
 373                 return;
 374         EXACTTRIGGER_TOUCH(this, toucher);
 375
 376
 377         if(NumTeams(nb_teams) == 2)
 378                 otherteam = OtherTeam(ball.team);
 379         else
 380                 otherteam = 0;
 381
 382         if((isclient = IS_CLIENT(ball.pusher)))
 383                 pname = ball.pusher.netname;
 384         else
 385                 pname = "Someone (?)";
 386
 387         if(ball.team == this.team)               //owngoal (regular goals)
 388         {
 389                 LogNB("owngoal", ball.pusher);
 390                 bprint("Boo! ", pname, "^7 scored a goal against their own team!\n");
 391                 pscore = -1;
 392         }
 393         else if(this.team == GOAL_FAULT)
 394         {
 395                 LogNB("fault", ball.pusher);
 396                 if(NumTeams(nb_teams) == 2)
 397                         bprint(Team_ColoredFullName(otherteam), " gets a point due to ", pname, "^7's silliness.\n");
 398                 else
 399                         bprint(Team_ColoredFullName(ball.team), " loses a point due to ", pname, "^7's silliness.\n");
 400                 pscore = -1;
 401         }
 402         else if(this.team == GOAL_OUT)
 403         {
 404                 LogNB("out", ball.pusher);
 405                 if((this.spawnflags & GOAL_TOUCHPLAYER) && ball.owner)
 406                         bprint(pname, "^7 went out of bounds.\n");
 407                 else
 408                         bprint("The ball was returned.\n");
 409                 pscore = 0;
 410         }
 411         else                                                       //score
 412         {
 413                 LogNB(strcat("goal:", ftos(this.team)), ball.pusher);
 414                 bprint("Goaaaaal! ", pname, "^7 scored a point for the ", Team_ColoredFullName(ball.team), ".\n");
 415                 pscore = 1;
 416         }
 417
 418         _sound(ball, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NONE);
 419
 420         if(ball.team && pscore)
 421         {
 422                 if(NumTeams(nb_teams) == 2 && pscore < 0)
 423                         TeamScore_AddToTeam(otherteam, ST_NEXBALL_GOALS, -pscore);
 424                 else
 425                         TeamScore_AddToTeam(ball.team, ST_NEXBALL_GOALS, pscore);
 426         }
 427         if(isclient)
 428         {
 429                 if(pscore > 0)
 430                         PlayerScore_Add(ball.pusher, SP_NEXBALL_GOALS, pscore);
 431                 else if(pscore < 0)
 432                         PlayerScore_Add(ball.pusher, SP_NEXBALL_FAULTS, -pscore);
 433         }
 434
 435         if(ball.owner)  // Happens on spawnflag GOAL_TOUCHPLAYER
 436                 DropBall(ball, ball.owner.origin, ball.owner.velocity);
 437
 438         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 439
 440         ball.cnt = 1;
 441         setthink(ball, ResetBall);
 442         if(ball.classname == "nexball_basketball")
 443                 settouch(ball, football_touch); // better than func_null: football control until the ball gets reset
 444         ball.nextthink = time + autocvar_g_nexball_delay_goal * (this.team != GOAL_OUT);
 445 }
 446
 447 //=======================//
 448 //         team ents       //
 449 //=======================//
 450 spawnfunc(nexball_team)
 451 {
 452         if(!g_nexball)
 453         {
 454                 delete(this);
 455                 return;
 456         }
 457         this.team = this.cnt + 1;
 458 }
 459
 460 void nb_spawnteam(string teamname, float teamcolor)
 461 {
 462         LOG_TRACE("^2spawned team ", teamname);
 463         entity e = new(nexball_team);
 464         e.netname = teamname;
 465         e.cnt = teamcolor;
 466         e.team = e.cnt + 1;
 467         //nb_teams += 1;
 468 }
 469
 470 void nb_spawnteams()
 471 {
 472         bool t_red = false, t_blue = false, t_yellow = false, t_pink = false;
 473         entity e;
 474         for(e = NULL; (e = find(e, classname, "nexball_goal"));)
 475         {
 476                 switch(e.team)
 477                 {
 478                 case NUM_TEAM_1:
 479                         if(!t_red)
 480                         {
 481                                 nb_spawnteam("Red", e.team-1)   ;
 482                                 nb_teams |= BIT(0);
 483                                 t_red = true;
 484                         }
 485                         break;
 486                 case NUM_TEAM_2:
 487                         if(!t_blue)
 488                         {
 489                                 nb_spawnteam("Blue", e.team-1)  ;
 490                                 t_blue = true;
 491                                 nb_teams |= BIT(1);
 492                         }
 493                         break;
 494                 case NUM_TEAM_3:
 495                         if(!t_yellow)
 496                         {
 497                                 nb_spawnteam("Yellow", e.team-1);
 498                                 t_yellow = true;
 499                                 nb_teams |= BIT(2);
 500                         }
 501                         break;
 502                 case NUM_TEAM_4:
 503                         if(!t_pink)
 504                         {
 505                                 nb_spawnteam("Pink", e.team-1)  ;
 506                                 t_pink = true;
 507                                 nb_teams |= BIT(3);
 508                         }
 509                         break;
 510                 }
 511         }
 512 }
 513
 514 void nb_delayedinit(entity this)
 515 {
 516         if(find(NULL, classname, "nexball_team") == NULL)
 517                 nb_spawnteams();
 518         nb_ScoreRules(nb_teams);
 519 }
 520
 521
 522 //=======================//
 523 //        spawnfuncs       //
 524 //=======================//
 525
 526 void SpawnBall(entity this)
 527 {
 528         if(!g_nexball) { delete(this); return; }
 529
 530 //      balls += 4; // using the remaining bits to count balls will leave more than the max edict count, so it's fine
 531
 532         if(this.model == "")
 533         {
 534                 this.model = "models/nexball/ball.md3";
 535                 this.scale = 1.3;
 536         }
 537
 538         precache_model(this.model);
 539         _setmodel(this, this.model);
 540         setsize(this, BALL_MINS, BALL_MAXS);
 541         ball_scale = this.scale;
 542
 543         relocate_nexball(this);
 544         this.spawnorigin = this.origin;
 545
 546         this.effects = this.effects | EF_LOWPRECISION;
 547
 548         if(cvar(strcat("g_", this.classname, "_trail")))  //nexball_basketball :p
 549         {
 550                 this.glow_color = autocvar_g_nexball_trail_color;
 551                 this.glow_trail = true;
 552         }
 553
 554         set_movetype(this, MOVETYPE_FLY);
 555
 556         if(!autocvar_g_nexball_sound_bounce)
 557                 this.noise = "";
 558         else if(this.noise == "")
 559                 this.noise = strzone(SND(NB_BOUNCE));
 560         //bounce sound placeholder (FIXME)
 561         if(this.noise1 == "")
 562                 this.noise1 = strzone(SND(NB_DROP));
 563         //ball drop sound placeholder (FIXME)
 564         if(this.noise2 == "")
 565                 this.noise2 = strzone(SND(NB_STEAL));
 566         //stealing sound placeholder (FIXME)
 567         if(this.noise) precache_sound(this.noise);
 568         precache_sound(this.noise1);
 569         precache_sound(this.noise2);
 570
 571         WaypointSprite_AttachCarrier(WP_NbBall, this, RADARICON_FLAGCARRIER); // the ball's team is not set yet, no rule update needed
 572
 573         this.reset = ball_restart;
 574         setthink(this, InitBall);
 575         this.nextthink = game_starttime + autocvar_g_nexball_delay_start;
 576 }
 577
 578 spawnfunc(nexball_basketball)
 579 {
 580         nexball_mode |= NBM_BASKETBALL;
 581         this.classname = "nexball_basketball";
 582         if (!(balls & BALL_BASKET))
 583         {
 584                 /*
 585                 CVTOV(g_nexball_basketball_effects_default);
 586                 CVTOV(g_nexball_basketball_delay_hold);
 587                 CVTOV(g_nexball_basketball_delay_hold_forteam);
 588                 CVTOV(g_nexball_basketball_teamsteal);
 589                 */
 590                 autocvar_g_nexball_basketball_effects_default = autocvar_g_nexball_basketball_effects_default & BALL_EFFECTMASK;
 591         }
 592         if(!this.effects)
 593                 this.effects = autocvar_g_nexball_basketball_effects_default;
 594         this.solid = SOLID_TRIGGER;
 595         this.pushable = autocvar_g_nexball_basketball_jumppad;
 596         balls |= BALL_BASKET;
 597         this.bouncefactor = autocvar_g_nexball_basketball_bouncefactor;
 598         this.bouncestop = autocvar_g_nexball_basketball_bouncestop;
 599         SpawnBall(this);
 600 }
 601
 602 spawnfunc(nexball_football)
 603 {
 604         nexball_mode |= NBM_FOOTBALL;
 605         this.classname = "nexball_football";
 606         this.solid = SOLID_TRIGGER;
 607         balls |= BALL_FOOT;
 608         this.pushable = autocvar_g_nexball_football_jumppad;
 609         this.bouncefactor = autocvar_g_nexball_football_bouncefactor;
 610         this.bouncestop = autocvar_g_nexball_football_bouncestop;
 611         SpawnBall(this);
 612 }
 613
 614 bool nb_Goal_Customize(entity this, entity client)
 615 {
 616         entity e = WaypointSprite_getviewentity(client);
 617         entity wp_owner = this.owner;
 618         if(SAME_TEAM(e, wp_owner)) { return false; }
 619
 620         return true;
 621 }
 622
 623 void SpawnGoal(entity this)
 624 {
 625         if(!g_nexball) { delete(this); return; }
 626
 627         EXACTTRIGGER_INIT;
 628
 629         if(this.team != GOAL_OUT && Team_TeamToNumber(this.team) != -1)
 630         {
 631                 entity wp = WaypointSprite_SpawnFixed(WP_NbGoal, (this.absmin + this.absmax) * 0.5, this, sprite, RADARICON_NONE);
 632                 wp.colormod = ((this.team) ? Team_ColorRGB(this.team) : '1 0.5 0');
 633                 setcefc(this.sprite, nb_Goal_Customize);
 634         }
 635
 636         this.classname = "nexball_goal";
 637         if(this.noise == "")
 638                 this.noise = "ctf/respawn.wav";
 639         precache_sound(this.noise);
 640         settouch(this, GoalTouch);
 641 }
 642
 643 spawnfunc(nexball_redgoal)
 644 {
 645         this.team = NUM_TEAM_1;
 646         SpawnGoal(this);
 647 }
 648 spawnfunc(nexball_bluegoal)
 649 {
 650         this.team = NUM_TEAM_2;
 651         SpawnGoal(this);
 652 }
 653 spawnfunc(nexball_yellowgoal)
 654 {
 655         this.team = NUM_TEAM_3;
 656         SpawnGoal(this);
 657 }
 658 spawnfunc(nexball_pinkgoal)
 659 {
 660         this.team = NUM_TEAM_4;
 661         SpawnGoal(this);
 662 }
 663
 664 spawnfunc(nexball_fault)
 665 {
 666         this.team = GOAL_FAULT;
 667         if(this.noise == "")
 668                 this.noise = strzone(SND(TYPEHIT));
 669         SpawnGoal(this);
 670 }
 671
 672 spawnfunc(nexball_out)
 673 {
 674         this.team = GOAL_OUT;
 675         if(this.noise == "")
 676                 this.noise = strzone(SND(TYPEHIT));
 677         SpawnGoal(this);
 678 }
 679
 680 //
 681 //Spawnfuncs preserved for compatibility
 682 //
 683
 684 spawnfunc(ball)
 685 {
 686         spawnfunc_nexball_football(this);
 687 }
 688 spawnfunc(ball_football)
 689 {
 690         spawnfunc_nexball_football(this);
 691 }
 692 spawnfunc(ball_basketball)
 693 {
 694         spawnfunc_nexball_basketball(this);
 695 }
 696 // The "red goal" is defended by blue team. A ball in there counts as a point for red.
 697 spawnfunc(ball_redgoal)
 698 {
 699         spawnfunc_nexball_bluegoal(this);       // I blame Revenant
 700 }
 701 spawnfunc(ball_bluegoal)
 702 {
 703         spawnfunc_nexball_redgoal(this);        // but he didn't mean to cause trouble :p
 704 }
 705 spawnfunc(ball_fault)
 706 {
 707         spawnfunc_nexball_fault(this);
 708 }
 709 spawnfunc(ball_bound)
 710 {
 711         spawnfunc_nexball_out(this);
 712 }
 713
 714 //=======================//
 715 //        Weapon code     //
 716 //=======================//
 717
 718
 719 void W_Nexball_Think(entity this)
 720 {
 721         //dprint("W_Nexball_Think\n");
 722         //vector new_dir = steerlib_arrive(this.enemy.origin, 2500);
 723         vector new_dir = normalize(this.enemy.origin + '0 0 50' - this.origin);
 724         vector old_dir = normalize(this.velocity);
 725         float _speed = vlen(this.velocity);
 726         vector new_vel = normalize(old_dir + (new_dir * autocvar_g_nexball_safepass_turnrate)) * _speed;
 727         //vector new_vel = (new_dir * autocvar_g_nexball_safepass_turnrate
 728
 729         this.velocity = new_vel;
 730
 731         this.nextthink = time;
 732 }
 733
 734 void W_Nexball_Touch(entity this, entity toucher)
 735 {
 736         entity ball, attacker;
 737         attacker = this.owner;
 738         //this.think = func_null;
 739         //this.enemy = NULL;
 740
 741         PROJECTILE_TOUCH(this, toucher);
 742         if(attacker.team != toucher.team || autocvar_g_nexball_basketball_teamsteal)
 743                 if((ball = toucher.ballcarried) && !STAT(FROZEN, toucher) && !IS_DEAD(toucher) && (IS_PLAYER(attacker)))
 744                 {
 745                         toucher.velocity = toucher.velocity + normalize(this.velocity) * toucher.damageforcescale * autocvar_g_balance_nexball_secondary_force;
 746                         UNSET_ONGROUND(toucher);
 747                         if(!attacker.ballcarried)
 748                         {
 749                                 LogNB("stole", attacker);
 750                                 _sound(toucher, CH_TRIGGER, ball.noise2, VOL_BASE, ATTEN_NORM);
 751
 752                                 if(SAME_TEAM(attacker, toucher) && time > attacker.teamkill_complain)
 753                                 {
 754                                         attacker.teamkill_complain = time + 5;
 755                                         attacker.teamkill_soundtime = time + 0.4;
 756                                         attacker.teamkill_soundsource = toucher;
 757                                 }
 758
 759                                 GiveBall(attacker, toucher.ballcarried);
 760                         }
 761                 }
 762         delete(this);
 763 }
 764
 765 void W_Nexball_Attack(entity actor, .entity weaponentity, float t)
 766 {
 767         entity ball;
 768         float mul, mi, ma;
 769         if(!(ball = actor.ballcarried))
 770                 return;
 771
 772         W_SetupShot(actor, weaponentity, false, 4, SND_NB_SHOOT1, CH_WEAPON_A, 0);
 773         tracebox(w_shotorg, BALL_MINS, BALL_MAXS, w_shotorg, MOVE_WORLDONLY, NULL);
 774         if(trace_startsolid)
 775         {
 776                 if(actor.metertime)
 777                         actor.metertime = 0; // Shot failed, hide the power meter
 778                 return;
 779         }
 780
 781         //Calculate multiplier
 782         if(t < 0)
 783                 mul = 1;
 784         else
 785         {
 786                 mi = autocvar_g_nexball_basketball_meter_minpower;
 787                 ma = max(mi, autocvar_g_nexball_basketball_meter_maxpower); // avoid confusion
 788                 //One triangle wave period with 1 as max
 789                 mul = 2 * (t % g_nexball_meter_period) / g_nexball_meter_period;
 790                 if(mul > 1)
 791                         mul = 2 - mul;
 792                 mul = mi + (ma - mi) * mul; // range from the minimal power to the maximal power
 793         }
 794
 795         DropBall(ball, w_shotorg, W_CalculateProjectileVelocity(actor, actor.velocity, w_shotdir * autocvar_g_balance_nexball_primary_speed * mul, false));
 796
 797
 798         //TODO: use the speed_up cvar too ??
 799 }
 800
 801 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht);
 802
 803 void W_Nexball_Attack2(entity actor, .entity weaponentity)
 804 {
 805         if(actor.ballcarried.enemy)
 806         {
 807                 entity _ball = actor.ballcarried;
 808                 W_SetupShot(actor, weaponentity, false, 4, SND_NB_SHOOT1, CH_WEAPON_A, 0);
 809                 DropBall(_ball, w_shotorg, trigger_push_calculatevelocity(_ball.origin, _ball.enemy, 32));
 810                 setthink(_ball, W_Nexball_Think);
 811                 _ball.nextthink = time;
 812                 return;
 813         }
 814
 815         if(!autocvar_g_nexball_tackling)
 816                 return;
 817
 818         W_SetupShot(actor, weaponentity, false, 2, SND_NB_SHOOT2, CH_WEAPON_A, 0);
 819         entity missile = new(ballstealer);
 820
 821         missile.owner = actor;
 822
 823         set_movetype(missile, MOVETYPE_FLY);
 824         PROJECTILE_MAKETRIGGER(missile);
 825
 826         //setmodel(missile, "models/elaser.mdl");  // precision set below
 827         setsize(missile, '0 0 0', '0 0 0');
 828         setorigin(missile, w_shotorg);
 829
 830         W_SetupProjVelocity_Basic(missile, autocvar_g_balance_nexball_secondary_speed, 0);
 831         missile.angles = vectoangles(missile.velocity);
 832         settouch(missile, W_Nexball_Touch);
 833         setthink(missile, SUB_Remove);
 834         missile.nextthink = time + autocvar_g_balance_nexball_secondary_lifetime; //FIXME: use a distance instead?
 835
 836         missile.effects = EF_BRIGHTFIELD | EF_LOWPRECISION;
 837         missile.flags = FL_PROJECTILE;
 838         IL_PUSH(g_projectiles, missile);
 839         IL_PUSH(g_bot_dodge, missile);
 840
 841         CSQCProjectile(missile, true, PROJECTILE_ELECTRO, true);
 842 }
 843
 844 bool ball_customize(entity this, entity client)
 845 {
 846         if(!this.owner)
 847         {
 848                 this.effects &= ~EF_FLAME;
 849                 this.scale = 1;
 850                 setcefc(this, func_null);
 851                 return true;
 852         }
 853
 854         if(client == this.owner)
 855         {
 856                 this.scale = autocvar_g_nexball_viewmodel_scale;
 857                 if(this.enemy)
 858                         this.effects |= EF_FLAME;
 859                 else
 860                         this.effects &= ~EF_FLAME;
 861         }
 862         else
 863         {
 864                 this.effects &= ~EF_FLAME;
 865                 this.scale = 1;
 866         }
 867
 868         return true;
 869 }
 870
 871 METHOD(BallStealer, wr_think, void(BallStealer thiswep, entity actor, .entity weaponentity, int fire))
 872 {
 873     TC(BallStealer, thiswep);
 874     if(fire & 1)
 875         if(weapon_prepareattack(thiswep, actor, weaponentity, false, autocvar_g_balance_nexball_primary_refire))
 876             if(autocvar_g_nexball_basketball_meter)
 877             {
 878                 if(actor.ballcarried && !actor.metertime)
 879                     actor.metertime = time;
 880                 else
 881                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 882             }
 883             else
 884             {
 885                 W_Nexball_Attack(actor, weaponentity, -1);
 886                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 887             }
 888     if(fire & 2)
 889         if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_nexball_secondary_refire))
 890         {
 891             W_Nexball_Attack2(actor, weaponentity);
 892             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_nexball_secondary_animtime, w_ready);
 893         }
 894
 895     if(!(fire & 1) && actor.metertime && actor.ballcarried)
 896     {
 897         W_Nexball_Attack(actor, weaponentity, time - actor.metertime);
 898         // DropBall or stealing will set metertime back to 0
 899         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 900     }
 901 }
 902
 903 METHOD(BallStealer, wr_setup, void(BallStealer this, entity actor, .entity weaponentity))
 904 {
 905     TC(BallStealer, this);
 906     //weapon_setup(WEP_PORTO.m_id);
 907 }
 908
 909 METHOD(BallStealer, wr_checkammo1, bool(BallStealer this, entity actor, .entity weaponentity))
 910 {
 911     TC(BallStealer, this);
 912     return true;
 913 }
 914
 915 METHOD(BallStealer, wr_checkammo2, bool(BallStealer this, entity actor, .entity weaponentity))
 916 {
 917     TC(BallStealer, this);
 918     return true;
 919 }
 920
 921 void nb_DropBall(entity player)
 922 {
 923         if(player.ballcarried && g_nexball)
 924                 DropBall(player.ballcarried, player.origin, player.velocity);
 925 }
 926
 927 MUTATOR_HOOKFUNCTION(nb, ClientDisconnect)
 928 {
 929         entity player = M_ARGV(0, entity);
 930
 931         nb_DropBall(player);
 932 }
 933
 934 MUTATOR_HOOKFUNCTION(nb, PlayerDies)
 935 {
 936         entity frag_target = M_ARGV(2, entity);
 937
 938         nb_DropBall(frag_target);
 939 }
 940
 941 MUTATOR_HOOKFUNCTION(nb, MakePlayerObserver)
 942 {
 943         entity player = M_ARGV(0, entity);
 944
 945         nb_DropBall(player);
 946         return false;
 947 }
 948
 949 MUTATOR_HOOKFUNCTION(nb, PlayerPreThink)
 950 {
 951         entity player = M_ARGV(0, entity);
 952
 953         makevectors(player.v_angle);
 954         if(nexball_mode & NBM_BASKETBALL)
 955         {
 956                 if(player.ballcarried)
 957                 {
 958                         // 'view ball'
 959                         player.ballcarried.velocity = player.velocity;
 960                         setcefc(player.ballcarried, ball_customize);
 961
 962                         vector org = player.origin + player.view_ofs +
 963                                           v_forward * autocvar_g_nexball_viewmodel_offset.x +
 964                                           v_right * autocvar_g_nexball_viewmodel_offset.y +
 965                                           v_up * autocvar_g_nexball_viewmodel_offset.z;
 966                         setorigin(player.ballcarried, org);
 967
 968                         // 'safe passing'
 969                         if(autocvar_g_nexball_safepass_maxdist)
 970                         {
 971                                 if(player.ballcarried.wait < time && player.ballcarried.enemy)
 972                                 {
 973                                         //centerprint(player, sprintf("Lost lock on %s", player.ballcarried.enemy.netname));
 974                                         player.ballcarried.enemy = NULL;
 975                                 }
 976
 977
 978                                 //tracebox(player.origin + player.view_ofs, '-2 -2 -2', '2 2 2', player.origin + player.view_ofs + v_forward * autocvar_g_nexball_safepass_maxdist);
 979                                 crosshair_trace(player);
 980                                 if( trace_ent &&
 981                                         IS_CLIENT(trace_ent) &&
 982                                         !IS_DEAD(trace_ent) &&
 983                                         trace_ent.team == player.team &&
 984                                         vdist(trace_ent.origin - player.origin, <=, autocvar_g_nexball_safepass_maxdist) )
 985                                 {
 986
 987                                         //if(player.ballcarried.enemy != trace_ent)
 988                                         //      centerprint(player, sprintf("Locked to %s", trace_ent.netname));
 989                                         player.ballcarried.enemy = trace_ent;
 990                                         player.ballcarried.wait = time + autocvar_g_nexball_safepass_holdtime;
 991
 992
 993                                 }
 994                         }
 995                 }
 996                 else
 997                 {
 998                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 999                         {
1000                                 .entity weaponentity = weaponentities[slot];
1001
1002                                 if(player.(weaponentity).weapons)
1003                                 {
1004                                         player.weapons = player.(weaponentity).weapons;
1005                                         Weapon w = WEP_NEXBALL;
1006                                         w.wr_resetplayer(w, player);
1007                                         player.(weaponentity).m_switchweapon = player.m_switchweapon;
1008                                         W_SwitchWeapon(player, player.(weaponentity).m_switchweapon, weaponentity);
1009
1010                                         player.(weaponentity).weapons = '0 0 0';
1011                                 }
1012                         }
1013                 }
1014
1015         }
1016
1017         nexball_setstatus(player);
1018 }
1019
1020 MUTATOR_HOOKFUNCTION(nb, SpectateCopy)
1021 {
1022         entity spectatee = M_ARGV(0, entity);
1023         entity client = M_ARGV(1, entity);
1024
1025         client.metertime = spectatee.metertime;
1026 }
1027
1028 MUTATOR_HOOKFUNCTION(nb, PlayerSpawn)
1029 {
1030         entity player = M_ARGV(0, entity);
1031
1032         player.metertime = 0;
1033         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1034         {
1035                 .entity weaponentity = weaponentities[slot];
1036                 player.(weaponentity).weapons = '0 0 0';
1037         }
1038
1039         if (nexball_mode & NBM_BASKETBALL)
1040                 player.weapons |= WEPSET(NEXBALL);
1041         else
1042                 player.weapons = '0 0 0';
1043
1044         return false;
1045 }
1046
1047 .float stat_sv_airspeedlimit_nonqw;
1048 .float stat_sv_maxspeed;
1049
1050 MUTATOR_HOOKFUNCTION(nb, PlayerPhysics)
1051 {
1052         entity player = M_ARGV(0, entity);
1053
1054         if(player.ballcarried)
1055         {
1056                 player.stat_sv_airspeedlimit_nonqw *= autocvar_g_nexball_basketball_carrier_highspeed;
1057                 player.stat_sv_maxspeed *= autocvar_g_nexball_basketball_carrier_highspeed;
1058         }
1059 }
1060
1061 MUTATOR_HOOKFUNCTION(nb, ForbidThrowCurrentWeapon)
1062 {
1063         //entity player = M_ARGV(0, entity);
1064         entity wepent = M_ARGV(1, entity);
1065
1066         return wepent.m_weapon == WEP_NEXBALL;
1067 }
1068
1069 MUTATOR_HOOKFUNCTION(nb, ForbidDropCurrentWeapon)
1070 {
1071         //entity player = M_ARGV(0, entity);
1072         int wep = M_ARGV(1, int);
1073
1074         return wep == WEP_MORTAR.m_id; // TODO: what is this for?
1075 }
1076
1077 MUTATOR_HOOKFUNCTION(nb, FilterItem)
1078 {
1079         entity item = M_ARGV(0, entity);
1080
1081         if(item.classname == "droppedweapon")
1082         if(item.weapon == WEP_NEXBALL.m_id)
1083                 return true;
1084
1085         return false;
1086 }
1087
1088 MUTATOR_HOOKFUNCTION(nb, ItemTouch)
1089 {
1090         entity item = M_ARGV(0, entity);
1091         entity toucher = M_ARGV(1, entity);
1092
1093         if(item.weapon && toucher.ballcarried)
1094                 return MUT_ITEMTOUCH_RETURN; // no new weapons for you, mister!
1095
1096         return MUT_ITEMTOUCH_CONTINUE;
1097 }
1098
1099 MUTATOR_HOOKFUNCTION(nb, CheckAllowedTeams)
1100 {
1101         M_ARGV(1, string) = "nexball_team";
1102         return true;
1103 }
1104
1105 MUTATOR_HOOKFUNCTION(nb, WantWeapon)
1106 {
1107         M_ARGV(1, float) = 0; // weapon is set a few lines later, apparently
1108         return true;
1109 }
1110
1111 MUTATOR_HOOKFUNCTION(nb, DropSpecialItems)
1112 {
1113         entity frag_target = M_ARGV(0, entity);
1114
1115         if(frag_target.ballcarried)
1116                 DropBall(frag_target.ballcarried, frag_target.origin, frag_target.velocity);
1117
1118         return false;
1119 }
1120
1121 MUTATOR_HOOKFUNCTION(nb, SendWaypoint)
1122 {
1123         M_ARGV(2, int) &= ~0x80;
1124 }
1125
1126 REGISTER_MUTATOR(nb, g_nexball)
1127 {
1128         MUTATOR_ONADD
1129         {
1130                 g_nexball_meter_period = autocvar_g_nexball_meter_period;
1131                 if(g_nexball_meter_period <= 0)
1132                         g_nexball_meter_period = 2; // avoid division by zero etc. due to silly users
1133                 g_nexball_meter_period = rint(g_nexball_meter_period * 32) / 32; //Round to 1/32ths to send as a byte multiplied by 32
1134
1135                 // General settings
1136                 /*
1137                 CVTOV(g_nexball_football_boost_forward);   //100
1138                 CVTOV(g_nexball_football_boost_up);             //200
1139                 CVTOV(g_nexball_delay_idle);                       //10
1140                 CVTOV(g_nexball_football_physics);               //0
1141                 */
1142                 radar_showennemies = autocvar_g_nexball_radar_showallplayers;
1143
1144                 InitializeEntity(NULL, nb_delayedinit, INITPRIO_GAMETYPE);
1145                 WEP_NEXBALL.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
1146
1147                 ActivateTeamplay();
1148                 SetLimits(autocvar_g_nexball_goallimit, autocvar_g_nexball_goalleadlimit, autocvar_timelimit_override, -1);
1149                 have_team_spawns = -1; // request team spawns
1150         }
1151
1152         MUTATOR_ONROLLBACK_OR_REMOVE
1153         {
1154                 WEP_NEXBALL.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
1155                 // we actually cannot roll back nb_delayedinit here
1156                 // BUT: we don't need to! If this gets called, adding always
1157                 // succeeds.
1158         }
1159
1160         MUTATOR_ONREMOVE
1161         {
1162                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
1163                 return -1;
1164         }
1165
1166         return 0;
1167 }
1168
1169 #endif