Add support for pitch shifting to the QC sound sending implementation, apply pitch...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / gamemodes / gamemode / onslaught / sv_onslaught.qc
1 #include "sv_onslaught.qh"
2 #include "sv_controlpoint.qh"
3 #include "sv_generator.qh"
4
5 bool g_onslaught;
6
7 float autocvar_g_onslaught_teleport_wait;
8 bool autocvar_g_onslaught_spawn_at_controlpoints;
9 bool autocvar_g_onslaught_spawn_at_generator;
10 float autocvar_g_onslaught_cp_proxydecap;
11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
15 float autocvar_g_onslaught_spawn_at_generator_chance;
16 float autocvar_g_onslaught_spawn_at_generator_random;
17 float autocvar_g_onslaught_cp_buildhealth;
18 float autocvar_g_onslaught_cp_buildtime;
19 float autocvar_g_onslaught_cp_health;
20 float autocvar_g_onslaught_cp_regen;
21 float autocvar_g_onslaught_gen_health;
22 float autocvar_g_onslaught_shield_force = 100;
23 float autocvar_g_onslaught_allow_vehicle_touch;
24 float autocvar_g_onslaught_round_timelimit;
25 float autocvar_g_onslaught_warmup;
26 float autocvar_g_onslaught_teleport_radius;
27 float autocvar_g_onslaught_spawn_choose;
28 float autocvar_g_onslaught_click_radius;
29
30 entity cam;
31
32 // =======================
33 // CaptureShield Functions
34 // =======================
35
36 bool clientcamera_send(entity this, entity to, int sf)
37 {
38         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
39
40         WriteVector(MSG_ENTITY, this.origin);
41
42         WriteAngle(MSG_ENTITY, this.angles_x);
43         WriteAngle(MSG_ENTITY, this.angles_y);
44         WriteAngle(MSG_ENTITY, this.angles_z);
45
46         return true;
47 }
48
49 bool ons_CaptureShield_Customize(entity this, entity client)
50 {
51         entity e = WaypointSprite_getviewentity(client);
52
53         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
54         if(SAME_TEAM(this, e)) { return false; }
55
56         return true;
57 }
58
59 void ons_CaptureShield_Touch(entity this, entity toucher)
60 {
61         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
62         if(!IS_PLAYER(toucher)) { return; }
63         if(SAME_TEAM(toucher, this)) { return; }
64
65         vector mymid = (this.absmin + this.absmax) * 0.5;
66         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
67
68         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
69
70         if(IS_REAL_CLIENT(toucher))
71         {
72                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
73
74                 if(this.enemy.classname == "onslaught_generator")
75                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
76                 else
77                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
78         }
79 }
80
81 void ons_CaptureShield_Reset(entity this)
82 {
83         this.colormap = this.enemy.colormap;
84         this.team = this.enemy.team;
85 }
86
87 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
88 {
89         entity shield = new(ons_captureshield);
90         IL_PUSH(g_onsshields, shield);
91
92         shield.enemy = generator;
93         shield.team = generator.team;
94         shield.colormap = generator.colormap;
95         shield.reset = ons_CaptureShield_Reset;
96         settouch(shield, ons_CaptureShield_Touch);
97         setcefc(shield, ons_CaptureShield_Customize);
98         shield.effects = EF_ADDITIVE;
99         set_movetype(shield, MOVETYPE_NOCLIP);
100         shield.solid = SOLID_TRIGGER;
101         shield.avelocity = '7 0 11';
102         shield.scale = 1;
103         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
104
105         precache_model(shield.model);
106         setorigin(shield, generator.origin);
107         _setmodel(shield, shield.model);
108         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
109 }
110
111
112 // ==========
113 // Junk Pile
114 // ==========
115
116 void onslaught_updatelinks()
117 {
118         entity l;
119         // first check if the game has ended
120         LOG_DEBUG("--- updatelinks ---");
121         // mark generators as being shielded and networked
122         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
123         {
124                 if (l.iscaptured)
125                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
126                 else
127                         LOG_DEBUG(etos(l), " (generator) is destroyed");
128                 l.islinked = l.iscaptured;
129                 l.isshielded = l.iscaptured;
130                 l.sprite.SendFlags |= 16;
131         }
132         // mark points as shielded and not networked
133         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
134         {
135                 l.islinked = false;
136                 l.isshielded = true;
137                 l.aregensneighbor = 0;
138                 l.arecpsneighbor = 0;
139                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
140                 l.sprite.SendFlags |= 16;
141         }
142         // flow power outward from the generators through the network
143         bool stop = false;
144         while (!stop)
145         {
146                 stop = true;
147                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
148                 {
149                         // if both points are captured by the same team, and only one of
150                         // them is powered, mark the other one as powered as well
151                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
152                                 if (l.enemy.islinked != l.goalentity.islinked)
153                                         if(SAME_TEAM(l.enemy, l.goalentity))
154                                         {
155                                                 if (!l.goalentity.islinked)
156                                                 {
157                                                         stop = false;
158                                                         l.goalentity.islinked = true;
159                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
160                                                 }
161                                                 else if (!l.enemy.islinked)
162                                                 {
163                                                         stop = false;
164                                                         l.enemy.islinked = true;
165                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
166                                                 }
167                                         }
168                 }
169         }
170         // now that we know which points are powered we can mark their neighbors
171         // as unshielded if team differs
172         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
173         {
174                 if (l.goalentity.islinked)
175                 {
176                         if(DIFF_TEAM(l.goalentity, l.enemy))
177                         {
178                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
179                                 l.enemy.isshielded = false;
180                         }
181                         if(l.goalentity.classname == "onslaught_generator")
182                                 l.enemy.aregensneighbor |= BIT(l.goalentity.team);
183                         else
184                                 l.enemy.arecpsneighbor |= BIT(l.goalentity.team);
185                 }
186                 if (l.enemy.islinked)
187                 {
188                         if(DIFF_TEAM(l.goalentity, l.enemy))
189                         {
190                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
191                                 l.goalentity.isshielded = false;
192                         }
193                         if(l.enemy.classname == "onslaught_generator")
194                                 l.goalentity.aregensneighbor |= BIT(l.enemy.team);
195                         else
196                                 l.goalentity.arecpsneighbor |= BIT(l.enemy.team);
197                 }
198         }
199         // now update the generators
200         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
201         {
202                 if (l.isshielded)
203                 {
204                         LOG_DEBUG(etos(l), " (generator) is shielded");
205                         l.takedamage = DAMAGE_NO;
206                         if(l.bot_attack)
207                                 IL_REMOVE(g_bot_targets, l);
208                         l.bot_attack = false;
209                 }
210                 else
211                 {
212                         LOG_DEBUG(etos(l), " (generator) is not shielded");
213                         l.takedamage = DAMAGE_AIM;
214                         if(!l.bot_attack)
215                                 IL_PUSH(g_bot_targets, l);
216                         l.bot_attack = true;
217                 }
218
219                 ons_Generator_UpdateSprite(l);
220         }
221         // now update the takedamage and alpha variables on control point icons
222         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
223         {
224                 if (l.isshielded)
225                 {
226                         LOG_DEBUG(etos(l), " (point) is shielded");
227                         if (l.goalentity)
228                         {
229                                 l.goalentity.takedamage = DAMAGE_NO;
230                                 if(l.goalentity.bot_attack)
231                                         IL_REMOVE(g_bot_targets, l.goalentity);
232                                 l.goalentity.bot_attack = false;
233                         }
234                 }
235                 else
236                 {
237                         LOG_DEBUG(etos(l), " (point) is not shielded");
238                         if (l.goalentity)
239                         {
240                                 l.goalentity.takedamage = DAMAGE_AIM;
241                                 if(!l.goalentity.bot_attack)
242                                         IL_PUSH(g_bot_targets, l.goalentity);
243                                 l.goalentity.bot_attack = true;
244                         }
245                 }
246                 ons_ControlPoint_UpdateSprite(l);
247         }
248         IL_EACH(g_onsshields, true,
249         {
250                 it.team = it.enemy.team;
251                 it.colormap = it.enemy.colormap;
252         });
253 }
254
255
256 // ===================
257 // Main Link Functions
258 // ===================
259
260 bool ons_Link_Send(entity this, entity to, int sendflags)
261 {
262         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
263         WriteByte(MSG_ENTITY, sendflags);
264         if(sendflags & 1)
265         {
266                 WriteVector(MSG_ENTITY, this.goalentity.origin);
267         }
268         if(sendflags & 2)
269         {
270                 WriteVector(MSG_ENTITY, this.enemy.origin);
271         }
272         if(sendflags & 4)
273         {
274                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
275         }
276         return true;
277 }
278
279 void ons_Link_CheckUpdate(entity this)
280 {
281         // TODO check if the two sides have moved (currently they won't move anyway)
282         float cc = 0, cc1 = 0, cc2 = 0;
283
284         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
285         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
286
287         cc = cc1 + cc2;
288
289         if(cc != this.clientcolors)
290         {
291                 this.clientcolors = cc;
292                 this.SendFlags |= 4;
293         }
294
295         this.nextthink = time;
296 }
297
298 void ons_DelayedLinkSetup(entity this)
299 {
300         this.goalentity = find(NULL, targetname, this.target);
301         this.enemy = find(NULL, targetname, this.target2);
302         if(!this.goalentity) { objerror(this, "can not find target\n"); }
303         if(!this.enemy) { objerror(this, "can not find target2\n"); }
304
305         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
306         this.SendFlags |= 3;
307         setthink(this, ons_Link_CheckUpdate);
308         this.nextthink = time;
309 }
310
311
312 // =============================
313 // Main Control Point Functions
314 // =============================
315
316 int ons_ControlPoint_CanBeLinked(entity cp, int teamnum)
317 {
318         if(cp.aregensneighbor & BIT(teamnum)) return 2;
319         if(cp.arecpsneighbor & BIT(teamnum)) return 1;
320
321         return 0;
322 }
323
324 int ons_ControlPoint_Attackable(entity cp, int teamnum)
325         // -2: SAME TEAM, attackable by enemy!
326         // -1: SAME TEAM!
327         // 0: off limits
328         // 1: attack it
329         // 2: touch it
330         // 3: attack it (HIGH PRIO)
331         // 4: touch it (HIGH PRIO)
332 {
333         int a;
334
335         if(cp.isshielded)
336         {
337                 return 0;
338         }
339         else if(cp.goalentity)
340         {
341                 // if there's already an icon built, nothing happens
342                 if(cp.team == teamnum)
343                 {
344                         a = ons_ControlPoint_CanBeLinked(cp, teamnum);
345                         if(a) // attackable by enemy?
346                                 return -2; // EMERGENCY!
347                         return -1;
348                 }
349                 // we know it can be linked, so no need to check
350                 // but...
351                 a = ons_ControlPoint_CanBeLinked(cp, teamnum);
352                 if(a == 2) // near our generator?
353                         return 3; // EMERGENCY!
354                 return 1;
355         }
356         else
357         {
358                 // free point
359                 if(ons_ControlPoint_CanBeLinked(cp, teamnum))
360                 {
361                         a = ons_ControlPoint_CanBeLinked(cp, teamnum); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
362                         if(a == 2)
363                                 return 4; // GET THIS ONE NOW!
364                         else
365                                 return 2; // TOUCH ME
366                 }
367         }
368         return 0;
369 }
370
371 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
372 {
373         if(damage <= 0) { return; }
374
375         if (this.owner.isshielded)
376         {
377                 // this is protected by a shield, so ignore the damage
378                 if (time > this.pain_finished)
379                         if (IS_PLAYER(attacker))
380                         {
381                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
382                                 this.pain_finished = time + 1;
383                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
384                         }
385
386                 return;
387         }
388
389         if(IS_PLAYER(attacker))
390         if(time - ons_notification_time[this.team] > 10)
391         {
392                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
393                 ons_notification_time[this.team] = time;
394         }
395
396         TakeResource(this, RES_HEALTH, damage);
397         if(this.owner.iscaptured)
398                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResource(this, RES_HEALTH));
399         else
400                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - GetResource(this, RES_HEALTH)) / (this.count / ONS_CP_THINKRATE));
401         this.pain_finished = time + 1;
402         // particles on every hit
403         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
404         //sound on every hit
405         if (random() < 0.5)
406                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
407         else
408                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
409
410         if (GetResource(this, RES_HEALTH) < 0)
411         {
412                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
413                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
414                 if (this.owner.message != "")
415                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
416                 else
417                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED_NONAME), attacker.netname);
418
419                 GameRules_scoring_add(attacker, ONS_TAKES, 1);
420                 GameRules_scoring_add(attacker, SCORE, 10);
421
422                 this.owner.goalentity = NULL;
423                 this.owner.islinked = false;
424                 this.owner.iscaptured = false;
425                 this.owner.team = 0;
426                 this.owner.colormap = 1024;
427
428                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
429
430                 onslaught_updatelinks();
431
432                 // Use targets now (somebody make sure this is in the right place..)
433                 SUB_UseTargets(this.owner, this, NULL);
434
435                 this.owner.waslinked = this.owner.islinked;
436                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
437                         setmodel(this.owner, MDL_ONS_CP_PAD1);
438                 //setsize(this, '-32 -32 0', '32 32 8');
439
440                 delete(this);
441         }
442
443         this.SendFlags |= CPSF_STATUS;
444 }
445
446 bool ons_ControlPoint_Icon_Heal(entity targ, entity inflictor, float amount, float limit)
447 {
448         float hlth = GetResource(targ, RES_HEALTH);
449         float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
450         if (hlth <= 0 || hlth >= true_limit)
451                 return false;
452
453         GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
454         hlth = GetResource(targ, RES_HEALTH);
455         if(targ.owner.iscaptured)
456                 WaypointSprite_UpdateHealth(targ.owner.sprite, hlth);
457         else
458                 WaypointSprite_UpdateBuildFinished(targ.owner.sprite, time + (targ.max_health - hlth) / (targ.count / ONS_CP_THINKRATE));
459         targ.SendFlags |= CPSF_STATUS;
460         return true;
461 }
462
463 void ons_ControlPoint_Icon_Think(entity this)
464 {
465         this.nextthink = time + ONS_CP_THINKRATE;
466
467         if(autocvar_g_onslaught_cp_proxydecap)
468         {
469                 int _enemy_count = 0;
470                 int _friendly_count = 0;
471
472                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
473                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
474                         {
475                                 if(SAME_TEAM(it, this))
476                                         ++_friendly_count;
477                                 else
478                                         ++_enemy_count;
479                         }
480                 });
481
482                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
483                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
484
485                 GiveResourceWithLimit(this, RES_HEALTH, (_friendly_count - _enemy_count), this.max_health);
486                 this.SendFlags |= CPSF_STATUS;
487                 if(GetResource(this, RES_HEALTH) <= 0)
488                 {
489                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, DMG_NOWEP, this.origin, '0 0 0');
490                         return;
491                 }
492         }
493
494         if (time > this.pain_finished + 5)
495         {
496                 if(GetResource(this, RES_HEALTH) < this.max_health)
497                 {
498                         GiveResourceWithLimit(this, RES_HEALTH, this.count, this.max_health);
499                         WaypointSprite_UpdateHealth(this.owner.sprite, GetResource(this, RES_HEALTH));
500                 }
501         }
502
503         if(this.owner.islinked != this.owner.waslinked)
504         {
505                 // unteam the spawnpoint if needed
506                 int t = this.owner.team;
507                 if(!this.owner.islinked)
508                         this.owner.team = 0;
509
510                 SUB_UseTargets(this.owner, this, NULL);
511
512                 this.owner.team = t;
513
514                 this.owner.waslinked = this.owner.islinked;
515         }
516
517         // damaged fx
518         if(random() < 0.6 - GetResource(this, RES_HEALTH) / this.max_health)
519         {
520                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
521
522                 if(random() > 0.8)
523                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
524                 else if (random() > 0.5)
525                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
526         }
527 }
528
529 void ons_ControlPoint_Icon_BuildThink(entity this)
530 {
531         int a;
532
533         this.nextthink = time + ONS_CP_THINKRATE;
534
535         // only do this if there is power
536         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
537         if(!a)
538                 return;
539
540         GiveResource(this, RES_HEALTH, this.count);
541
542         this.SendFlags |= CPSF_STATUS;
543
544         if (GetResource(this, RES_HEALTH) >= this.max_health)
545         {
546                 SetResourceExplicit(this, RES_HEALTH, this.max_health);
547                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
548                 setthink(this, ons_ControlPoint_Icon_Think);
549                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
550                 this.owner.iscaptured = true;
551                 this.solid = SOLID_BBOX;
552
553                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
554
555                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
556                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResource(this, RES_HEALTH));
557
558                 if(IS_PLAYER(this.owner.ons_toucher))
559                 {
560                         if(this.owner.message != "")
561                         {
562                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
563                                 Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
564                                 Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
565                         }
566                         else
567                         {
568                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE_NONAME, this.owner.ons_toucher.netname);
569                                 Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM_NONAME));
570                                 Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE_NONAME);
571                         }
572                         GameRules_scoring_add(this.owner.ons_toucher, ONS_CAPS, 1);
573                         GameRules_scoring_add_team(this.owner.ons_toucher, SCORE, 10);
574                 }
575
576                 this.owner.ons_toucher = NULL;
577
578                 onslaught_updatelinks();
579
580                 // Use targets now (somebody make sure this is in the right place..)
581                 SUB_UseTargets(this.owner, this, NULL);
582
583                 this.SendFlags |= CPSF_SETUP;
584         }
585         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
586                 setmodel(this.owner, MDL_ONS_CP_PAD2);
587
588         if(random() < 0.9 - GetResource(this, RES_HEALTH) / this.max_health)
589                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
590 }
591
592 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
593
594 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
595 {
596         entity e = new(onslaught_controlpoint_icon);
597
598         setsize(e, CPICON_MIN, CPICON_MAX);
599         setorigin(e, cp.origin + CPICON_OFFSET);
600
601         e.owner = cp;
602         e.max_health = autocvar_g_onslaught_cp_health;
603         SetResourceExplicit(e, RES_HEALTH, autocvar_g_onslaught_cp_buildhealth);
604         e.solid = SOLID_NOT;
605         e.takedamage = DAMAGE_AIM;
606         e.bot_attack = true;
607         IL_PUSH(g_bot_targets, e);
608         e.event_damage = ons_ControlPoint_Icon_Damage;
609         e.event_heal = ons_ControlPoint_Icon_Heal;
610         e.team = player.team;
611         e.colormap = 1024 + (e.team - 1) * 17;
612         e.count = (e.max_health - GetResource(e, RES_HEALTH)) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
613
614         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
615
616         cp.goalentity = e;
617         cp.team = e.team;
618         cp.colormap = e.colormap;
619
620         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
621
622         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - GetResource(e, RES_HEALTH)) / (e.count / ONS_CP_THINKRATE));
623         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
624         cp.sprite.SendFlags |= 16;
625
626         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
627 }
628
629 entity ons_ControlPoint_Waypoint(entity e)
630 {
631         if(e.team)
632         {
633                 int a = ons_ControlPoint_Attackable(e, e.team);
634
635                 if(a == -2) { return WP_OnsCPDefend; } // defend now
636                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
637                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
638         }
639         else
640                 return WP_OnsCP;
641
642         return WP_Null;
643 }
644
645 void ons_ControlPoint_UpdateSprite(entity e)
646 {
647         entity s1 = ons_ControlPoint_Waypoint(e);
648         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
649
650         bool sh;
651         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
652
653         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
654         {
655                 if(e.iscaptured) // don't mess up build bars!
656                 {
657                         if(sh)
658                         {
659                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
660                         }
661                         else
662                         {
663                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
664                                 WaypointSprite_UpdateHealth(e.sprite, GetResource(e.goalentity, RES_HEALTH));
665                         }
666                 }
667                 if(e.lastshielded)
668                 {
669                         if(e.team)
670                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
671                         else
672                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
673                 }
674                 else
675                 {
676                         if(e.team)
677                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
678                         else
679                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
680                 }
681                 WaypointSprite_Ping(e.sprite);
682
683                 e.lastteam = e.team + 2;
684                 e.lastshielded = sh;
685                 e.lastcaptured = e.iscaptured;
686         }
687 }
688
689 void ons_ControlPoint_Touch(entity this, entity toucher)
690 {
691         int attackable;
692
693         if(IS_VEHICLE(toucher) && toucher.owner)
694         {
695                 if (!autocvar_g_onslaught_allow_vehicle_touch)
696                         return;
697                 toucher = toucher.owner;
698         }
699
700         if(!IS_PLAYER(toucher)) { return; }
701         if(STAT(FROZEN, toucher)) { return; }
702         if(IS_DEAD(toucher)) { return; }
703
704         if ( SAME_TEAM(this,toucher) )
705         if ( this.iscaptured )
706         {
707                 if(time <= toucher.teleport_antispam)
708                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
709                 else
710                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
711         }
712
713         attackable = ons_ControlPoint_Attackable(this, toucher.team);
714         if(attackable != 2 && attackable != 4)
715                 return;
716         // we've verified that this player has a legitimate claim to this point,
717         // so start building the captured point icon (which only captures this
718         // point if it successfully builds without being destroyed first)
719         ons_ControlPoint_Icon_Spawn(this, toucher);
720
721         this.ons_toucher = toucher;
722
723         onslaught_updatelinks();
724 }
725
726 void ons_ControlPoint_Think(entity this)
727 {
728         this.nextthink = time + ONS_CP_THINKRATE;
729         CSQCMODEL_AUTOUPDATE(this);
730 }
731
732 void ons_ControlPoint_Reset(entity this)
733 {
734         if(this.goalentity)
735                 delete(this.goalentity);
736
737         this.goalentity = NULL;
738         this.team = 0;
739         this.colormap = 1024;
740         this.iscaptured = false;
741         this.islinked = false;
742         this.isshielded = true;
743         setthink(this, ons_ControlPoint_Think);
744         this.ons_toucher = NULL;
745         this.nextthink = time + ONS_CP_THINKRATE;
746         setmodel(this, MDL_ONS_CP_PAD1);
747
748         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
749         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
750
751         onslaught_updatelinks();
752
753         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
754
755         CSQCMODEL_AUTOUPDATE(this);
756 }
757
758 void ons_DelayedControlPoint_Setup(entity this)
759 {
760         onslaught_updatelinks();
761
762         // captureshield setup
763         ons_CaptureShield_Spawn(this, false);
764
765         CSQCMODEL_AUTOINIT(this);
766 }
767
768 void ons_ControlPoint_Setup(entity cp)
769 {
770         // main setup
771         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
772         ons_worldcplist = cp;
773
774         cp.netname = "Control point";
775         cp.team = 0;
776         cp.solid = SOLID_BBOX;
777         set_movetype(cp, MOVETYPE_NONE);
778         settouch(cp, ons_ControlPoint_Touch);
779         setthink(cp, ons_ControlPoint_Think);
780         cp.nextthink = time + ONS_CP_THINKRATE;
781         cp.reset = ons_ControlPoint_Reset;
782         cp.colormap = 1024;
783         cp.iscaptured = false;
784         cp.islinked = false;
785         cp.isshielded = true;
786
787         // appearence
788         setmodel(cp, MDL_ONS_CP_PAD1);
789
790         // control point placement
791         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
792         {
793                 cp.noalign = true;
794                 set_movetype(cp, MOVETYPE_NONE);
795         }
796         else // drop to floor, automatically find a platform and set that as spawn origin
797         {
798                 setorigin(cp, cp.origin + '0 0 20');
799                 cp.noalign = false;
800                 droptofloor(cp);
801                 set_movetype(cp, MOVETYPE_TOSS);
802         }
803
804         // waypointsprites
805         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
806         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
807
808         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
809 }
810
811
812 // =========================
813 // Main Generator Functions
814 // =========================
815
816 entity ons_Generator_Waypoint(entity e)
817 {
818         if (e.isshielded)
819                 return WP_OnsGenShielded;
820         return WP_OnsGen;
821 }
822
823 void ons_Generator_UpdateSprite(entity e)
824 {
825         entity s1 = ons_Generator_Waypoint(e);
826         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
827
828         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
829         {
830                 e.lastteam = e.team + 2;
831                 e.lastshielded = e.isshielded;
832                 if(e.lastshielded)
833                 {
834                         if(e.team)
835                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
836                         else
837                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
838                 }
839                 else
840                 {
841                         if(e.team)
842                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
843                         else
844                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
845                 }
846                 WaypointSprite_Ping(e.sprite);
847         }
848 }
849
850 void ons_camSetup(entity this)
851 {
852         vector dir;
853         vector ang = '0 0 0';
854         vector best_ang = '0 0 0';
855         float best_trace_fraction = 0;
856         while(ang.y < 360)
857         {
858                 dir = vec2(cos(ang.y * DEG2RAD), sin(ang.y * DEG2RAD));
859                 dir *= 500;
860                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
861                 if(trace_fraction > best_trace_fraction)
862                 {
863                         best_trace_fraction = trace_fraction;
864                         best_ang = ang;
865                         if(trace_fraction == 1)
866                                 break;
867                 }
868                 ang.y += 90;
869                 if(ang.y == 360)
870                         ang.y = 45;
871         }
872         cam.origin = this.origin;
873         setorigin(cam, cam.origin);
874         cam.angles = best_ang;
875         Net_LinkEntity(cam, false, 0, clientcamera_send);
876
877         FOREACH_CLIENT(true, it.clientcamera = cam;);
878
879         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
880         WriteAngle(MSG_ALL, cam.angles_x);
881         WriteAngle(MSG_ALL, cam.angles_y);
882         WriteAngle(MSG_ALL, cam.angles_z);
883 }
884
885 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
886 {
887         if(damage <= 0) return;
888         if(warmup_stage || game_stopped) return;
889         if(!round_handler_IsRoundStarted()) return;
890
891         if (attacker != this)
892         {
893                 if (this.isshielded)
894                 {
895                         // generator is protected by a shield, so ignore the damage
896                         if (time > this.pain_finished)
897                                 if (IS_PLAYER(attacker))
898                                 {
899                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
900                                         attacker.typehitsound += 1;
901                                         this.pain_finished = time + 1;
902                                 }
903                         return;
904                 }
905                 if (time > this.pain_finished)
906                 {
907                         this.pain_finished = time + 10;
908                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
909                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
910                 }
911         }
912         TakeResource(this, RES_HEALTH, damage);
913         float hlth = GetResource(this, RES_HEALTH);
914         WaypointSprite_UpdateHealth(this.sprite, hlth);
915         // choose an animation frame based on health
916         this.frame = 10 * bound(0, (1 - hlth / this.max_health), 1);
917         // see if the generator is still functional, or dying
918         if (hlth > 0)
919         {
920                 this.lasthealth = hlth;
921         }
922         else
923         {
924                 if (attacker == this)
925                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
926                 else
927                 {
928                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
929                         GameRules_scoring_add(attacker, SCORE, 100);
930                 }
931                 this.iscaptured = false;
932                 this.islinked = false;
933                 this.isshielded = false;
934                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
935                 this.event_damage = func_null; // won't do anything if hurt
936                 this.event_heal = func_null;
937                 this.count = 0; // reset counter
938                 setthink(this, func_null);
939                 this.nextthink = 0;
940                 //this.think(); // do the first explosion now
941
942                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
943                 WaypointSprite_Ping(this.sprite);
944                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
945
946                 onslaught_updatelinks();
947
948                 ons_camSetup(this);
949         }
950
951         // Throw some flaming gibs on damage, more damage = more chance for gib
952         if(random() < damage/220)
953         {
954                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
955         }
956         else
957         {
958                 // particles on every hit
959                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
960
961                 //sound on every hit
962                 if (random() < 0.5)
963                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
964                 else
965                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
966         }
967
968         this.SendFlags |= GSF_STATUS;
969 }
970
971 bool ons_GeneratorHeal(entity targ, entity inflictor, float amount, float limit)
972 {
973         float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
974         float hlth = GetResource(targ, RES_HEALTH);
975         if (hlth <= 0 || hlth >= true_limit)
976                 return false;
977
978         GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
979         hlth = GetResource(targ, RES_HEALTH);
980         WaypointSprite_UpdateHealth(targ.sprite, hlth);
981         targ.frame = 10 * bound(0, (1 - hlth / targ.max_health), 1);
982         targ.lasthealth = hlth;
983         targ.SendFlags |= GSF_STATUS;
984         return true;
985 }
986
987 void ons_GeneratorThink(entity this)
988 {
989         this.nextthink = time + GEN_THINKRATE;
990
991         if (game_stopped || this.isshielded || time < this.wait)
992                 return;
993
994         this.wait = time + 5;
995         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it),
996         {
997                 if (SAME_TEAM(it, this))
998                 {
999                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
1000                         msg_entity = it;
1001                         soundto(MSG_ONE, this, CHAN_AUTO, SND(ONS_GENERATOR_ALARM), VOL_BASE, ATTEN_NONE, 0);
1002                 }
1003                 else
1004                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
1005         });
1006 }
1007
1008 void ons_GeneratorReset(entity this)
1009 {
1010         this.team = this.team_saved;
1011         SetResourceExplicit(this, RES_HEALTH, autocvar_g_onslaught_gen_health);
1012         this.lasthealth = this.max_health = autocvar_g_onslaught_gen_health;
1013         this.takedamage = DAMAGE_AIM;
1014         this.bot_attack = true;
1015         if(!IL_CONTAINS(g_bot_targets, this))
1016                 IL_PUSH(g_bot_targets, this);
1017         this.iscaptured = true;
1018         this.islinked = true;
1019         this.isshielded = true;
1020         this.event_damage = ons_GeneratorDamage;
1021         this.event_heal = ons_GeneratorHeal;
1022         setthink(this, ons_GeneratorThink);
1023         this.nextthink = time + GEN_THINKRATE;
1024
1025         Net_LinkEntity(this, false, 0, generator_send);
1026
1027         this.SendFlags = GSF_SETUP; // just incase
1028         this.SendFlags |= GSF_STATUS;
1029
1030         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
1031         WaypointSprite_UpdateHealth(this.sprite, GetResource(this, RES_HEALTH));
1032         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
1033
1034         onslaught_updatelinks();
1035 }
1036
1037 void ons_DelayedGeneratorSetup(entity this)
1038 {
1039         // bot waypoints
1040         waypoint_spawnforitem_force(this, this.origin);
1041         this.nearestwaypointtimeout = 0; // activate waypointing again
1042         this.bot_basewaypoint = this.nearestwaypoint;
1043
1044         // captureshield setup
1045         ons_CaptureShield_Spawn(this, true);
1046
1047         onslaught_updatelinks();
1048
1049         Net_LinkEntity(this, false, 0, generator_send);
1050 }
1051
1052
1053 void onslaught_generator_touch(entity this, entity toucher)
1054 {
1055         if ( IS_PLAYER(toucher) )
1056         if ( SAME_TEAM(this,toucher) )
1057         if ( this.iscaptured )
1058         {
1059                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1060         }
1061 }
1062
1063 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1064 {
1065         // declarations
1066         int teamnum = gen.team;
1067
1068         // main setup
1069         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1070         ons_worldgeneratorlist = gen;
1071
1072         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnum));
1073         gen.classname = "onslaught_generator";
1074         gen.solid = SOLID_BBOX;
1075         gen.team_saved = teamnum;
1076         IL_PUSH(g_saved_team, gen);
1077         set_movetype(gen, MOVETYPE_NONE);
1078         gen.lasthealth = gen.max_health = autocvar_g_onslaught_gen_health;
1079         SetResourceExplicit(gen, RES_HEALTH, autocvar_g_onslaught_gen_health);
1080         gen.takedamage = DAMAGE_AIM;
1081         gen.bot_attack = true;
1082         IL_PUSH(g_bot_targets, gen);
1083         gen.event_damage = ons_GeneratorDamage;
1084         gen.event_heal = ons_GeneratorHeal;
1085         gen.reset = ons_GeneratorReset;
1086         setthink(gen, ons_GeneratorThink);
1087         gen.nextthink = time + GEN_THINKRATE;
1088         gen.iscaptured = true;
1089         gen.islinked = true;
1090         gen.isshielded = true;
1091         settouch(gen, onslaught_generator_touch);
1092
1093         // appearence
1094         // model handled by CSQC
1095         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1096         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1097         gen.colormap = 1024 + (teamnum - 1) * 17;
1098
1099         // generator placement
1100         droptofloor(gen);
1101
1102         // waypointsprites
1103         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1104         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1105         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1106         WaypointSprite_UpdateHealth(gen.sprite, GetResource(gen, RES_HEALTH));
1107
1108         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1109 }
1110
1111
1112 // ===============
1113 //  Round Handler
1114 // ===============
1115
1116 int total_generators;
1117 void Onslaught_count_generators()
1118 {
1119         entity e;
1120         total_generators = 0;
1121         for (int i = 1; i <= NUM_TEAMS; ++i)
1122         {
1123                 Team_SetNumberOfControlPoints(Team_GetTeamFromIndex(i), 0);
1124         }
1125         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1126         {
1127                 ++total_generators;
1128                 if (GetResource(e, RES_HEALTH) < 1)
1129                 {
1130                         continue;
1131                 }
1132                 entity team_ = Entity_GetTeam(e);
1133                 int num_control_points = Team_GetNumberOfControlPoints(team_);
1134                 ++num_control_points;
1135                 Team_SetNumberOfControlPoints(team_, num_control_points);
1136         }
1137 }
1138
1139 int Onslaught_GetWinnerTeam()
1140 {
1141         int winner_team = 0;
1142         if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(1)) >= 1)
1143         {
1144                 winner_team = NUM_TEAM_1;
1145         }
1146         for (int i = 2; i <= NUM_TEAMS; ++i)
1147         {
1148                 if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(i)) >= 1)
1149                 {
1150                         if (winner_team != 0)
1151                         {
1152                                 return 0;
1153                         }
1154                         winner_team = Team_IndexToTeam(i);
1155                 }
1156         }
1157         if (winner_team)
1158         {
1159                 return winner_team;
1160         }
1161         return -1; // no generators left?
1162 }
1163
1164 void nades_Clear(entity e);
1165
1166 bool Onslaught_CheckWinner()
1167 {
1168         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1169         {
1170                 ons_stalemate = true;
1171
1172                 if (!wpforenemy_announced)
1173                 {
1174                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1175                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1176
1177                         wpforenemy_announced = true;
1178                 }
1179
1180                 entity tmp_entity; // temporary entity
1181                 float d;
1182                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1183                 {
1184                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1185                         // control points reduce the overtime duration.
1186                         d = 1;
1187                         entity e;
1188                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1189                         {
1190                                 if(DIFF_TEAM(e, tmp_entity))
1191                                 if(e.islinked)
1192                                         d = d + 1;
1193                         }
1194
1195                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1196                                 d = d * tmp_entity.max_health;
1197                         else
1198                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1199
1200                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, tmp_entity.origin, '0 0 0');
1201
1202                         tmp_entity.sprite.SendFlags |= 16;
1203
1204                         tmp_entity.ons_overtime_damagedelay = time + 1;
1205                 }
1206         }
1207         else { wpforenemy_announced = false; ons_stalemate = false; }
1208
1209         Onslaught_count_generators();
1210
1211         if (Team_GetNumberOfTeamsWithControlPoints() > 1)
1212         {
1213                 return 0;
1214         }
1215
1216         int winner_team = Onslaught_GetWinnerTeam();
1217
1218         if(winner_team > 0)
1219         {
1220                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1221                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1222                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1223         }
1224         else if(winner_team == -1)
1225         {
1226                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1227                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1228         }
1229
1230         ons_stalemate = false;
1231
1232         play2all(SND(CTF_CAPTURE(winner_team)));
1233
1234         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1235
1236         FOREACH_CLIENT(IS_PLAYER(it), {
1237                 STAT(ROUNDLOST, it) = true;
1238                 it.player_blocked = true;
1239
1240                 nades_Clear(it);
1241         });
1242
1243         game_stopped = true;
1244         return 1;
1245 }
1246
1247 bool Onslaught_CheckPlayers()
1248 {
1249         return 1;
1250 }
1251
1252 void Onslaught_RoundStart()
1253 {
1254         entity tmp_entity;
1255         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1256
1257         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1258                 tmp_entity.sprite.SendFlags |= 16;
1259
1260         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1261                 tmp_entity.sprite.SendFlags |= 16;
1262 }
1263
1264
1265 // ================
1266 // Bot player logic
1267 // ================
1268
1269 // NOTE: LEGACY CODE, needs to be re-written!
1270
1271 void havocbot_role_ons_setrole(entity this, int role)
1272 {
1273         switch(role)
1274         {
1275                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1276                         LOG_DEBUG(this.netname, " switched to defense");
1277                         this.havocbot_role = havocbot_role_ons_defense;
1278                         this.havocbot_role_timeout = 0;
1279                         break;
1280                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1281                         LOG_DEBUG(this.netname, " switched to assistant");
1282                         this.havocbot_role = havocbot_role_ons_assistant;
1283                         this.havocbot_role_timeout = 0;
1284                         break;
1285                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1286                         LOG_DEBUG(this.netname, " switched to offense");
1287                         this.havocbot_role = havocbot_role_ons_offense;
1288                         this.havocbot_role_timeout = 0;
1289                         break;
1290         }
1291 }
1292
1293 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1294 {
1295         entity cp, cp1, cp2, best, wp;
1296         float radius, bestvalue;
1297         int c;
1298         bool found;
1299
1300         // Filter control points
1301         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1302         {
1303                 cp2.wpcost = c = 0;
1304                 cp2.wpconsidered = false;
1305
1306                 if(cp2.isshielded)
1307                         continue;
1308
1309                 // Ignore owned controlpoints
1310                 if(!((cp2.aregensneighbor & BIT(this.team)) || (cp2.arecpsneighbor & BIT(this.team))))
1311                         continue;
1312
1313                 // Count team mates interested in this control point
1314                 // (easier and cleaner than keeping counters per cp and teams)
1315                 FOREACH_CLIENT(it != this && IS_PLAYER(it), {
1316                         if(SAME_TEAM(it, this))
1317                         if(it.havocbot_role == havocbot_role_ons_offense)
1318                         if(it.havocbot_ons_target == cp2)
1319                                 ++c;
1320                 });
1321
1322                 // NOTE: probably decrease the cost of attackable control points
1323                 cp2.wpcost = c;
1324                 cp2.wpconsidered = true;
1325         }
1326
1327         // We'll consider only the best case
1328         bestvalue = FLOAT_MAX;
1329         cp = NULL;
1330         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1331         {
1332                 if (!cp1.wpconsidered)
1333                         continue;
1334
1335                 if(cp1.wpcost<bestvalue)
1336                 {
1337                         bestvalue = cp1.wpcost;
1338                         cp = cp1;
1339                         this.havocbot_ons_target = cp1;
1340                 }
1341         }
1342
1343         if (!cp)
1344                 return;
1345
1346         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1347
1348         if(cp.goalentity)
1349         {
1350                 // Should be attacked
1351                 // Rate waypoints near it
1352                 found = false;
1353                 best = NULL;
1354                 bestvalue = FLOAT_MAX;
1355                 for (radius = 500; radius <= 1000 && !found; radius += 500)
1356                 {
1357                         IL_EACH(g_waypoints, vdist(cp.origin - it.origin, <, radius),
1358                         {
1359                                 if (!(it.wpflags & WAYPOINTFLAG_GENERATED) && checkpvs(it.origin, cp))
1360                                 {
1361                                         found = true;
1362                                         if (it.cnt < bestvalue)
1363                                         {
1364                                                 best = it;
1365                                                 bestvalue = it.cnt;
1366                                         }
1367                                 }
1368                         });
1369                 }
1370
1371                 if(best)
1372                 {
1373                         navigation_routerating(this, best, ratingscale, 10000);
1374                         best.cnt += 1;
1375
1376                         this.havocbot_attack_time = 0;
1377                         if(checkpvs(this.origin + this.view_ofs, cp))
1378                         if(checkpvs(this.origin + this.view_ofs, best))
1379                                 this.havocbot_attack_time = time + 2;
1380                 }
1381                 else
1382                 {
1383                         navigation_routerating(this, cp, ratingscale, 10000);
1384                 }
1385                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1386         }
1387         else
1388         {
1389                 // Should be touched
1390                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1391                 navigation_routerating(this, cp, ratingscale * 2, 10000);
1392         }
1393 }
1394
1395 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1396 {
1397         entity g, wp, bestwp;
1398         bool found;
1399         int bestvalue;
1400
1401         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1402         {
1403                 if(SAME_TEAM(g, this) || g.isshielded)
1404                         continue;
1405
1406                 // Should be attacked
1407                 // Rate waypoints near it
1408                 found = false;
1409                 bestwp = NULL;
1410                 bestvalue = FLOAT_MAX;
1411
1412                 IL_EACH(g_waypoints, vdist(g.origin - it.origin, <, 400),
1413                 {
1414                         if (checkpvs(it.origin, g))
1415                         {
1416                                 found = true;
1417                                 if (it.cnt < bestvalue)
1418                                 {
1419                                         bestwp = it;
1420                                         bestvalue = it.cnt;
1421                                 }
1422                         }
1423                 });
1424
1425                 if(bestwp)
1426                 {
1427                         LOG_DEBUG("waypoints found around generator");
1428                         navigation_routerating(this, bestwp, ratingscale, 10000);
1429                         bestwp.cnt += 1;
1430
1431                         this.havocbot_attack_time = 0;
1432                         if(checkpvs(this.origin + this.view_ofs, g))
1433                         if(checkpvs(this.origin + this.view_ofs, bestwp))
1434                                 this.havocbot_attack_time = time + 5;
1435
1436                         return true;
1437                 }
1438                 else
1439                 {
1440                         LOG_DEBUG("generator found without waypoints around");
1441                         // if there aren't waypoints near the generator go straight to it
1442                         navigation_routerating(this, g, ratingscale, 10000);
1443                         this.havocbot_attack_time = 0;
1444                         return true;
1445                 }
1446         }
1447         return false;
1448 }
1449
1450 void havocbot_role_ons_offense(entity this)
1451 {
1452         if(IS_DEAD(this))
1453         {
1454                 this.havocbot_attack_time = 0;
1455                 havocbot_ons_reset_role(this);
1456                 return;
1457         }
1458
1459         // Set the role timeout if necessary
1460         if (!this.havocbot_role_timeout)
1461                 this.havocbot_role_timeout = time + 120;
1462
1463         if (time > this.havocbot_role_timeout)
1464         {
1465                 havocbot_ons_reset_role(this);
1466                 return;
1467         }
1468
1469         if(this.havocbot_attack_time>time)
1470                 return;
1471
1472         if (navigation_goalrating_timeout(this))
1473         {
1474                 navigation_goalrating_start(this);
1475                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1476                 if(!havocbot_goalrating_ons_generator_attack(this, 10000))
1477                         havocbot_goalrating_ons_controlpoints_attack(this, 10000);
1478                 havocbot_goalrating_items(this, 25000, this.origin, 10000);
1479                 navigation_goalrating_end(this);
1480
1481                 navigation_goalrating_timeout_set(this);
1482         }
1483 }
1484
1485 void havocbot_role_ons_assistant(entity this)
1486 {
1487         havocbot_ons_reset_role(this);
1488 }
1489
1490 void havocbot_role_ons_defense(entity this)
1491 {
1492         havocbot_ons_reset_role(this);
1493 }
1494
1495 void havocbot_ons_reset_role(entity this)
1496 {
1497         if(IS_DEAD(this))
1498                 return;
1499
1500         this.havocbot_ons_target = NULL;
1501
1502         // TODO: Defend control points or generator if necessary
1503
1504         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1505 }
1506
1507
1508 /*
1509  * Find control point or generator owned by the same team self which is nearest to pos
1510  * if max_dist is positive, only control points within this range will be considered
1511  */
1512 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1513 {
1514         entity closest_target = NULL;
1515         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1516         {
1517                 if(SAME_TEAM(cp, this))
1518                 if(cp.iscaptured)
1519                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1520                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1521                         closest_target = cp;
1522         }
1523         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1524         {
1525                 if(SAME_TEAM(gen, this))
1526                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1527                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1528                         closest_target = gen;
1529         }
1530
1531         return closest_target;
1532 }
1533
1534 /*
1535  * Find control point or generator owned by the same team self which is nearest to pos
1536  * if max_dist is positive, only control points within this range will be considered
1537  * This function only check distances on the XY plane, disregarding Z
1538  */
1539 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1540 {
1541         entity closest_target = NULL;
1542         vector delta;
1543         float smallest_distance = 0, distance;
1544
1545         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1546         {
1547                 delta = cp.origin - pos;
1548                 delta_z = 0;
1549                 distance = vlen(delta);
1550
1551                 if(SAME_TEAM(cp, this))
1552                 if(cp.iscaptured)
1553                 if(max_dist <= 0 || distance <= max_dist)
1554                 if(closest_target == NULL || distance <= smallest_distance )
1555                 {
1556                         closest_target = cp;
1557                         smallest_distance = distance;
1558                 }
1559         }
1560         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1561         {
1562                 delta = gen.origin - pos;
1563                 delta_z = 0;
1564                 distance = vlen(delta);
1565
1566                 if(SAME_TEAM(gen, this))
1567                 if(max_dist <= 0 || distance <= max_dist)
1568                 if(closest_target == NULL || distance <= smallest_distance )
1569                 {
1570                         closest_target = gen;
1571                         smallest_distance = distance;
1572                 }
1573         }
1574
1575         return closest_target;
1576 }
1577 /**
1578  * find the number of control points and generators in the same team as this
1579  */
1580 int ons_Count_SelfControlPoints(entity this)
1581 {
1582         int n = 0;
1583         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1584         {
1585                 if(SAME_TEAM(cp, this))
1586                 if(cp.iscaptured)
1587                         n++;
1588         }
1589         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1590         {
1591                 if(SAME_TEAM(gen, this))
1592                         n++;
1593         }
1594         return n;
1595 }
1596
1597 /**
1598  * Teleport player to a random position near tele_target
1599  * if tele_effects is true, teleport sound+particles are created
1600  * return false on failure
1601  */
1602 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1603 {
1604         if ( !tele_target )
1605                 return false;
1606
1607         int i;
1608         vector loc;
1609         float theta;
1610         // narrow the range for each iteration to increase chances that a spawnpoint
1611         // can be found even if there's little room around the control point
1612         float iteration_scale = 1;
1613         for(i = 0; i < 16; ++i)
1614         {
1615                 iteration_scale -= i / 16;
1616                 theta = random() * 2 * M_PI;
1617                 loc_y = sin(theta);
1618                 loc_x = cos(theta);
1619                 loc_z = 0;
1620                 loc *= random() * range * iteration_scale;
1621
1622                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1623
1624                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1625                 if(trace_fraction == 1.0 && !trace_startsolid)
1626                 {
1627                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1628                         if(trace_fraction == 1.0 && !trace_startsolid)
1629                         {
1630                                 if ( tele_effects )
1631                                 {
1632                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1633                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1634                                 }
1635                                 setorigin(player, loc);
1636                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1637                                 makevectors(player.angles);
1638                                 player.fixangle = true;
1639                                 if (IS_BOT_CLIENT(player))
1640                                 {
1641                                         player.v_angle = player.angles;
1642                                         bot_aim_reset(player);
1643                                 }
1644                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1645
1646                                 if ( tele_effects )
1647                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1648                                 return true;
1649                         }
1650                 }
1651         }
1652
1653         return false;
1654 }
1655
1656 // ==============
1657 // Hook Functions
1658 // ==============
1659
1660 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1661 {
1662         FOREACH_CLIENT(IS_PLAYER(it), {
1663                 STAT(ROUNDLOST, it) = false;
1664                 it.ons_deathloc = '0 0 0';
1665                 PutClientInServer(it);
1666                 it.clientcamera = it;
1667         });
1668         return false;
1669 }
1670
1671 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1672 {
1673         entity player = M_ARGV(0, entity);
1674
1675         player.ons_deathloc = '0 0 0';
1676 }
1677
1678 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1679 {
1680         entity player = M_ARGV(0, entity);
1681
1682         player.ons_deathloc = '0 0 0';
1683 }
1684
1685 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1686 {
1687         entity player = M_ARGV(0, entity);
1688
1689         if(!round_handler_IsRoundStarted())
1690         {
1691                 player.player_blocked = true;
1692                 return false;
1693         }
1694
1695         entity l;
1696         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1697         {
1698                 l.sprite.SendFlags |= 16;
1699         }
1700         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1701         {
1702                 l.sprite.SendFlags |= 16;
1703         }
1704
1705         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1706
1707         if ( autocvar_g_onslaught_spawn_choose )
1708         if ( player.ons_spawn_by )
1709         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1710         {
1711                 player.ons_spawn_by = NULL;
1712                 return false;
1713         }
1714
1715         if(autocvar_g_onslaught_spawn_at_controlpoints)
1716         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1717         {
1718                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1719                 entity tmp_entity, closest_target = NULL;
1720                 vector spawn_loc = player.ons_deathloc;
1721
1722                 // new joining player or round reset, don't bother checking
1723                 if(spawn_loc == '0 0 0') { return false; }
1724
1725                 if(random_target) { RandomSelection_Init(); }
1726
1727                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1728                 {
1729                         if(SAME_TEAM(tmp_entity, player))
1730                         {
1731                                 if(random_target)
1732                                         RandomSelection_AddEnt(tmp_entity, 1, 1);
1733                                 else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1734                                         closest_target = tmp_entity;
1735                         }
1736                 }
1737
1738                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1739
1740                 if(closest_target)
1741                 {
1742                         float i;
1743                         vector loc;
1744                         float iteration_scale = 1;
1745                         for(i = 0; i < 10; ++i)
1746                         {
1747                                 iteration_scale -= i / 10;
1748                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1749                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1750                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1751                                 if(trace_fraction == 1.0 && !trace_startsolid)
1752                                 {
1753                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1754                                         if(trace_fraction == 1.0 && !trace_startsolid)
1755                                         {
1756                                                 setorigin(player, loc);
1757                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1758                                                 return false;
1759                                         }
1760                                 }
1761                         }
1762                 }
1763         }
1764
1765         if(autocvar_g_onslaught_spawn_at_generator)
1766         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1767         {
1768                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1769                 entity tmp_entity, closest_target = NULL;
1770                 vector spawn_loc = player.ons_deathloc;
1771
1772                 // new joining player or round reset, don't bother checking
1773                 if(spawn_loc == '0 0 0') { return false; }
1774
1775                 if(random_target) { RandomSelection_Init(); }
1776
1777                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1778                 {
1779                         if(random_target)
1780                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1781                         else
1782                         {
1783                                 if(SAME_TEAM(tmp_entity, player))
1784                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1785                                         closest_target = tmp_entity;
1786                         }
1787                 }
1788
1789                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1790
1791                 if(closest_target)
1792                 {
1793                         float i;
1794                         vector loc;
1795                         float iteration_scale = 1;
1796                         for(i = 0; i < 10; ++i)
1797                         {
1798                                 iteration_scale -= i / 10;
1799                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1800                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1801                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1802                                 if(trace_fraction == 1.0 && !trace_startsolid)
1803                                 {
1804                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1805                                         if(trace_fraction == 1.0 && !trace_startsolid)
1806                                         {
1807                                                 setorigin(player, loc);
1808                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1809                                                 return false;
1810                                         }
1811                                 }
1812                         }
1813                 }
1814         }
1815
1816         return false;
1817 }
1818
1819 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1820 {
1821         entity frag_target = M_ARGV(2, entity);
1822
1823         frag_target.ons_deathloc = frag_target.origin;
1824         entity l;
1825         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1826         {
1827                 l.sprite.SendFlags |= 16;
1828         }
1829         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1830         {
1831                 l.sprite.SendFlags |= 16;
1832         }
1833
1834         if ( autocvar_g_onslaught_spawn_choose )
1835         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1836                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1837
1838         return false;
1839 }
1840
1841 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1842 {
1843         entity mon = M_ARGV(0, entity);
1844
1845         entity e = find(NULL, targetname, mon.target);
1846         if (e != NULL)
1847                 mon.team = e.team;
1848 }
1849
1850 void ons_MonsterSpawn_Delayed(entity this)
1851 {
1852         entity own = this.owner;
1853
1854         if(!own) { delete(this); return; }
1855
1856         if(own.targetname)
1857         {
1858                 entity e = find(NULL, target, own.targetname);
1859                 if(e != NULL)
1860                 {
1861                         own.team = e.team;
1862
1863                         own.use(own, e, NULL);
1864                 }
1865         }
1866
1867         delete(this);
1868 }
1869
1870 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1871 {
1872         entity mon = M_ARGV(0, entity);
1873
1874         entity e = spawn();
1875         e.owner = mon;
1876         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1877 }
1878
1879 void ons_TurretSpawn_Delayed(entity this)
1880 {
1881         entity own = this.owner;
1882
1883         if(!own) { delete(this); return; }
1884
1885         if(own.targetname)
1886         {
1887                 entity e = find(NULL, target, own.targetname);
1888                 if(e != NULL)
1889                 {
1890                         own.team = e.team;
1891                         own.active = ACTIVE_NOT;
1892
1893                         own.use(own, e, NULL);
1894                 }
1895         }
1896
1897         delete(this);
1898 }
1899
1900 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1901 {
1902         entity turret = M_ARGV(0, entity);
1903
1904         entity e = spawn();
1905         e.owner = turret;
1906         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1907
1908         return false;
1909 }
1910
1911 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1912 {
1913         entity bot = M_ARGV(0, entity);
1914
1915         havocbot_ons_reset_role(bot);
1916         return true;
1917 }
1918
1919 MUTATOR_HOOKFUNCTION(ons, TeamBalance_CheckAllowedTeams)
1920 {
1921         // onslaught is special
1922         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1923         {
1924                 if (Team_IsValidTeam(tmp_entity.team))
1925                 {
1926                         M_ARGV(0, float) |= Team_TeamToBit(tmp_entity.team);
1927                 }
1928         }
1929
1930         return true;
1931 }
1932
1933 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1934 {
1935         entity spectatee = M_ARGV(0, entity);
1936         entity client = M_ARGV(1, entity);
1937
1938         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1939 }
1940
1941 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1942 {
1943         if(MUTATOR_RETURNVALUE) // command was already handled?
1944                 return false;
1945
1946         entity player = M_ARGV(0, entity);
1947         string cmd_name = M_ARGV(1, string);
1948         int cmd_argc = M_ARGV(2, int);
1949
1950         if ( cmd_name == "ons_spawn" )
1951         {
1952                 vector pos = player.origin;
1953                 if(cmd_argc > 1)
1954                         pos_x = stof(argv(1));
1955                 if(cmd_argc > 2)
1956                         pos_y = stof(argv(2));
1957                 if(cmd_argc > 3)
1958                         pos_z = stof(argv(3));
1959
1960                 if ( IS_PLAYER(player) )
1961                 {
1962                         if ( !STAT(FROZEN, player) )
1963                         {
1964                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1965
1966                                 if ( !source_point && GetResource(player, RES_HEALTH) > 0 )
1967                                 {
1968                                         sprint(player, "\nYou need to be next to a control point\n");
1969                                         return true;
1970                                 }
1971
1972
1973                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1974
1975                                 if ( closest_target == NULL )
1976                                 {
1977                                         sprint(player, "\nNo control point found\n");
1978                                         return true;
1979                                 }
1980
1981                                 if ( GetResource(player, RES_HEALTH) <= 0 )
1982                                 {
1983                                         player.ons_spawn_by = closest_target;
1984                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1985                                 }
1986                                 else
1987                                 {
1988                                         if ( source_point == closest_target )
1989                                         {
1990                                                 sprint(player, "\nTeleporting to the same point\n");
1991                                                 return true;
1992                                         }
1993
1994                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
1995                                                 sprint(player, "\nUnable to teleport there\n");
1996                                 }
1997
1998                                 return true;
1999                         }
2000
2001                         sprint(player, "\nNo teleportation for you\n");
2002                 }
2003
2004                 return true;
2005         }
2006         return false;
2007 }
2008
2009 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2010 {
2011         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2012
2013         entity player = M_ARGV(0, entity);
2014
2015         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2016         {
2017                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2018                 if ( source_point )
2019                 {
2020                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2021                         return true;
2022                 }
2023         }
2024 }
2025
2026 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2027 {
2028         entity frag_victim = M_ARGV(0, entity);
2029
2030         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2031                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2032 }
2033
2034 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2035 {
2036     entity wp = M_ARGV(0, entity);
2037     entity to = M_ARGV(1, entity);
2038     int sf = M_ARGV(2, int);
2039     int wp_flag = M_ARGV(3, int);
2040
2041         if(sf & 16)
2042         {
2043                 if(wp.owner.classname == "onslaught_controlpoint")
2044                 {
2045                         entity wp_owner = wp.owner;
2046                         entity e = WaypointSprite_getviewentity(to);
2047                         if(SAME_TEAM(e, wp_owner) && GetResource(wp_owner.goalentity, RES_HEALTH) >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2048                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2049                 }
2050                 if(wp.owner.classname == "onslaught_generator")
2051                 {
2052                         entity wp_owner = wp.owner;
2053                         if(wp_owner.isshielded && GetResource(wp_owner, RES_HEALTH) >= wp_owner.max_health) { wp_flag |= 2; }
2054                         if(GetResource(wp_owner, RES_HEALTH) <= 0) { wp_flag |= 2; }
2055                 }
2056         }
2057
2058         M_ARGV(3, int) = wp_flag;
2059 }
2060
2061 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2062 {
2063         entity turret_target = M_ARGV(1, entity);
2064
2065         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2066         {
2067                 M_ARGV(3, float) = -3;
2068                 return true;
2069         }
2070
2071         return false;
2072 }
2073
2074 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2075 {
2076     entity turret = M_ARGV(0, entity);
2077
2078         // ONS uses somewhat backwards linking.
2079         if(turret.target)
2080         {
2081                 entity e = find(NULL, targetname, turret.target);
2082                 if (e != NULL)
2083                         turret.team = e.team;
2084         }
2085
2086         if(turret.team != turret.tur_head.team)
2087                 turret_respawn(turret);
2088 }
2089
2090
2091 // ==========
2092 // Spawnfuncs
2093 // ==========
2094
2095 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2096   Link between control points.
2097
2098   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2099
2100 keys:
2101 "target" - first control point.
2102 "target2" - second control point.
2103  */
2104 spawnfunc(onslaught_link)
2105 {
2106         if(!g_onslaught) { delete(this); return; }
2107
2108         if (this.target == "" || this.target2 == "")
2109                 objerror(this, "target and target2 must be set\n");
2110
2111         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2112         ons_worldlinklist = this;
2113
2114         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2115         Net_LinkEntity(this, false, 0, ons_Link_Send);
2116 }
2117
2118 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2119   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2120
2121   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2122
2123 keys:
2124 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2125 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2126 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2127  */
2128
2129 spawnfunc(onslaught_controlpoint)
2130 {
2131         if(!g_onslaught) { delete(this); return; }
2132
2133         ons_ControlPoint_Setup(this);
2134 }
2135
2136 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2137   Base generator.
2138
2139   spawnfunc_onslaught_link entities can target this.
2140
2141 keys:
2142 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2143 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2144  */
2145 spawnfunc(onslaught_generator)
2146 {
2147         if(!g_onslaught) { delete(this); return; }
2148         if(!this.team) { objerror(this, "team must be set"); }
2149
2150         ons_GeneratorSetup(this);
2151 }
2152
2153 // scoreboard setup
2154 void ons_ScoreRules()
2155 {
2156         entity balance = TeamBalance_CheckAllowedTeams(NULL);
2157         int teams = TeamBalance_GetAllowedTeams(balance);
2158         TeamBalance_Destroy(balance);
2159         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
2160             field_team(ST_ONS_CAPS, "destroyed", SFL_SORT_PRIO_PRIMARY);
2161             field(SP_ONS_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
2162             field(SP_ONS_TAKES, "takes", 0);
2163         });
2164 }
2165
2166 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2167 {
2168         ons_ScoreRules();
2169
2170         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2171         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2172 }
2173
2174 void ons_Initialize()
2175 {
2176         g_onslaught = true;
2177         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2178
2179         cam = new(objective_camera);
2180
2181         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2182 }