qcsrc/common/items/inventory.qh

   1 #pragma once
   2
   3 #include "all.qh"
   4
   5 #ifdef GAMEQC
   6 CLASS(Inventory, Object)
   7     /** Stores counts of items, the id being the index */
   8     ATTRIBARRAY(Inventory, inv_items, int, Items_MAX);
   9     /** Previous state */
  10     ATTRIB(Inventory, inventory, Inventory);
  11 ENDCLASS(Inventory)
  12
  13 /** Player inventory */
  14 .Inventory inventory;
  15
  16 REGISTER_NET_LINKED(ENT_CLIENT_INVENTORY)
  17
  18 const int Inventory_groups_major = 16;
  19 const int Inventory_groups_minor = 8; // ceil(Items_MAX / Inventory_groups_major)
  20
  21 #define G_MAJOR(id) (floor((id) / Inventory_groups_minor))
  22 #define G_MINOR(id) ((id) % Inventory_groups_minor)
  23 #endif
  24
  25 #ifdef CSQC
  26 Inventory g_inventory;
  27 NET_HANDLE(ENT_CLIENT_INVENTORY, bool isnew)
  28 {
  29     make_pure(this);
  30     g_inventory = this;
  31     const int majorBits = ReadShort();
  32     for (int i = 0; i < Inventory_groups_major; ++i) {
  33         if (!(majorBits & BIT(i))) {
  34             continue;
  35         }
  36         const int minorBits = ReadByte();
  37         for (int j = 0; j < Inventory_groups_minor; ++j) {
  38             if (!(minorBits & BIT(j))) {
  39                 continue;
  40             }
  41             const GameItem it = Items_from(Inventory_groups_minor * i + j);
  42             .int fld = inv_items[it.m_id];
  43             int prev = this.(fld);
  44             int next = this.(fld) = ReadByte();
  45             LOG_TRACEF("%s: %.0f -> %.0f", it.m_name, prev, next);
  46         }
  47     }
  48     return true;
  49 }
  50 #endif
  51
  52 #ifdef SVQC
  53 void Inventory_Write(Inventory data)
  54 {
  55     if (!data) {
  56         WriteShort(MSG_ENTITY, 0);
  57         return;
  58     }
  59     TC(Inventory, data);
  60
  61     int majorBits = 0;
  62     FOREACH(Items, true, {
  63         .int fld = inv_items[it.m_id];
  64         const bool changed = data.inventory.(fld) != data.(fld);
  65         if (changed) {
  66             majorBits = BITSET(majorBits, BIT(G_MAJOR(it.m_id)), true);
  67         }
  68     });
  69     WriteShort(MSG_ENTITY, majorBits);
  70
  71     int minorBits = 0;
  72     int lastMaj = 0;
  73     int maj = 0;
  74     FOREACH(Items, majorBits & BIT(maj = G_MAJOR(it.m_id)), {
  75         .int fld = inv_items[it.m_id];
  76         const bool changed = data.inventory.(fld) != (data.inventory.(fld) = data.(fld));
  77         if (changed) {
  78             if (maj != lastMaj) {
  79                 lastMaj = maj;
  80 #define X() MACRO_BEGIN \
  81     if (minorBits) { \
  82         WriteByte(MSG_ENTITY, minorBits); \
  83         for (int j = 0; j < Inventory_groups_minor; ++j) { \
  84             if (!(minorBits & BIT(j))) { \
  85                 continue; \
  86             } \
  87             const entity it = Items_from(Inventory_groups_minor * maj + j); \
  88             WriteByte(MSG_ENTITY, data.inv_items[it.m_id]); \
  89         } \
  90     } \
  91 MACRO_END
  92                 X();
  93                 minorBits = 0;
  94             }
  95             minorBits = BITSET(minorBits, BIT(G_MINOR(it.m_id)), true);
  96         }
  97     });
  98     X();
  99 #undef X
 100 }
 101 #endif
 102
 103 #undef G_MAJOR
 104 #undef G_MINOR
 105
 106 #ifdef SVQC
 107 bool Inventory_Send(Inventory this, Client to, int sf)
 108 {
 109     TC(Inventory, this);
 110     WriteHeader(MSG_ENTITY, ENT_CLIENT_INVENTORY);
 111     TC(PlayerState, this.owner);
 112     Inventory_Write(this);
 113     return true;
 114 }
 115
 116 bool Inventory_customize(entity this, entity client)
 117 {
 118     // sends to spectators too!
 119     return (PS(client) && PS(client).inventory == this);
 120 }
 121
 122 void Inventory_new(PlayerState this)
 123 {
 124     Inventory inv = NEW(Inventory), bak = NEW(Inventory);
 125     inv.inventory = bak;
 126     setcefc(inv, Inventory_customize);
 127     Net_LinkEntity((inv.owner = this).inventory = inv, false, 0, Inventory_Send);
 128 }
 129 void Inventory_delete(entity e) { delete(e.inventory.inventory); delete(e.inventory); }
 130 void Inventory_update(entity e) { e.inventory.SendFlags = 0xFFFFFF; }
 131 #endif