qcsrc/common/items/inventory.qh

   1 #pragma once
   2
   3 #include "all.qh"
   4 #include "item/pickup.qh"
   5
   6 CLASS(Inventory, Object)
   7     /** Stores counts of items, the id being the index */
   8     ATTRIBARRAY(Inventory, inv_items, int, Items_MAX);
   9     /** Previous state */
  10     ATTRIB(Inventory, inventory, Inventory);
  11 ENDCLASS(Inventory)
  12
  13 /** Player inventory */
  14 .Inventory inventory;
  15
  16 REGISTER_NET_LINKED(ENT_CLIENT_INVENTORY)
  17
  18 const int Inventory_groups_major = 16;
  19 const int Inventory_groups_minor = 8; // ceil(Items_MAX / Inventory_groups_major)
  20
  21 #define G_MAJOR(id) (floor((id) / Inventory_groups_minor))
  22 #define G_MINOR(id) ((id) % Inventory_groups_minor)
  23
  24 #ifdef CSQC
  25 NET_HANDLE(ENT_CLIENT_INVENTORY, bool isnew)
  26 {
  27     make_pure(this);
  28     const int majorBits = ReadShort();
  29     for (int i = 0; i < Inventory_groups_major; ++i) {
  30         if (!(majorBits & BIT(i))) {
  31             continue;
  32         }
  33         const int minorBits = ReadByte();
  34         for (int j = 0; j < Inventory_groups_minor; ++j) {
  35             if (!(minorBits & BIT(j))) {
  36                 continue;
  37             }
  38             const GameItem it = Items_from(Inventory_groups_minor * i + j);
  39             .int fld = inv_items[it.m_id];
  40             int prev = this.(fld);
  41             int next = this.(fld) = ReadByte();
  42             LOG_TRACEF("%s: %.0f -> %.0f", it.m_name, prev, next);
  43         }
  44     }
  45     return true;
  46 }
  47 #endif
  48
  49 #ifdef SVQC
  50 void Inventory_Write(Inventory data)
  51 {
  52     if (!data) {
  53         WriteShort(MSG_ENTITY, 0);
  54         return;
  55     }
  56     TC(Inventory, data);
  57
  58     int majorBits = 0;
  59     FOREACH(Items, true, {
  60         .int fld = inv_items[it.m_id];
  61         const bool changed = data.inventory.(fld) != data.(fld);
  62         if (changed) {
  63             majorBits = BITSET(majorBits, BIT(G_MAJOR(it.m_id)), true);
  64         }
  65     });
  66     WriteShort(MSG_ENTITY, majorBits);
  67
  68     int minorBits = 0;
  69     int lastMaj = 0;
  70     int maj = 0;
  71     FOREACH(Items, majorBits & BIT(maj = G_MAJOR(it.m_id)), {
  72         .int fld = inv_items[it.m_id];
  73         const bool changed = data.inventory.(fld) != (data.inventory.(fld) = data.(fld));
  74         if (changed) {
  75             if (maj != lastMaj) {
  76                 lastMaj = maj;
  77 #define X() MACRO_BEGIN \
  78     if (minorBits) { \
  79         WriteByte(MSG_ENTITY, minorBits); \
  80         for (int j = 0; j < Inventory_groups_minor; ++j) { \
  81             if (!(minorBits & BIT(j))) { \
  82                 continue; \
  83             } \
  84             const GameItem it = Items_from(Inventory_groups_minor * maj + j); \
  85             WriteByte(MSG_ENTITY, data.inv_items[it.m_id]); \
  86         } \
  87     } \
  88 MACRO_END
  89                 X();
  90                 minorBits = 0;
  91             }
  92             minorBits = BITSET(minorBits, BIT(G_MINOR(it.m_id)), true);
  93         }
  94     });
  95     X();
  96 #undef X
  97 }
  98 #endif
  99
 100 #undef G_MAJOR
 101 #undef G_MINOR
 102
 103 #ifdef SVQC
 104 bool Inventory_Send(Inventory this, Client to, int sf)
 105 {
 106     TC(Inventory, this);
 107     WriteHeader(MSG_ENTITY, ENT_CLIENT_INVENTORY);
 108     entity e = this.owner;
 109     if (IS_SPEC(e)) e = e.enemy;
 110     TC(Player, e);
 111     Inventory data = e.inventory;
 112     Inventory_Write(data);
 113     return true;
 114 }
 115
 116 void Inventory_new(entity e)
 117 {
 118     Inventory inv = NEW(Inventory), bak = NEW(Inventory);
 119     inv.inventory = bak;
 120     inv.drawonlytoclient = e;
 121     Net_LinkEntity((inv.owner = e).inventory = inv, false, 0, Inventory_Send);
 122 }
 123 void Inventory_delete(entity e) { delete(e.inventory.inventory); delete(e.inventory); }
 124 void Inventory_update(entity e) { e.inventory.SendFlags = 0xFFFFFF; }
 125 #endif