qcsrc/common/gamemodes/gamemode/onslaught/sv_onslaught.qc

   1 #include "sv_onslaught.qh"
   2 #include "sv_controlpoint.qh"
   3 #include "sv_generator.qh"
   4
   5 bool g_onslaught;
   6
   7 float autocvar_g_onslaught_teleport_wait;
   8 bool autocvar_g_onslaught_spawn_at_controlpoints;
   9 bool autocvar_g_onslaught_spawn_at_generator;
  10 float autocvar_g_onslaught_cp_proxydecap;
  11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
  12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
  13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
  14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
  15 float autocvar_g_onslaught_spawn_at_generator_chance;
  16 float autocvar_g_onslaught_spawn_at_generator_random;
  17 float autocvar_g_onslaught_cp_buildhealth;
  18 float autocvar_g_onslaught_cp_buildtime;
  19 float autocvar_g_onslaught_cp_health;
  20 float autocvar_g_onslaught_cp_regen;
  21 float autocvar_g_onslaught_gen_health;
  22 float autocvar_g_onslaught_shield_force = 100;
  23 float autocvar_g_onslaught_allow_vehicle_touch;
  24 float autocvar_g_onslaught_round_timelimit;
  25 float autocvar_g_onslaught_warmup;
  26 float autocvar_g_onslaught_teleport_radius;
  27 float autocvar_g_onslaught_spawn_choose;
  28 float autocvar_g_onslaught_click_radius;
  29
  30 entity cam;
  31
  32 // =======================
  33 // CaptureShield Functions
  34 // =======================
  35
  36 bool clientcamera_send(entity this, entity to, int sf)
  37 {
  38         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
  39
  40         WriteVector(MSG_ENTITY, this.origin);
  41
  42         WriteAngle(MSG_ENTITY, this.angles_x);
  43         WriteAngle(MSG_ENTITY, this.angles_y);
  44         WriteAngle(MSG_ENTITY, this.angles_z);
  45
  46         return true;
  47 }
  48
  49 bool ons_CaptureShield_Customize(entity this, entity client)
  50 {
  51         entity e = WaypointSprite_getviewentity(client);
  52
  53         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
  54         if(SAME_TEAM(this, e)) { return false; }
  55
  56         return true;
  57 }
  58
  59 void ons_CaptureShield_Touch(entity this, entity toucher)
  60 {
  61         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
  62         if(!IS_PLAYER(toucher)) { return; }
  63         if(SAME_TEAM(toucher, this)) { return; }
  64
  65         vector mymid = (this.absmin + this.absmax) * 0.5;
  66         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
  67
  68         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
  69
  70         if(IS_REAL_CLIENT(toucher))
  71         {
  72                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
  73
  74                 if(this.enemy.classname == "onslaught_generator")
  75                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
  76                 else
  77                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
  78         }
  79 }
  80
  81 void ons_CaptureShield_Reset(entity this)
  82 {
  83         this.colormap = this.enemy.colormap;
  84         this.team = this.enemy.team;
  85 }
  86
  87 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
  88 {
  89         entity shield = new(ons_captureshield);
  90         IL_PUSH(g_onsshields, shield);
  91
  92         shield.enemy = generator;
  93         shield.team = generator.team;
  94         shield.colormap = generator.colormap;
  95         shield.reset = ons_CaptureShield_Reset;
  96         settouch(shield, ons_CaptureShield_Touch);
  97         setcefc(shield, ons_CaptureShield_Customize);
  98         shield.effects = EF_ADDITIVE;
  99         set_movetype(shield, MOVETYPE_NOCLIP);
 100         shield.solid = SOLID_TRIGGER;
 101         shield.avelocity = '7 0 11';
 102         shield.scale = 1;
 103         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
 104
 105         precache_model(shield.model);
 106         setorigin(shield, generator.origin);
 107         _setmodel(shield, shield.model);
 108         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 109 }
 110
 111
 112 // ==========
 113 // Junk Pile
 114 // ==========
 115
 116 void onslaught_updatelinks()
 117 {
 118         entity l;
 119         // first check if the game has ended
 120         LOG_DEBUG("--- updatelinks ---");
 121         // mark generators as being shielded and networked
 122         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 123         {
 124                 if (l.iscaptured)
 125                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
 126                 else
 127                         LOG_DEBUG(etos(l), " (generator) is destroyed");
 128                 l.islinked = l.iscaptured;
 129                 l.isshielded = l.iscaptured;
 130                 l.sprite.SendFlags |= 16;
 131         }
 132         // mark points as shielded and not networked
 133         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 134         {
 135                 l.islinked = false;
 136                 l.isshielded = true;
 137                 l.aregensneighbor = 0;
 138                 l.arecpsneighbor = 0;
 139                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
 140                 l.sprite.SendFlags |= 16;
 141         }
 142         // flow power outward from the generators through the network
 143         bool stop = false;
 144         while (!stop)
 145         {
 146                 stop = true;
 147                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 148                 {
 149                         // if both points are captured by the same team, and only one of
 150                         // them is powered, mark the other one as powered as well
 151                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 152                                 if (l.enemy.islinked != l.goalentity.islinked)
 153                                         if(SAME_TEAM(l.enemy, l.goalentity))
 154                                         {
 155                                                 if (!l.goalentity.islinked)
 156                                                 {
 157                                                         stop = false;
 158                                                         l.goalentity.islinked = true;
 159                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
 160                                                 }
 161                                                 else if (!l.enemy.islinked)
 162                                                 {
 163                                                         stop = false;
 164                                                         l.enemy.islinked = true;
 165                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
 166                                                 }
 167                                         }
 168                 }
 169         }
 170         // now that we know which points are powered we can mark their neighbors
 171         // as unshielded if team differs
 172         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 173         {
 174                 if (l.goalentity.islinked)
 175                 {
 176                         if(DIFF_TEAM(l.goalentity, l.enemy))
 177                         {
 178                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
 179                                 l.enemy.isshielded = false;
 180                         }
 181                         if(l.goalentity.classname == "onslaught_generator")
 182                                 l.enemy.aregensneighbor |= BIT(l.goalentity.team);
 183                         else
 184                                 l.enemy.arecpsneighbor |= BIT(l.goalentity.team);
 185                 }
 186                 if (l.enemy.islinked)
 187                 {
 188                         if(DIFF_TEAM(l.goalentity, l.enemy))
 189                         {
 190                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
 191                                 l.goalentity.isshielded = false;
 192                         }
 193                         if(l.enemy.classname == "onslaught_generator")
 194                                 l.goalentity.aregensneighbor |= BIT(l.enemy.team);
 195                         else
 196                                 l.goalentity.arecpsneighbor |= BIT(l.enemy.team);
 197                 }
 198         }
 199         // now update the generators
 200         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 201         {
 202                 if (l.isshielded)
 203                 {
 204                         LOG_DEBUG(etos(l), " (generator) is shielded");
 205                         l.takedamage = DAMAGE_NO;
 206                         if(l.bot_attack)
 207                                 IL_REMOVE(g_bot_targets, l);
 208                         l.bot_attack = false;
 209                 }
 210                 else
 211                 {
 212                         LOG_DEBUG(etos(l), " (generator) is not shielded");
 213                         l.takedamage = DAMAGE_AIM;
 214                         if(!l.bot_attack)
 215                                 IL_PUSH(g_bot_targets, l);
 216                         l.bot_attack = true;
 217                 }
 218
 219                 ons_Generator_UpdateSprite(l);
 220         }
 221         // now update the takedamage and alpha variables on control point icons
 222         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 223         {
 224                 if (l.isshielded)
 225                 {
 226                         LOG_DEBUG(etos(l), " (point) is shielded");
 227                         if (l.goalentity)
 228                         {
 229                                 l.goalentity.takedamage = DAMAGE_NO;
 230                                 if(l.goalentity.bot_attack)
 231                                         IL_REMOVE(g_bot_targets, l.goalentity);
 232                                 l.goalentity.bot_attack = false;
 233                         }
 234                 }
 235                 else
 236                 {
 237                         LOG_DEBUG(etos(l), " (point) is not shielded");
 238                         if (l.goalentity)
 239                         {
 240                                 l.goalentity.takedamage = DAMAGE_AIM;
 241                                 if(!l.goalentity.bot_attack)
 242                                         IL_PUSH(g_bot_targets, l.goalentity);
 243                                 l.goalentity.bot_attack = true;
 244                         }
 245                 }
 246                 ons_ControlPoint_UpdateSprite(l);
 247         }
 248         IL_EACH(g_onsshields, true,
 249         {
 250                 it.team = it.enemy.team;
 251                 it.colormap = it.enemy.colormap;
 252         });
 253 }
 254
 255
 256 // ===================
 257 // Main Link Functions
 258 // ===================
 259
 260 bool ons_Link_Send(entity this, entity to, int sendflags)
 261 {
 262         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 263         WriteByte(MSG_ENTITY, sendflags);
 264         if(sendflags & 1)
 265         {
 266                 WriteVector(MSG_ENTITY, this.goalentity.origin);
 267         }
 268         if(sendflags & 2)
 269         {
 270                 WriteVector(MSG_ENTITY, this.enemy.origin);
 271         }
 272         if(sendflags & 4)
 273         {
 274                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
 275         }
 276         return true;
 277 }
 278
 279 void ons_Link_CheckUpdate(entity this)
 280 {
 281         // TODO check if the two sides have moved (currently they won't move anyway)
 282         float cc = 0, cc1 = 0, cc2 = 0;
 283
 284         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
 285         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
 286
 287         cc = cc1 + cc2;
 288
 289         if(cc != this.clientcolors)
 290         {
 291                 this.clientcolors = cc;
 292                 this.SendFlags |= 4;
 293         }
 294
 295         this.nextthink = time;
 296 }
 297
 298 void ons_DelayedLinkSetup(entity this)
 299 {
 300         this.goalentity = find(NULL, targetname, this.target);
 301         this.enemy = find(NULL, targetname, this.target2);
 302         if(!this.goalentity) { objerror(this, "can not find target\n"); }
 303         if(!this.enemy) { objerror(this, "can not find target2\n"); }
 304
 305         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
 306         this.SendFlags |= 3;
 307         setthink(this, ons_Link_CheckUpdate);
 308         this.nextthink = time;
 309 }
 310
 311
 312 // =============================
 313 // Main Control Point Functions
 314 // =============================
 315
 316 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
 317 {
 318         if(cp.aregensneighbor & BIT(teamnumber)) return 2;
 319         if(cp.arecpsneighbor & BIT(teamnumber)) return 1;
 320
 321         return 0;
 322 }
 323
 324 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
 325         // -2: SAME TEAM, attackable by enemy!
 326         // -1: SAME TEAM!
 327         // 0: off limits
 328         // 1: attack it
 329         // 2: touch it
 330         // 3: attack it (HIGH PRIO)
 331         // 4: touch it (HIGH PRIO)
 332 {
 333         int a;
 334
 335         if(cp.isshielded)
 336         {
 337                 return 0;
 338         }
 339         else if(cp.goalentity)
 340         {
 341                 // if there's already an icon built, nothing happens
 342                 if(cp.team == teamnumber)
 343                 {
 344                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 345                         if(a) // attackable by enemy?
 346                                 return -2; // EMERGENCY!
 347                         return -1;
 348                 }
 349                 // we know it can be linked, so no need to check
 350                 // but...
 351                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 352                 if(a == 2) // near our generator?
 353                         return 3; // EMERGENCY!
 354                 return 1;
 355         }
 356         else
 357         {
 358                 // free point
 359                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
 360                 {
 361                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
 362                         if(a == 2)
 363                                 return 4; // GET THIS ONE NOW!
 364                         else
 365                                 return 2; // TOUCH ME
 366                 }
 367         }
 368         return 0;
 369 }
 370
 371 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 372 {
 373         if(damage <= 0) { return; }
 374
 375         if (this.owner.isshielded)
 376         {
 377                 // this is protected by a shield, so ignore the damage
 378                 if (time > this.pain_finished)
 379                         if (IS_PLAYER(attacker))
 380                         {
 381                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 382                                 this.pain_finished = time + 1;
 383                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
 384                         }
 385
 386                 return;
 387         }
 388
 389         if(IS_PLAYER(attacker))
 390         if(time - ons_notification_time[this.team] > 10)
 391         {
 392                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
 393                 ons_notification_time[this.team] = time;
 394         }
 395
 396         TakeResource(this, RES_HEALTH, damage);
 397         if(this.owner.iscaptured)
 398                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResource(this, RES_HEALTH));
 399         else
 400                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - GetResource(this, RES_HEALTH)) / (this.count / ONS_CP_THINKRATE));
 401         this.pain_finished = time + 1;
 402         // particles on every hit
 403         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
 404         //sound on every hit
 405         if (random() < 0.5)
 406                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
 407         else
 408                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
 409
 410         if (GetResource(this, RES_HEALTH) < 0)
 411         {
 412                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 413                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 414                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
 415
 416                 GameRules_scoring_add(attacker, ONS_TAKES, 1);
 417                 GameRules_scoring_add(attacker, SCORE, 10);
 418
 419                 this.owner.goalentity = NULL;
 420                 this.owner.islinked = false;
 421                 this.owner.iscaptured = false;
 422                 this.owner.team = 0;
 423                 this.owner.colormap = 1024;
 424
 425                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
 426
 427                 onslaught_updatelinks();
 428
 429                 // Use targets now (somebody make sure this is in the right place..)
 430                 SUB_UseTargets(this.owner, this, NULL);
 431
 432                 this.owner.waslinked = this.owner.islinked;
 433                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
 434                         setmodel(this.owner, MDL_ONS_CP_PAD1);
 435                 //setsize(this, '-32 -32 0', '32 32 8');
 436
 437                 delete(this);
 438         }
 439
 440         this.SendFlags |= CPSF_STATUS;
 441 }
 442
 443 bool ons_ControlPoint_Icon_Heal(entity targ, entity inflictor, float amount, float limit)
 444 {
 445         float hlth = GetResource(targ, RES_HEALTH);
 446         float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
 447         if (hlth <= 0 || hlth >= true_limit)
 448                 return false;
 449
 450         GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
 451         hlth = GetResource(targ, RES_HEALTH);
 452         if(targ.owner.iscaptured)
 453                 WaypointSprite_UpdateHealth(targ.owner.sprite, hlth);
 454         else
 455                 WaypointSprite_UpdateBuildFinished(targ.owner.sprite, time + (targ.max_health - hlth) / (targ.count / ONS_CP_THINKRATE));
 456         targ.SendFlags |= CPSF_STATUS;
 457         return true;
 458 }
 459
 460 void ons_ControlPoint_Icon_Think(entity this)
 461 {
 462         this.nextthink = time + ONS_CP_THINKRATE;
 463
 464         if(autocvar_g_onslaught_cp_proxydecap)
 465         {
 466                 int _enemy_count = 0;
 467                 int _friendly_count = 0;
 468
 469                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
 470                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
 471                         {
 472                                 if(SAME_TEAM(it, this))
 473                                         ++_friendly_count;
 474                                 else
 475                                         ++_enemy_count;
 476                         }
 477                 });
 478
 479                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 480                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 481
 482                 GiveResourceWithLimit(this, RES_HEALTH, (_friendly_count - _enemy_count), this.max_health);
 483                 this.SendFlags |= CPSF_STATUS;
 484                 if(GetResource(this, RES_HEALTH) <= 0)
 485                 {
 486                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, DMG_NOWEP, this.origin, '0 0 0');
 487                         return;
 488                 }
 489         }
 490
 491         if (time > this.pain_finished + 5)
 492         {
 493                 if(GetResource(this, RES_HEALTH) < this.max_health)
 494                 {
 495                         GiveResourceWithLimit(this, RES_HEALTH, this.count, this.max_health);
 496                         WaypointSprite_UpdateHealth(this.owner.sprite, GetResource(this, RES_HEALTH));
 497                 }
 498         }
 499
 500         if(this.owner.islinked != this.owner.waslinked)
 501         {
 502                 // unteam the spawnpoint if needed
 503                 int t = this.owner.team;
 504                 if(!this.owner.islinked)
 505                         this.owner.team = 0;
 506
 507                 SUB_UseTargets(this.owner, this, NULL);
 508
 509                 this.owner.team = t;
 510
 511                 this.owner.waslinked = this.owner.islinked;
 512         }
 513
 514         // damaged fx
 515         if(random() < 0.6 - GetResource(this, RES_HEALTH) / this.max_health)
 516         {
 517                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
 518
 519                 if(random() > 0.8)
 520                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
 521                 else if (random() > 0.5)
 522                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
 523         }
 524 }
 525
 526 void ons_ControlPoint_Icon_BuildThink(entity this)
 527 {
 528         int a;
 529
 530         this.nextthink = time + ONS_CP_THINKRATE;
 531
 532         // only do this if there is power
 533         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
 534         if(!a)
 535                 return;
 536
 537         GiveResource(this, RES_HEALTH, this.count);
 538
 539         this.SendFlags |= CPSF_STATUS;
 540
 541         if (GetResource(this, RES_HEALTH) >= this.max_health)
 542         {
 543                 SetResourceExplicit(this, RES_HEALTH, this.max_health);
 544                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
 545                 setthink(this, ons_ControlPoint_Icon_Think);
 546                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
 547                 this.owner.iscaptured = true;
 548                 this.solid = SOLID_BBOX;
 549
 550                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
 551
 552                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
 553                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResource(this, RES_HEALTH));
 554
 555                 if(IS_PLAYER(this.owner.ons_toucher))
 556                 {
 557                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
 558                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
 559                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
 560                         GameRules_scoring_add(this.owner.ons_toucher, ONS_CAPS, 1);
 561                         GameRules_scoring_add_team(this.owner.ons_toucher, SCORE, 10);
 562                 }
 563
 564                 this.owner.ons_toucher = NULL;
 565
 566                 onslaught_updatelinks();
 567
 568                 // Use targets now (somebody make sure this is in the right place..)
 569                 SUB_UseTargets(this.owner, this, NULL);
 570
 571                 this.SendFlags |= CPSF_SETUP;
 572         }
 573         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
 574                 setmodel(this.owner, MDL_ONS_CP_PAD2);
 575
 576         if(random() < 0.9 - GetResource(this, RES_HEALTH) / this.max_health)
 577                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
 578 }
 579
 580 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
 581
 582 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
 583 {
 584         entity e = new(onslaught_controlpoint_icon);
 585
 586         setsize(e, CPICON_MIN, CPICON_MAX);
 587         setorigin(e, cp.origin + CPICON_OFFSET);
 588
 589         e.owner = cp;
 590         e.max_health = autocvar_g_onslaught_cp_health;
 591         SetResourceExplicit(e, RES_HEALTH, autocvar_g_onslaught_cp_buildhealth);
 592         e.solid = SOLID_NOT;
 593         e.takedamage = DAMAGE_AIM;
 594         e.bot_attack = true;
 595         IL_PUSH(g_bot_targets, e);
 596         e.event_damage = ons_ControlPoint_Icon_Damage;
 597         e.event_heal = ons_ControlPoint_Icon_Heal;
 598         e.team = player.team;
 599         e.colormap = 1024 + (e.team - 1) * 17;
 600         e.count = (e.max_health - GetResource(e, RES_HEALTH)) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
 601
 602         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
 603
 604         cp.goalentity = e;
 605         cp.team = e.team;
 606         cp.colormap = e.colormap;
 607
 608         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
 609
 610         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - GetResource(e, RES_HEALTH)) / (e.count / ONS_CP_THINKRATE));
 611         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
 612         cp.sprite.SendFlags |= 16;
 613
 614         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
 615 }
 616
 617 entity ons_ControlPoint_Waypoint(entity e)
 618 {
 619         if(e.team)
 620         {
 621                 int a = ons_ControlPoint_Attackable(e, e.team);
 622
 623                 if(a == -2) { return WP_OnsCPDefend; } // defend now
 624                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
 625                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
 626         }
 627         else
 628                 return WP_OnsCP;
 629
 630         return WP_Null;
 631 }
 632
 633 void ons_ControlPoint_UpdateSprite(entity e)
 634 {
 635         entity s1 = ons_ControlPoint_Waypoint(e);
 636         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 637
 638         bool sh;
 639         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
 640
 641         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 642         {
 643                 if(e.iscaptured) // don't mess up build bars!
 644                 {
 645                         if(sh)
 646                         {
 647                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 648                         }
 649                         else
 650                         {
 651                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 652                                 WaypointSprite_UpdateHealth(e.sprite, GetResource(e.goalentity, RES_HEALTH));
 653                         }
 654                 }
 655                 if(e.lastshielded)
 656                 {
 657                         if(e.team)
 658                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
 659                         else
 660                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 661                 }
 662                 else
 663                 {
 664                         if(e.team)
 665                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
 666                         else
 667                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 668                 }
 669                 WaypointSprite_Ping(e.sprite);
 670
 671                 e.lastteam = e.team + 2;
 672                 e.lastshielded = sh;
 673                 e.lastcaptured = e.iscaptured;
 674         }
 675 }
 676
 677 void ons_ControlPoint_Touch(entity this, entity toucher)
 678 {
 679         int attackable;
 680
 681         if(IS_VEHICLE(toucher) && toucher.owner)
 682         {
 683                 if (!autocvar_g_onslaught_allow_vehicle_touch)
 684                         return;
 685                 toucher = toucher.owner;
 686         }
 687
 688         if(!IS_PLAYER(toucher)) { return; }
 689         if(STAT(FROZEN, toucher)) { return; }
 690         if(IS_DEAD(toucher)) { return; }
 691
 692         if ( SAME_TEAM(this,toucher) )
 693         if ( this.iscaptured )
 694         {
 695                 if(time <= toucher.teleport_antispam)
 696                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
 697                 else
 698                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
 699         }
 700
 701         attackable = ons_ControlPoint_Attackable(this, toucher.team);
 702         if(attackable != 2 && attackable != 4)
 703                 return;
 704         // we've verified that this player has a legitimate claim to this point,
 705         // so start building the captured point icon (which only captures this
 706         // point if it successfully builds without being destroyed first)
 707         ons_ControlPoint_Icon_Spawn(this, toucher);
 708
 709         this.ons_toucher = toucher;
 710
 711         onslaught_updatelinks();
 712 }
 713
 714 void ons_ControlPoint_Think(entity this)
 715 {
 716         this.nextthink = time + ONS_CP_THINKRATE;
 717         CSQCMODEL_AUTOUPDATE(this);
 718 }
 719
 720 void ons_ControlPoint_Reset(entity this)
 721 {
 722         if(this.goalentity)
 723                 delete(this.goalentity);
 724
 725         this.goalentity = NULL;
 726         this.team = 0;
 727         this.colormap = 1024;
 728         this.iscaptured = false;
 729         this.islinked = false;
 730         this.isshielded = true;
 731         setthink(this, ons_ControlPoint_Think);
 732         this.ons_toucher = NULL;
 733         this.nextthink = time + ONS_CP_THINKRATE;
 734         setmodel(this, MDL_ONS_CP_PAD1);
 735
 736         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 737         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 738
 739         onslaught_updatelinks();
 740
 741         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
 742
 743         CSQCMODEL_AUTOUPDATE(this);
 744 }
 745
 746 void ons_DelayedControlPoint_Setup(entity this)
 747 {
 748         onslaught_updatelinks();
 749
 750         // captureshield setup
 751         ons_CaptureShield_Spawn(this, false);
 752
 753         CSQCMODEL_AUTOINIT(this);
 754 }
 755
 756 void ons_ControlPoint_Setup(entity cp)
 757 {
 758         // main setup
 759         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
 760         ons_worldcplist = cp;
 761
 762         cp.netname = "Control point";
 763         cp.team = 0;
 764         cp.solid = SOLID_BBOX;
 765         set_movetype(cp, MOVETYPE_NONE);
 766         settouch(cp, ons_ControlPoint_Touch);
 767         setthink(cp, ons_ControlPoint_Think);
 768         cp.nextthink = time + ONS_CP_THINKRATE;
 769         cp.reset = ons_ControlPoint_Reset;
 770         cp.colormap = 1024;
 771         cp.iscaptured = false;
 772         cp.islinked = false;
 773         cp.isshielded = true;
 774
 775         if(cp.message == "") { cp.message = "a"; }
 776
 777         // appearence
 778         setmodel(cp, MDL_ONS_CP_PAD1);
 779
 780         // control point placement
 781         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
 782         {
 783                 cp.noalign = true;
 784                 set_movetype(cp, MOVETYPE_NONE);
 785         }
 786         else // drop to floor, automatically find a platform and set that as spawn origin
 787         {
 788                 setorigin(cp, cp.origin + '0 0 20');
 789                 cp.noalign = false;
 790                 droptofloor(cp);
 791                 set_movetype(cp, MOVETYPE_TOSS);
 792         }
 793
 794         // waypointsprites
 795         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
 796         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
 797
 798         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
 799 }
 800
 801
 802 // =========================
 803 // Main Generator Functions
 804 // =========================
 805
 806 entity ons_Generator_Waypoint(entity e)
 807 {
 808         if (e.isshielded)
 809                 return WP_OnsGenShielded;
 810         return WP_OnsGen;
 811 }
 812
 813 void ons_Generator_UpdateSprite(entity e)
 814 {
 815         entity s1 = ons_Generator_Waypoint(e);
 816         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 817
 818         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 819         {
 820                 e.lastteam = e.team + 2;
 821                 e.lastshielded = e.isshielded;
 822                 if(e.lastshielded)
 823                 {
 824                         if(e.team)
 825                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
 826                         else
 827                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 828                 }
 829                 else
 830                 {
 831                         if(e.team)
 832                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
 833                         else
 834                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 835                 }
 836                 WaypointSprite_Ping(e.sprite);
 837         }
 838 }
 839
 840 void ons_camSetup(entity this)
 841 {
 842         vector dir;
 843         vector ang = '0 0 0';
 844         vector best_ang = '0 0 0';
 845         float best_trace_fraction = 0;
 846         while(ang.y < 360)
 847         {
 848                 dir = vec2(cos(ang.y * DEG2RAD), sin(ang.y * DEG2RAD));
 849                 dir *= 500;
 850                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
 851                 if(trace_fraction > best_trace_fraction)
 852                 {
 853                         best_trace_fraction = trace_fraction;
 854                         best_ang = ang;
 855                         if(trace_fraction == 1)
 856                                 break;
 857                 }
 858                 ang.y += 90;
 859                 if(ang.y == 360)
 860                         ang.y = 45;
 861         }
 862         cam.origin = this.origin;
 863         setorigin(cam, cam.origin);
 864         cam.angles = best_ang;
 865         Net_LinkEntity(cam, false, 0, clientcamera_send);
 866
 867         FOREACH_CLIENT(true, it.clientcamera = cam;);
 868
 869         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
 870         WriteAngle(MSG_ALL, cam.angles_x);
 871         WriteAngle(MSG_ALL, cam.angles_y);
 872         WriteAngle(MSG_ALL, cam.angles_z);
 873 }
 874
 875 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 876 {
 877         if(damage <= 0) return;
 878         if(warmup_stage || game_stopped) return;
 879         if(!round_handler_IsRoundStarted()) return;
 880
 881         if (attacker != this)
 882         {
 883                 if (this.isshielded)
 884                 {
 885                         // generator is protected by a shield, so ignore the damage
 886                         if (time > this.pain_finished)
 887                                 if (IS_PLAYER(attacker))
 888                                 {
 889                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 890                                         attacker.typehitsound += 1;
 891                                         this.pain_finished = time + 1;
 892                                 }
 893                         return;
 894                 }
 895                 if (time > this.pain_finished)
 896                 {
 897                         this.pain_finished = time + 10;
 898                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
 899                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
 900                 }
 901         }
 902         TakeResource(this, RES_HEALTH, damage);
 903         float hlth = GetResource(this, RES_HEALTH);
 904         WaypointSprite_UpdateHealth(this.sprite, hlth);
 905         // choose an animation frame based on health
 906         this.frame = 10 * bound(0, (1 - hlth / this.max_health), 1);
 907         // see if the generator is still functional, or dying
 908         if (hlth > 0)
 909         {
 910                 this.lasthealth = hlth;
 911         }
 912         else
 913         {
 914                 if (attacker == this)
 915                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
 916                 else
 917                 {
 918                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
 919                         GameRules_scoring_add(attacker, SCORE, 100);
 920                 }
 921                 this.iscaptured = false;
 922                 this.islinked = false;
 923                 this.isshielded = false;
 924                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
 925                 this.event_damage = func_null; // won't do anything if hurt
 926                 this.event_heal = func_null;
 927                 this.count = 0; // reset counter
 928                 setthink(this, func_null);
 929                 this.nextthink = 0;
 930                 //this.think(); // do the first explosion now
 931
 932                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 933                 WaypointSprite_Ping(this.sprite);
 934                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
 935
 936                 onslaught_updatelinks();
 937
 938                 ons_camSetup(this);
 939         }
 940
 941         // Throw some flaming gibs on damage, more damage = more chance for gib
 942         if(random() < damage/220)
 943         {
 944                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 945         }
 946         else
 947         {
 948                 // particles on every hit
 949                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
 950
 951                 //sound on every hit
 952                 if (random() < 0.5)
 953                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
 954                 else
 955                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
 956         }
 957
 958         this.SendFlags |= GSF_STATUS;
 959 }
 960
 961 bool ons_GeneratorHeal(entity targ, entity inflictor, float amount, float limit)
 962 {
 963         float true_limit = ((limit != RES_LIMIT_NONE) ? limit : targ.max_health);
 964         float hlth = GetResource(targ, RES_HEALTH);
 965         if (hlth <= 0 || hlth >= true_limit)
 966                 return false;
 967
 968         GiveResourceWithLimit(targ, RES_HEALTH, amount, true_limit);
 969         hlth = GetResource(targ, RES_HEALTH);
 970         WaypointSprite_UpdateHealth(targ.sprite, hlth);
 971         targ.frame = 10 * bound(0, (1 - hlth / targ.max_health), 1);
 972         targ.lasthealth = hlth;
 973         targ.SendFlags |= GSF_STATUS;
 974         return true;
 975 }
 976
 977 void ons_GeneratorThink(entity this)
 978 {
 979         this.nextthink = time + GEN_THINKRATE;
 980
 981         if (game_stopped || this.isshielded || time < this.wait)
 982                 return;
 983
 984         this.wait = time + 5;
 985         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it),
 986         {
 987                 if (SAME_TEAM(it, this))
 988                 {
 989                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
 990                         msg_entity = it;
 991                         soundto(MSG_ONE, this, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE); // FIXME: unique sound?
 992                 }
 993                 else
 994                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
 995         });
 996 }
 997
 998 void ons_GeneratorReset(entity this)
 999 {
1000         this.team = this.team_saved;
1001         SetResourceExplicit(this, RES_HEALTH, autocvar_g_onslaught_gen_health);
1002         this.lasthealth = this.max_health = autocvar_g_onslaught_gen_health;
1003         this.takedamage = DAMAGE_AIM;
1004         this.bot_attack = true;
1005         if(!IL_CONTAINS(g_bot_targets, this))
1006                 IL_PUSH(g_bot_targets, this);
1007         this.iscaptured = true;
1008         this.islinked = true;
1009         this.isshielded = true;
1010         this.event_damage = ons_GeneratorDamage;
1011         this.event_heal = ons_GeneratorHeal;
1012         setthink(this, ons_GeneratorThink);
1013         this.nextthink = time + GEN_THINKRATE;
1014
1015         Net_LinkEntity(this, false, 0, generator_send);
1016
1017         this.SendFlags = GSF_SETUP; // just incase
1018         this.SendFlags |= GSF_STATUS;
1019
1020         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
1021         WaypointSprite_UpdateHealth(this.sprite, GetResource(this, RES_HEALTH));
1022         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
1023
1024         onslaught_updatelinks();
1025 }
1026
1027 void ons_DelayedGeneratorSetup(entity this)
1028 {
1029         // bot waypoints
1030         waypoint_spawnforitem_force(this, this.origin);
1031         this.nearestwaypointtimeout = 0; // activate waypointing again
1032         this.bot_basewaypoint = this.nearestwaypoint;
1033
1034         // captureshield setup
1035         ons_CaptureShield_Spawn(this, true);
1036
1037         onslaught_updatelinks();
1038
1039         Net_LinkEntity(this, false, 0, generator_send);
1040 }
1041
1042
1043 void onslaught_generator_touch(entity this, entity toucher)
1044 {
1045         if ( IS_PLAYER(toucher) )
1046         if ( SAME_TEAM(this,toucher) )
1047         if ( this.iscaptured )
1048         {
1049                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1050         }
1051 }
1052
1053 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1054 {
1055         // declarations
1056         int teamnumber = gen.team;
1057
1058         // main setup
1059         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1060         ons_worldgeneratorlist = gen;
1061
1062         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1063         gen.classname = "onslaught_generator";
1064         gen.solid = SOLID_BBOX;
1065         gen.team_saved = teamnumber;
1066         IL_PUSH(g_saved_team, gen);
1067         set_movetype(gen, MOVETYPE_NONE);
1068         gen.lasthealth = gen.max_health = autocvar_g_onslaught_gen_health;
1069         SetResourceExplicit(gen, RES_HEALTH, autocvar_g_onslaught_gen_health);
1070         gen.takedamage = DAMAGE_AIM;
1071         gen.bot_attack = true;
1072         IL_PUSH(g_bot_targets, gen);
1073         gen.event_damage = ons_GeneratorDamage;
1074         gen.event_heal = ons_GeneratorHeal;
1075         gen.reset = ons_GeneratorReset;
1076         setthink(gen, ons_GeneratorThink);
1077         gen.nextthink = time + GEN_THINKRATE;
1078         gen.iscaptured = true;
1079         gen.islinked = true;
1080         gen.isshielded = true;
1081         settouch(gen, onslaught_generator_touch);
1082
1083         // appearence
1084         // model handled by CSQC
1085         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1086         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1087         gen.colormap = 1024 + (teamnumber - 1) * 17;
1088
1089         // generator placement
1090         droptofloor(gen);
1091
1092         // waypointsprites
1093         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1094         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1095         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1096         WaypointSprite_UpdateHealth(gen.sprite, GetResource(gen, RES_HEALTH));
1097
1098         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1099 }
1100
1101
1102 // ===============
1103 //  Round Handler
1104 // ===============
1105
1106 int total_generators;
1107 void Onslaught_count_generators()
1108 {
1109         entity e;
1110         total_generators = 0;
1111         for (int i = 1; i <= NUM_TEAMS; ++i)
1112         {
1113                 Team_SetNumberOfControlPoints(Team_GetTeamFromIndex(i), 0);
1114         }
1115         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1116         {
1117                 ++total_generators;
1118                 if (GetResource(e, RES_HEALTH) < 1)
1119                 {
1120                         continue;
1121                 }
1122                 entity team_ = Entity_GetTeam(e);
1123                 int num_control_points = Team_GetNumberOfControlPoints(team_);
1124                 ++num_control_points;
1125                 Team_SetNumberOfControlPoints(team_, num_control_points);
1126         }
1127 }
1128
1129 int Onslaught_GetWinnerTeam()
1130 {
1131         int winner_team = 0;
1132         if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(1)) >= 1)
1133         {
1134                 winner_team = NUM_TEAM_1;
1135         }
1136         for (int i = 2; i <= NUM_TEAMS; ++i)
1137         {
1138                 if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(i)) >= 1)
1139                 {
1140                         if (winner_team != 0)
1141                         {
1142                                 return 0;
1143                         }
1144                         winner_team = Team_IndexToTeam(i);
1145                 }
1146         }
1147         if (winner_team)
1148         {
1149                 return winner_team;
1150         }
1151         return -1; // no generators left?
1152 }
1153
1154 void nades_Clear(entity e);
1155
1156 bool Onslaught_CheckWinner()
1157 {
1158         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1159         {
1160                 ons_stalemate = true;
1161
1162                 if (!wpforenemy_announced)
1163                 {
1164                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1165                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1166
1167                         wpforenemy_announced = true;
1168                 }
1169
1170                 entity tmp_entity; // temporary entity
1171                 float d;
1172                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1173                 {
1174                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1175                         // control points reduce the overtime duration.
1176                         d = 1;
1177                         entity e;
1178                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1179                         {
1180                                 if(DIFF_TEAM(e, tmp_entity))
1181                                 if(e.islinked)
1182                                         d = d + 1;
1183                         }
1184
1185                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1186                                 d = d * tmp_entity.max_health;
1187                         else
1188                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1189
1190                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, tmp_entity.origin, '0 0 0');
1191
1192                         tmp_entity.sprite.SendFlags |= 16;
1193
1194                         tmp_entity.ons_overtime_damagedelay = time + 1;
1195                 }
1196         }
1197         else { wpforenemy_announced = false; ons_stalemate = false; }
1198
1199         Onslaught_count_generators();
1200
1201         if (Team_GetNumberOfTeamsWithControlPoints() > 1)
1202         {
1203                 return 0;
1204         }
1205
1206         int winner_team = Onslaught_GetWinnerTeam();
1207
1208         if(winner_team > 0)
1209         {
1210                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1211                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1212                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1213         }
1214         else if(winner_team == -1)
1215         {
1216                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1217                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1218         }
1219
1220         ons_stalemate = false;
1221
1222         play2all(SND(CTF_CAPTURE(winner_team)));
1223
1224         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1225
1226         FOREACH_CLIENT(IS_PLAYER(it), {
1227                 STAT(ROUNDLOST, it) = true;
1228                 it.player_blocked = true;
1229
1230                 nades_Clear(it);
1231         });
1232
1233         game_stopped = true;
1234         return 1;
1235 }
1236
1237 bool Onslaught_CheckPlayers()
1238 {
1239         return 1;
1240 }
1241
1242 void Onslaught_RoundStart()
1243 {
1244         entity tmp_entity;
1245         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1246
1247         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1248                 tmp_entity.sprite.SendFlags |= 16;
1249
1250         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1251                 tmp_entity.sprite.SendFlags |= 16;
1252 }
1253
1254
1255 // ================
1256 // Bot player logic
1257 // ================
1258
1259 // NOTE: LEGACY CODE, needs to be re-written!
1260
1261 void havocbot_role_ons_setrole(entity this, int role)
1262 {
1263         switch(role)
1264         {
1265                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1266                         LOG_DEBUG(this.netname, " switched to defense");
1267                         this.havocbot_role = havocbot_role_ons_defense;
1268                         this.havocbot_role_timeout = 0;
1269                         break;
1270                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1271                         LOG_DEBUG(this.netname, " switched to assistant");
1272                         this.havocbot_role = havocbot_role_ons_assistant;
1273                         this.havocbot_role_timeout = 0;
1274                         break;
1275                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1276                         LOG_DEBUG(this.netname, " switched to offense");
1277                         this.havocbot_role = havocbot_role_ons_offense;
1278                         this.havocbot_role_timeout = 0;
1279                         break;
1280         }
1281 }
1282
1283 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1284 {
1285         entity cp, cp1, cp2, best, wp;
1286         float radius, bestvalue;
1287         int c;
1288         bool found;
1289
1290         // Filter control points
1291         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1292         {
1293                 cp2.wpcost = c = 0;
1294                 cp2.wpconsidered = false;
1295
1296                 if(cp2.isshielded)
1297                         continue;
1298
1299                 // Ignore owned controlpoints
1300                 if(!((cp2.aregensneighbor & BIT(this.team)) || (cp2.arecpsneighbor & BIT(this.team))))
1301                         continue;
1302
1303                 // Count team mates interested in this control point
1304                 // (easier and cleaner than keeping counters per cp and teams)
1305                 FOREACH_CLIENT(it != this && IS_PLAYER(it), {
1306                         if(SAME_TEAM(it, this))
1307                         if(it.havocbot_role == havocbot_role_ons_offense)
1308                         if(it.havocbot_ons_target == cp2)
1309                                 ++c;
1310                 });
1311
1312                 // NOTE: probably decrease the cost of attackable control points
1313                 cp2.wpcost = c;
1314                 cp2.wpconsidered = true;
1315         }
1316
1317         // We'll consider only the best case
1318         bestvalue = FLOAT_MAX;
1319         cp = NULL;
1320         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1321         {
1322                 if (!cp1.wpconsidered)
1323                         continue;
1324
1325                 if(cp1.wpcost<bestvalue)
1326                 {
1327                         bestvalue = cp1.wpcost;
1328                         cp = cp1;
1329                         this.havocbot_ons_target = cp1;
1330                 }
1331         }
1332
1333         if (!cp)
1334                 return;
1335
1336         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1337
1338         if(cp.goalentity)
1339         {
1340                 // Should be attacked
1341                 // Rate waypoints near it
1342                 found = false;
1343                 best = NULL;
1344                 bestvalue = FLOAT_MAX;
1345                 for (radius = 500; radius <= 1000 && !found; radius += 500)
1346                 {
1347                         IL_EACH(g_waypoints, vdist(cp.origin - it.origin, <, radius),
1348                         {
1349                                 if (!(it.wpflags & WAYPOINTFLAG_GENERATED) && checkpvs(it.origin, cp))
1350                                 {
1351                                         found = true;
1352                                         if (it.cnt < bestvalue)
1353                                         {
1354                                                 best = it;
1355                                                 bestvalue = it.cnt;
1356                                         }
1357                                 }
1358                         });
1359                 }
1360
1361                 if(best)
1362                 {
1363                         navigation_routerating(this, best, ratingscale, 10000);
1364                         best.cnt += 1;
1365
1366                         this.havocbot_attack_time = 0;
1367                         if(checkpvs(this.origin + this.view_ofs, cp))
1368                         if(checkpvs(this.origin + this.view_ofs, best))
1369                                 this.havocbot_attack_time = time + 2;
1370                 }
1371                 else
1372                 {
1373                         navigation_routerating(this, cp, ratingscale, 10000);
1374                 }
1375                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1376         }
1377         else
1378         {
1379                 // Should be touched
1380                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1381                 navigation_routerating(this, cp, ratingscale * 2, 10000);
1382         }
1383 }
1384
1385 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1386 {
1387         entity g, wp, bestwp;
1388         bool found;
1389         int bestvalue;
1390
1391         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1392         {
1393                 if(SAME_TEAM(g, this) || g.isshielded)
1394                         continue;
1395
1396                 // Should be attacked
1397                 // Rate waypoints near it
1398                 found = false;
1399                 bestwp = NULL;
1400                 bestvalue = FLOAT_MAX;
1401
1402                 IL_EACH(g_waypoints, vdist(g.origin - it.origin, <, 400),
1403                 {
1404                         if (checkpvs(it.origin, g))
1405                         {
1406                                 found = true;
1407                                 if (it.cnt < bestvalue)
1408                                 {
1409                                         bestwp = it;
1410                                         bestvalue = it.cnt;
1411                                 }
1412                         }
1413                 });
1414
1415                 if(bestwp)
1416                 {
1417                         LOG_DEBUG("waypoints found around generator");
1418                         navigation_routerating(this, bestwp, ratingscale, 10000);
1419                         bestwp.cnt += 1;
1420
1421                         this.havocbot_attack_time = 0;
1422                         if(checkpvs(this.origin + this.view_ofs, g))
1423                         if(checkpvs(this.origin + this.view_ofs, bestwp))
1424                                 this.havocbot_attack_time = time + 5;
1425
1426                         return true;
1427                 }
1428                 else
1429                 {
1430                         LOG_DEBUG("generator found without waypoints around");
1431                         // if there aren't waypoints near the generator go straight to it
1432                         navigation_routerating(this, g, ratingscale, 10000);
1433                         this.havocbot_attack_time = 0;
1434                         return true;
1435                 }
1436         }
1437         return false;
1438 }
1439
1440 void havocbot_role_ons_offense(entity this)
1441 {
1442         if(IS_DEAD(this))
1443         {
1444                 this.havocbot_attack_time = 0;
1445                 havocbot_ons_reset_role(this);
1446                 return;
1447         }
1448
1449         // Set the role timeout if necessary
1450         if (!this.havocbot_role_timeout)
1451                 this.havocbot_role_timeout = time + 120;
1452
1453         if (time > this.havocbot_role_timeout)
1454         {
1455                 havocbot_ons_reset_role(this);
1456                 return;
1457         }
1458
1459         if(this.havocbot_attack_time>time)
1460                 return;
1461
1462         if (navigation_goalrating_timeout(this))
1463         {
1464                 navigation_goalrating_start(this);
1465                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1466                 if(!havocbot_goalrating_ons_generator_attack(this, 10000))
1467                         havocbot_goalrating_ons_controlpoints_attack(this, 10000);
1468                 havocbot_goalrating_items(this, 25000, this.origin, 10000);
1469                 navigation_goalrating_end(this);
1470
1471                 navigation_goalrating_timeout_set(this);
1472         }
1473 }
1474
1475 void havocbot_role_ons_assistant(entity this)
1476 {
1477         havocbot_ons_reset_role(this);
1478 }
1479
1480 void havocbot_role_ons_defense(entity this)
1481 {
1482         havocbot_ons_reset_role(this);
1483 }
1484
1485 void havocbot_ons_reset_role(entity this)
1486 {
1487         if(IS_DEAD(this))
1488                 return;
1489
1490         this.havocbot_ons_target = NULL;
1491
1492         // TODO: Defend control points or generator if necessary
1493
1494         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1495 }
1496
1497
1498 /*
1499  * Find control point or generator owned by the same team self which is nearest to pos
1500  * if max_dist is positive, only control points within this range will be considered
1501  */
1502 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1503 {
1504         entity closest_target = NULL;
1505         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1506         {
1507                 if(SAME_TEAM(cp, this))
1508                 if(cp.iscaptured)
1509                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1510                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1511                         closest_target = cp;
1512         }
1513         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1514         {
1515                 if(SAME_TEAM(gen, this))
1516                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1517                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1518                         closest_target = gen;
1519         }
1520
1521         return closest_target;
1522 }
1523
1524 /*
1525  * Find control point or generator owned by the same team self which is nearest to pos
1526  * if max_dist is positive, only control points within this range will be considered
1527  * This function only check distances on the XY plane, disregarding Z
1528  */
1529 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1530 {
1531         entity closest_target = NULL;
1532         vector delta;
1533         float smallest_distance = 0, distance;
1534
1535         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1536         {
1537                 delta = cp.origin - pos;
1538                 delta_z = 0;
1539                 distance = vlen(delta);
1540
1541                 if(SAME_TEAM(cp, this))
1542                 if(cp.iscaptured)
1543                 if(max_dist <= 0 || distance <= max_dist)
1544                 if(closest_target == NULL || distance <= smallest_distance )
1545                 {
1546                         closest_target = cp;
1547                         smallest_distance = distance;
1548                 }
1549         }
1550         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1551         {
1552                 delta = gen.origin - pos;
1553                 delta_z = 0;
1554                 distance = vlen(delta);
1555
1556                 if(SAME_TEAM(gen, this))
1557                 if(max_dist <= 0 || distance <= max_dist)
1558                 if(closest_target == NULL || distance <= smallest_distance )
1559                 {
1560                         closest_target = gen;
1561                         smallest_distance = distance;
1562                 }
1563         }
1564
1565         return closest_target;
1566 }
1567 /**
1568  * find the number of control points and generators in the same team as this
1569  */
1570 int ons_Count_SelfControlPoints(entity this)
1571 {
1572         int n = 0;
1573         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1574         {
1575                 if(SAME_TEAM(cp, this))
1576                 if(cp.iscaptured)
1577                         n++;
1578         }
1579         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1580         {
1581                 if(SAME_TEAM(gen, this))
1582                         n++;
1583         }
1584         return n;
1585 }
1586
1587 /**
1588  * Teleport player to a random position near tele_target
1589  * if tele_effects is true, teleport sound+particles are created
1590  * return false on failure
1591  */
1592 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1593 {
1594         if ( !tele_target )
1595                 return false;
1596
1597         int i;
1598         vector loc;
1599         float theta;
1600         // narrow the range for each iteration to increase chances that a spawnpoint
1601         // can be found even if there's little room around the control point
1602         float iteration_scale = 1;
1603         for(i = 0; i < 16; ++i)
1604         {
1605                 iteration_scale -= i / 16;
1606                 theta = random() * 2 * M_PI;
1607                 loc_y = sin(theta);
1608                 loc_x = cos(theta);
1609                 loc_z = 0;
1610                 loc *= random() * range * iteration_scale;
1611
1612                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1613
1614                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1615                 if(trace_fraction == 1.0 && !trace_startsolid)
1616                 {
1617                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1618                         if(trace_fraction == 1.0 && !trace_startsolid)
1619                         {
1620                                 if ( tele_effects )
1621                                 {
1622                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1623                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1624                                 }
1625                                 setorigin(player, loc);
1626                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1627                                 makevectors(player.angles);
1628                                 player.fixangle = true;
1629                                 if (IS_BOT_CLIENT(player))
1630                                 {
1631                                         player.v_angle = player.angles;
1632                                         bot_aim_reset(player);
1633                                 }
1634                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1635
1636                                 if ( tele_effects )
1637                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1638                                 return true;
1639                         }
1640                 }
1641         }
1642
1643         return false;
1644 }
1645
1646 // ==============
1647 // Hook Functions
1648 // ==============
1649
1650 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1651 {
1652         FOREACH_CLIENT(IS_PLAYER(it), {
1653                 STAT(ROUNDLOST, it) = false;
1654                 it.ons_deathloc = '0 0 0';
1655                 PutClientInServer(it);
1656                 it.clientcamera = it;
1657         });
1658         return false;
1659 }
1660
1661 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1662 {
1663         entity player = M_ARGV(0, entity);
1664
1665         player.ons_deathloc = '0 0 0';
1666 }
1667
1668 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1669 {
1670         entity player = M_ARGV(0, entity);
1671
1672         player.ons_deathloc = '0 0 0';
1673 }
1674
1675 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1676 {
1677         entity player = M_ARGV(0, entity);
1678
1679         if(!round_handler_IsRoundStarted())
1680         {
1681                 player.player_blocked = true;
1682                 return false;
1683         }
1684
1685         entity l;
1686         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1687         {
1688                 l.sprite.SendFlags |= 16;
1689         }
1690         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1691         {
1692                 l.sprite.SendFlags |= 16;
1693         }
1694
1695         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1696
1697         if ( autocvar_g_onslaught_spawn_choose )
1698         if ( player.ons_spawn_by )
1699         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1700         {
1701                 player.ons_spawn_by = NULL;
1702                 return false;
1703         }
1704
1705         if(autocvar_g_onslaught_spawn_at_controlpoints)
1706         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1707         {
1708                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1709                 entity tmp_entity, closest_target = NULL;
1710                 vector spawn_loc = player.ons_deathloc;
1711
1712                 // new joining player or round reset, don't bother checking
1713                 if(spawn_loc == '0 0 0') { return false; }
1714
1715                 if(random_target) { RandomSelection_Init(); }
1716
1717                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1718                 {
1719                         if(SAME_TEAM(tmp_entity, player))
1720                         {
1721                                 if(random_target)
1722                                         RandomSelection_AddEnt(tmp_entity, 1, 1);
1723                                 else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1724                                         closest_target = tmp_entity;
1725                         }
1726                 }
1727
1728                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1729
1730                 if(closest_target)
1731                 {
1732                         float i;
1733                         vector loc;
1734                         float iteration_scale = 1;
1735                         for(i = 0; i < 10; ++i)
1736                         {
1737                                 iteration_scale -= i / 10;
1738                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1739                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1740                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1741                                 if(trace_fraction == 1.0 && !trace_startsolid)
1742                                 {
1743                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1744                                         if(trace_fraction == 1.0 && !trace_startsolid)
1745                                         {
1746                                                 setorigin(player, loc);
1747                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1748                                                 return false;
1749                                         }
1750                                 }
1751                         }
1752                 }
1753         }
1754
1755         if(autocvar_g_onslaught_spawn_at_generator)
1756         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1757         {
1758                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1759                 entity tmp_entity, closest_target = NULL;
1760                 vector spawn_loc = player.ons_deathloc;
1761
1762                 // new joining player or round reset, don't bother checking
1763                 if(spawn_loc == '0 0 0') { return false; }
1764
1765                 if(random_target) { RandomSelection_Init(); }
1766
1767                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1768                 {
1769                         if(random_target)
1770                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1771                         else
1772                         {
1773                                 if(SAME_TEAM(tmp_entity, player))
1774                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1775                                         closest_target = tmp_entity;
1776                         }
1777                 }
1778
1779                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1780
1781                 if(closest_target)
1782                 {
1783                         float i;
1784                         vector loc;
1785                         float iteration_scale = 1;
1786                         for(i = 0; i < 10; ++i)
1787                         {
1788                                 iteration_scale -= i / 10;
1789                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1790                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1791                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1792                                 if(trace_fraction == 1.0 && !trace_startsolid)
1793                                 {
1794                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1795                                         if(trace_fraction == 1.0 && !trace_startsolid)
1796                                         {
1797                                                 setorigin(player, loc);
1798                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1799                                                 return false;
1800                                         }
1801                                 }
1802                         }
1803                 }
1804         }
1805
1806         return false;
1807 }
1808
1809 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1810 {
1811         entity frag_target = M_ARGV(2, entity);
1812
1813         frag_target.ons_deathloc = frag_target.origin;
1814         entity l;
1815         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1816         {
1817                 l.sprite.SendFlags |= 16;
1818         }
1819         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1820         {
1821                 l.sprite.SendFlags |= 16;
1822         }
1823
1824         if ( autocvar_g_onslaught_spawn_choose )
1825         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1826                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1827
1828         return false;
1829 }
1830
1831 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1832 {
1833         entity mon = M_ARGV(0, entity);
1834
1835         entity e = find(NULL, targetname, mon.target);
1836         if (e != NULL)
1837                 mon.team = e.team;
1838 }
1839
1840 void ons_MonsterSpawn_Delayed(entity this)
1841 {
1842         entity own = this.owner;
1843
1844         if(!own) { delete(this); return; }
1845
1846         if(own.targetname)
1847         {
1848                 entity e = find(NULL, target, own.targetname);
1849                 if(e != NULL)
1850                 {
1851                         own.team = e.team;
1852
1853                         own.use(own, e, NULL);
1854                 }
1855         }
1856
1857         delete(this);
1858 }
1859
1860 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1861 {
1862         entity mon = M_ARGV(0, entity);
1863
1864         entity e = spawn();
1865         e.owner = mon;
1866         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1867 }
1868
1869 void ons_TurretSpawn_Delayed(entity this)
1870 {
1871         entity own = this.owner;
1872
1873         if(!own) { delete(this); return; }
1874
1875         if(own.targetname)
1876         {
1877                 entity e = find(NULL, target, own.targetname);
1878                 if(e != NULL)
1879                 {
1880                         own.team = e.team;
1881                         own.active = ACTIVE_NOT;
1882
1883                         own.use(own, e, NULL);
1884                 }
1885         }
1886
1887         delete(this);
1888 }
1889
1890 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1891 {
1892         entity turret = M_ARGV(0, entity);
1893
1894         entity e = spawn();
1895         e.owner = turret;
1896         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1897
1898         return false;
1899 }
1900
1901 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1902 {
1903         entity bot = M_ARGV(0, entity);
1904
1905         havocbot_ons_reset_role(bot);
1906         return true;
1907 }
1908
1909 MUTATOR_HOOKFUNCTION(ons, TeamBalance_CheckAllowedTeams)
1910 {
1911         // onslaught is special
1912         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1913         {
1914                 if (Team_IsValidTeam(tmp_entity.team))
1915                 {
1916                         M_ARGV(0, float) |= Team_TeamToBit(tmp_entity.team);
1917                 }
1918         }
1919
1920         return true;
1921 }
1922
1923 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1924 {
1925         entity spectatee = M_ARGV(0, entity);
1926         entity client = M_ARGV(1, entity);
1927
1928         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1929 }
1930
1931 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1932 {
1933         if(MUTATOR_RETURNVALUE) // command was already handled?
1934                 return false;
1935
1936         entity player = M_ARGV(0, entity);
1937         string cmd_name = M_ARGV(1, string);
1938         int cmd_argc = M_ARGV(2, int);
1939
1940         if ( cmd_name == "ons_spawn" )
1941         {
1942                 vector pos = player.origin;
1943                 if(cmd_argc > 1)
1944                         pos_x = stof(argv(1));
1945                 if(cmd_argc > 2)
1946                         pos_y = stof(argv(2));
1947                 if(cmd_argc > 3)
1948                         pos_z = stof(argv(3));
1949
1950                 if ( IS_PLAYER(player) )
1951                 {
1952                         if ( !STAT(FROZEN, player) )
1953                         {
1954                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1955
1956                                 if ( !source_point && GetResource(player, RES_HEALTH) > 0 )
1957                                 {
1958                                         sprint(player, "\nYou need to be next to a control point\n");
1959                                         return true;
1960                                 }
1961
1962
1963                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1964
1965                                 if ( closest_target == NULL )
1966                                 {
1967                                         sprint(player, "\nNo control point found\n");
1968                                         return true;
1969                                 }
1970
1971                                 if ( GetResource(player, RES_HEALTH) <= 0 )
1972                                 {
1973                                         player.ons_spawn_by = closest_target;
1974                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1975                                 }
1976                                 else
1977                                 {
1978                                         if ( source_point == closest_target )
1979                                         {
1980                                                 sprint(player, "\nTeleporting to the same point\n");
1981                                                 return true;
1982                                         }
1983
1984                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
1985                                                 sprint(player, "\nUnable to teleport there\n");
1986                                 }
1987
1988                                 return true;
1989                         }
1990
1991                         sprint(player, "\nNo teleportation for you\n");
1992                 }
1993
1994                 return true;
1995         }
1996         return false;
1997 }
1998
1999 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2000 {
2001         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2002
2003         entity player = M_ARGV(0, entity);
2004
2005         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2006         {
2007                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2008                 if ( source_point )
2009                 {
2010                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2011                         return true;
2012                 }
2013         }
2014 }
2015
2016 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2017 {
2018         entity frag_victim = M_ARGV(0, entity);
2019
2020         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2021                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2022 }
2023
2024 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2025 {
2026     entity wp = M_ARGV(0, entity);
2027     entity to = M_ARGV(1, entity);
2028     int sf = M_ARGV(2, int);
2029     int wp_flag = M_ARGV(3, int);
2030
2031         if(sf & 16)
2032         {
2033                 if(wp.owner.classname == "onslaught_controlpoint")
2034                 {
2035                         entity wp_owner = wp.owner;
2036                         entity e = WaypointSprite_getviewentity(to);
2037                         if(SAME_TEAM(e, wp_owner) && GetResource(wp_owner.goalentity, RES_HEALTH) >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2038                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2039                 }
2040                 if(wp.owner.classname == "onslaught_generator")
2041                 {
2042                         entity wp_owner = wp.owner;
2043                         if(wp_owner.isshielded && GetResource(wp_owner, RES_HEALTH) >= wp_owner.max_health) { wp_flag |= 2; }
2044                         if(GetResource(wp_owner, RES_HEALTH) <= 0) { wp_flag |= 2; }
2045                 }
2046         }
2047
2048         M_ARGV(3, int) = wp_flag;
2049 }
2050
2051 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2052 {
2053         entity turret_target = M_ARGV(1, entity);
2054
2055         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2056         {
2057                 M_ARGV(3, float) = -3;
2058                 return true;
2059         }
2060
2061         return false;
2062 }
2063
2064 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2065 {
2066     entity turret = M_ARGV(0, entity);
2067
2068         // ONS uses somewhat backwards linking.
2069         if(turret.target)
2070         {
2071                 entity e = find(NULL, targetname, turret.target);
2072                 if (e != NULL)
2073                         turret.team = e.team;
2074         }
2075
2076         if(turret.team != turret.tur_head.team)
2077                 turret_respawn(turret);
2078 }
2079
2080
2081 // ==========
2082 // Spawnfuncs
2083 // ==========
2084
2085 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2086   Link between control points.
2087
2088   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2089
2090 keys:
2091 "target" - first control point.
2092 "target2" - second control point.
2093  */
2094 spawnfunc(onslaught_link)
2095 {
2096         if(!g_onslaught) { delete(this); return; }
2097
2098         if (this.target == "" || this.target2 == "")
2099                 objerror(this, "target and target2 must be set\n");
2100
2101         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2102         ons_worldlinklist = this;
2103
2104         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2105         Net_LinkEntity(this, false, 0, ons_Link_Send);
2106 }
2107
2108 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2109   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2110
2111   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2112
2113 keys:
2114 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2115 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2116 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2117  */
2118
2119 spawnfunc(onslaught_controlpoint)
2120 {
2121         if(!g_onslaught) { delete(this); return; }
2122
2123         ons_ControlPoint_Setup(this);
2124 }
2125
2126 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2127   Base generator.
2128
2129   spawnfunc_onslaught_link entities can target this.
2130
2131 keys:
2132 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2133 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2134  */
2135 spawnfunc(onslaught_generator)
2136 {
2137         if(!g_onslaught) { delete(this); return; }
2138         if(!this.team) { objerror(this, "team must be set"); }
2139
2140         ons_GeneratorSetup(this);
2141 }
2142
2143 // scoreboard setup
2144 void ons_ScoreRules()
2145 {
2146         entity balance = TeamBalance_CheckAllowedTeams(NULL);
2147         int teams = TeamBalance_GetAllowedTeams(balance);
2148         TeamBalance_Destroy(balance);
2149         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
2150             field_team(ST_ONS_CAPS, "destroyed", SFL_SORT_PRIO_PRIMARY);
2151             field(SP_ONS_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
2152             field(SP_ONS_TAKES, "takes", 0);
2153         });
2154 }
2155
2156 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2157 {
2158         ons_ScoreRules();
2159
2160         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2161         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2162 }
2163
2164 void ons_Initialize()
2165 {
2166         g_onslaught = true;
2167         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2168
2169         cam = new(objective_camera);
2170
2171         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2172 }