qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(!s) // empty string is NOT valid here!
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  57 }
  58
  59 float MapInfo_Cache_Retrieve(string map)
  60 {
  61         float i;
  62         string s;
  63         if(!_MapInfo_Cache_Active)
  64                 return 0;
  65
  66         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  67         if(!s)
  68                 return 0;
  69         i = stof(s);
  70
  71         // now retrieve all the stuff
  72         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  73         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  74         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  77         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  78         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         return 1;
  80 }
  81
  82 // GLOB HANDLING (for all BSP files)
  83 float _MapInfo_globopen;
  84 float _MapInfo_globcount;
  85 float _MapInfo_globhandle;
  86 string _MapInfo_GlobItem(float i)
  87 {
  88         string s;
  89         s = search_getfilename(_MapInfo_globhandle, i);
  90         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  91 }
  92
  93 void MapInfo_Enumerate()
  94 {
  95         if(_MapInfo_globopen)
  96                 search_end(_MapInfo_globhandle);
  97         MapInfo_Cache_Invalidate();
  98         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
  99         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 100         _MapInfo_globopen = 1;
 101 }
 102
 103 // filter the info by game type mask (updates MapInfo_count)
 104 //
 105 float _MapInfo_filtered;
 106 float _MapInfo_filtered_allocated;
 107 float MapInfo_FilterList_Lookup(float i)
 108 {
 109         return stof(bufstr_get(_MapInfo_filtered, i));
 110 }
 111
 112 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 113 {
 114         string h;
 115         h = bufstr_get(_MapInfo_filtered, i);
 116         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 117         bufstr_set(_MapInfo_filtered, j, h);
 118 }
 119
 120 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 121 {
 122         string a, b;
 123         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 124         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 125         return strcasecmp(a, b);
 126 }
 127
 128 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 129 {
 130         float i, j;
 131         if not(_MapInfo_filtered_allocated)
 132         {
 133                 _MapInfo_filtered_allocated = 1;
 134                 _MapInfo_filtered = buf_create();
 135         }
 136         MapInfo_count = 0;
 137         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 138         {
 139                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 140                         if(pAbortOnGenerate)
 141                         {
 142                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 143                                 MapInfo_progress = i / _MapInfo_globcount;
 144                                 return 0;
 145                         }
 146                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 147                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 148                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 149                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 150                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 151         }
 152         MapInfo_count = j + 1;
 153         MapInfo_ClearTemps();
 154
 155         // sometimes the glob isn't sorted nicely, so fix it here...
 156         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 157
 158         return 1;
 159 }
 160
 161 void MapInfo_Filter_Free()
 162 {
 163         if(_MapInfo_filtered_allocated)
 164         {
 165                 buf_del(_MapInfo_filtered);
 166                 _MapInfo_filtered_allocated = 0;
 167         }
 168 }
 169
 170 // load info about the i-th map into the MapInfo_Map_* globals
 171 string MapInfo_BSPName_ByID(float i)
 172 {
 173         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 174 }
 175
 176 string unquote(string s)
 177 {
 178         float i, j, l;
 179         l = strlen(s);
 180         j = -1;
 181         for(i = 0; i < l; ++i)
 182         {
 183                 string ch;
 184                 ch = substring(s, i, 1);
 185                 if(ch != " ") if(ch != "\"")
 186                 {
 187                         for(j = strlen(s) - i - 1; j > 0; --j)
 188                         {
 189                                 ch = substring(s, i+j, 1);
 190                                 if(ch != " ") if(ch != "\"")
 191                                         return substring(s, i, j+1);
 192                         }
 193                         return substring(s, i, 1);
 194                 }
 195         }
 196         return "";
 197 }
 198
 199 float MapInfo_Get_ByID(float i)
 200 {
 201         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 202                 return 1;
 203         return 0;
 204 }
 205
 206 string _MapInfo_Map_worldspawn_music;
 207
 208 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 209 {
 210         string fn;
 211         float fh;
 212         string s, k, v;
 213         vector o;
 214         float i;
 215         float inWorldspawn;
 216         float r;
 217         float twoBaseModes;
 218         float diameter, spawnpoints;
 219         float spawnplaces;
 220
 221         vector mapMins, mapMaxs;
 222
 223         r = 1;
 224         fn = strcat("maps/", pFilename, ".ent");
 225         fh = fopen(fn, FILE_READ);
 226         if(fh < 0)
 227         {
 228                 r = 2;
 229                 fn = strcat("maps/", pFilename, ".bsp");
 230                 fh = fopen(fn, FILE_READ);
 231         }
 232         if(fh < 0)
 233                 return 0;
 234         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 235
 236         inWorldspawn = 2;
 237         MapInfo_Map_flags = 0;
 238         MapInfo_Map_supportedGametypes = 0;
 239         spawnpoints = 0;
 240         spawnplaces = 0;
 241         _MapInfo_Map_worldspawn_music = "";
 242
 243         for(;;)
 244         {
 245                 if not((s = fgets(fh)))
 246                         break;
 247                 if(inWorldspawn == 1)
 248                         if(startsWith(s, "}"))
 249                                 inWorldspawn = 0;
 250                 k = unquote(car(s));
 251                 v = unquote(cdr(s));
 252                 if(inWorldspawn)
 253                 {
 254                         if(k == "classname" && v == "worldspawn")
 255                                 inWorldspawn = 1;
 256                         else if(k == "author")
 257                                 MapInfo_Map_author = v;
 258                         else if(k == "_description")
 259                                 MapInfo_Map_description = v;
 260                         else if(k == "music")
 261                                 _MapInfo_Map_worldspawn_music = v;
 262                         else if(k == "noise")
 263                                 _MapInfo_Map_worldspawn_music = v;
 264                         else if(k == "message")
 265                         {
 266                                 i = strstrofs(v, " by ", 0);
 267                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 268                                 {
 269                                         MapInfo_Map_title = substring(v, 0, i);
 270                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 271                                 }
 272                                 else
 273                                         MapInfo_Map_title = v;
 274                         }
 275                 }
 276                 else
 277                 {
 278                         if(k == "origin")
 279                         {
 280                                 o = stov(strcat("'", v, "'"));
 281                                 mapMins_x = min(mapMins_x, o_x);
 282                                 mapMins_y = min(mapMins_y, o_y);
 283                                 mapMins_z = min(mapMins_z, o_z);
 284                                 mapMaxs_x = max(mapMaxs_x, o_x);
 285                                 mapMaxs_y = max(mapMaxs_y, o_y);
 286                                 mapMaxs_z = max(mapMaxs_z, o_z);
 287                         }
 288                         else if(k == "race_place")
 289                         {
 290                                 if(stof(v) > 0)
 291                                         spawnplaces = 1;
 292                         }
 293                         else if(k == "classname")
 294                         {
 295                                 if(v == "dom_controlpoint")
 296                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 297                                 else if(v == "item_flag_team2")
 298                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 299                                 else if(v == "team_CTF_blueflag")
 300                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 301                                 else if(v == "runematch_spawn_point")
 302                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 303                                 else if(v == "target_assault_roundend")
 304                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 305                                 else if(v == "onslaught_generator")
 306                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 307                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 308                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 309                                 else if(v == "info_player_team1")
 310                                         ++spawnpoints;
 311                                 else if(v == "info_player_team2")
 312                                         ++spawnpoints;
 313                                 else if(v == "info_player_start")
 314                                         ++spawnpoints;
 315                                 else if(v == "info_player_deathmatch")
 316                                         ++spawnpoints;
 317                                 else if(v == "trigger_race_checkpoint")
 318                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 319                                 else if(v == "target_startTimer")
 320                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 321                                 else if(v == "weapon_nex")
 322                                         { }
 323                                 else if(v == "weapon_railgun")
 324                                         { }
 325                                 else if(startsWith(v, "weapon_"))
 326                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 327                         }
 328                 }
 329         }
 330         if(inWorldspawn)
 331         {
 332                 print(fn, " ended still in worldspawn, BUG\n");
 333                 return 0;
 334         }
 335         diameter = vlen(mapMaxs - mapMins);
 336
 337         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 338         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 339         {
 340                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 341                 // as the map is too symmetric for them.
 342         }
 343         else
 344         {
 345                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 346                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 347                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 348
 349                 if(spawnpoints >= 8  && diameter > 4096) {
 350                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 351                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 352                 }
 353                 if(                     diameter < 4096)
 354                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 355                 if(spawnpoints >= 12 && diameter > 5120)
 356                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 357         }
 358
 359         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 360         if(!spawnplaces)
 361         {
 362                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 363                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 364         }
 365
 366         dprint("-> diameter ",    ftos(diameter));
 367         dprint(";  spawnpoints ", ftos(spawnpoints));
 368         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 369
 370         fclose(fh);
 371
 372         return r;
 373 }
 374
 375 void _MapInfo_Map_Reset()
 376 {
 377         MapInfo_Map_title = "<TITLE>";
 378         MapInfo_Map_description = "<DESCRIPTION>";
 379         MapInfo_Map_author = "<AUTHOR>";
 380         MapInfo_Map_supportedGametypes = 0;
 381         MapInfo_Map_supportedFeatures = 0;
 382         MapInfo_Map_flags = 0;
 383         MapInfo_Map_clientstuff = "";
 384         MapInfo_Map_fog = "";
 385         MapInfo_Map_mins = '0 0 0';
 386         MapInfo_Map_maxs = '0 0 0';
 387 }
 388
 389 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 390 {
 391         string sa;
 392         MapInfo_Map_supportedGametypes |= pThisType;
 393         if(!(pThisType & pWantedType))
 394                 return;
 395
 396         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 397         {
 398                 cvar_set("fraglimit", "0");
 399         }
 400         else
 401         {
 402                 cvar_set("fraglimit", car(s));
 403                 s = cdr(s);
 404         }
 405
 406         cvar_set("timelimit", car(s));
 407         s = cdr(s);
 408
 409         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 410         {
 411                 sa = car(s); if(sa == "") sa = "2";
 412                 cvar_set("g_tdm_teams", sa);
 413                 s = cdr(s);
 414         }
 415
 416         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 417         {
 418                 sa = car(s); if(sa == "") sa = "3";
 419                 cvar_set("g_keyhunt_teams", sa);
 420                 s = cdr(s);
 421         }
 422
 423         if(pWantedType == MAPINFO_TYPE_CTF)
 424         {
 425                 sa = car(s); if(sa == "") sa = "10";
 426                 if(cvar("g_ctf_win_mode") < 2)
 427                         cvar_set("fraglimit", sa);
 428                 s = cdr(s);
 429         }
 430
 431         // rc = timelimit timelimit_qualification laps laps_teamplay
 432         if(pWantedType == MAPINFO_TYPE_RACE)
 433         {
 434                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 435                 cvar_set("g_race_qualifying_timelimit", sa);
 436                 s = cdr(s);
 437
 438                 sa = car(s); if(sa == "") sa = "10";
 439                 if(cvar("g_race_teams") < 2)
 440                         cvar_set("fraglimit", sa);
 441                 s = cdr(s);
 442
 443                 sa = car(s); if(sa == "") sa = "20";
 444                 if(cvar("g_race_teams") >= 2)
 445                         cvar_set("fraglimit", sa);
 446                 s = cdr(s);
 447         }
 448
 449         if(pWantedType == MAPINFO_TYPE_CTS)
 450         {
 451                 sa = car(s); if(sa == "") sa = cvar_string("fraglimit");
 452                 if(cvar("g_race_teams"))
 453                         cvar_set("fraglimit", sa);
 454                 s = cdr(s);
 455         }
 456
 457         sa = car(s); if(sa == "") sa = "0";
 458         cvar_set("leadlimit", sa);
 459         s = cdr(s);
 460 }
 461
 462 float MapInfo_Type_FromString(string t)
 463 {
 464         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
 465         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
 466         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
 467         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
 468         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
 469         else if(t == "lms")     return MAPINFO_TYPE_LMS;
 470         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
 471         else if(t == "ca")      return MAPINFO_TYPE_CA;
 472         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
 473         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
 474         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
 475         else if(t == "rc")      return MAPINFO_TYPE_RACE;
 476         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
 477         else if(t == "cts")     return MAPINFO_TYPE_CTS;
 478         else if(t == "all")     return MAPINFO_TYPE_ALL;
 479         else                    return 0;
 480 }
 481
 482 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 483 {
 484         string t;
 485         float fh, o;
 486         t = car(s); s = cdr(s);
 487
 488         // limited support of "" and comments
 489         //   remove trailing and leading " of t
 490         if(substring(t, 0, 1) == "\"")
 491         {
 492                 if(substring(t, -1, 1) == "\"")
 493                         t = substring(t, 1, -2);
 494         }
 495
 496         //   remove leading " of s
 497         if(substring(s, 0, 1) == "\"")
 498         {
 499                 s = substring(s, 1, -1);
 500         }
 501         //   remove trailing " of s, and all that follows (cvar description)
 502         o = strstrofs(s, "\"", 0);
 503         if(o >= 0)
 504                 s = substring(s, 0, o);
 505
 506         //   remove // comments
 507         o = strstrofs(s, "//", 0);
 508         if(o >= 0)
 509                 s = substring(s, 0, o);
 510
 511         //   remove trailing spaces
 512         while(substring(s, -1, 1) == " ")
 513                 s = substring(s, 0, -2);
 514
 515         if(t == "#include")
 516         {
 517                 if(recurse > 0)
 518                 {
 519                         fh = fopen(s, FILE_READ);
 520                         if(fh < 0)
 521                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 522                         else
 523                         {
 524                                 for(;;)
 525                                 {
 526                                         if not((s = fgets(fh)))
 527                                                 break;
 528
 529                                         // catch different sorts of comments
 530                                         if(s == "")                    // empty lines
 531                                                 continue;
 532                                         if(substring(s, 0, 1) == "#")  // UNIX style
 533                                                 continue;
 534                                         if(substring(s, 0, 2) == "//") // C++ style
 535                                                 continue;
 536                                         if(substring(s, 0, 1) == "_")  // q3map style
 537                                                 continue;
 538
 539                                         if(substring(s, 0, 4) == "set ")
 540                                                 s = substring(s, 4, -1);
 541                                         if(substring(s, 0, 5) == "seta ")
 542                                                 s = substring(s, 5, -1);
 543
 544                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 545                                 }
 546                                 fclose(fh);
 547                         }
 548                 }
 549                 else
 550                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 551         }
 552         else if(t == "")
 553                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 554         else if not(cvar_value_issafe(t))
 555                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 556         else if not (cvar_value_issafe(s))
 557                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 558         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 559                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 560         else if(matchacl(acl, t) <= 0)
 561                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 562         else
 563         {
 564                 if(type == 0) // server set
 565                 {
 566                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 567                         if(cvar("g_campaign"))
 568                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 569                         else
 570                                 cvar_settemp(t, s);
 571                 }
 572                 else
 573                 {
 574                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 575                         MapInfo_Map_clientstuff = strcat(
 576                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 577                                         );
 578                 }
 579         }
 580 }
 581
 582 // load info about a map by name into the MapInfo_Map_* globals
 583 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 584 {
 585         string fn;
 586         string s, t;
 587         float fh, fh2;
 588         float r, f, n, i;
 589         string acl;
 590
 591         acl = MAPINFO_SETTEMP_ACL_USER;
 592
 593         if(strstrofs(pFilename, "/", 0) >= 0)
 594         {
 595                 print("Invalid character in map name, ignored\n");
 596                 return 0;
 597         }
 598
 599         if(pGametypeToSet == 0)
 600                 if(MapInfo_Cache_Retrieve(pFilename))
 601                         return 1;
 602
 603         r = 1;
 604
 605         MapInfo_Map_bspname = pFilename;
 606
 607         // default all generic fields so they have "good" values in case something fails
 608         fn = strcat("maps/", pFilename, ".mapinfo");
 609         fh = fopen(fn, FILE_READ);
 610         if(fh < 0)
 611         {
 612                 if(!pAllowGenerate)
 613                         return 0;
 614                 _MapInfo_Map_Reset();
 615                 r = _MapInfo_Generate(pFilename);
 616                 if(!r)
 617                         return 0;
 618                 fh = fopen(fn, FILE_WRITE);
 619                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 620                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 621                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 622                 if(_MapInfo_Map_worldspawn_music != "")
 623                 {
 624                         if(
 625                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 626                                 ||
 627                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 628                         )
 629                                 fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 630                         else
 631                                 fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 632                 }
 633                 else
 634                 {
 635                         n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 636                         s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 637                         for(;;)
 638                         {
 639                                 i = floor(random() * n);
 640                                 if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 641                                         break;
 642                         }
 643                         fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 644                 }
 645                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 646                         fputs(fh, "has weapons\n");
 647                 else
 648                         fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 649                 if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 650                         fputs(fh, "frustrating\n");
 651                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 652                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 653                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 654                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 655                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 656                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 657                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 658                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CA)              fputs(fh, "type ca 10 20\n");
 659                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 660                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 661                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)            fputs(fh, "type rc 20 5 7 15\n");
 662                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 663                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_NEXBALL)         fputs(fh, "type nexball 5 20\n");
 664                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTS)             fputs(fh, "type cts 20 -1\n");
 665
 666                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 667                 if(fh2 >= 0)
 668                 {
 669                         fclose(fh2);
 670                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 671                 }
 672
 673                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 674                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 675                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 676                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 677                 fputs(fh, "// optional: hidden\n");
 678
 679                 fclose(fh);
 680                 r = 2;
 681                 // return r;
 682                 fh = fopen(fn, FILE_READ);
 683                 if(fh < 0)
 684                         error("... but I just wrote it!");
 685         }
 686
 687         _MapInfo_Map_Reset();
 688         for(;;)
 689         {
 690                 if not((s = fgets(fh)))
 691                         break;
 692
 693                 // catch different sorts of comments
 694                 if(s == "")                    // empty lines
 695                         continue;
 696                 if(substring(s, 0, 1) == "#")  // UNIX style
 697                         continue;
 698                 if(substring(s, 0, 2) == "//") // C++ style
 699                         continue;
 700                 if(substring(s, 0, 1) == "_")  // q3map style
 701                         continue;
 702
 703                 t = car(s); s = cdr(s);
 704                 if(t == "title")
 705                         MapInfo_Map_title = s;
 706                 else if(t == "description")
 707                         MapInfo_Map_description = s;
 708                 else if(t == "author")
 709                         MapInfo_Map_author = s;
 710                 else if(t == "has")
 711                 {
 712                         t = car(s); s = cdr(s);
 713                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 714                         else
 715                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 716                 }
 717                 else if(t == "hidden")
 718                 {
 719                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 720                 }
 721                 else if(t == "forbidden")
 722                 {
 723                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 724                 }
 725                 else if(t == "frustrating")
 726                 {
 727                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 728                 }
 729                 else if(t == "type")
 730                 {
 731                         t = car(s); s = cdr(s);
 732                         f = MapInfo_Type_FromString(t);
 733                         if(f)
 734                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 735                         else
 736                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 737                 }
 738                 else if(t == "size")
 739                 {
 740                         float a, b, c, d, e;
 741                         t = car(s); s = cdr(s); a = stof(t);
 742                         t = car(s); s = cdr(s); b = stof(t);
 743                         t = car(s); s = cdr(s); c = stof(t);
 744                         t = car(s); s = cdr(s); d = stof(t);
 745                         t = car(s); s = cdr(s); e = stof(t);
 746                         if(s == "")
 747                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 748                         else
 749                         {
 750                                 t = car(s); s = cdr(s); f = stof(t);
 751                                 if(s != "")
 752                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 753                                 else
 754                                 {
 755                                         if(a >= d || b >= e || c >= f)
 756                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 757                                         else
 758                                         {
 759                                                 MapInfo_Map_mins_x = a;
 760                                                 MapInfo_Map_mins_y = b;
 761                                                 MapInfo_Map_mins_z = c;
 762                                                 MapInfo_Map_maxs_x = d;
 763                                                 MapInfo_Map_maxs_y = e;
 764                                                 MapInfo_Map_maxs_z = f;
 765                                         }
 766                                 }
 767                         }
 768                 }
 769                 else if(t == "settemp_for_type")
 770                 {
 771                         t = car(s); s = cdr(s);
 772                         if((f = MapInfo_Type_FromString(t)))
 773                         {
 774                                 if(f & pGametypeToSet)
 775                                 {
 776                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
 777                                 }
 778                         }
 779                         else
 780                         {
 781                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 782                         }
 783                 }
 784                 else if(t == "clientsettemp_for_type")
 785                 {
 786                         t = car(s); s = cdr(s);
 787                         if((f = MapInfo_Type_FromString(t)))
 788                         {
 789                                 if(f & pGametypeToSet)
 790                                 {
 791                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
 792                                 }
 793                         }
 794                         else
 795                         {
 796                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
 797                         }
 798                 }
 799                 else if(t == "fog")
 800                 {
 801                         if not(cvar_value_issafe(t))
 802                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
 803                         else
 804                                 MapInfo_Map_fog = s;
 805                 }
 806                 else if(t == "cdtrack")
 807                 {
 808                         if(pGametypeToSet)
 809                         {
 810                                 if not(cvar_value_issafe(t))
 811                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
 812                                 else
 813                                         MapInfo_Map_clientstuff = strcat(
 814                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
 815                                         );
 816                         }
 817                 }
 818                 else
 819                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 820         }
 821         fclose(fh);
 822
 823         if(pGametypeToSet)
 824         {
 825                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 826                 {
 827                         print("Can't select the requested game type. Trying anyway with stupid settings.\n");
 828                         _MapInfo_Map_ApplyGametype("0 0 0", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
 829                 }
 830         }
 831
 832         MapInfo_Cache_Store();
 833         if(MapInfo_Map_supportedGametypes != 0)
 834                 return r;
 835         dprint("Map ", pFilename, " supports no game types, ignored\n");
 836         return 0;
 837 }
 838
 839 float MapInfo_FindName(string s)
 840 {
 841         // if there is exactly one map of prefix s, return it
 842         // if not, return the null string
 843         // note that DP sorts glob results... so I can use a binary search
 844         float l, r, m, cmp;
 845         l = 0;
 846         r = MapInfo_count;
 847         // invariants: r is behind s, l-1 is equal or before
 848         while(l != r)
 849         {
 850                 m = floor((l + r) / 2);
 851                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 852                 cmp = strcasecmp(MapInfo_FindName_match, s);
 853                 if(cmp == 0)
 854                         return m; // found and good
 855                 if(cmp < 0)
 856                         l = m + 1; // l-1 is before s
 857                 else
 858                         r = m; // behind s
 859         }
 860         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 861         MapInfo_FindName_firstResult = l;
 862         // r == l, so: l is behind s, l-1 is before
 863         // SO: if there is any, l is the one with the right prefix
 864         //     and l+1 may be one too
 865         if(l == MapInfo_count)
 866         {
 867                 MapInfo_FindName_match = string_null;
 868                 MapInfo_FindName_firstResult = -1;
 869                 return -1; // no MapInfo_FindName_match, behind last item
 870         }
 871         if(!startsWithNocase(MapInfo_FindName_match, s))
 872         {
 873                 MapInfo_FindName_match = string_null;
 874                 MapInfo_FindName_firstResult = -1;
 875                 return -1; // wrong prefix
 876         }
 877         if(l == MapInfo_count - 1)
 878                 return l; // last one, nothing can follow => unique
 879         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 880         {
 881                 MapInfo_FindName_match = string_null;
 882                 return -1; // ambigous MapInfo_FindName_match
 883         }
 884         return l;
 885 }
 886
 887 string MapInfo_FixName(string s)
 888 {
 889         MapInfo_FindName(s);
 890         return MapInfo_FindName_match;
 891 }
 892
 893 float MapInfo_CurrentFeatures()
 894 {
 895         float req;
 896         req = 0;
 897         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
 898                 req |= MAPINFO_FEATURE_WEAPONS;
 899         return req;
 900 }
 901
 902 float MapInfo_CurrentGametype()
 903 {
 904         if(cvar("g_domination"))
 905                 return MAPINFO_TYPE_DOMINATION;
 906         else if(cvar("g_ctf"))
 907                 return MAPINFO_TYPE_CTF;
 908         else if(cvar("g_runematch"))
 909                 return MAPINFO_TYPE_RUNEMATCH;
 910         else if(cvar("g_tdm"))
 911                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 912         else if(cvar("g_assault"))
 913                 return MAPINFO_TYPE_ASSAULT;
 914         else if(cvar("g_lms"))
 915                 return MAPINFO_TYPE_LMS;
 916         else if(cvar("g_arena"))
 917                 return MAPINFO_TYPE_ARENA;
 918         else if(cvar("g_ca"))
 919                 return MAPINFO_TYPE_CA;
 920         else if(cvar("g_keyhunt"))
 921                 return MAPINFO_TYPE_KEYHUNT;
 922         else if(cvar("g_onslaught"))
 923                 return MAPINFO_TYPE_ONSLAUGHT;
 924         else if(cvar("g_race"))
 925                 return MAPINFO_TYPE_RACE;
 926         else if(cvar("g_nexball"))
 927                 return MAPINFO_TYPE_NEXBALL;
 928         else if(cvar("g_cts"))
 929                 return MAPINFO_TYPE_CTS;
 930         else
 931                 return MAPINFO_TYPE_DEATHMATCH;
 932 }
 933
 934 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 935 {
 936         if(!MapInfo_Get_ByName(s, 1, 0))
 937                 return 0;
 938         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 939                 return 0;
 940         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 941                 return 0;
 942         return 1;
 943 }
 944
 945 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 946 {
 947         float r;
 948         r = _MapInfo_CheckMap(s);
 949         MapInfo_ClearTemps();
 950         return r;
 951 }
 952
 953 string MapInfo_GetGameTypeCvar(float t)
 954 {
 955         switch(t)
 956         {
 957                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
 958                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
 959                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
 960                 case MAPINFO_TYPE_CTF: return "g_ctf";
 961                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
 962                 case MAPINFO_TYPE_LMS: return "g_lms";
 963                 case MAPINFO_TYPE_ARENA: return "g_arena";
 964                 case MAPINFO_TYPE_CA: return "g_ca";
 965                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
 966                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
 967                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
 968                 case MAPINFO_TYPE_RACE: return "g_race";
 969                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
 970                 case MAPINFO_TYPE_CTS: return "g_cts";
 971                 default: return "";
 972         }
 973 }
 974
 975 void MapInfo_SwitchGameType(float t)
 976 {
 977         cvar_set("gamecfg",      "0");
 978         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 979         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 980         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 981         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 982         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 983         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 984         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 985         cvar_set("g_ca",         (t == MAPINFO_TYPE_CA)              ? "1" : "0");
 986         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 987         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 988         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 989         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
 990         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
 991         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
 992 }
 993
 994 void MapInfo_LoadMap(string s)
 995 {
 996         MapInfo_Map_supportedGametypes = 0;
 997         // we shouldn't need this, as LoadMapSettings already fixes the gametype
 998         //if(!MapInfo_CheckMap(s))
 999         //{
1000         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1001         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1002         //}
1003         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1004 }
1005
1006 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1007 {
1008         string out;
1009         float i;
1010
1011         // to make absolutely sure:
1012         MapInfo_Enumerate();
1013         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1014
1015         out = "";
1016         for(i = 0; i < MapInfo_count; ++i)
1017                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1018         return substring(out, 1, strlen(out) - 1);
1019 }
1020
1021 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1022 {
1023         float t, t0;
1024         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1025         {
1026                 if(MapInfo_Map_supportedGametypes == 0)
1027                 {
1028                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1029                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1030                 }
1031
1032                 t = 1;
1033                 while(!(MapInfo_Map_supportedGametypes & 1))
1034                 {
1035                         t *= 2;
1036                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1037                 }
1038                 // t is now a supported mode!
1039                 t0 = MapInfo_CurrentGametype();
1040                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1041                 {
1042                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1043                         cvar_set("timelimit", "0");
1044                         cvar_set("fraglimit", "0");
1045                         cvar_set("g_tdm_teams", "2");
1046                         cvar_set("g_keyhunt_teams", "3");
1047                         cvar_set("g_race_qualifying_timelimit", "0");
1048                         cvar_set("leadlimit", "0");
1049                 }
1050                 else
1051                 {
1052                         print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1053                         MapInfo_SwitchGameType(t);
1054                 }
1055         }
1056         cvar_settemp_restore();
1057         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1058 }
1059
1060 void MapInfo_ClearTemps()
1061 {
1062         MapInfo_Map_bspname = string_null;
1063         MapInfo_Map_title = string_null;
1064         MapInfo_Map_description = string_null;
1065         MapInfo_Map_author = string_null;
1066         MapInfo_Map_clientstuff = string_null;
1067         MapInfo_Map_supportedGametypes = 0;
1068         MapInfo_Map_supportedFeatures = 0;
1069 }
1070
1071 void MapInfo_Shutdown()
1072 {
1073         MapInfo_ClearTemps();
1074         MapInfo_Filter_Free();
1075         MapInfo_Cache_Destroy();
1076         if(_MapInfo_globopen)
1077         {
1078                 search_end(_MapInfo_globhandle);
1079                 _MapInfo_globhandle = -1;
1080                 _MapInfo_globopen = FALSE;
1081         }
1082 }
1083
1084 float MapInfo_ForbiddenFlags()
1085 {
1086         float f;
1087         f = MAPINFO_FLAG_FORBIDDEN;
1088
1089 #ifndef MENUQC
1090         if not(cvar("g_maplist_allow_hidden"))
1091 #endif
1092                 f |= MAPINFO_FLAG_HIDDEN;
1093
1094         if not(cvar("g_maplist_allow_frustrating"))
1095                 f |= MAPINFO_FLAG_FRUSTRATING;
1096
1097         return f;
1098 }
1099
1100 float MapInfo_RequiredFlags()
1101 {
1102         float f;
1103         f = 0;
1104
1105         if(cvar("g_maplist_allow_frustrating") > 1)
1106                 f |= MAPINFO_FLAG_FRUSTRATING;
1107
1108         return f;
1109 }