qcsrc/common/items.qc

   1 // WEAPON PLUGIN SYSTEM
   2 entity weapon_info[24];
   3 entity dummy_weapon_info;
   4
   5 void register_weapon(float id, float(float) func, float ammotype, float i, float weapontype, float pickupbasevalue, string modelname, string shortname, string wname)
   6 {
   7         entity e;
   8         weapon_info[id - 1] = e = spawn();
   9         e.classname = "weapon_info";
  10         e.weapon = id;
  11         e.weapons = power2of(id - WEP_FIRST);
  12         e.netname = shortname;
  13         e.message = wname;
  14         e.items = ammotype;
  15         e.weapon_func = func;
  16         e.mdl = modelname;
  17         e.model = strzone(strcat("models/weapons/g_", modelname, ".md3"));
  18         e.spawnflags = weapontype;
  19         e.model2 = strzone(strcat("wpn-", e.mdl));
  20         e.impulse = i;
  21         e.bot_pickupbasevalue = pickupbasevalue;
  22 }
  23 float w_null(float dummy)
  24 {
  25         return 0;
  26 }
  27 void register_weapons_done()
  28 {
  29         entity wi;
  30
  31         dummy_weapon_info = spawn();
  32         dummy_weapon_info.classname = "weapon_info";
  33         dummy_weapon_info.weapon = 0; // you can recognize dummies by this
  34         dummy_weapon_info.weapons = 0; // you can recognize dummies by this too
  35         dummy_weapon_info.netname = "@!#%'n Tuba";
  36         dummy_weapon_info.items = 0;
  37         dummy_weapon_info.weapon_func = w_null;
  38         dummy_weapon_info.mdl = "";
  39         dummy_weapon_info.model = "";
  40         dummy_weapon_info.spawnflags = 0;
  41         dummy_weapon_info.impulse = -1;
  42         dummy_weapon_info.bot_pickupbasevalue = 0;
  43         dummy_weapon_info.model2 = "";
  44
  45         float i;
  46         weaponorder_byid = "";
  47         for(i = 24; i >= 1; --i)
  48                 if(weapon_info[i-1])
  49                         weaponorder_byid = strcat(weaponorder_byid, " ", ftos(i));
  50
  51         float imp;
  52         weaponorder_byimpulse = "";
  53         for(i = 1; i <= 24; ++i)
  54         {
  55                 wi = weapon_info[i-1];
  56                 if(wi && wi.impulse == 0)
  57                         weaponorder_byimpulse = strcat(weaponorder_byimpulse, " ", ftos(i));
  58         }
  59         for(imp = 9; imp > 0; --imp)
  60                 for(i = 1; i <= 24; ++i)
  61                 {
  62                         wi = weapon_info[i-1];
  63                         if(wi && wi.impulse == imp)
  64                                 weaponorder_byimpulse = strcat(weaponorder_byimpulse, " ", ftos(i));
  65                 }
  66
  67         weaponorder_byid = strzone(substring(weaponorder_byid, 1, strlen(weaponorder_byid) - 1));
  68         weaponorder_byimpulse = strzone(substring(weaponorder_byimpulse, 1, strlen(weaponorder_byimpulse) - 1));
  69 }
  70 entity get_weaponinfo(float id)
  71 {
  72         entity w;
  73         if(id < WEP_FIRST || id > WEP_LAST)
  74                 return dummy_weapon_info;
  75         w = weapon_info[id - 1];
  76         if(w)
  77                 return w;
  78         return dummy_weapon_info;
  79 }
  80 string W_FixWeaponOrder(string order, float complete)
  81 {
  82         return fixPriorityList(order, WEP_FIRST, WEP_LAST, 230 - WEP_FIRST, complete);
  83 }
  84 string W_NameWeaponOrder_MapFunc(string s)
  85 {
  86         entity wi;
  87         if(s == "0" || stof(s))
  88         {
  89                 wi = get_weaponinfo(stof(s));
  90                 if(wi != dummy_weapon_info)
  91                         return wi.netname;
  92         }
  93         return s;
  94 }
  95 string W_NameWeaponOrder(string order)
  96 {
  97         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
  98 }
  99 string W_NumberWeaponOrder_MapFunc(string s)
 100 {
 101         float i;
 102         if(s == "0" || stof(s))
 103                 return s;
 104         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 105                 if(s == get_weaponinfo(i).netname)
 106                         return ftos(i);
 107         return s;
 108 }
 109 string W_NumberWeaponOrder(string order)
 110 {
 111         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 112 }