Merge branch 'master' into terencehill/vec2_optimizations
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / gamemodes / gamemode / onslaught / sv_onslaught.qc
1 #include "sv_onslaught.qh"
2 #include "sv_controlpoint.qh"
3 #include "sv_generator.qh"
4
5 bool g_onslaught;
6
7 float autocvar_g_onslaught_teleport_wait;
8 bool autocvar_g_onslaught_spawn_at_controlpoints;
9 bool autocvar_g_onslaught_spawn_at_generator;
10 float autocvar_g_onslaught_cp_proxydecap;
11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
15 float autocvar_g_onslaught_spawn_at_generator_chance;
16 float autocvar_g_onslaught_spawn_at_generator_random;
17 float autocvar_g_onslaught_cp_buildhealth;
18 float autocvar_g_onslaught_cp_buildtime;
19 float autocvar_g_onslaught_cp_health;
20 float autocvar_g_onslaught_cp_regen;
21 float autocvar_g_onslaught_gen_health;
22 float autocvar_g_onslaught_shield_force = 100;
23 float autocvar_g_onslaught_allow_vehicle_touch;
24 float autocvar_g_onslaught_round_timelimit;
25 float autocvar_g_onslaught_warmup;
26 float autocvar_g_onslaught_teleport_radius;
27 float autocvar_g_onslaught_spawn_choose;
28 float autocvar_g_onslaught_click_radius;
29
30 void FixSize(entity e);
31 entity cam;
32
33 // =======================
34 // CaptureShield Functions
35 // =======================
36
37 bool clientcamera_send(entity this, entity to, int sf)
38 {
39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
40
41         WriteCoord(MSG_ENTITY, this.origin_x);
42         WriteCoord(MSG_ENTITY, this.origin_y);
43         WriteCoord(MSG_ENTITY, this.origin_z);
44
45         WriteAngle(MSG_ENTITY, this.angles_x);
46         WriteAngle(MSG_ENTITY, this.angles_y);
47         WriteAngle(MSG_ENTITY, this.angles_z);
48
49         return true;
50 }
51
52 bool ons_CaptureShield_Customize(entity this, entity client)
53 {
54         entity e = WaypointSprite_getviewentity(client);
55
56         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
57         if(SAME_TEAM(this, e)) { return false; }
58
59         return true;
60 }
61
62 void ons_CaptureShield_Touch(entity this, entity toucher)
63 {
64         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
65         if(!IS_PLAYER(toucher)) { return; }
66         if(SAME_TEAM(toucher, this)) { return; }
67
68         vector mymid = (this.absmin + this.absmax) * 0.5;
69         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
70
71         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
72
73         if(IS_REAL_CLIENT(toucher))
74         {
75                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
76
77                 if(this.enemy.classname == "onslaught_generator")
78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
79                 else
80                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
81         }
82 }
83
84 void ons_CaptureShield_Reset(entity this)
85 {
86         this.colormap = this.enemy.colormap;
87         this.team = this.enemy.team;
88 }
89
90 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
91 {
92         entity shield = new(ons_captureshield);
93         IL_PUSH(g_onsshields, shield);
94
95         shield.enemy = generator;
96         shield.team = generator.team;
97         shield.colormap = generator.colormap;
98         shield.reset = ons_CaptureShield_Reset;
99         settouch(shield, ons_CaptureShield_Touch);
100         setcefc(shield, ons_CaptureShield_Customize);
101         shield.effects = EF_ADDITIVE;
102         set_movetype(shield, MOVETYPE_NOCLIP);
103         shield.solid = SOLID_TRIGGER;
104         shield.avelocity = '7 0 11';
105         shield.scale = 1;
106         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
107
108         precache_model(shield.model);
109         setorigin(shield, generator.origin);
110         _setmodel(shield, shield.model);
111         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
112 }
113
114
115 // ==========
116 // Junk Pile
117 // ==========
118
119 void setmodel_fixsize(entity e, Model m)
120 {
121         setmodel(e, m);
122         FixSize(e);
123 }
124
125 void onslaught_updatelinks()
126 {
127         entity l;
128         // first check if the game has ended
129         LOG_DEBUG("--- updatelinks ---");
130         // mark generators as being shielded and networked
131         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
132         {
133                 if (l.iscaptured)
134                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
135                 else
136                         LOG_DEBUG(etos(l), " (generator) is destroyed");
137                 l.islinked = l.iscaptured;
138                 l.isshielded = l.iscaptured;
139                 l.sprite.SendFlags |= 16;
140         }
141         // mark points as shielded and not networked
142         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
143         {
144                 l.islinked = false;
145                 l.isshielded = true;
146                 l.aregensneighbor = 0;
147                 l.arecpsneighbor = 0;
148                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
149                 l.sprite.SendFlags |= 16;
150         }
151         // flow power outward from the generators through the network
152         bool stop = false;
153         while (!stop)
154         {
155                 stop = true;
156                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
157                 {
158                         // if both points are captured by the same team, and only one of
159                         // them is powered, mark the other one as powered as well
160                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
161                                 if (l.enemy.islinked != l.goalentity.islinked)
162                                         if(SAME_TEAM(l.enemy, l.goalentity))
163                                         {
164                                                 if (!l.goalentity.islinked)
165                                                 {
166                                                         stop = false;
167                                                         l.goalentity.islinked = true;
168                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
169                                                 }
170                                                 else if (!l.enemy.islinked)
171                                                 {
172                                                         stop = false;
173                                                         l.enemy.islinked = true;
174                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
175                                                 }
176                                         }
177                 }
178         }
179         // now that we know which points are powered we can mark their neighbors
180         // as unshielded if team differs
181         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
182         {
183                 if (l.goalentity.islinked)
184                 {
185                         if(DIFF_TEAM(l.goalentity, l.enemy))
186                         {
187                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
188                                 l.enemy.isshielded = false;
189                         }
190                         if(l.goalentity.classname == "onslaught_generator")
191                                 l.enemy.aregensneighbor |= BIT(l.goalentity.team);
192                         else
193                                 l.enemy.arecpsneighbor |= BIT(l.goalentity.team);
194                 }
195                 if (l.enemy.islinked)
196                 {
197                         if(DIFF_TEAM(l.goalentity, l.enemy))
198                         {
199                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
200                                 l.goalentity.isshielded = false;
201                         }
202                         if(l.enemy.classname == "onslaught_generator")
203                                 l.goalentity.aregensneighbor |= BIT(l.enemy.team);
204                         else
205                                 l.goalentity.arecpsneighbor |= BIT(l.enemy.team);
206                 }
207         }
208         // now update the generators
209         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
210         {
211                 if (l.isshielded)
212                 {
213                         LOG_DEBUG(etos(l), " (generator) is shielded");
214                         l.takedamage = DAMAGE_NO;
215                         if(l.bot_attack)
216                                 IL_REMOVE(g_bot_targets, l);
217                         l.bot_attack = false;
218                 }
219                 else
220                 {
221                         LOG_DEBUG(etos(l), " (generator) is not shielded");
222                         l.takedamage = DAMAGE_AIM;
223                         if(!l.bot_attack)
224                                 IL_PUSH(g_bot_targets, l);
225                         l.bot_attack = true;
226                 }
227
228                 ons_Generator_UpdateSprite(l);
229         }
230         // now update the takedamage and alpha variables on control point icons
231         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
232         {
233                 if (l.isshielded)
234                 {
235                         LOG_DEBUG(etos(l), " (point) is shielded");
236                         if (l.goalentity)
237                         {
238                                 l.goalentity.takedamage = DAMAGE_NO;
239                                 if(l.goalentity.bot_attack)
240                                         IL_REMOVE(g_bot_targets, l.goalentity);
241                                 l.goalentity.bot_attack = false;
242                         }
243                 }
244                 else
245                 {
246                         LOG_DEBUG(etos(l), " (point) is not shielded");
247                         if (l.goalentity)
248                         {
249                                 l.goalentity.takedamage = DAMAGE_AIM;
250                                 if(!l.goalentity.bot_attack)
251                                         IL_PUSH(g_bot_targets, l.goalentity);
252                                 l.goalentity.bot_attack = true;
253                         }
254                 }
255                 ons_ControlPoint_UpdateSprite(l);
256         }
257         IL_EACH(g_onsshields, true,
258         {
259                 it.team = it.enemy.team;
260                 it.colormap = it.enemy.colormap;
261         });
262 }
263
264
265 // ===================
266 // Main Link Functions
267 // ===================
268
269 bool ons_Link_Send(entity this, entity to, int sendflags)
270 {
271         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
272         WriteByte(MSG_ENTITY, sendflags);
273         if(sendflags & 1)
274         {
275                 WriteCoord(MSG_ENTITY, this.goalentity.origin_x);
276                 WriteCoord(MSG_ENTITY, this.goalentity.origin_y);
277                 WriteCoord(MSG_ENTITY, this.goalentity.origin_z);
278         }
279         if(sendflags & 2)
280         {
281                 WriteCoord(MSG_ENTITY, this.enemy.origin_x);
282                 WriteCoord(MSG_ENTITY, this.enemy.origin_y);
283                 WriteCoord(MSG_ENTITY, this.enemy.origin_z);
284         }
285         if(sendflags & 4)
286         {
287                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
288         }
289         return true;
290 }
291
292 void ons_Link_CheckUpdate(entity this)
293 {
294         // TODO check if the two sides have moved (currently they won't move anyway)
295         float cc = 0, cc1 = 0, cc2 = 0;
296
297         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
298         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
299
300         cc = cc1 + cc2;
301
302         if(cc != this.clientcolors)
303         {
304                 this.clientcolors = cc;
305                 this.SendFlags |= 4;
306         }
307
308         this.nextthink = time;
309 }
310
311 void ons_DelayedLinkSetup(entity this)
312 {
313         this.goalentity = find(NULL, targetname, this.target);
314         this.enemy = find(NULL, targetname, this.target2);
315         if(!this.goalentity) { objerror(this, "can not find target\n"); }
316         if(!this.enemy) { objerror(this, "can not find target2\n"); }
317
318         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
319         this.SendFlags |= 3;
320         setthink(this, ons_Link_CheckUpdate);
321         this.nextthink = time;
322 }
323
324
325 // =============================
326 // Main Control Point Functions
327 // =============================
328
329 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
330 {
331         if(cp.aregensneighbor & BIT(teamnumber)) return 2;
332         if(cp.arecpsneighbor & BIT(teamnumber)) return 1;
333
334         return 0;
335 }
336
337 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
338         // -2: SAME TEAM, attackable by enemy!
339         // -1: SAME TEAM!
340         // 0: off limits
341         // 1: attack it
342         // 2: touch it
343         // 3: attack it (HIGH PRIO)
344         // 4: touch it (HIGH PRIO)
345 {
346         int a;
347
348         if(cp.isshielded)
349         {
350                 return 0;
351         }
352         else if(cp.goalentity)
353         {
354                 // if there's already an icon built, nothing happens
355                 if(cp.team == teamnumber)
356                 {
357                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
358                         if(a) // attackable by enemy?
359                                 return -2; // EMERGENCY!
360                         return -1;
361                 }
362                 // we know it can be linked, so no need to check
363                 // but...
364                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
365                 if(a == 2) // near our generator?
366                         return 3; // EMERGENCY!
367                 return 1;
368         }
369         else
370         {
371                 // free point
372                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
373                 {
374                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
375                         if(a == 2)
376                                 return 4; // GET THIS ONE NOW!
377                         else
378                                 return 2; // TOUCH ME
379                 }
380         }
381         return 0;
382 }
383
384 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
385 {
386         if(damage <= 0) { return; }
387
388         if (this.owner.isshielded)
389         {
390                 // this is protected by a shield, so ignore the damage
391                 if (time > this.pain_finished)
392                         if (IS_PLAYER(attacker))
393                         {
394                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
395                                 this.pain_finished = time + 1;
396                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
397                         }
398
399                 return;
400         }
401
402         if(IS_PLAYER(attacker))
403         if(time - ons_notification_time[this.team] > 10)
404         {
405                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
406                 ons_notification_time[this.team] = time;
407         }
408
409         this.health = this.health - damage;
410         if(this.owner.iscaptured)
411                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
412         else
413                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - this.health) / (this.count / ONS_CP_THINKRATE));
414         this.pain_finished = time + 1;
415         // particles on every hit
416         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
417         //sound on every hit
418         if (random() < 0.5)
419                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
420         else
421                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
422
423         if (this.health < 0)
424         {
425                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
426                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
427                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
428
429                 PlayerScore_Add(attacker, SP_ONS_TAKES, 1);
430                 PlayerScore_Add(attacker, SP_SCORE, 10);
431
432                 this.owner.goalentity = NULL;
433                 this.owner.islinked = false;
434                 this.owner.iscaptured = false;
435                 this.owner.team = 0;
436                 this.owner.colormap = 1024;
437
438                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
439
440                 onslaught_updatelinks();
441
442                 // Use targets now (somebody make sure this is in the right place..)
443                 SUB_UseTargets(this.owner, this, NULL);
444
445                 this.owner.waslinked = this.owner.islinked;
446                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
447                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
448                 //setsize(this, '-32 -32 0', '32 32 8');
449
450                 delete(this);
451         }
452
453         this.SendFlags |= CPSF_STATUS;
454 }
455
456 void ons_ControlPoint_Icon_Think(entity this)
457 {
458         this.nextthink = time + ONS_CP_THINKRATE;
459
460         if(autocvar_g_onslaught_cp_proxydecap)
461         {
462                 int _enemy_count = 0;
463                 int _friendly_count = 0;
464
465                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
466                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
467                         {
468                                 if(SAME_TEAM(it, this))
469                                         ++_friendly_count;
470                                 else
471                                         ++_enemy_count;
472                         }
473                 });
474
475                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
476                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
477
478                 this.health = bound(0, this.health + (_friendly_count - _enemy_count), this.max_health);
479                 this.SendFlags |= CPSF_STATUS;
480                 if(this.health <= 0)
481                 {
482                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, this.origin, '0 0 0');
483                         return;
484                 }
485         }
486
487         if (time > this.pain_finished + 5)
488         {
489                 if(this.health < this.max_health)
490                 {
491                         this.health = this.health + this.count;
492                         if (this.health >= this.max_health)
493                                 this.health = this.max_health;
494                         WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
495                 }
496         }
497
498         if(this.owner.islinked != this.owner.waslinked)
499         {
500                 // unteam the spawnpoint if needed
501                 int t = this.owner.team;
502                 if(!this.owner.islinked)
503                         this.owner.team = 0;
504
505                 SUB_UseTargets(this.owner, this, NULL);
506
507                 this.owner.team = t;
508
509                 this.owner.waslinked = this.owner.islinked;
510         }
511
512         // damaged fx
513         if(random() < 0.6 - this.health / this.max_health)
514         {
515                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
516
517                 if(random() > 0.8)
518                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
519                 else if (random() > 0.5)
520                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
521         }
522 }
523
524 void ons_ControlPoint_Icon_BuildThink(entity this)
525 {
526         int a;
527
528         this.nextthink = time + ONS_CP_THINKRATE;
529
530         // only do this if there is power
531         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
532         if(!a)
533                 return;
534
535         this.health = this.health + this.count;
536
537         this.SendFlags |= CPSF_STATUS;
538
539         if (this.health >= this.max_health)
540         {
541                 this.health = this.max_health;
542                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
543                 setthink(this, ons_ControlPoint_Icon_Think);
544                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
545                 this.owner.iscaptured = true;
546                 this.solid = SOLID_BBOX;
547
548                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
549
550                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
551                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
552
553                 if(IS_PLAYER(this.owner.ons_toucher))
554                 {
555                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
556                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
557                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
558                         PlayerScore_Add(this.owner.ons_toucher, SP_ONS_CAPS, 1);
559                         PlayerTeamScore_AddScore(this.owner.ons_toucher, 10);
560                 }
561
562                 this.owner.ons_toucher = NULL;
563
564                 onslaught_updatelinks();
565
566                 // Use targets now (somebody make sure this is in the right place..)
567                 SUB_UseTargets(this.owner, this, NULL);
568
569                 this.SendFlags |= CPSF_SETUP;
570         }
571         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
572                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
573
574         if(random() < 0.9 - this.health / this.max_health)
575                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
576 }
577
578 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
579
580 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
581 {
582         entity e = new(onslaught_controlpoint_icon);
583
584         setsize(e, CPICON_MIN, CPICON_MAX);
585         setorigin(e, cp.origin + CPICON_OFFSET);
586
587         e.owner = cp;
588         e.max_health = autocvar_g_onslaught_cp_health;
589         e.health = autocvar_g_onslaught_cp_buildhealth;
590         e.solid = SOLID_NOT;
591         e.takedamage = DAMAGE_AIM;
592         e.bot_attack = true;
593         IL_PUSH(g_bot_targets, e);
594         e.event_damage = ons_ControlPoint_Icon_Damage;
595         e.team = player.team;
596         e.colormap = 1024 + (e.team - 1) * 17;
597         e.count = (e.max_health - e.health) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
598
599         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
600
601         cp.goalentity = e;
602         cp.team = e.team;
603         cp.colormap = e.colormap;
604
605         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
606
607         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - e.health) / (e.count / ONS_CP_THINKRATE));
608         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
609         cp.sprite.SendFlags |= 16;
610
611         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
612 }
613
614 entity ons_ControlPoint_Waypoint(entity e)
615 {
616         if(e.team)
617         {
618                 int a = ons_ControlPoint_Attackable(e, e.team);
619
620                 if(a == -2) { return WP_OnsCPDefend; } // defend now
621                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
622                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
623         }
624         else
625                 return WP_OnsCP;
626
627         return WP_Null;
628 }
629
630 void ons_ControlPoint_UpdateSprite(entity e)
631 {
632         entity s1 = ons_ControlPoint_Waypoint(e);
633         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
634
635         bool sh;
636         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
637
638         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
639         {
640                 if(e.iscaptured) // don't mess up build bars!
641                 {
642                         if(sh)
643                         {
644                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
645                         }
646                         else
647                         {
648                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
649                                 WaypointSprite_UpdateHealth(e.sprite, e.goalentity.health);
650                         }
651                 }
652                 if(e.lastshielded)
653                 {
654                         if(e.team)
655                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
656                         else
657                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
658                 }
659                 else
660                 {
661                         if(e.team)
662                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
663                         else
664                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
665                 }
666                 WaypointSprite_Ping(e.sprite);
667
668                 e.lastteam = e.team + 2;
669                 e.lastshielded = sh;
670                 e.lastcaptured = e.iscaptured;
671         }
672 }
673
674 void ons_ControlPoint_Touch(entity this, entity toucher)
675 {
676         int attackable;
677
678         if(IS_VEHICLE(toucher) && toucher.owner)
679         if(autocvar_g_onslaught_allow_vehicle_touch)
680                 toucher = toucher.owner;
681         else
682                 return;
683
684         if(!IS_PLAYER(toucher)) { return; }
685         if(STAT(FROZEN, toucher)) { return; }
686         if(IS_DEAD(toucher)) { return; }
687
688         if ( SAME_TEAM(this,toucher) )
689         if ( this.iscaptured )
690         {
691                 if(time <= toucher.teleport_antispam)
692                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
693                 else
694                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
695         }
696
697         attackable = ons_ControlPoint_Attackable(this, toucher.team);
698         if(attackable != 2 && attackable != 4)
699                 return;
700         // we've verified that this player has a legitimate claim to this point,
701         // so start building the captured point icon (which only captures this
702         // point if it successfully builds without being destroyed first)
703         ons_ControlPoint_Icon_Spawn(this, toucher);
704
705         this.ons_toucher = toucher;
706
707         onslaught_updatelinks();
708 }
709
710 void ons_ControlPoint_Think(entity this)
711 {
712         this.nextthink = time + ONS_CP_THINKRATE;
713         CSQCMODEL_AUTOUPDATE(this);
714 }
715
716 void ons_ControlPoint_Reset(entity this)
717 {
718         if(this.goalentity)
719                 delete(this.goalentity);
720
721         this.goalentity = NULL;
722         this.team = 0;
723         this.colormap = 1024;
724         this.iscaptured = false;
725         this.islinked = false;
726         this.isshielded = true;
727         setthink(this, ons_ControlPoint_Think);
728         this.ons_toucher = NULL;
729         this.nextthink = time + ONS_CP_THINKRATE;
730         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
731
732         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
733         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
734
735         onslaught_updatelinks();
736
737         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
738
739         CSQCMODEL_AUTOUPDATE(this);
740 }
741
742 void ons_DelayedControlPoint_Setup(entity this)
743 {
744         onslaught_updatelinks();
745
746         // captureshield setup
747         ons_CaptureShield_Spawn(this, false);
748
749         CSQCMODEL_AUTOINIT(this);
750 }
751
752 void ons_ControlPoint_Setup(entity cp)
753 {
754         // main setup
755         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
756         ons_worldcplist = cp;
757
758         cp.netname = "Control point";
759         cp.team = 0;
760         cp.solid = SOLID_BBOX;
761         set_movetype(cp, MOVETYPE_NONE);
762         settouch(cp, ons_ControlPoint_Touch);
763         setthink(cp, ons_ControlPoint_Think);
764         cp.nextthink = time + ONS_CP_THINKRATE;
765         cp.reset = ons_ControlPoint_Reset;
766         cp.colormap = 1024;
767         cp.iscaptured = false;
768         cp.islinked = false;
769         cp.isshielded = true;
770
771         if(cp.message == "") { cp.message = "a"; }
772
773         // appearence
774         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
775
776         // control point placement
777         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
778         {
779                 cp.noalign = true;
780                 set_movetype(cp, MOVETYPE_NONE);
781         }
782         else // drop to floor, automatically find a platform and set that as spawn origin
783         {
784                 setorigin(cp, cp.origin + '0 0 20');
785                 cp.noalign = false;
786                 droptofloor(cp);
787                 set_movetype(cp, MOVETYPE_TOSS);
788         }
789
790         // waypointsprites
791         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
792         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
793
794         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
795 }
796
797
798 // =========================
799 // Main Generator Functions
800 // =========================
801
802 entity ons_Generator_Waypoint(entity e)
803 {
804         if (e.isshielded)
805                 return WP_OnsGenShielded;
806         return WP_OnsGen;
807 }
808
809 void ons_Generator_UpdateSprite(entity e)
810 {
811         entity s1 = ons_Generator_Waypoint(e);
812         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
813
814         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
815         {
816                 e.lastteam = e.team + 2;
817                 e.lastshielded = e.isshielded;
818                 if(e.lastshielded)
819                 {
820                         if(e.team)
821                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
822                         else
823                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
824                 }
825                 else
826                 {
827                         if(e.team)
828                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
829                         else
830                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
831                 }
832                 WaypointSprite_Ping(e.sprite);
833         }
834 }
835
836 void ons_camSetup(entity this)
837 {
838         vector dir;
839         vector ang = '0 0 0';
840         vector best_ang = '0 0 0';
841         float best_trace_fraction = 0;
842         while(ang.y < 360)
843         {
844                 dir = vec2(cos(ang.y * DEG2RAD), sin(ang.y * DEG2RAD));
845                 dir *= 500;
846                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
847                 if(trace_fraction > best_trace_fraction)
848                 {
849                         best_trace_fraction = trace_fraction;
850                         best_ang = ang;
851                         if(trace_fraction == 1)
852                                 break;
853                 }
854                 ang.y += 90;
855                 if(ang.y == 360)
856                         ang.y = 45;
857         }
858         cam.origin = this.origin;
859         setorigin(cam, cam.origin);
860         cam.angles = best_ang;
861         Net_LinkEntity(cam, false, 0, clientcamera_send);
862
863         FOREACH_CLIENT(true, it.clientcamera = cam;);
864
865         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
866         WriteAngle(MSG_ALL, cam.angles_x);
867         WriteAngle(MSG_ALL, cam.angles_y);
868         WriteAngle(MSG_ALL, cam.angles_z);
869 }
870
871 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
872 {
873         if(damage <= 0) return;
874         if(warmup_stage || game_stopped) return;
875         if(!round_handler_IsRoundStarted()) return;
876
877         if (attacker != this)
878         {
879                 if (this.isshielded)
880                 {
881                         // generator is protected by a shield, so ignore the damage
882                         if (time > this.pain_finished)
883                                 if (IS_PLAYER(attacker))
884                                 {
885                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
886                                         attacker.typehitsound += 1;
887                                         this.pain_finished = time + 1;
888                                 }
889                         return;
890                 }
891                 if (time > this.pain_finished)
892                 {
893                         this.pain_finished = time + 10;
894                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
895                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
896                 }
897         }
898         this.health = this.health - damage;
899         WaypointSprite_UpdateHealth(this.sprite, this.health);
900         // choose an animation frame based on health
901         this.frame = 10 * bound(0, (1 - this.health / this.max_health), 1);
902         // see if the generator is still functional, or dying
903         if (this.health > 0)
904         {
905                 this.lasthealth = this.health;
906         }
907         else
908         {
909                 if (attacker == this)
910                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
911                 else
912                 {
913                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
914                         PlayerScore_Add(attacker, SP_SCORE, 100);
915                 }
916                 this.iscaptured = false;
917                 this.islinked = false;
918                 this.isshielded = false;
919                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
920                 this.event_damage = func_null; // won't do anything if hurt
921                 this.count = 0; // reset counter
922                 setthink(this, func_null);
923                 this.nextthink = 0;
924                 //this.think(); // do the first explosion now
925
926                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
927                 WaypointSprite_Ping(this.sprite);
928                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
929
930                 onslaught_updatelinks();
931
932                 ons_camSetup(this);
933         }
934
935         // Throw some flaming gibs on damage, more damage = more chance for gib
936         if(random() < damage/220)
937         {
938                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
939         }
940         else
941         {
942                 // particles on every hit
943                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
944
945                 //sound on every hit
946                 if (random() < 0.5)
947                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
948                 else
949                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
950         }
951
952         this.SendFlags |= GSF_STATUS;
953 }
954
955 void ons_GeneratorThink(entity this)
956 {
957         this.nextthink = time + GEN_THINKRATE;
958         if (!game_stopped)
959         {
960                 if(!this.isshielded && this.wait < time)
961                 {
962                         this.wait = time + 5;
963                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
964                                 if(SAME_TEAM(it, this))
965                                 {
966                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
967                                         soundto(MSG_ONE, it, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE);    // FIXME: unique sound?
968                                 }
969                                 else
970                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
971                         });
972                 }
973         }
974 }
975
976 void ons_GeneratorReset(entity this)
977 {
978         this.team = this.team_saved;
979         this.lasthealth = this.max_health = this.health = autocvar_g_onslaught_gen_health;
980         this.takedamage = DAMAGE_AIM;
981         this.bot_attack = true;
982         if(!IL_CONTAINS(g_bot_targets, this))
983                 IL_PUSH(g_bot_targets, this);
984         this.iscaptured = true;
985         this.islinked = true;
986         this.isshielded = true;
987         this.event_damage = ons_GeneratorDamage;
988         setthink(this, ons_GeneratorThink);
989         this.nextthink = time + GEN_THINKRATE;
990
991         Net_LinkEntity(this, false, 0, generator_send);
992
993         this.SendFlags = GSF_SETUP; // just incase
994         this.SendFlags |= GSF_STATUS;
995
996         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
997         WaypointSprite_UpdateHealth(this.sprite, this.health);
998         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
999
1000         onslaught_updatelinks();
1001 }
1002
1003 void ons_DelayedGeneratorSetup(entity this)
1004 {
1005         // bot waypoints
1006         waypoint_spawnforitem_force(this, this.origin);
1007         this.nearestwaypointtimeout = 0; // activate waypointing again
1008         this.bot_basewaypoint = this.nearestwaypoint;
1009
1010         // captureshield setup
1011         ons_CaptureShield_Spawn(this, true);
1012
1013         onslaught_updatelinks();
1014
1015         Net_LinkEntity(this, false, 0, generator_send);
1016 }
1017
1018
1019 void onslaught_generator_touch(entity this, entity toucher)
1020 {
1021         if ( IS_PLAYER(toucher) )
1022         if ( SAME_TEAM(this,toucher) )
1023         if ( this.iscaptured )
1024         {
1025                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1026         }
1027 }
1028
1029 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1030 {
1031         // declarations
1032         int teamnumber = gen.team;
1033
1034         // main setup
1035         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1036         ons_worldgeneratorlist = gen;
1037
1038         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1039         gen.classname = "onslaught_generator";
1040         gen.solid = SOLID_BBOX;
1041         gen.team_saved = teamnumber;
1042         IL_PUSH(g_saved_team, gen);
1043         set_movetype(gen, MOVETYPE_NONE);
1044         gen.lasthealth = gen.max_health = gen.health = autocvar_g_onslaught_gen_health;
1045         gen.takedamage = DAMAGE_AIM;
1046         gen.bot_attack = true;
1047         IL_PUSH(g_bot_targets, gen);
1048         gen.event_damage = ons_GeneratorDamage;
1049         gen.reset = ons_GeneratorReset;
1050         setthink(gen, ons_GeneratorThink);
1051         gen.nextthink = time + GEN_THINKRATE;
1052         gen.iscaptured = true;
1053         gen.islinked = true;
1054         gen.isshielded = true;
1055         settouch(gen, onslaught_generator_touch);
1056
1057         // appearence
1058         // model handled by CSQC
1059         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1060         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1061         gen.colormap = 1024 + (teamnumber - 1) * 17;
1062
1063         // generator placement
1064         droptofloor(gen);
1065
1066         // waypointsprites
1067         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1068         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1069         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1070         WaypointSprite_UpdateHealth(gen.sprite, gen.health);
1071
1072         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1073 }
1074
1075
1076 // ===============
1077 //  Round Handler
1078 // ===============
1079
1080 int total_generators;
1081 void Onslaught_count_generators()
1082 {
1083         entity e;
1084         total_generators = redowned = blueowned = yellowowned = pinkowned = 0;
1085         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1086         {
1087                 ++total_generators;
1088                 redowned += (e.team == NUM_TEAM_1 && e.health > 0);
1089                 blueowned += (e.team == NUM_TEAM_2 && e.health > 0);
1090                 yellowowned += (e.team == NUM_TEAM_3 && e.health > 0);
1091                 pinkowned += (e.team == NUM_TEAM_4 && e.health > 0);
1092         }
1093 }
1094
1095 int Onslaught_GetWinnerTeam()
1096 {
1097         int winner_team = 0;
1098         if(redowned > 0)
1099                 winner_team = NUM_TEAM_1;
1100         if(blueowned > 0)
1101         {
1102                 if(winner_team) return 0;
1103                 winner_team = NUM_TEAM_2;
1104         }
1105         if(yellowowned > 0)
1106         {
1107                 if(winner_team) return 0;
1108                 winner_team = NUM_TEAM_3;
1109         }
1110         if(pinkowned > 0)
1111         {
1112                 if(winner_team) return 0;
1113                 winner_team = NUM_TEAM_4;
1114         }
1115         if(winner_team)
1116                 return winner_team;
1117         return -1; // no generators left?
1118 }
1119
1120 void nades_Clear(entity e);
1121
1122 #define ONS_OWNED_GENERATORS() ((redowned > 0) + (blueowned > 0) + (yellowowned > 0) + (pinkowned > 0))
1123 #define ONS_OWNED_GENERATORS_OK() (ONS_OWNED_GENERATORS() > 1)
1124 bool Onslaught_CheckWinner()
1125 {
1126         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1127         {
1128                 ons_stalemate = true;
1129
1130                 if (!wpforenemy_announced)
1131                 {
1132                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1133                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1134
1135                         wpforenemy_announced = true;
1136                 }
1137
1138                 entity tmp_entity; // temporary entity
1139                 float d;
1140                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1141                 {
1142                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1143                         // control points reduce the overtime duration.
1144                         d = 1;
1145                         entity e;
1146                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1147                         {
1148                                 if(DIFF_TEAM(e, tmp_entity))
1149                                 if(e.islinked)
1150                                         d = d + 1;
1151                         }
1152
1153                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1154                                 d = d * tmp_entity.max_health;
1155                         else
1156                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1157
1158                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, tmp_entity.origin, '0 0 0');
1159
1160                         tmp_entity.sprite.SendFlags |= 16;
1161
1162                         tmp_entity.ons_overtime_damagedelay = time + 1;
1163                 }
1164         }
1165         else { wpforenemy_announced = false; ons_stalemate = false; }
1166
1167         Onslaught_count_generators();
1168
1169         if(ONS_OWNED_GENERATORS_OK())
1170                 return 0;
1171
1172         int winner_team = Onslaught_GetWinnerTeam();
1173
1174         if(winner_team > 0)
1175         {
1176                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1177                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1178                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1179         }
1180         else if(winner_team == -1)
1181         {
1182                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1183                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1184         }
1185
1186         ons_stalemate = false;
1187
1188         play2all(SND(CTF_CAPTURE(winner_team)));
1189
1190         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1191
1192         FOREACH_CLIENT(IS_PLAYER(it), {
1193                 STAT(ROUNDLOST, it) = true;
1194                 it.player_blocked = true;
1195
1196                 nades_Clear(it);
1197         });
1198
1199         game_stopped = true;
1200         return 1;
1201 }
1202
1203 bool Onslaught_CheckPlayers()
1204 {
1205         return 1;
1206 }
1207
1208 void Onslaught_RoundStart()
1209 {
1210         entity tmp_entity;
1211         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1212
1213         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1214                 tmp_entity.sprite.SendFlags |= 16;
1215
1216         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1217                 tmp_entity.sprite.SendFlags |= 16;
1218 }
1219
1220
1221 // ================
1222 // Bot player logic
1223 // ================
1224
1225 // NOTE: LEGACY CODE, needs to be re-written!
1226
1227 void havocbot_goalrating_ons_offenseitems(entity this, float ratingscale, vector org, float sradius)
1228 {
1229         bool needarmor = false, needweapons = false;
1230
1231         // Needs armor/health?
1232         if(this.health<100)
1233                 needarmor = true;
1234
1235         // Needs weapons?
1236         int c = 0;
1237         FOREACH(Weapons, it != WEP_Null, {
1238                 if(this.weapons & (it.m_wepset))
1239                 if(++c >= 4)
1240                         break;
1241         });
1242
1243         if(c<4)
1244                 needweapons = true;
1245
1246         if(!needweapons && !needarmor)
1247                 return;
1248
1249         LOG_DEBUG(this.netname, " needs weapons ", ftos(needweapons));
1250         LOG_DEBUG(this.netname, " needs armor ", ftos(needarmor));
1251
1252         // See what is around
1253         IL_EACH(g_items, it.bot_pickup,
1254         {
1255                 // gather health and armor only
1256                 if (it.solid)
1257                 if ( ((it.health || it.armorvalue) && needarmor) || (it.weapons && needweapons ) )
1258                 if (vdist(it.origin - org, <, sradius))
1259                 {
1260                         int t = it.bot_pickupevalfunc(this, it);
1261                         if (t > 0)
1262                                 navigation_routerating(this, it, t * ratingscale, 500);
1263                 }
1264         });
1265 }
1266
1267 void havocbot_role_ons_setrole(entity this, int role)
1268 {
1269         LOG_DEBUG(this.netname," switched to ");
1270         switch(role)
1271         {
1272                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1273                         LOG_DEBUG("defense");
1274                         this.havocbot_role = havocbot_role_ons_defense;
1275                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_DEFENSE;
1276                         this.havocbot_role_timeout = 0;
1277                         break;
1278                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1279                         LOG_DEBUG("assistant");
1280                         this.havocbot_role = havocbot_role_ons_assistant;
1281                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_ASSISTANT;
1282                         this.havocbot_role_timeout = 0;
1283                         break;
1284                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1285                         LOG_DEBUG("offense");
1286                         this.havocbot_role = havocbot_role_ons_offense;
1287                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_OFFENSE;
1288                         this.havocbot_role_timeout = 0;
1289                         break;
1290         }
1291         LOG_DEBUG("");
1292 }
1293
1294 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1295 {
1296         entity cp, cp1, cp2, best, wp;
1297         float radius, bestvalue;
1298         int c;
1299         bool found;
1300
1301         // Filter control points
1302         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1303         {
1304                 cp2.wpcost = c = 0;
1305                 cp2.wpconsidered = false;
1306
1307                 if(cp2.isshielded)
1308                         continue;
1309
1310                 // Ignore owned controlpoints
1311                 if(!((cp2.aregensneighbor & BIT(this.team)) || (cp2.arecpsneighbor & BIT(this.team))))
1312                         continue;
1313
1314                 // Count team mates interested in this control point
1315                 // (easier and cleaner than keeping counters per cp and teams)
1316                 FOREACH_CLIENT(IS_PLAYER(it), {
1317                         if(SAME_TEAM(it, this))
1318                         if(it.havocbot_role_flags & HAVOCBOT_ONS_ROLE_OFFENSE)
1319                         if(it.havocbot_ons_target == cp2)
1320                                 ++c;
1321                 });
1322
1323                 // NOTE: probably decrease the cost of attackable control points
1324                 cp2.wpcost = c;
1325                 cp2.wpconsidered = true;
1326         }
1327
1328         // We'll consider only the best case
1329         bestvalue = 99999999999;
1330         cp = NULL;
1331         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1332         {
1333                 if (!cp1.wpconsidered)
1334                         continue;
1335
1336                 if(cp1.wpcost<bestvalue)
1337                 {
1338                         bestvalue = cp1.wpcost;
1339                         cp = cp1;
1340                         this.havocbot_ons_target = cp1;
1341                 }
1342         }
1343
1344         if (!cp)
1345                 return;
1346
1347         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1348
1349         if(cp.goalentity)
1350         {
1351                 // Should be attacked
1352                 // Rate waypoints near it
1353                 found = false;
1354                 best = NULL;
1355                 bestvalue = 99999999999;
1356                 for(radius=0; radius<1000 && !found; radius+=500)
1357                 {
1358                         for(wp=findradius(cp.origin,radius); wp; wp=wp.chain)
1359                         {
1360                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
1361                                 if(wp.classname=="waypoint")
1362                                 if(checkpvs(wp.origin,cp))
1363                                 {
1364                                         found = true;
1365                                         if(wp.cnt<bestvalue)
1366                                         {
1367                                                 best = wp;
1368                                                 bestvalue = wp.cnt;
1369                                         }
1370                                 }
1371                         }
1372                 }
1373
1374                 if(best)
1375                 {
1376                         navigation_routerating(this, best, ratingscale, 10000);
1377                         best.cnt += 1;
1378
1379                         this.havocbot_attack_time = 0;
1380                         if(checkpvs(this.view_ofs,cp))
1381                         if(checkpvs(this.view_ofs,best))
1382                                 this.havocbot_attack_time = time + 2;
1383                 }
1384                 else
1385                 {
1386                         navigation_routerating(this, cp, ratingscale, 10000);
1387                 }
1388                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1389         }
1390         else
1391         {
1392                 // Should be touched
1393                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1394                 found = false;
1395
1396                 // Look for auto generated waypoint
1397                 if (!bot_waypoints_for_items)
1398                 for (wp = findradius(cp.origin,100); wp; wp = wp.chain)
1399                 {
1400                         if(wp.classname=="waypoint")
1401                         {
1402                                 navigation_routerating(this, wp, ratingscale, 10000);
1403                                 found = true;
1404                         }
1405                 }
1406
1407                 // Nothing found, rate the controlpoint itself
1408                 if (!found)
1409                         navigation_routerating(this, cp, ratingscale, 10000);
1410         }
1411 }
1412
1413 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1414 {
1415         entity g, wp, bestwp;
1416         bool found;
1417         int best;
1418
1419         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1420         {
1421                 if(SAME_TEAM(g, this) || g.isshielded)
1422                         continue;
1423
1424                 // Should be attacked
1425                 // Rate waypoints near it
1426                 found = false;
1427                 bestwp = NULL;
1428                 best = 99999999999;
1429
1430                 for(wp=findradius(g.origin,400); wp; wp=wp.chain)
1431                 {
1432                         if(wp.classname=="waypoint")
1433                         if(checkpvs(wp.origin,g))
1434                         {
1435                                 found = true;
1436                                 if(wp.cnt<best)
1437                                 {
1438                                         bestwp = wp;
1439                                         best = wp.cnt;
1440                                 }
1441                         }
1442                 }
1443
1444                 if(bestwp)
1445                 {
1446                         LOG_DEBUG("waypoints found around generator");
1447                         navigation_routerating(this, bestwp, ratingscale, 10000);
1448                         bestwp.cnt += 1;
1449
1450                         this.havocbot_attack_time = 0;
1451                         if(checkpvs(this.view_ofs,g))
1452                         if(checkpvs(this.view_ofs,bestwp))
1453                                 this.havocbot_attack_time = time + 5;
1454
1455                         return true;
1456                 }
1457                 else
1458                 {
1459                         LOG_DEBUG("generator found without waypoints around");
1460                         // if there aren't waypoints near the generator go straight to it
1461                         navigation_routerating(this, g, ratingscale, 10000);
1462                         this.havocbot_attack_time = 0;
1463                         return true;
1464                 }
1465         }
1466         return false;
1467 }
1468
1469 void havocbot_role_ons_offense(entity this)
1470 {
1471         if(IS_DEAD(this))
1472         {
1473                 this.havocbot_attack_time = 0;
1474                 havocbot_ons_reset_role(this);
1475                 return;
1476         }
1477
1478         // Set the role timeout if necessary
1479         if (!this.havocbot_role_timeout)
1480                 this.havocbot_role_timeout = time + 120;
1481
1482         if (time > this.havocbot_role_timeout)
1483         {
1484                 havocbot_ons_reset_role(this);
1485                 return;
1486         }
1487
1488         if(this.havocbot_attack_time>time)
1489                 return;
1490
1491         if (this.bot_strategytime < time)
1492         {
1493                 navigation_goalrating_start(this);
1494                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1495                 if(!havocbot_goalrating_ons_generator_attack(this, 20000))
1496                         havocbot_goalrating_ons_controlpoints_attack(this, 20000);
1497                 havocbot_goalrating_ons_offenseitems(this, 10000, this.origin, 10000);
1498                 navigation_goalrating_end(this);
1499
1500                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1501         }
1502 }
1503
1504 void havocbot_role_ons_assistant(entity this)
1505 {
1506         havocbot_ons_reset_role(this);
1507 }
1508
1509 void havocbot_role_ons_defense(entity this)
1510 {
1511         havocbot_ons_reset_role(this);
1512 }
1513
1514 void havocbot_ons_reset_role(entity this)
1515 {
1516         if(IS_DEAD(this))
1517                 return;
1518
1519         this.havocbot_ons_target = NULL;
1520
1521         // TODO: Defend control points or generator if necessary
1522
1523         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1524 }
1525
1526
1527 /*
1528  * Find control point or generator owned by the same team self which is nearest to pos
1529  * if max_dist is positive, only control points within this range will be considered
1530  */
1531 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1532 {
1533         entity closest_target = NULL;
1534         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1535         {
1536                 if(SAME_TEAM(cp, this))
1537                 if(cp.iscaptured)
1538                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1539                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1540                         closest_target = cp;
1541         }
1542         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1543         {
1544                 if(SAME_TEAM(gen, this))
1545                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1546                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1547                         closest_target = gen;
1548         }
1549
1550         return closest_target;
1551 }
1552
1553 /*
1554  * Find control point or generator owned by the same team self which is nearest to pos
1555  * if max_dist is positive, only control points within this range will be considered
1556  * This function only check distances on the XY plane, disregarding Z
1557  */
1558 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1559 {
1560         entity closest_target = NULL;
1561         vector delta;
1562         float smallest_distance = 0, distance;
1563
1564         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1565         {
1566                 delta = cp.origin - pos;
1567                 delta_z = 0;
1568                 distance = vlen(delta);
1569
1570                 if(SAME_TEAM(cp, this))
1571                 if(cp.iscaptured)
1572                 if(max_dist <= 0 || distance <= max_dist)
1573                 if(closest_target == NULL || distance <= smallest_distance )
1574                 {
1575                         closest_target = cp;
1576                         smallest_distance = distance;
1577                 }
1578         }
1579         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1580         {
1581                 delta = gen.origin - pos;
1582                 delta_z = 0;
1583                 distance = vlen(delta);
1584
1585                 if(SAME_TEAM(gen, this))
1586                 if(max_dist <= 0 || distance <= max_dist)
1587                 if(closest_target == NULL || distance <= smallest_distance )
1588                 {
1589                         closest_target = gen;
1590                         smallest_distance = distance;
1591                 }
1592         }
1593
1594         return closest_target;
1595 }
1596 /**
1597  * find the number of control points and generators in the same team as this
1598  */
1599 int ons_Count_SelfControlPoints(entity this)
1600 {
1601         int n = 0;
1602         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1603         {
1604                 if(SAME_TEAM(cp, this))
1605                 if(cp.iscaptured)
1606                         n++;
1607         }
1608         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1609         {
1610                 if(SAME_TEAM(gen, this))
1611                         n++;
1612         }
1613         return n;
1614 }
1615
1616 /**
1617  * Teleport player to a random position near tele_target
1618  * if tele_effects is true, teleport sound+particles are created
1619  * return false on failure
1620  */
1621 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1622 {
1623         if ( !tele_target )
1624                 return false;
1625
1626         int i;
1627         vector loc;
1628         float theta;
1629         // narrow the range for each iteration to increase chances that a spawnpoint
1630         // can be found even if there's little room around the control point
1631         float iteration_scale = 1;
1632         for(i = 0; i < 16; ++i)
1633         {
1634                 iteration_scale -= i / 16;
1635                 theta = random() * 2 * M_PI;
1636                 loc_y = sin(theta);
1637                 loc_x = cos(theta);
1638                 loc_z = 0;
1639                 loc *= random() * range * iteration_scale;
1640
1641                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1642
1643                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1644                 if(trace_fraction == 1.0 && !trace_startsolid)
1645                 {
1646                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1647                         if(trace_fraction == 1.0 && !trace_startsolid)
1648                         {
1649                                 if ( tele_effects )
1650                                 {
1651                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1652                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1653                                 }
1654                                 setorigin(player, loc);
1655                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1656                                 makevectors(player.angles);
1657                                 player.fixangle = true;
1658                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1659
1660                                 if ( tele_effects )
1661                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1662                                 return true;
1663                         }
1664                 }
1665         }
1666
1667         return false;
1668 }
1669
1670 // ==============
1671 // Hook Functions
1672 // ==============
1673
1674 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1675 {
1676         FOREACH_CLIENT(IS_PLAYER(it), {
1677                 STAT(ROUNDLOST, it) = false;
1678                 it.ons_deathloc = '0 0 0';
1679                 PutClientInServer(it);
1680                 it.clientcamera = it;
1681         });
1682         return false;
1683 }
1684
1685 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1686 {
1687         entity player = M_ARGV(0, entity);
1688
1689         player.ons_deathloc = '0 0 0';
1690 }
1691
1692 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1693 {
1694         entity player = M_ARGV(0, entity);
1695
1696         player.ons_deathloc = '0 0 0';
1697 }
1698
1699 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1700 {
1701         entity player = M_ARGV(0, entity);
1702
1703         if(!round_handler_IsRoundStarted())
1704         {
1705                 player.player_blocked = true;
1706                 return false;
1707         }
1708
1709         entity l;
1710         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1711         {
1712                 l.sprite.SendFlags |= 16;
1713         }
1714         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1715         {
1716                 l.sprite.SendFlags |= 16;
1717         }
1718
1719         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1720
1721         if ( autocvar_g_onslaught_spawn_choose )
1722         if ( player.ons_spawn_by )
1723         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1724         {
1725                 player.ons_spawn_by = NULL;
1726                 return false;
1727         }
1728
1729         if(autocvar_g_onslaught_spawn_at_controlpoints)
1730         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1731         {
1732                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1733                 entity tmp_entity, closest_target = NULL;
1734                 vector spawn_loc = player.ons_deathloc;
1735
1736                 // new joining player or round reset, don't bother checking
1737                 if(spawn_loc == '0 0 0') { return false; }
1738
1739                 if(random_target) { RandomSelection_Init(); }
1740
1741                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1742                 {
1743                         if(SAME_TEAM(tmp_entity, player))
1744                         if(random_target)
1745                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1746                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1747                                 closest_target = tmp_entity;
1748                 }
1749
1750                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1751
1752                 if(closest_target)
1753                 {
1754                         float i;
1755                         vector loc;
1756                         float iteration_scale = 1;
1757                         for(i = 0; i < 10; ++i)
1758                         {
1759                                 iteration_scale -= i / 10;
1760                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1761                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1762                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1763                                 if(trace_fraction == 1.0 && !trace_startsolid)
1764                                 {
1765                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1766                                         if(trace_fraction == 1.0 && !trace_startsolid)
1767                                         {
1768                                                 setorigin(player, loc);
1769                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1770                                                 return false;
1771                                         }
1772                                 }
1773                         }
1774                 }
1775         }
1776
1777         if(autocvar_g_onslaught_spawn_at_generator)
1778         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1779         {
1780                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1781                 entity tmp_entity, closest_target = NULL;
1782                 vector spawn_loc = player.ons_deathloc;
1783
1784                 // new joining player or round reset, don't bother checking
1785                 if(spawn_loc == '0 0 0') { return false; }
1786
1787                 if(random_target) { RandomSelection_Init(); }
1788
1789                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1790                 {
1791                         if(random_target)
1792                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1793                         else
1794                         {
1795                                 if(SAME_TEAM(tmp_entity, player))
1796                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1797                                         closest_target = tmp_entity;
1798                         }
1799                 }
1800
1801                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1802
1803                 if(closest_target)
1804                 {
1805                         float i;
1806                         vector loc;
1807                         float iteration_scale = 1;
1808                         for(i = 0; i < 10; ++i)
1809                         {
1810                                 iteration_scale -= i / 10;
1811                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1812                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1813                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1814                                 if(trace_fraction == 1.0 && !trace_startsolid)
1815                                 {
1816                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1817                                         if(trace_fraction == 1.0 && !trace_startsolid)
1818                                         {
1819                                                 setorigin(player, loc);
1820                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1821                                                 return false;
1822                                         }
1823                                 }
1824                         }
1825                 }
1826         }
1827
1828         return false;
1829 }
1830
1831 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1832 {
1833         entity frag_target = M_ARGV(2, entity);
1834
1835         frag_target.ons_deathloc = frag_target.origin;
1836         entity l;
1837         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1838         {
1839                 l.sprite.SendFlags |= 16;
1840         }
1841         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1842         {
1843                 l.sprite.SendFlags |= 16;
1844         }
1845
1846         if ( autocvar_g_onslaught_spawn_choose )
1847         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1848                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1849
1850         return false;
1851 }
1852
1853 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1854 {
1855         entity mon = M_ARGV(0, entity);
1856
1857         entity e = find(NULL, targetname, mon.target);
1858         if (e != NULL)
1859                 mon.team = e.team;
1860 }
1861
1862 void ons_MonsterSpawn_Delayed(entity this)
1863 {
1864         entity own = this.owner;
1865
1866         if(!own) { delete(this); return; }
1867
1868         if(own.targetname)
1869         {
1870                 entity e = find(NULL, target, own.targetname);
1871                 if(e != NULL)
1872                 {
1873                         own.team = e.team;
1874
1875                         own.use(own, e, NULL);
1876                 }
1877         }
1878
1879         delete(this);
1880 }
1881
1882 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1883 {
1884         entity mon = M_ARGV(0, entity);
1885
1886         entity e = spawn();
1887         e.owner = mon;
1888         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1889 }
1890
1891 void ons_TurretSpawn_Delayed(entity this)
1892 {
1893         entity own = this.owner;
1894
1895         if(!own) { delete(this); return; }
1896
1897         if(own.targetname)
1898         {
1899                 entity e = find(NULL, target, own.targetname);
1900                 if(e != NULL)
1901                 {
1902                         own.team = e.team;
1903                         own.active = ACTIVE_NOT;
1904
1905                         own.use(own, e, NULL);
1906                 }
1907         }
1908
1909         delete(this);
1910 }
1911
1912 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1913 {
1914         entity turret = M_ARGV(0, entity);
1915
1916         entity e = spawn();
1917         e.owner = turret;
1918         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1919
1920         return false;
1921 }
1922
1923 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1924 {
1925         entity bot = M_ARGV(0, entity);
1926
1927         havocbot_ons_reset_role(bot);
1928         return true;
1929 }
1930
1931 MUTATOR_HOOKFUNCTION(ons, CheckAllowedTeams)
1932 {
1933         // onslaught is special
1934         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1935         {
1936                 switch(tmp_entity.team)
1937                 {
1938                         case NUM_TEAM_1: c1 = 0; break;
1939                         case NUM_TEAM_2: c2 = 0; break;
1940                         case NUM_TEAM_3: c3 = 0; break;
1941                         case NUM_TEAM_4: c4 = 0; break;
1942                 }
1943         }
1944
1945         return true;
1946 }
1947
1948 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1949 {
1950         entity spectatee = M_ARGV(0, entity);
1951         entity client = M_ARGV(1, entity);
1952
1953         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1954 }
1955
1956 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1957 {
1958         if(MUTATOR_RETURNVALUE) // command was already handled?
1959                 return false;
1960
1961         entity player = M_ARGV(0, entity);
1962         string cmd_name = M_ARGV(1, string);
1963         int cmd_argc = M_ARGV(2, int);
1964
1965         if ( cmd_name == "ons_spawn" )
1966         {
1967                 vector pos = player.origin;
1968                 if(cmd_argc > 1)
1969                         pos_x = stof(argv(1));
1970                 if(cmd_argc > 2)
1971                         pos_y = stof(argv(2));
1972                 if(cmd_argc > 3)
1973                         pos_z = stof(argv(3));
1974
1975                 if ( IS_PLAYER(player) )
1976                 {
1977                         if ( !STAT(FROZEN, player) )
1978                         {
1979                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1980
1981                                 if ( !source_point && player.health > 0 )
1982                                 {
1983                                         sprint(player, "\nYou need to be next to a control point\n");
1984                                         return true;
1985                                 }
1986
1987
1988                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1989
1990                                 if ( closest_target == NULL )
1991                                 {
1992                                         sprint(player, "\nNo control point found\n");
1993                                         return true;
1994                                 }
1995
1996                                 if ( player.health <= 0 )
1997                                 {
1998                                         player.ons_spawn_by = closest_target;
1999                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
2000                                 }
2001                                 else
2002                                 {
2003                                         if ( source_point == closest_target )
2004                                         {
2005                                                 sprint(player, "\nTeleporting to the same point\n");
2006                                                 return true;
2007                                         }
2008
2009                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
2010                                                 sprint(player, "\nUnable to teleport there\n");
2011                                 }
2012
2013                                 return true;
2014                         }
2015
2016                         sprint(player, "\nNo teleportation for you\n");
2017                 }
2018
2019                 return true;
2020         }
2021         return false;
2022 }
2023
2024 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2025 {
2026         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2027
2028         entity player = M_ARGV(0, entity);
2029
2030         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2031         {
2032                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2033                 if ( source_point )
2034                 {
2035                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2036                         return true;
2037                 }
2038         }
2039 }
2040
2041 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2042 {
2043         entity frag_victim = M_ARGV(0, entity);
2044
2045         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2046                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2047 }
2048
2049 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2050 {
2051     entity wp = M_ARGV(0, entity);
2052     entity to = M_ARGV(1, entity);
2053     int sf = M_ARGV(2, int);
2054     int wp_flag = M_ARGV(3, int);
2055
2056         if(sf & 16)
2057         {
2058                 if(wp.owner.classname == "onslaught_controlpoint")
2059                 {
2060                         entity wp_owner = wp.owner;
2061                         entity e = WaypointSprite_getviewentity(to);
2062                         if(SAME_TEAM(e, wp_owner) && wp_owner.goalentity.health >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2063                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2064                 }
2065                 if(wp.owner.classname == "onslaught_generator")
2066                 {
2067                         entity wp_owner = wp.owner;
2068                         if(wp_owner.isshielded && wp_owner.health >= wp_owner.max_health) { wp_flag |= 2; }
2069                         if(wp_owner.health <= 0) { wp_flag |= 2; }
2070                 }
2071         }
2072
2073         M_ARGV(3, int) = wp_flag;
2074 }
2075
2076 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2077 {
2078         entity turret_target = M_ARGV(1, entity);
2079
2080         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2081         {
2082                 M_ARGV(3, float) = -3;
2083                 return true;
2084         }
2085
2086         return false;
2087 }
2088
2089 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2090 {
2091     entity turret = M_ARGV(0, entity);
2092
2093         // ONS uses somewhat backwards linking.
2094         if(turret.target)
2095         {
2096                 entity e = find(NULL, targetname, turret.target);
2097                 if (e != NULL)
2098                         turret.team = e.team;
2099         }
2100
2101         if(turret.team != turret.tur_head.team)
2102                 turret_respawn(turret);
2103 }
2104
2105
2106 // ==========
2107 // Spawnfuncs
2108 // ==========
2109
2110 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2111   Link between control points.
2112
2113   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2114
2115 keys:
2116 "target" - first control point.
2117 "target2" - second control point.
2118  */
2119 spawnfunc(onslaught_link)
2120 {
2121         if(!g_onslaught) { delete(this); return; }
2122
2123         if (this.target == "" || this.target2 == "")
2124                 objerror(this, "target and target2 must be set\n");
2125
2126         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2127         ons_worldlinklist = this;
2128
2129         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2130         Net_LinkEntity(this, false, 0, ons_Link_Send);
2131 }
2132
2133 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2134   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2135
2136   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2137
2138 keys:
2139 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2140 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2141 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2142  */
2143
2144 spawnfunc(onslaught_controlpoint)
2145 {
2146         if(!g_onslaught) { delete(this); return; }
2147
2148         ons_ControlPoint_Setup(this);
2149 }
2150
2151 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2152   Base generator.
2153
2154   spawnfunc_onslaught_link entities can target this.
2155
2156 keys:
2157 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2158 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2159  */
2160 spawnfunc(onslaught_generator)
2161 {
2162         if(!g_onslaught) { delete(this); return; }
2163         if(!this.team) { objerror(this, "team must be set"); }
2164
2165         ons_GeneratorSetup(this);
2166 }
2167
2168 // scoreboard setup
2169 void ons_ScoreRules()
2170 {
2171         CheckAllowedTeams(NULL);
2172         int teams = 0;
2173         if(c1 >= 0) teams |= BIT(0);
2174         if(c2 >= 0) teams |= BIT(1);
2175         if(c3 >= 0) teams |= BIT(2);
2176         if(c4 >= 0) teams |= BIT(3);
2177         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, 0, true);
2178         ScoreInfo_SetLabel_TeamScore  (ST_ONS_CAPS,     "destroyed", SFL_SORT_PRIO_PRIMARY);
2179         ScoreInfo_SetLabel_PlayerScore(SP_ONS_CAPS,    "caps",      SFL_SORT_PRIO_SECONDARY);
2180         ScoreInfo_SetLabel_PlayerScore(SP_ONS_TAKES,    "takes",     0);
2181         ScoreRules_basics_end();
2182 }
2183
2184 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2185 {
2186         ons_ScoreRules();
2187
2188         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2189         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2190 }
2191
2192 void ons_Initialize()
2193 {
2194         g_onslaught = true;
2195         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2196
2197         cam = new(objective_camera);
2198
2199         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2200 }