qcsrc/common/gamemodes/gamemode/race/race.qc

   1 #include "race.qh"
   2
   3 // TODO: sv_race
   4 #ifdef SVQC
   5 #include <server/race.qh>
   6
   7 #define autocvar_g_race_laps_limit cvar("g_race_laps_limit")
   8 float autocvar_g_race_qualifying_timelimit;
   9 float autocvar_g_race_qualifying_timelimit_override;
  10 int autocvar_g_race_teams;
  11
  12 // legacy bot roles
  13 .float race_checkpoint;
  14 void havocbot_role_race(entity this)
  15 {
  16         if(IS_DEAD(this))
  17                 return;
  18
  19         if (navigation_goalrating_timeout(this))
  20         {
  21                 navigation_goalrating_start(this);
  22
  23                 bool raw_touch_check = true;
  24                 int cp = this.race_checkpoint;
  25
  26                 LABEL(search_racecheckpoints)
  27                 IL_EACH(g_racecheckpoints, true,
  28                 {
  29                         if(it.cnt == cp || cp == -1)
  30                         {
  31                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  32                                 // e.g. checkpoint in front of Stormkeep's warpzone
  33                                 // the same workaround is applied in CTS game mode
  34                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  35                                 {
  36                                         cp = race_NextCheckpoint(cp);
  37                                         raw_touch_check = false;
  38                                         goto search_racecheckpoints;
  39                                 }
  40                                 navigation_routerating(this, it, 1000000, 5000);
  41                         }
  42                 });
  43
  44                 navigation_goalrating_end(this);
  45
  46                 navigation_goalrating_timeout_set(this);
  47         }
  48 }
  49
  50 void race_ScoreRules()
  51 {
  52     GameRules_score_enabled(false);
  53         GameRules_scoring(race_teams, 0, 0, {
  54         if (race_teams) {
  55             field_team(ST_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  56             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  57             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  58             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  59         } else if (g_race_qualifying) {
  60             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  61         } else {
  62             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  63             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  64             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  65         }
  66         });
  67 }
  68
  69 void race_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  70 {
  71         if(autocvar_sv_eventlog)
  72                 GameLogEcho(strcat(":race:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  73 }
  74
  75 float WinningCondition_Race(float fraglimit)
  76 {
  77         float wc;
  78         float n, c;
  79
  80         n = 0;
  81         c = 0;
  82         FOREACH_CLIENT(IS_PLAYER(it), {
  83                 ++n;
  84                 if(CS(it).race_completed)
  85                         ++c;
  86         });
  87         if(n && (n == c))
  88                 return WINNING_YES;
  89         wc = WinningCondition_Scores(fraglimit, 0);
  90
  91         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
  92         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
  93         // do NOT support equality when the laps are all raced!
  94                 return WINNING_STARTSUDDENDEATHOVERTIME;
  95         else
  96                 return WINNING_NEVER;
  97 }
  98
  99 float WinningCondition_QualifyingThenRace(float limit)
 100 {
 101         float wc;
 102         wc = WinningCondition_Scores(limit, 0);
 103
 104         // NEVER initiate overtime
 105         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
 106         {
 107                 return WINNING_YES;
 108         }
 109
 110         return wc;
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(rc, ClientKill)
 114 {
 115         if(g_race_qualifying)
 116                 M_ARGV(1, float) = 0; // killtime
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(rc, AbortSpeedrun)
 120 {
 121         entity player = M_ARGV(0, entity);
 122
 123         if(autocvar_g_allow_checkpoints)
 124                 race_PreparePlayer(player); // nice try
 125 }
 126
 127 MUTATOR_HOOKFUNCTION(rc, PlayerPhysics)
 128 {
 129         entity player = M_ARGV(0, entity);
 130         float dt = M_ARGV(1, float);
 131
 132         player.race_movetime_frac += dt;
 133         float f = floor(player.race_movetime_frac);
 134         player.race_movetime_frac -= f;
 135         player.race_movetime_count += f;
 136         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
 137
 138 #ifdef SVQC
 139         if(IS_PLAYER(player))
 140         {
 141                 if (player.race_penalty)
 142                         if (time > player.race_penalty)
 143                                 player.race_penalty = 0;
 144                 if(player.race_penalty)
 145                 {
 146                         player.velocity = '0 0 0';
 147                         set_movetype(player, MOVETYPE_NONE);
 148                         player.disableclientprediction = 2;
 149                 }
 150         }
 151 #endif
 152
 153         // force kbd movement for fairness
 154         float wishspeed;
 155         vector wishvel;
 156
 157         // if record times matter
 158         // ensure nothing EVIL is being done (i.e. div0_evade)
 159         // this hinders joystick users though
 160         // but it still gives SOME analog control
 161         wishvel.x = fabs(CS(player).movement.x);
 162         wishvel.y = fabs(CS(player).movement.y);
 163         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 164         {
 165                 wishvel.z = 0;
 166                 wishspeed = vlen(wishvel);
 167                 if(wishvel.x >= 2 * wishvel.y)
 168                 {
 169                         // pure X motion
 170                         if(CS(player).movement.x > 0)
 171                                 CS(player).movement_x = wishspeed;
 172                         else
 173                                 CS(player).movement_x = -wishspeed;
 174                         CS(player).movement_y = 0;
 175                 }
 176                 else if(wishvel.y >= 2 * wishvel.x)
 177                 {
 178                         // pure Y motion
 179                         CS(player).movement_x = 0;
 180                         if(CS(player).movement.y > 0)
 181                                 CS(player).movement_y = wishspeed;
 182                         else
 183                                 CS(player).movement_y = -wishspeed;
 184                 }
 185                 else
 186                 {
 187                         // diagonal
 188                         if(CS(player).movement.x > 0)
 189                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 190                         else
 191                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 192                         if(CS(player).movement.y > 0)
 193                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 194                         else
 195                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 196                 }
 197         }
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(rc, reset_map_global)
 201 {
 202         float s;
 203
 204         Score_NicePrint(NULL);
 205
 206         race_ClearRecords();
 207         PlayerScore_Sort(race_place, 0, 1, 0);
 208
 209         FOREACH_CLIENT(true, {
 210                 if(it.race_place)
 211                 {
 212                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 213                         if(!s)
 214                                 it.race_place = 0;
 215                 }
 216                 race_EventLog(ftos(it.race_place), it);
 217         });
 218
 219         if(g_race_qualifying == 2)
 220         {
 221                 g_race_qualifying = 0;
 222                 independent_players = 0;
 223                 cvar_set("fraglimit", ftos(race_fraglimit));
 224                 cvar_set("leadlimit", ftos(race_leadlimit));
 225                 cvar_set("timelimit", ftos(race_timelimit));
 226                 race_ScoreRules();
 227         }
 228 }
 229
 230 MUTATOR_HOOKFUNCTION(rc, ClientConnect)
 231 {
 232         entity player = M_ARGV(0, entity);
 233
 234         race_PreparePlayer(player);
 235         player.race_checkpoint = -1;
 236
 237         string rr = RACE_RECORD;
 238
 239         if(IS_REAL_CLIENT(player))
 240         {
 241                 msg_entity = player;
 242                 race_send_recordtime(MSG_ONE);
 243                 race_send_speedaward(MSG_ONE);
 244
 245                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 246                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 247                 race_send_speedaward_alltimebest(MSG_ONE);
 248
 249                 float i;
 250                 int m = min(RANKINGS_CNT, autocvar_g_cts_send_rankings_cnt);
 251                 race_send_rankings_cnt(MSG_ONE);
 252                 for (i = 1; i <= m; ++i)
 253                 {
 254                         race_SendRankings(i, 0, 0, MSG_ONE);
 255                 }
 256         }
 257 }
 258
 259 MUTATOR_HOOKFUNCTION(rc, MakePlayerObserver)
 260 {
 261         entity player = M_ARGV(0, entity);
 262
 263         if(g_race_qualifying)
 264         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 265                 player.frags = FRAGS_LMS_LOSER;
 266         else
 267                 player.frags = FRAGS_SPECTATOR;
 268
 269         race_PreparePlayer(player);
 270         player.race_checkpoint = -1;
 271 }
 272
 273 MUTATOR_HOOKFUNCTION(rc, PlayerSpawn)
 274 {
 275         entity player = M_ARGV(0, entity);
 276         entity spawn_spot = M_ARGV(1, entity);
 277
 278         if(spawn_spot.target == "")
 279                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 280                 race_PreparePlayer(player);
 281
 282         // if we need to respawn, do it right
 283         player.race_respawn_checkpoint = player.race_checkpoint;
 284         player.race_respawn_spotref = spawn_spot;
 285
 286         player.race_place = 0;
 287 }
 288
 289 MUTATOR_HOOKFUNCTION(rc, PutClientInServer)
 290 {
 291         entity player = M_ARGV(0, entity);
 292
 293         if(IS_PLAYER(player))
 294         if(!game_stopped)
 295         {
 296                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 297                         race_PreparePlayer(player);
 298                 else // respawn
 299                         race_RetractPlayer(player);
 300
 301                 race_AbandonRaceCheck(player);
 302         }
 303 }
 304
 305 MUTATOR_HOOKFUNCTION(rc, PlayerDies)
 306 {
 307         entity frag_target = M_ARGV(2, entity);
 308
 309         frag_target.respawn_flags |= RESPAWN_FORCE;
 310         race_AbandonRaceCheck(frag_target);
 311 }
 312
 313 MUTATOR_HOOKFUNCTION(rc, HavocBot_ChooseRole)
 314 {
 315         entity bot = M_ARGV(0, entity);
 316
 317         bot.havocbot_role = havocbot_role_race;
 318         return true;
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(rc, GetPressedKeys)
 322 {
 323         entity player = M_ARGV(0, entity);
 324
 325         if(CS(player).cvar_cl_allow_uidtracking == 1 && CS(player).cvar_cl_allow_uid2name == 1)
 326         {
 327                 if (!player.stored_netname)
 328                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 329                 if(player.stored_netname != player.netname)
 330                 {
 331                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 332                         strcpy(player.stored_netname, player.netname);
 333                 }
 334         }
 335
 336         if (!IS_OBSERVER(player))
 337         {
 338                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 339                 {
 340                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 341                         speedaward_holder = player.netname;
 342                         speedaward_uid = player.crypto_idfp;
 343                         speedaward_lastupdate = time;
 344                 }
 345                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 346                 {
 347                         string rr = RACE_RECORD;
 348                         race_send_speedaward(MSG_ALL);
 349                         speedaward_lastsent = speedaward_speed;
 350                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 351                         {
 352                                 speedaward_alltimebest = speedaward_speed;
 353                                 speedaward_alltimebest_holder = speedaward_holder;
 354                                 speedaward_alltimebest_uid = speedaward_uid;
 355                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 356                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 357                                 race_send_speedaward_alltimebest(MSG_ALL);
 358                         }
 359                 }
 360         }
 361 }
 362
 363 MUTATOR_HOOKFUNCTION(rc, ForbidPlayerScore_Clear)
 364 {
 365         if(g_race_qualifying)
 366                 return true; // in qualifying, you don't lose score by observing
 367 }
 368
 369 MUTATOR_HOOKFUNCTION(rc, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 370 {
 371         M_ARGV(0, float) = race_teams;
 372 }
 373
 374 MUTATOR_HOOKFUNCTION(rc, Scores_CountFragsRemaining)
 375 {
 376         // announce remaining frags if not in qualifying mode
 377         if(!g_race_qualifying)
 378                 return true;
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(rc, GetRecords)
 382 {
 383         int record_page = M_ARGV(0, int);
 384         string ret_string = M_ARGV(1, string);
 385
 386         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 387         {
 388                 if(MapInfo_Get_ByID(i))
 389                 {
 390                         float r = race_readTime(MapInfo_Map_bspname, 1);
 391
 392                         if(!r)
 393                                 continue;
 394
 395                         string h = race_readName(MapInfo_Map_bspname, 1);
 396                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 397                 }
 398         }
 399
 400         M_ARGV(1, string) = ret_string;
 401 }
 402
 403 MUTATOR_HOOKFUNCTION(rc, HideTeamNagger)
 404 {
 405         return true; // doesn't work so well
 406 }
 407
 408 MUTATOR_HOOKFUNCTION(rc, FixClientCvars)
 409 {
 410         entity player = M_ARGV(0, entity);
 411
 412         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 413 }
 414
 415 MUTATOR_HOOKFUNCTION(rc, CheckRules_World)
 416 {
 417         float checkrules_timelimit = M_ARGV(1, float);
 418         float checkrules_fraglimit = M_ARGV(2, float);
 419
 420         if(checkrules_timelimit >= 0)
 421         {
 422                 if(!g_race_qualifying)
 423                 {
 424                         M_ARGV(0, float) = WinningCondition_Race(checkrules_fraglimit);
 425                         return true;
 426                 }
 427                 else if(g_race_qualifying == 2)
 428                 {
 429                         M_ARGV(0, float) = WinningCondition_QualifyingThenRace(checkrules_fraglimit);
 430                         return true;
 431                 }
 432         }
 433 }
 434
 435 MUTATOR_HOOKFUNCTION(rc, ReadLevelCvars)
 436 {
 437         if(g_race_qualifying == 2)
 438                 warmup_stage = 0;
 439 }
 440
 441 void race_Initialize()
 442 {
 443         race_ScoreRules();
 444         if(g_race_qualifying == 2)
 445                 warmup_stage = 0;
 446 }
 447
 448 void rc_SetLimits()
 449 {
 450         int fraglimit_override, leadlimit_override;
 451         float timelimit_override, qualifying_override;
 452
 453         if(autocvar_g_race_teams)
 454         {
 455                 GameRules_teams(true);
 456                 race_teams = BITS(bound(2, autocvar_g_race_teams, 4));
 457         }
 458         else
 459                 race_teams = 0;
 460
 461         qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 462         fraglimit_override = autocvar_g_race_laps_limit;
 463         leadlimit_override = 0; // currently not supported by race
 464         timelimit_override = autocvar_timelimit_override;
 465
 466         float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 467
 468         if(autocvar_g_campaign)
 469         {
 470                 g_race_qualifying = 1;
 471                 independent_players = 1;
 472         }
 473         else if(want_qualifying)
 474         {
 475                 g_race_qualifying = 2;
 476                 independent_players = 1;
 477                 race_fraglimit = (fraglimit_override >= 0) ? fraglimit_override : autocvar_fraglimit;
 478                 race_leadlimit = (leadlimit_override >= 0) ? leadlimit_override : autocvar_leadlimit;
 479                 race_timelimit = (timelimit_override >= 0) ? timelimit_override : autocvar_timelimit;
 480                 qualifying_override = (qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit;
 481                 fraglimit_override = 0;
 482                 leadlimit_override = 0;
 483                 timelimit_override = qualifying_override;
 484         }
 485         else
 486                 g_race_qualifying = 0;
 487     GameRules_limit_score(fraglimit_override);
 488     GameRules_limit_lead(leadlimit_override);
 489     GameRules_limit_time(timelimit_override);
 490     GameRules_limit_time_qualifying(qualifying_override);
 491 }
 492 #endif