qcsrc/common/items/inventory.qh

   1 #ifndef INVENTORY_H
   2 #define INVENTORY_H
   3
   4 #include "all.qh"
   5 #include "item/pickup.qh"
   6
   7 entityclass(Inventory);
   8 /** Stores counts of items, the id being the index */
   9 class(Inventory) .int inv_items[Items_MAX];
  10
  11 /** Player inventory; Inventories also have one inventory for storing the previous state */
  12 .Inventory inventory;
  13
  14 #ifdef CSQC
  15 void Inventory_Read(Inventory data)
  16 {
  17     make_pure(self);
  18     const int bits = ReadInt24_t();
  19     FOREACH(Items, bits & BIT(it.m_id), LAMBDA(
  20         .int fld = inv_items[it.m_id];
  21         int prev = data.(fld);
  22         int next = data.(fld) = ReadByte();
  23         LOG_TRACEF("%s: %.0f -> %.0f\n", it.m_name, prev, next);
  24     ));
  25 }
  26 #endif
  27
  28 #ifdef SVQC
  29 void Inventory_Write(Inventory data)
  30 {
  31     int bits = 0;
  32     FOREACH(Items, true, LAMBDA(
  33         .int fld = inv_items[it.m_id];
  34         bits = BITSET(bits, BIT(it.m_id), data.inventory.(fld) != (data.inventory.(fld) = data.(fld)));
  35     ));
  36     WriteInt24_t(MSG_ENTITY, bits);
  37     FOREACH(Items, bits & BIT(it.m_id), LAMBDA(
  38         WriteByte(MSG_ENTITY, data.inv_items[it.m_id]);
  39     ));
  40 }
  41 #endif
  42
  43 #ifdef SVQC
  44 bool Inventory_Send(entity this, entity to, int sf)
  45 {
  46     WriteByte(MSG_ENTITY, ENT_CLIENT_INVENTORY);
  47     entity e = self.owner;
  48     if (/*IS_SPEC(e)*/ (e.classname == "spectator")) e = e.enemy;
  49     Inventory data = e.inventory;
  50     Inventory_Write(data);
  51     return true;
  52 }
  53
  54 void Inventory_new(entity e)
  55 {
  56     Inventory inv = new(Inventory), bak = new(Inventory);
  57     make_pure(inv); make_pure(bak);
  58     inv.inventory = bak;
  59     inv.drawonlytoclient = e;
  60     Net_LinkEntity((inv.owner = e).inventory = inv, false, 0, Inventory_Send);
  61 }
  62 void Inventory_delete(entity e) { remove(e.inventory.inventory); remove(e.inventory); }
  63 void Inventory_update(entity e) { e.inventory.SendFlags = 0xFFFFFF; }
  64 #endif
  65
  66 #endif