qcsrc/common/gamemodes/gamemode/onslaught/sv_onslaught.qc

   1 #include "sv_onslaught.qh"
   2 #include "sv_controlpoint.qh"
   3 #include "sv_generator.qh"
   4
   5 bool g_onslaught;
   6
   7 float autocvar_g_onslaught_teleport_wait;
   8 bool autocvar_g_onslaught_spawn_at_controlpoints;
   9 bool autocvar_g_onslaught_spawn_at_generator;
  10 float autocvar_g_onslaught_cp_proxydecap;
  11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
  12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
  13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
  14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
  15 float autocvar_g_onslaught_spawn_at_generator_chance;
  16 float autocvar_g_onslaught_spawn_at_generator_random;
  17 float autocvar_g_onslaught_cp_buildhealth;
  18 float autocvar_g_onslaught_cp_buildtime;
  19 float autocvar_g_onslaught_cp_health;
  20 float autocvar_g_onslaught_cp_regen;
  21 float autocvar_g_onslaught_gen_health;
  22 float autocvar_g_onslaught_shield_force = 100;
  23 float autocvar_g_onslaught_allow_vehicle_touch;
  24 float autocvar_g_onslaught_round_timelimit;
  25 float autocvar_g_onslaught_warmup;
  26 float autocvar_g_onslaught_teleport_radius;
  27 float autocvar_g_onslaught_spawn_choose;
  28 float autocvar_g_onslaught_click_radius;
  29
  30 void FixSize(entity e);
  31 entity cam;
  32
  33 // =======================
  34 // CaptureShield Functions
  35 // =======================
  36
  37 bool clientcamera_send(entity this, entity to, int sf)
  38 {
  39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
  40
  41         WriteVector(MSG_ENTITY, this.origin);
  42
  43         WriteAngle(MSG_ENTITY, this.angles_x);
  44         WriteAngle(MSG_ENTITY, this.angles_y);
  45         WriteAngle(MSG_ENTITY, this.angles_z);
  46
  47         return true;
  48 }
  49
  50 bool ons_CaptureShield_Customize(entity this, entity client)
  51 {
  52         entity e = WaypointSprite_getviewentity(client);
  53
  54         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
  55         if(SAME_TEAM(this, e)) { return false; }
  56
  57         return true;
  58 }
  59
  60 void ons_CaptureShield_Touch(entity this, entity toucher)
  61 {
  62         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
  63         if(!IS_PLAYER(toucher)) { return; }
  64         if(SAME_TEAM(toucher, this)) { return; }
  65
  66         vector mymid = (this.absmin + this.absmax) * 0.5;
  67         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
  68
  69         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
  70
  71         if(IS_REAL_CLIENT(toucher))
  72         {
  73                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
  74
  75                 if(this.enemy.classname == "onslaught_generator")
  76                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
  77                 else
  78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
  79         }
  80 }
  81
  82 void ons_CaptureShield_Reset(entity this)
  83 {
  84         this.colormap = this.enemy.colormap;
  85         this.team = this.enemy.team;
  86 }
  87
  88 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
  89 {
  90         entity shield = new(ons_captureshield);
  91         IL_PUSH(g_onsshields, shield);
  92
  93         shield.enemy = generator;
  94         shield.team = generator.team;
  95         shield.colormap = generator.colormap;
  96         shield.reset = ons_CaptureShield_Reset;
  97         settouch(shield, ons_CaptureShield_Touch);
  98         setcefc(shield, ons_CaptureShield_Customize);
  99         shield.effects = EF_ADDITIVE;
 100         set_movetype(shield, MOVETYPE_NOCLIP);
 101         shield.solid = SOLID_TRIGGER;
 102         shield.avelocity = '7 0 11';
 103         shield.scale = 1;
 104         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
 105
 106         precache_model(shield.model);
 107         setorigin(shield, generator.origin);
 108         _setmodel(shield, shield.model);
 109         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 110 }
 111
 112
 113 // ==========
 114 // Junk Pile
 115 // ==========
 116
 117 void setmodel_fixsize(entity e, Model m)
 118 {
 119         setmodel(e, m);
 120         FixSize(e);
 121 }
 122
 123 void onslaught_updatelinks()
 124 {
 125         entity l;
 126         // first check if the game has ended
 127         LOG_DEBUG("--- updatelinks ---");
 128         // mark generators as being shielded and networked
 129         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 130         {
 131                 if (l.iscaptured)
 132                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
 133                 else
 134                         LOG_DEBUG(etos(l), " (generator) is destroyed");
 135                 l.islinked = l.iscaptured;
 136                 l.isshielded = l.iscaptured;
 137                 l.sprite.SendFlags |= 16;
 138         }
 139         // mark points as shielded and not networked
 140         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 141         {
 142                 l.islinked = false;
 143                 l.isshielded = true;
 144                 l.aregensneighbor = 0;
 145                 l.arecpsneighbor = 0;
 146                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
 147                 l.sprite.SendFlags |= 16;
 148         }
 149         // flow power outward from the generators through the network
 150         bool stop = false;
 151         while (!stop)
 152         {
 153                 stop = true;
 154                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 155                 {
 156                         // if both points are captured by the same team, and only one of
 157                         // them is powered, mark the other one as powered as well
 158                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 159                                 if (l.enemy.islinked != l.goalentity.islinked)
 160                                         if(SAME_TEAM(l.enemy, l.goalentity))
 161                                         {
 162                                                 if (!l.goalentity.islinked)
 163                                                 {
 164                                                         stop = false;
 165                                                         l.goalentity.islinked = true;
 166                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
 167                                                 }
 168                                                 else if (!l.enemy.islinked)
 169                                                 {
 170                                                         stop = false;
 171                                                         l.enemy.islinked = true;
 172                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
 173                                                 }
 174                                         }
 175                 }
 176         }
 177         // now that we know which points are powered we can mark their neighbors
 178         // as unshielded if team differs
 179         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 180         {
 181                 if (l.goalentity.islinked)
 182                 {
 183                         if(DIFF_TEAM(l.goalentity, l.enemy))
 184                         {
 185                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
 186                                 l.enemy.isshielded = false;
 187                         }
 188                         if(l.goalentity.classname == "onslaught_generator")
 189                                 l.enemy.aregensneighbor |= BIT(l.goalentity.team);
 190                         else
 191                                 l.enemy.arecpsneighbor |= BIT(l.goalentity.team);
 192                 }
 193                 if (l.enemy.islinked)
 194                 {
 195                         if(DIFF_TEAM(l.goalentity, l.enemy))
 196                         {
 197                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
 198                                 l.goalentity.isshielded = false;
 199                         }
 200                         if(l.enemy.classname == "onslaught_generator")
 201                                 l.goalentity.aregensneighbor |= BIT(l.enemy.team);
 202                         else
 203                                 l.goalentity.arecpsneighbor |= BIT(l.enemy.team);
 204                 }
 205         }
 206         // now update the generators
 207         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 208         {
 209                 if (l.isshielded)
 210                 {
 211                         LOG_DEBUG(etos(l), " (generator) is shielded");
 212                         l.takedamage = DAMAGE_NO;
 213                         if(l.bot_attack)
 214                                 IL_REMOVE(g_bot_targets, l);
 215                         l.bot_attack = false;
 216                 }
 217                 else
 218                 {
 219                         LOG_DEBUG(etos(l), " (generator) is not shielded");
 220                         l.takedamage = DAMAGE_AIM;
 221                         if(!l.bot_attack)
 222                                 IL_PUSH(g_bot_targets, l);
 223                         l.bot_attack = true;
 224                 }
 225
 226                 ons_Generator_UpdateSprite(l);
 227         }
 228         // now update the takedamage and alpha variables on control point icons
 229         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 230         {
 231                 if (l.isshielded)
 232                 {
 233                         LOG_DEBUG(etos(l), " (point) is shielded");
 234                         if (l.goalentity)
 235                         {
 236                                 l.goalentity.takedamage = DAMAGE_NO;
 237                                 if(l.goalentity.bot_attack)
 238                                         IL_REMOVE(g_bot_targets, l.goalentity);
 239                                 l.goalentity.bot_attack = false;
 240                         }
 241                 }
 242                 else
 243                 {
 244                         LOG_DEBUG(etos(l), " (point) is not shielded");
 245                         if (l.goalentity)
 246                         {
 247                                 l.goalentity.takedamage = DAMAGE_AIM;
 248                                 if(!l.goalentity.bot_attack)
 249                                         IL_PUSH(g_bot_targets, l.goalentity);
 250                                 l.goalentity.bot_attack = true;
 251                         }
 252                 }
 253                 ons_ControlPoint_UpdateSprite(l);
 254         }
 255         IL_EACH(g_onsshields, true,
 256         {
 257                 it.team = it.enemy.team;
 258                 it.colormap = it.enemy.colormap;
 259         });
 260 }
 261
 262
 263 // ===================
 264 // Main Link Functions
 265 // ===================
 266
 267 bool ons_Link_Send(entity this, entity to, int sendflags)
 268 {
 269         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 270         WriteByte(MSG_ENTITY, sendflags);
 271         if(sendflags & 1)
 272         {
 273                 WriteVector(MSG_ENTITY, this.goalentity.origin);
 274         }
 275         if(sendflags & 2)
 276         {
 277                 WriteVector(MSG_ENTITY, this.enemy.origin);
 278         }
 279         if(sendflags & 4)
 280         {
 281                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
 282         }
 283         return true;
 284 }
 285
 286 void ons_Link_CheckUpdate(entity this)
 287 {
 288         // TODO check if the two sides have moved (currently they won't move anyway)
 289         float cc = 0, cc1 = 0, cc2 = 0;
 290
 291         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
 292         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
 293
 294         cc = cc1 + cc2;
 295
 296         if(cc != this.clientcolors)
 297         {
 298                 this.clientcolors = cc;
 299                 this.SendFlags |= 4;
 300         }
 301
 302         this.nextthink = time;
 303 }
 304
 305 void ons_DelayedLinkSetup(entity this)
 306 {
 307         this.goalentity = find(NULL, targetname, this.target);
 308         this.enemy = find(NULL, targetname, this.target2);
 309         if(!this.goalentity) { objerror(this, "can not find target\n"); }
 310         if(!this.enemy) { objerror(this, "can not find target2\n"); }
 311
 312         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
 313         this.SendFlags |= 3;
 314         setthink(this, ons_Link_CheckUpdate);
 315         this.nextthink = time;
 316 }
 317
 318
 319 // =============================
 320 // Main Control Point Functions
 321 // =============================
 322
 323 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
 324 {
 325         if(cp.aregensneighbor & BIT(teamnumber)) return 2;
 326         if(cp.arecpsneighbor & BIT(teamnumber)) return 1;
 327
 328         return 0;
 329 }
 330
 331 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
 332         // -2: SAME TEAM, attackable by enemy!
 333         // -1: SAME TEAM!
 334         // 0: off limits
 335         // 1: attack it
 336         // 2: touch it
 337         // 3: attack it (HIGH PRIO)
 338         // 4: touch it (HIGH PRIO)
 339 {
 340         int a;
 341
 342         if(cp.isshielded)
 343         {
 344                 return 0;
 345         }
 346         else if(cp.goalentity)
 347         {
 348                 // if there's already an icon built, nothing happens
 349                 if(cp.team == teamnumber)
 350                 {
 351                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 352                         if(a) // attackable by enemy?
 353                                 return -2; // EMERGENCY!
 354                         return -1;
 355                 }
 356                 // we know it can be linked, so no need to check
 357                 // but...
 358                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 359                 if(a == 2) // near our generator?
 360                         return 3; // EMERGENCY!
 361                 return 1;
 362         }
 363         else
 364         {
 365                 // free point
 366                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
 367                 {
 368                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
 369                         if(a == 2)
 370                                 return 4; // GET THIS ONE NOW!
 371                         else
 372                                 return 2; // TOUCH ME
 373                 }
 374         }
 375         return 0;
 376 }
 377
 378 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 379 {
 380         if(damage <= 0) { return; }
 381
 382         if (this.owner.isshielded)
 383         {
 384                 // this is protected by a shield, so ignore the damage
 385                 if (time > this.pain_finished)
 386                         if (IS_PLAYER(attacker))
 387                         {
 388                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 389                                 this.pain_finished = time + 1;
 390                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
 391                         }
 392
 393                 return;
 394         }
 395
 396         if(IS_PLAYER(attacker))
 397         if(time - ons_notification_time[this.team] > 10)
 398         {
 399                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
 400                 ons_notification_time[this.team] = time;
 401         }
 402
 403         this.health = this.health - damage;
 404         if(this.owner.iscaptured)
 405                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 406         else
 407                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - this.health) / (this.count / ONS_CP_THINKRATE));
 408         this.pain_finished = time + 1;
 409         // particles on every hit
 410         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
 411         //sound on every hit
 412         if (random() < 0.5)
 413                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
 414         else
 415                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
 416
 417         if (this.health < 0)
 418         {
 419                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 420                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 421                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
 422
 423                 GameRules_scoring_add(attacker, ONS_TAKES, 1);
 424                 GameRules_scoring_add(attacker, SCORE, 10);
 425
 426                 this.owner.goalentity = NULL;
 427                 this.owner.islinked = false;
 428                 this.owner.iscaptured = false;
 429                 this.owner.team = 0;
 430                 this.owner.colormap = 1024;
 431
 432                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
 433
 434                 onslaught_updatelinks();
 435
 436                 // Use targets now (somebody make sure this is in the right place..)
 437                 SUB_UseTargets(this.owner, this, NULL);
 438
 439                 this.owner.waslinked = this.owner.islinked;
 440                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
 441                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
 442                 //setsize(this, '-32 -32 0', '32 32 8');
 443
 444                 delete(this);
 445         }
 446
 447         this.SendFlags |= CPSF_STATUS;
 448 }
 449
 450 void ons_ControlPoint_Icon_Think(entity this)
 451 {
 452         this.nextthink = time + ONS_CP_THINKRATE;
 453
 454         if(autocvar_g_onslaught_cp_proxydecap)
 455         {
 456                 int _enemy_count = 0;
 457                 int _friendly_count = 0;
 458
 459                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
 460                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
 461                         {
 462                                 if(SAME_TEAM(it, this))
 463                                         ++_friendly_count;
 464                                 else
 465                                         ++_enemy_count;
 466                         }
 467                 });
 468
 469                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 470                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 471
 472                 this.health = bound(0, this.health + (_friendly_count - _enemy_count), this.max_health);
 473                 this.SendFlags |= CPSF_STATUS;
 474                 if(this.health <= 0)
 475                 {
 476                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, DMG_NOWEP, this.origin, '0 0 0');
 477                         return;
 478                 }
 479         }
 480
 481         if (time > this.pain_finished + 5)
 482         {
 483                 if(this.health < this.max_health)
 484                 {
 485                         this.health = this.health + this.count;
 486                         if (this.health >= this.max_health)
 487                                 this.health = this.max_health;
 488                         WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 489                 }
 490         }
 491
 492         if(this.owner.islinked != this.owner.waslinked)
 493         {
 494                 // unteam the spawnpoint if needed
 495                 int t = this.owner.team;
 496                 if(!this.owner.islinked)
 497                         this.owner.team = 0;
 498
 499                 SUB_UseTargets(this.owner, this, NULL);
 500
 501                 this.owner.team = t;
 502
 503                 this.owner.waslinked = this.owner.islinked;
 504         }
 505
 506         // damaged fx
 507         if(random() < 0.6 - this.health / this.max_health)
 508         {
 509                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
 510
 511                 if(random() > 0.8)
 512                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
 513                 else if (random() > 0.5)
 514                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
 515         }
 516 }
 517
 518 void ons_ControlPoint_Icon_BuildThink(entity this)
 519 {
 520         int a;
 521
 522         this.nextthink = time + ONS_CP_THINKRATE;
 523
 524         // only do this if there is power
 525         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
 526         if(!a)
 527                 return;
 528
 529         this.health = this.health + this.count;
 530
 531         this.SendFlags |= CPSF_STATUS;
 532
 533         if (this.health >= this.max_health)
 534         {
 535                 this.health = this.max_health;
 536                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
 537                 setthink(this, ons_ControlPoint_Icon_Think);
 538                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
 539                 this.owner.iscaptured = true;
 540                 this.solid = SOLID_BBOX;
 541
 542                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
 543
 544                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
 545                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 546
 547                 if(IS_PLAYER(this.owner.ons_toucher))
 548                 {
 549                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
 550                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
 551                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
 552                         GameRules_scoring_add(this.owner.ons_toucher, ONS_CAPS, 1);
 553                         GameRules_scoring_add_team(this.owner.ons_toucher, SCORE, 10);
 554                 }
 555
 556                 this.owner.ons_toucher = NULL;
 557
 558                 onslaught_updatelinks();
 559
 560                 // Use targets now (somebody make sure this is in the right place..)
 561                 SUB_UseTargets(this.owner, this, NULL);
 562
 563                 this.SendFlags |= CPSF_SETUP;
 564         }
 565         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
 566                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
 567
 568         if(random() < 0.9 - this.health / this.max_health)
 569                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
 570 }
 571
 572 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
 573
 574 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
 575 {
 576         entity e = new(onslaught_controlpoint_icon);
 577
 578         setsize(e, CPICON_MIN, CPICON_MAX);
 579         setorigin(e, cp.origin + CPICON_OFFSET);
 580
 581         e.owner = cp;
 582         e.max_health = autocvar_g_onslaught_cp_health;
 583         e.health = autocvar_g_onslaught_cp_buildhealth;
 584         e.solid = SOLID_NOT;
 585         e.takedamage = DAMAGE_AIM;
 586         e.bot_attack = true;
 587         IL_PUSH(g_bot_targets, e);
 588         e.event_damage = ons_ControlPoint_Icon_Damage;
 589         e.team = player.team;
 590         e.colormap = 1024 + (e.team - 1) * 17;
 591         e.count = (e.max_health - e.health) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
 592
 593         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
 594
 595         cp.goalentity = e;
 596         cp.team = e.team;
 597         cp.colormap = e.colormap;
 598
 599         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
 600
 601         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - e.health) / (e.count / ONS_CP_THINKRATE));
 602         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
 603         cp.sprite.SendFlags |= 16;
 604
 605         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
 606 }
 607
 608 entity ons_ControlPoint_Waypoint(entity e)
 609 {
 610         if(e.team)
 611         {
 612                 int a = ons_ControlPoint_Attackable(e, e.team);
 613
 614                 if(a == -2) { return WP_OnsCPDefend; } // defend now
 615                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
 616                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
 617         }
 618         else
 619                 return WP_OnsCP;
 620
 621         return WP_Null;
 622 }
 623
 624 void ons_ControlPoint_UpdateSprite(entity e)
 625 {
 626         entity s1 = ons_ControlPoint_Waypoint(e);
 627         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 628
 629         bool sh;
 630         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
 631
 632         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 633         {
 634                 if(e.iscaptured) // don't mess up build bars!
 635                 {
 636                         if(sh)
 637                         {
 638                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 639                         }
 640                         else
 641                         {
 642                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 643                                 WaypointSprite_UpdateHealth(e.sprite, e.goalentity.health);
 644                         }
 645                 }
 646                 if(e.lastshielded)
 647                 {
 648                         if(e.team)
 649                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
 650                         else
 651                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 652                 }
 653                 else
 654                 {
 655                         if(e.team)
 656                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
 657                         else
 658                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 659                 }
 660                 WaypointSprite_Ping(e.sprite);
 661
 662                 e.lastteam = e.team + 2;
 663                 e.lastshielded = sh;
 664                 e.lastcaptured = e.iscaptured;
 665         }
 666 }
 667
 668 void ons_ControlPoint_Touch(entity this, entity toucher)
 669 {
 670         int attackable;
 671
 672         if(IS_VEHICLE(toucher) && toucher.owner)
 673         if(autocvar_g_onslaught_allow_vehicle_touch)
 674                 toucher = toucher.owner;
 675         else
 676                 return;
 677
 678         if(!IS_PLAYER(toucher)) { return; }
 679         if(STAT(FROZEN, toucher)) { return; }
 680         if(IS_DEAD(toucher)) { return; }
 681
 682         if ( SAME_TEAM(this,toucher) )
 683         if ( this.iscaptured )
 684         {
 685                 if(time <= toucher.teleport_antispam)
 686                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
 687                 else
 688                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
 689         }
 690
 691         attackable = ons_ControlPoint_Attackable(this, toucher.team);
 692         if(attackable != 2 && attackable != 4)
 693                 return;
 694         // we've verified that this player has a legitimate claim to this point,
 695         // so start building the captured point icon (which only captures this
 696         // point if it successfully builds without being destroyed first)
 697         ons_ControlPoint_Icon_Spawn(this, toucher);
 698
 699         this.ons_toucher = toucher;
 700
 701         onslaught_updatelinks();
 702 }
 703
 704 void ons_ControlPoint_Think(entity this)
 705 {
 706         this.nextthink = time + ONS_CP_THINKRATE;
 707         CSQCMODEL_AUTOUPDATE(this);
 708 }
 709
 710 void ons_ControlPoint_Reset(entity this)
 711 {
 712         if(this.goalentity)
 713                 delete(this.goalentity);
 714
 715         this.goalentity = NULL;
 716         this.team = 0;
 717         this.colormap = 1024;
 718         this.iscaptured = false;
 719         this.islinked = false;
 720         this.isshielded = true;
 721         setthink(this, ons_ControlPoint_Think);
 722         this.ons_toucher = NULL;
 723         this.nextthink = time + ONS_CP_THINKRATE;
 724         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
 725
 726         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 727         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 728
 729         onslaught_updatelinks();
 730
 731         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
 732
 733         CSQCMODEL_AUTOUPDATE(this);
 734 }
 735
 736 void ons_DelayedControlPoint_Setup(entity this)
 737 {
 738         onslaught_updatelinks();
 739
 740         // captureshield setup
 741         ons_CaptureShield_Spawn(this, false);
 742
 743         CSQCMODEL_AUTOINIT(this);
 744 }
 745
 746 void ons_ControlPoint_Setup(entity cp)
 747 {
 748         // main setup
 749         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
 750         ons_worldcplist = cp;
 751
 752         cp.netname = "Control point";
 753         cp.team = 0;
 754         cp.solid = SOLID_BBOX;
 755         set_movetype(cp, MOVETYPE_NONE);
 756         settouch(cp, ons_ControlPoint_Touch);
 757         setthink(cp, ons_ControlPoint_Think);
 758         cp.nextthink = time + ONS_CP_THINKRATE;
 759         cp.reset = ons_ControlPoint_Reset;
 760         cp.colormap = 1024;
 761         cp.iscaptured = false;
 762         cp.islinked = false;
 763         cp.isshielded = true;
 764
 765         if(cp.message == "") { cp.message = "a"; }
 766
 767         // appearence
 768         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
 769
 770         // control point placement
 771         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
 772         {
 773                 cp.noalign = true;
 774                 set_movetype(cp, MOVETYPE_NONE);
 775         }
 776         else // drop to floor, automatically find a platform and set that as spawn origin
 777         {
 778                 setorigin(cp, cp.origin + '0 0 20');
 779                 cp.noalign = false;
 780                 droptofloor(cp);
 781                 set_movetype(cp, MOVETYPE_TOSS);
 782         }
 783
 784         // waypointsprites
 785         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
 786         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
 787
 788         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
 789 }
 790
 791
 792 // =========================
 793 // Main Generator Functions
 794 // =========================
 795
 796 entity ons_Generator_Waypoint(entity e)
 797 {
 798         if (e.isshielded)
 799                 return WP_OnsGenShielded;
 800         return WP_OnsGen;
 801 }
 802
 803 void ons_Generator_UpdateSprite(entity e)
 804 {
 805         entity s1 = ons_Generator_Waypoint(e);
 806         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 807
 808         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 809         {
 810                 e.lastteam = e.team + 2;
 811                 e.lastshielded = e.isshielded;
 812                 if(e.lastshielded)
 813                 {
 814                         if(e.team)
 815                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
 816                         else
 817                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 818                 }
 819                 else
 820                 {
 821                         if(e.team)
 822                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
 823                         else
 824                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 825                 }
 826                 WaypointSprite_Ping(e.sprite);
 827         }
 828 }
 829
 830 void ons_camSetup(entity this)
 831 {
 832         vector dir;
 833         vector ang = '0 0 0';
 834         vector best_ang = '0 0 0';
 835         float best_trace_fraction = 0;
 836         while(ang.y < 360)
 837         {
 838                 dir = vec2(cos(ang.y * DEG2RAD), sin(ang.y * DEG2RAD));
 839                 dir *= 500;
 840                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
 841                 if(trace_fraction > best_trace_fraction)
 842                 {
 843                         best_trace_fraction = trace_fraction;
 844                         best_ang = ang;
 845                         if(trace_fraction == 1)
 846                                 break;
 847                 }
 848                 ang.y += 90;
 849                 if(ang.y == 360)
 850                         ang.y = 45;
 851         }
 852         cam.origin = this.origin;
 853         setorigin(cam, cam.origin);
 854         cam.angles = best_ang;
 855         Net_LinkEntity(cam, false, 0, clientcamera_send);
 856
 857         FOREACH_CLIENT(true, it.clientcamera = cam;);
 858
 859         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
 860         WriteAngle(MSG_ALL, cam.angles_x);
 861         WriteAngle(MSG_ALL, cam.angles_y);
 862         WriteAngle(MSG_ALL, cam.angles_z);
 863 }
 864
 865 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 866 {
 867         if(damage <= 0) return;
 868         if(warmup_stage || game_stopped) return;
 869         if(!round_handler_IsRoundStarted()) return;
 870
 871         if (attacker != this)
 872         {
 873                 if (this.isshielded)
 874                 {
 875                         // generator is protected by a shield, so ignore the damage
 876                         if (time > this.pain_finished)
 877                                 if (IS_PLAYER(attacker))
 878                                 {
 879                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 880                                         attacker.typehitsound += 1;
 881                                         this.pain_finished = time + 1;
 882                                 }
 883                         return;
 884                 }
 885                 if (time > this.pain_finished)
 886                 {
 887                         this.pain_finished = time + 10;
 888                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
 889                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
 890                 }
 891         }
 892         this.health = this.health - damage;
 893         WaypointSprite_UpdateHealth(this.sprite, this.health);
 894         // choose an animation frame based on health
 895         this.frame = 10 * bound(0, (1 - this.health / this.max_health), 1);
 896         // see if the generator is still functional, or dying
 897         if (this.health > 0)
 898         {
 899                 this.lasthealth = this.health;
 900         }
 901         else
 902         {
 903                 if (attacker == this)
 904                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
 905                 else
 906                 {
 907                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
 908                         GameRules_scoring_add(attacker, SCORE, 100);
 909                 }
 910                 this.iscaptured = false;
 911                 this.islinked = false;
 912                 this.isshielded = false;
 913                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
 914                 this.event_damage = func_null; // won't do anything if hurt
 915                 this.count = 0; // reset counter
 916                 setthink(this, func_null);
 917                 this.nextthink = 0;
 918                 //this.think(); // do the first explosion now
 919
 920                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 921                 WaypointSprite_Ping(this.sprite);
 922                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
 923
 924                 onslaught_updatelinks();
 925
 926                 ons_camSetup(this);
 927         }
 928
 929         // Throw some flaming gibs on damage, more damage = more chance for gib
 930         if(random() < damage/220)
 931         {
 932                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 933         }
 934         else
 935         {
 936                 // particles on every hit
 937                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
 938
 939                 //sound on every hit
 940                 if (random() < 0.5)
 941                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
 942                 else
 943                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
 944         }
 945
 946         this.SendFlags |= GSF_STATUS;
 947 }
 948
 949 void ons_GeneratorThink(entity this)
 950 {
 951         this.nextthink = time + GEN_THINKRATE;
 952         if (!game_stopped)
 953         {
 954                 if(!this.isshielded && this.wait < time)
 955                 {
 956                         this.wait = time + 5;
 957                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 958                                 if(SAME_TEAM(it, this))
 959                                 {
 960                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
 961                                         soundto(MSG_ONE, it, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE);    // FIXME: unique sound?
 962                                 }
 963                                 else
 964                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
 965                         });
 966                 }
 967         }
 968 }
 969
 970 void ons_GeneratorReset(entity this)
 971 {
 972         this.team = this.team_saved;
 973         this.lasthealth = this.max_health = this.health = autocvar_g_onslaught_gen_health;
 974         this.takedamage = DAMAGE_AIM;
 975         this.bot_attack = true;
 976         if(!IL_CONTAINS(g_bot_targets, this))
 977                 IL_PUSH(g_bot_targets, this);
 978         this.iscaptured = true;
 979         this.islinked = true;
 980         this.isshielded = true;
 981         this.event_damage = ons_GeneratorDamage;
 982         setthink(this, ons_GeneratorThink);
 983         this.nextthink = time + GEN_THINKRATE;
 984
 985         Net_LinkEntity(this, false, 0, generator_send);
 986
 987         this.SendFlags = GSF_SETUP; // just incase
 988         this.SendFlags |= GSF_STATUS;
 989
 990         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
 991         WaypointSprite_UpdateHealth(this.sprite, this.health);
 992         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 993
 994         onslaught_updatelinks();
 995 }
 996
 997 void ons_DelayedGeneratorSetup(entity this)
 998 {
 999         // bot waypoints
1000         waypoint_spawnforitem_force(this, this.origin);
1001         this.nearestwaypointtimeout = 0; // activate waypointing again
1002         this.bot_basewaypoint = this.nearestwaypoint;
1003
1004         // captureshield setup
1005         ons_CaptureShield_Spawn(this, true);
1006
1007         onslaught_updatelinks();
1008
1009         Net_LinkEntity(this, false, 0, generator_send);
1010 }
1011
1012
1013 void onslaught_generator_touch(entity this, entity toucher)
1014 {
1015         if ( IS_PLAYER(toucher) )
1016         if ( SAME_TEAM(this,toucher) )
1017         if ( this.iscaptured )
1018         {
1019                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1020         }
1021 }
1022
1023 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1024 {
1025         // declarations
1026         int teamnumber = gen.team;
1027
1028         // main setup
1029         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1030         ons_worldgeneratorlist = gen;
1031
1032         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1033         gen.classname = "onslaught_generator";
1034         gen.solid = SOLID_BBOX;
1035         gen.team_saved = teamnumber;
1036         IL_PUSH(g_saved_team, gen);
1037         set_movetype(gen, MOVETYPE_NONE);
1038         gen.lasthealth = gen.max_health = gen.health = autocvar_g_onslaught_gen_health;
1039         gen.takedamage = DAMAGE_AIM;
1040         gen.bot_attack = true;
1041         IL_PUSH(g_bot_targets, gen);
1042         gen.event_damage = ons_GeneratorDamage;
1043         gen.reset = ons_GeneratorReset;
1044         setthink(gen, ons_GeneratorThink);
1045         gen.nextthink = time + GEN_THINKRATE;
1046         gen.iscaptured = true;
1047         gen.islinked = true;
1048         gen.isshielded = true;
1049         settouch(gen, onslaught_generator_touch);
1050
1051         // appearence
1052         // model handled by CSQC
1053         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1054         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1055         gen.colormap = 1024 + (teamnumber - 1) * 17;
1056
1057         // generator placement
1058         droptofloor(gen);
1059
1060         // waypointsprites
1061         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1062         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1063         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1064         WaypointSprite_UpdateHealth(gen.sprite, gen.health);
1065
1066         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1067 }
1068
1069
1070 // ===============
1071 //  Round Handler
1072 // ===============
1073
1074 int total_generators;
1075 void Onslaught_count_generators()
1076 {
1077         entity e;
1078         total_generators = 0;
1079         for (int i = 1; i <= NUM_TEAMS; ++i)
1080         {
1081                 Team_SetNumberOfControlPoints(Team_GetTeamFromIndex(i), 0);
1082         }
1083         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1084         {
1085                 ++total_generators;
1086                 if (GetResourceAmount(e, RESOURCE_HEALTH) < 1)
1087                 {
1088                         continue;
1089                 }
1090                 entity team_ = Entity_GetTeam(e);
1091                 int num_control_points = Team_GetNumberOfControlPoints(team_);
1092                 ++num_control_points;
1093                 Team_SetNumberOfControlPoints(team_, num_control_points);
1094         }
1095 }
1096
1097 int Onslaught_GetWinnerTeam()
1098 {
1099         int winner_team = 0;
1100         if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(1)) >= 1)
1101         {
1102                 winner_team = NUM_TEAM_1;
1103         }
1104         for (int i = 2; i <= NUM_TEAMS; ++i)
1105         {
1106                 if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(i)) >= 1)
1107                 {
1108                         if (winner_team != 0)
1109                         {
1110                                 return 0;
1111                         }
1112                         winner_team = Team_IndexToTeam(i);
1113                 }
1114         }
1115         if (winner_team)
1116         {
1117                 return winner_team;
1118         }
1119         return -1; // no generators left?
1120 }
1121
1122 void nades_Clear(entity e);
1123
1124 bool Onslaught_CheckWinner()
1125 {
1126         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1127         {
1128                 ons_stalemate = true;
1129
1130                 if (!wpforenemy_announced)
1131                 {
1132                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1133                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1134
1135                         wpforenemy_announced = true;
1136                 }
1137
1138                 entity tmp_entity; // temporary entity
1139                 float d;
1140                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1141                 {
1142                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1143                         // control points reduce the overtime duration.
1144                         d = 1;
1145                         entity e;
1146                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1147                         {
1148                                 if(DIFF_TEAM(e, tmp_entity))
1149                                 if(e.islinked)
1150                                         d = d + 1;
1151                         }
1152
1153                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1154                                 d = d * tmp_entity.max_health;
1155                         else
1156                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1157
1158                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, tmp_entity.origin, '0 0 0');
1159
1160                         tmp_entity.sprite.SendFlags |= 16;
1161
1162                         tmp_entity.ons_overtime_damagedelay = time + 1;
1163                 }
1164         }
1165         else { wpforenemy_announced = false; ons_stalemate = false; }
1166
1167         Onslaught_count_generators();
1168
1169         if (Team_GetNumberOfTeamsWithControlPoints() > 1)
1170         {
1171                 return 0;
1172         }
1173
1174         int winner_team = Onslaught_GetWinnerTeam();
1175
1176         if(winner_team > 0)
1177         {
1178                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1179                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1180                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1181         }
1182         else if(winner_team == -1)
1183         {
1184                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1185                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1186         }
1187
1188         ons_stalemate = false;
1189
1190         play2all(SND(CTF_CAPTURE(winner_team)));
1191
1192         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1193
1194         FOREACH_CLIENT(IS_PLAYER(it), {
1195                 STAT(ROUNDLOST, it) = true;
1196                 it.player_blocked = true;
1197
1198                 nades_Clear(it);
1199         });
1200
1201         game_stopped = true;
1202         return 1;
1203 }
1204
1205 bool Onslaught_CheckPlayers()
1206 {
1207         return 1;
1208 }
1209
1210 void Onslaught_RoundStart()
1211 {
1212         entity tmp_entity;
1213         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1214
1215         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1216                 tmp_entity.sprite.SendFlags |= 16;
1217
1218         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1219                 tmp_entity.sprite.SendFlags |= 16;
1220 }
1221
1222
1223 // ================
1224 // Bot player logic
1225 // ================
1226
1227 // NOTE: LEGACY CODE, needs to be re-written!
1228
1229 void havocbot_goalrating_ons_offenseitems(entity this, float ratingscale, vector org, float sradius)
1230 {
1231         bool needarmor = false, needweapons = false;
1232
1233         // Needs armor/health?
1234         if(this.health<100)
1235                 needarmor = true;
1236
1237         // Needs weapons?
1238         int c = 0;
1239         FOREACH(Weapons, it != WEP_Null, {
1240                 if(STAT(WEAPONS, this) & (it.m_wepset))
1241                 if(++c >= 4)
1242                         break;
1243         });
1244
1245         if(c<4)
1246                 needweapons = true;
1247
1248         if(!needweapons && !needarmor)
1249                 return;
1250
1251         LOG_DEBUG(this.netname, " needs weapons ", ftos(needweapons));
1252         LOG_DEBUG(this.netname, " needs armor ", ftos(needarmor));
1253
1254         // See what is around
1255         IL_EACH(g_items, it.bot_pickup,
1256         {
1257                 // gather health and armor only
1258                 if (it.solid)
1259                 if ( ((it.health || it.armorvalue) && needarmor) || (STAT(WEAPONS, it) && needweapons ) )
1260                 if (vdist(it.origin - org, <, sradius))
1261                 {
1262                         int t = it.bot_pickupevalfunc(this, it);
1263                         if (t > 0)
1264                                 navigation_routerating(this, it, t * ratingscale, 500);
1265                 }
1266         });
1267 }
1268
1269 void havocbot_role_ons_setrole(entity this, int role)
1270 {
1271         LOG_DEBUG(this.netname," switched to ");
1272         switch(role)
1273         {
1274                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1275                         LOG_DEBUG("defense");
1276                         this.havocbot_role = havocbot_role_ons_defense;
1277                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_DEFENSE;
1278                         this.havocbot_role_timeout = 0;
1279                         break;
1280                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1281                         LOG_DEBUG("assistant");
1282                         this.havocbot_role = havocbot_role_ons_assistant;
1283                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_ASSISTANT;
1284                         this.havocbot_role_timeout = 0;
1285                         break;
1286                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1287                         LOG_DEBUG("offense");
1288                         this.havocbot_role = havocbot_role_ons_offense;
1289                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_OFFENSE;
1290                         this.havocbot_role_timeout = 0;
1291                         break;
1292         }
1293         LOG_DEBUG("");
1294 }
1295
1296 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1297 {
1298         entity cp, cp1, cp2, best, wp;
1299         float radius, bestvalue;
1300         int c;
1301         bool found;
1302
1303         // Filter control points
1304         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1305         {
1306                 cp2.wpcost = c = 0;
1307                 cp2.wpconsidered = false;
1308
1309                 if(cp2.isshielded)
1310                         continue;
1311
1312                 // Ignore owned controlpoints
1313                 if(!((cp2.aregensneighbor & BIT(this.team)) || (cp2.arecpsneighbor & BIT(this.team))))
1314                         continue;
1315
1316                 // Count team mates interested in this control point
1317                 // (easier and cleaner than keeping counters per cp and teams)
1318                 FOREACH_CLIENT(IS_PLAYER(it), {
1319                         if(SAME_TEAM(it, this))
1320                         if(it.havocbot_role_flags & HAVOCBOT_ONS_ROLE_OFFENSE)
1321                         if(it.havocbot_ons_target == cp2)
1322                                 ++c;
1323                 });
1324
1325                 // NOTE: probably decrease the cost of attackable control points
1326                 cp2.wpcost = c;
1327                 cp2.wpconsidered = true;
1328         }
1329
1330         // We'll consider only the best case
1331         bestvalue = 99999999999;
1332         cp = NULL;
1333         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1334         {
1335                 if (!cp1.wpconsidered)
1336                         continue;
1337
1338                 if(cp1.wpcost<bestvalue)
1339                 {
1340                         bestvalue = cp1.wpcost;
1341                         cp = cp1;
1342                         this.havocbot_ons_target = cp1;
1343                 }
1344         }
1345
1346         if (!cp)
1347                 return;
1348
1349         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1350
1351         if(cp.goalentity)
1352         {
1353                 // Should be attacked
1354                 // Rate waypoints near it
1355                 found = false;
1356                 best = NULL;
1357                 bestvalue = 99999999999;
1358                 for(radius=0; radius<1000 && !found; radius+=500)
1359                 {
1360                         for(wp=findradius(cp.origin,radius); wp; wp=wp.chain)
1361                         {
1362                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
1363                                 if(wp.classname=="waypoint")
1364                                 if(checkpvs(wp.origin,cp))
1365                                 {
1366                                         found = true;
1367                                         if(wp.cnt<bestvalue)
1368                                         {
1369                                                 best = wp;
1370                                                 bestvalue = wp.cnt;
1371                                         }
1372                                 }
1373                         }
1374                 }
1375
1376                 if(best)
1377                 {
1378                         navigation_routerating(this, best, ratingscale, 10000);
1379                         best.cnt += 1;
1380
1381                         this.havocbot_attack_time = 0;
1382                         if(checkpvs(this.origin + this.view_ofs, cp))
1383                         if(checkpvs(this.origin + this.view_ofs, best))
1384                                 this.havocbot_attack_time = time + 2;
1385                 }
1386                 else
1387                 {
1388                         navigation_routerating(this, cp, ratingscale, 10000);
1389                 }
1390                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1391         }
1392         else
1393         {
1394                 // Should be touched
1395                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1396                 found = false;
1397
1398                 // Look for auto generated waypoint
1399                 if (!bot_waypoints_for_items)
1400                 for (wp = findradius(cp.origin,100); wp; wp = wp.chain)
1401                 {
1402                         if(wp.classname=="waypoint")
1403                         {
1404                                 navigation_routerating(this, wp, ratingscale, 10000);
1405                                 found = true;
1406                         }
1407                 }
1408
1409                 // Nothing found, rate the controlpoint itself
1410                 if (!found)
1411                         navigation_routerating(this, cp, ratingscale, 10000);
1412         }
1413 }
1414
1415 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1416 {
1417         entity g, wp, bestwp;
1418         bool found;
1419         int best;
1420
1421         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1422         {
1423                 if(SAME_TEAM(g, this) || g.isshielded)
1424                         continue;
1425
1426                 // Should be attacked
1427                 // Rate waypoints near it
1428                 found = false;
1429                 bestwp = NULL;
1430                 best = 99999999999;
1431
1432                 for(wp=findradius(g.origin,400); wp; wp=wp.chain)
1433                 {
1434                         if(wp.classname=="waypoint")
1435                         if(checkpvs(wp.origin,g))
1436                         {
1437                                 found = true;
1438                                 if(wp.cnt<best)
1439                                 {
1440                                         bestwp = wp;
1441                                         best = wp.cnt;
1442                                 }
1443                         }
1444                 }
1445
1446                 if(bestwp)
1447                 {
1448                         LOG_DEBUG("waypoints found around generator");
1449                         navigation_routerating(this, bestwp, ratingscale, 10000);
1450                         bestwp.cnt += 1;
1451
1452                         this.havocbot_attack_time = 0;
1453                         if(checkpvs(this.origin + this.view_ofs, g))
1454                         if(checkpvs(this.origin + this.view_ofs, bestwp))
1455                                 this.havocbot_attack_time = time + 5;
1456
1457                         return true;
1458                 }
1459                 else
1460                 {
1461                         LOG_DEBUG("generator found without waypoints around");
1462                         // if there aren't waypoints near the generator go straight to it
1463                         navigation_routerating(this, g, ratingscale, 10000);
1464                         this.havocbot_attack_time = 0;
1465                         return true;
1466                 }
1467         }
1468         return false;
1469 }
1470
1471 void havocbot_role_ons_offense(entity this)
1472 {
1473         if(IS_DEAD(this))
1474         {
1475                 this.havocbot_attack_time = 0;
1476                 havocbot_ons_reset_role(this);
1477                 return;
1478         }
1479
1480         // Set the role timeout if necessary
1481         if (!this.havocbot_role_timeout)
1482                 this.havocbot_role_timeout = time + 120;
1483
1484         if (time > this.havocbot_role_timeout)
1485         {
1486                 havocbot_ons_reset_role(this);
1487                 return;
1488         }
1489
1490         if(this.havocbot_attack_time>time)
1491                 return;
1492
1493         if (navigation_goalrating_timeout(this))
1494         {
1495                 navigation_goalrating_start(this);
1496                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1497                 if(!havocbot_goalrating_ons_generator_attack(this, 20000))
1498                         havocbot_goalrating_ons_controlpoints_attack(this, 20000);
1499                 havocbot_goalrating_ons_offenseitems(this, 10000, this.origin, 10000);
1500                 navigation_goalrating_end(this);
1501
1502                 navigation_goalrating_timeout_set(this);
1503         }
1504 }
1505
1506 void havocbot_role_ons_assistant(entity this)
1507 {
1508         havocbot_ons_reset_role(this);
1509 }
1510
1511 void havocbot_role_ons_defense(entity this)
1512 {
1513         havocbot_ons_reset_role(this);
1514 }
1515
1516 void havocbot_ons_reset_role(entity this)
1517 {
1518         if(IS_DEAD(this))
1519                 return;
1520
1521         this.havocbot_ons_target = NULL;
1522
1523         // TODO: Defend control points or generator if necessary
1524
1525         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1526 }
1527
1528
1529 /*
1530  * Find control point or generator owned by the same team self which is nearest to pos
1531  * if max_dist is positive, only control points within this range will be considered
1532  */
1533 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1534 {
1535         entity closest_target = NULL;
1536         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1537         {
1538                 if(SAME_TEAM(cp, this))
1539                 if(cp.iscaptured)
1540                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1541                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1542                         closest_target = cp;
1543         }
1544         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1545         {
1546                 if(SAME_TEAM(gen, this))
1547                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1548                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1549                         closest_target = gen;
1550         }
1551
1552         return closest_target;
1553 }
1554
1555 /*
1556  * Find control point or generator owned by the same team self which is nearest to pos
1557  * if max_dist is positive, only control points within this range will be considered
1558  * This function only check distances on the XY plane, disregarding Z
1559  */
1560 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1561 {
1562         entity closest_target = NULL;
1563         vector delta;
1564         float smallest_distance = 0, distance;
1565
1566         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1567         {
1568                 delta = cp.origin - pos;
1569                 delta_z = 0;
1570                 distance = vlen(delta);
1571
1572                 if(SAME_TEAM(cp, this))
1573                 if(cp.iscaptured)
1574                 if(max_dist <= 0 || distance <= max_dist)
1575                 if(closest_target == NULL || distance <= smallest_distance )
1576                 {
1577                         closest_target = cp;
1578                         smallest_distance = distance;
1579                 }
1580         }
1581         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1582         {
1583                 delta = gen.origin - pos;
1584                 delta_z = 0;
1585                 distance = vlen(delta);
1586
1587                 if(SAME_TEAM(gen, this))
1588                 if(max_dist <= 0 || distance <= max_dist)
1589                 if(closest_target == NULL || distance <= smallest_distance )
1590                 {
1591                         closest_target = gen;
1592                         smallest_distance = distance;
1593                 }
1594         }
1595
1596         return closest_target;
1597 }
1598 /**
1599  * find the number of control points and generators in the same team as this
1600  */
1601 int ons_Count_SelfControlPoints(entity this)
1602 {
1603         int n = 0;
1604         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1605         {
1606                 if(SAME_TEAM(cp, this))
1607                 if(cp.iscaptured)
1608                         n++;
1609         }
1610         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1611         {
1612                 if(SAME_TEAM(gen, this))
1613                         n++;
1614         }
1615         return n;
1616 }
1617
1618 /**
1619  * Teleport player to a random position near tele_target
1620  * if tele_effects is true, teleport sound+particles are created
1621  * return false on failure
1622  */
1623 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1624 {
1625         if ( !tele_target )
1626                 return false;
1627
1628         int i;
1629         vector loc;
1630         float theta;
1631         // narrow the range for each iteration to increase chances that a spawnpoint
1632         // can be found even if there's little room around the control point
1633         float iteration_scale = 1;
1634         for(i = 0; i < 16; ++i)
1635         {
1636                 iteration_scale -= i / 16;
1637                 theta = random() * 2 * M_PI;
1638                 loc_y = sin(theta);
1639                 loc_x = cos(theta);
1640                 loc_z = 0;
1641                 loc *= random() * range * iteration_scale;
1642
1643                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1644
1645                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1646                 if(trace_fraction == 1.0 && !trace_startsolid)
1647                 {
1648                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1649                         if(trace_fraction == 1.0 && !trace_startsolid)
1650                         {
1651                                 if ( tele_effects )
1652                                 {
1653                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1654                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1655                                 }
1656                                 setorigin(player, loc);
1657                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1658                                 makevectors(player.angles);
1659                                 player.fixangle = true;
1660                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1661
1662                                 if ( tele_effects )
1663                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1664                                 return true;
1665                         }
1666                 }
1667         }
1668
1669         return false;
1670 }
1671
1672 // ==============
1673 // Hook Functions
1674 // ==============
1675
1676 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1677 {
1678         FOREACH_CLIENT(IS_PLAYER(it), {
1679                 STAT(ROUNDLOST, it) = false;
1680                 it.ons_deathloc = '0 0 0';
1681                 PutClientInServer(it);
1682                 it.clientcamera = it;
1683         });
1684         return false;
1685 }
1686
1687 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1688 {
1689         entity player = M_ARGV(0, entity);
1690
1691         player.ons_deathloc = '0 0 0';
1692 }
1693
1694 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1695 {
1696         entity player = M_ARGV(0, entity);
1697
1698         player.ons_deathloc = '0 0 0';
1699 }
1700
1701 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1702 {
1703         entity player = M_ARGV(0, entity);
1704
1705         if(!round_handler_IsRoundStarted())
1706         {
1707                 player.player_blocked = true;
1708                 return false;
1709         }
1710
1711         entity l;
1712         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1713         {
1714                 l.sprite.SendFlags |= 16;
1715         }
1716         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1717         {
1718                 l.sprite.SendFlags |= 16;
1719         }
1720
1721         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1722
1723         if ( autocvar_g_onslaught_spawn_choose )
1724         if ( player.ons_spawn_by )
1725         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1726         {
1727                 player.ons_spawn_by = NULL;
1728                 return false;
1729         }
1730
1731         if(autocvar_g_onslaught_spawn_at_controlpoints)
1732         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1733         {
1734                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1735                 entity tmp_entity, closest_target = NULL;
1736                 vector spawn_loc = player.ons_deathloc;
1737
1738                 // new joining player or round reset, don't bother checking
1739                 if(spawn_loc == '0 0 0') { return false; }
1740
1741                 if(random_target) { RandomSelection_Init(); }
1742
1743                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1744                 {
1745                         if(SAME_TEAM(tmp_entity, player))
1746                         if(random_target)
1747                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1748                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1749                                 closest_target = tmp_entity;
1750                 }
1751
1752                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1753
1754                 if(closest_target)
1755                 {
1756                         float i;
1757                         vector loc;
1758                         float iteration_scale = 1;
1759                         for(i = 0; i < 10; ++i)
1760                         {
1761                                 iteration_scale -= i / 10;
1762                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1763                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1764                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1765                                 if(trace_fraction == 1.0 && !trace_startsolid)
1766                                 {
1767                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1768                                         if(trace_fraction == 1.0 && !trace_startsolid)
1769                                         {
1770                                                 setorigin(player, loc);
1771                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1772                                                 return false;
1773                                         }
1774                                 }
1775                         }
1776                 }
1777         }
1778
1779         if(autocvar_g_onslaught_spawn_at_generator)
1780         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1781         {
1782                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1783                 entity tmp_entity, closest_target = NULL;
1784                 vector spawn_loc = player.ons_deathloc;
1785
1786                 // new joining player or round reset, don't bother checking
1787                 if(spawn_loc == '0 0 0') { return false; }
1788
1789                 if(random_target) { RandomSelection_Init(); }
1790
1791                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1792                 {
1793                         if(random_target)
1794                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1795                         else
1796                         {
1797                                 if(SAME_TEAM(tmp_entity, player))
1798                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1799                                         closest_target = tmp_entity;
1800                         }
1801                 }
1802
1803                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1804
1805                 if(closest_target)
1806                 {
1807                         float i;
1808                         vector loc;
1809                         float iteration_scale = 1;
1810                         for(i = 0; i < 10; ++i)
1811                         {
1812                                 iteration_scale -= i / 10;
1813                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1814                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1815                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1816                                 if(trace_fraction == 1.0 && !trace_startsolid)
1817                                 {
1818                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1819                                         if(trace_fraction == 1.0 && !trace_startsolid)
1820                                         {
1821                                                 setorigin(player, loc);
1822                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1823                                                 return false;
1824                                         }
1825                                 }
1826                         }
1827                 }
1828         }
1829
1830         return false;
1831 }
1832
1833 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1834 {
1835         entity frag_target = M_ARGV(2, entity);
1836
1837         frag_target.ons_deathloc = frag_target.origin;
1838         entity l;
1839         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1840         {
1841                 l.sprite.SendFlags |= 16;
1842         }
1843         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1844         {
1845                 l.sprite.SendFlags |= 16;
1846         }
1847
1848         if ( autocvar_g_onslaught_spawn_choose )
1849         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1850                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1851
1852         return false;
1853 }
1854
1855 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1856 {
1857         entity mon = M_ARGV(0, entity);
1858
1859         entity e = find(NULL, targetname, mon.target);
1860         if (e != NULL)
1861                 mon.team = e.team;
1862 }
1863
1864 void ons_MonsterSpawn_Delayed(entity this)
1865 {
1866         entity own = this.owner;
1867
1868         if(!own) { delete(this); return; }
1869
1870         if(own.targetname)
1871         {
1872                 entity e = find(NULL, target, own.targetname);
1873                 if(e != NULL)
1874                 {
1875                         own.team = e.team;
1876
1877                         own.use(own, e, NULL);
1878                 }
1879         }
1880
1881         delete(this);
1882 }
1883
1884 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1885 {
1886         entity mon = M_ARGV(0, entity);
1887
1888         entity e = spawn();
1889         e.owner = mon;
1890         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1891 }
1892
1893 void ons_TurretSpawn_Delayed(entity this)
1894 {
1895         entity own = this.owner;
1896
1897         if(!own) { delete(this); return; }
1898
1899         if(own.targetname)
1900         {
1901                 entity e = find(NULL, target, own.targetname);
1902                 if(e != NULL)
1903                 {
1904                         own.team = e.team;
1905                         own.active = ACTIVE_NOT;
1906
1907                         own.use(own, e, NULL);
1908                 }
1909         }
1910
1911         delete(this);
1912 }
1913
1914 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1915 {
1916         entity turret = M_ARGV(0, entity);
1917
1918         entity e = spawn();
1919         e.owner = turret;
1920         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1921
1922         return false;
1923 }
1924
1925 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1926 {
1927         entity bot = M_ARGV(0, entity);
1928
1929         havocbot_ons_reset_role(bot);
1930         return true;
1931 }
1932
1933 MUTATOR_HOOKFUNCTION(ons, TeamBalance_CheckAllowedTeams)
1934 {
1935         // onslaught is special
1936         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1937         {
1938                 if (Team_IsValidTeam(tmp_entity.team))
1939                 {
1940                         M_ARGV(0, float) |= Team_TeamToBit(tmp_entity.team);
1941                 }
1942         }
1943
1944         return true;
1945 }
1946
1947 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1948 {
1949         entity spectatee = M_ARGV(0, entity);
1950         entity client = M_ARGV(1, entity);
1951
1952         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1953 }
1954
1955 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1956 {
1957         if(MUTATOR_RETURNVALUE) // command was already handled?
1958                 return false;
1959
1960         entity player = M_ARGV(0, entity);
1961         string cmd_name = M_ARGV(1, string);
1962         int cmd_argc = M_ARGV(2, int);
1963
1964         if ( cmd_name == "ons_spawn" )
1965         {
1966                 vector pos = player.origin;
1967                 if(cmd_argc > 1)
1968                         pos_x = stof(argv(1));
1969                 if(cmd_argc > 2)
1970                         pos_y = stof(argv(2));
1971                 if(cmd_argc > 3)
1972                         pos_z = stof(argv(3));
1973
1974                 if ( IS_PLAYER(player) )
1975                 {
1976                         if ( !STAT(FROZEN, player) )
1977                         {
1978                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1979
1980                                 if ( !source_point && player.health > 0 )
1981                                 {
1982                                         sprint(player, "\nYou need to be next to a control point\n");
1983                                         return true;
1984                                 }
1985
1986
1987                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1988
1989                                 if ( closest_target == NULL )
1990                                 {
1991                                         sprint(player, "\nNo control point found\n");
1992                                         return true;
1993                                 }
1994
1995                                 if ( player.health <= 0 )
1996                                 {
1997                                         player.ons_spawn_by = closest_target;
1998                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1999                                 }
2000                                 else
2001                                 {
2002                                         if ( source_point == closest_target )
2003                                         {
2004                                                 sprint(player, "\nTeleporting to the same point\n");
2005                                                 return true;
2006                                         }
2007
2008                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
2009                                                 sprint(player, "\nUnable to teleport there\n");
2010                                 }
2011
2012                                 return true;
2013                         }
2014
2015                         sprint(player, "\nNo teleportation for you\n");
2016                 }
2017
2018                 return true;
2019         }
2020         return false;
2021 }
2022
2023 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2024 {
2025         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2026
2027         entity player = M_ARGV(0, entity);
2028
2029         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2030         {
2031                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2032                 if ( source_point )
2033                 {
2034                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2035                         return true;
2036                 }
2037         }
2038 }
2039
2040 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2041 {
2042         entity frag_victim = M_ARGV(0, entity);
2043
2044         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2045                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2046 }
2047
2048 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2049 {
2050     entity wp = M_ARGV(0, entity);
2051     entity to = M_ARGV(1, entity);
2052     int sf = M_ARGV(2, int);
2053     int wp_flag = M_ARGV(3, int);
2054
2055         if(sf & 16)
2056         {
2057                 if(wp.owner.classname == "onslaught_controlpoint")
2058                 {
2059                         entity wp_owner = wp.owner;
2060                         entity e = WaypointSprite_getviewentity(to);
2061                         if(SAME_TEAM(e, wp_owner) && wp_owner.goalentity.health >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2062                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2063                 }
2064                 if(wp.owner.classname == "onslaught_generator")
2065                 {
2066                         entity wp_owner = wp.owner;
2067                         if(wp_owner.isshielded && wp_owner.health >= wp_owner.max_health) { wp_flag |= 2; }
2068                         if(wp_owner.health <= 0) { wp_flag |= 2; }
2069                 }
2070         }
2071
2072         M_ARGV(3, int) = wp_flag;
2073 }
2074
2075 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2076 {
2077         entity turret_target = M_ARGV(1, entity);
2078
2079         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2080         {
2081                 M_ARGV(3, float) = -3;
2082                 return true;
2083         }
2084
2085         return false;
2086 }
2087
2088 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2089 {
2090     entity turret = M_ARGV(0, entity);
2091
2092         // ONS uses somewhat backwards linking.
2093         if(turret.target)
2094         {
2095                 entity e = find(NULL, targetname, turret.target);
2096                 if (e != NULL)
2097                         turret.team = e.team;
2098         }
2099
2100         if(turret.team != turret.tur_head.team)
2101                 turret_respawn(turret);
2102 }
2103
2104
2105 // ==========
2106 // Spawnfuncs
2107 // ==========
2108
2109 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2110   Link between control points.
2111
2112   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2113
2114 keys:
2115 "target" - first control point.
2116 "target2" - second control point.
2117  */
2118 spawnfunc(onslaught_link)
2119 {
2120         if(!g_onslaught) { delete(this); return; }
2121
2122         if (this.target == "" || this.target2 == "")
2123                 objerror(this, "target and target2 must be set\n");
2124
2125         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2126         ons_worldlinklist = this;
2127
2128         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2129         Net_LinkEntity(this, false, 0, ons_Link_Send);
2130 }
2131
2132 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2133   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2134
2135   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2136
2137 keys:
2138 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2139 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2140 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2141  */
2142
2143 spawnfunc(onslaught_controlpoint)
2144 {
2145         if(!g_onslaught) { delete(this); return; }
2146
2147         ons_ControlPoint_Setup(this);
2148 }
2149
2150 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2151   Base generator.
2152
2153   spawnfunc_onslaught_link entities can target this.
2154
2155 keys:
2156 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2157 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2158  */
2159 spawnfunc(onslaught_generator)
2160 {
2161         if(!g_onslaught) { delete(this); return; }
2162         if(!this.team) { objerror(this, "team must be set"); }
2163
2164         ons_GeneratorSetup(this);
2165 }
2166
2167 // scoreboard setup
2168 void ons_ScoreRules()
2169 {
2170         entity balance = TeamBalance_CheckAllowedTeams(NULL);
2171         int teams = TeamBalance_GetAllowedTeams(balance);
2172         TeamBalance_Destroy(balance);
2173         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
2174             field_team(ST_ONS_CAPS, "destroyed", SFL_SORT_PRIO_PRIMARY);
2175             field(SP_ONS_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
2176             field(SP_ONS_TAKES, "takes", 0);
2177         });
2178 }
2179
2180 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2181 {
2182         ons_ScoreRules();
2183
2184         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2185         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2186 }
2187
2188 void ons_Initialize()
2189 {
2190         g_onslaught = true;
2191         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2192
2193         cam = new(objective_camera);
2194
2195         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2196 }