qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(s == "")
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(s == "")
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         if(!_MapInfo_globopen)
  93                 return string_null;
  94         s = search_getfilename(_MapInfo_globhandle, i);
  95         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  96 }
  97
  98 void MapInfo_Enumerate()
  99 {
 100         if(_MapInfo_globopen)
 101         {
 102                 search_end(_MapInfo_globhandle);
 103                 _MapInfo_globopen = 0;
 104         }
 105         MapInfo_Cache_Invalidate();
 106         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 107         if(_MapInfo_globhandle >= 0)
 108         {
 109                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 110                 _MapInfo_globopen = 1;
 111         }
 112         else
 113                 _MapInfo_globcount = 0;
 114 }
 115
 116 // filter the info by game type mask (updates MapInfo_count)
 117 //
 118 float _MapInfo_filtered;
 119 float _MapInfo_filtered_allocated;
 120 float MapInfo_FilterList_Lookup(float i)
 121 {
 122         return stof(bufstr_get(_MapInfo_filtered, i));
 123 }
 124
 125 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 126 {
 127         string h;
 128         h = bufstr_get(_MapInfo_filtered, i);
 129         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 130         bufstr_set(_MapInfo_filtered, j, h);
 131 }
 132
 133 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 134 {
 135         string a, b;
 136         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 137         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 138         return strcasecmp(a, b);
 139 }
 140
 141 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 142 {
 143         float i, j;
 144         if (!_MapInfo_filtered_allocated)
 145         {
 146                 _MapInfo_filtered_allocated = 1;
 147                 _MapInfo_filtered = buf_create();
 148         }
 149         MapInfo_count = 0;
 150         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 151         {
 152                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 153                         if(pAbortOnGenerate)
 154                         {
 155                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 156                                 MapInfo_progress = i / _MapInfo_globcount;
 157                                 return 0;
 158                         }
 159                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 160                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 161                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 162                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 163                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 164         }
 165         MapInfo_count = j + 1;
 166         MapInfo_ClearTemps();
 167
 168         // sometimes the glob isn't sorted nicely, so fix it here...
 169         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 170
 171         return 1;
 172 }
 173
 174 void MapInfo_Filter_Free()
 175 {
 176         if(_MapInfo_filtered_allocated)
 177         {
 178                 buf_del(_MapInfo_filtered);
 179                 _MapInfo_filtered_allocated = 0;
 180         }
 181 }
 182
 183 // load info about the i-th map into the MapInfo_Map_* globals
 184 string MapInfo_BSPName_ByID(float i)
 185 {
 186         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 187 }
 188
 189 string unquote(string s)
 190 {
 191         float i, j, l;
 192         l = strlen(s);
 193         j = -1;
 194         for(i = 0; i < l; ++i)
 195         {
 196                 string ch;
 197                 ch = substring(s, i, 1);
 198                 if(ch != " ") if(ch != "\"")
 199                 {
 200                         for(j = strlen(s) - i - 1; j > 0; --j)
 201                         {
 202                                 ch = substring(s, i+j, 1);
 203                                 if(ch != " ") if(ch != "\"")
 204                                         return substring(s, i, j+1);
 205                         }
 206                         return substring(s, i, 1);
 207                 }
 208         }
 209         return "";
 210 }
 211
 212 float MapInfo_Get_ByID(float i)
 213 {
 214         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 215                 return 1;
 216         return 0;
 217 }
 218
 219 string _MapInfo_Map_worldspawn_music;
 220
 221 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 222 {
 223         string fn;
 224         float fh;
 225         string s, k, v;
 226         vector o;
 227         float i;
 228         float inWorldspawn;
 229         float r;
 230         float twoBaseModes;
 231         float diameter, spawnpoints;
 232         float spawnplaces;
 233
 234         vector mapMins, mapMaxs;
 235
 236         r = 1;
 237         fn = strcat("maps/", pFilename, ".ent");
 238         fh = fopen(fn, FILE_READ);
 239         if(fh < 0)
 240         {
 241                 r = 2;
 242                 fn = strcat("maps/", pFilename, ".bsp");
 243                 fh = fopen(fn, FILE_READ);
 244         }
 245         if(fh < 0)
 246                 return 0;
 247         print("Analyzing ", fn, " to generate initial mapinfo\n");
 248
 249         inWorldspawn = 2;
 250         MapInfo_Map_flags = 0;
 251         MapInfo_Map_supportedGametypes = 0;
 252         spawnpoints = 0;
 253         spawnplaces = 0;
 254         _MapInfo_Map_worldspawn_music = "";
 255         mapMins = '0 0 0';
 256         mapMaxs = '0 0 0';
 257
 258         for(;;)
 259         {
 260                 if (!((s = fgets(fh))))
 261                         break;
 262                 if(inWorldspawn == 1)
 263                         if(startsWith(s, "}"))
 264                                 inWorldspawn = 0;
 265                 k = unquote(car(s));
 266                 v = unquote(cdr(s));
 267                 if(inWorldspawn)
 268                 {
 269                         if(k == "classname" && v == "worldspawn")
 270                                 inWorldspawn = 1;
 271                         else if(k == "author")
 272                                 MapInfo_Map_author = v;
 273                         else if(k == "_description")
 274                                 MapInfo_Map_description = v;
 275                         else if(k == "music")
 276                                 _MapInfo_Map_worldspawn_music = v;
 277                         else if(k == "noise")
 278                                 _MapInfo_Map_worldspawn_music = v;
 279                         else if(k == "message")
 280                         {
 281                                 i = strstrofs(v, " by ", 0);
 282                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 283                                 {
 284                                         MapInfo_Map_title = substring(v, 0, i);
 285                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 286                                 }
 287                                 else
 288                                         MapInfo_Map_title = v;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if(k == "origin")
 294                         {
 295                                 o = stov(strcat("'", v, "'"));
 296                                 mapMins_x = min(mapMins_x, o_x);
 297                                 mapMins_y = min(mapMins_y, o_y);
 298                                 mapMins_z = min(mapMins_z, o_z);
 299                                 mapMaxs_x = max(mapMaxs_x, o_x);
 300                                 mapMaxs_y = max(mapMaxs_y, o_y);
 301                                 mapMaxs_z = max(mapMaxs_z, o_z);
 302                         }
 303                         else if(k == "race_place")
 304                         {
 305                                 if(stof(v) > 0)
 306                                         spawnplaces = 1;
 307                         }
 308                         else if(k == "classname")
 309                         {
 310                                 if(v == "dom_controlpoint")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 312                                 else if(v == "item_flag_team2")
 313                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 314                                 else if(v == "team_CTF_blueflag")
 315                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 316                                 else if(v == "target_assault_roundend")
 317                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 318                                 else if(v == "onslaught_generator")
 319                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 320                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 322                                 else if(v == "info_player_team1")
 323                                         ++spawnpoints;
 324                                 else if(v == "info_player_team2")
 325                                         ++spawnpoints;
 326                                 else if(v == "info_player_start")
 327                                         ++spawnpoints;
 328                                 else if(v == "info_player_deathmatch")
 329                                         ++spawnpoints;
 330                                 else if(v == "trigger_race_checkpoint")
 331                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 332                                 else if(v == "target_startTimer")
 333                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 334                                 else if(v == "weapon_nex")
 335                                         { }
 336                                 else if(v == "weapon_railgun")
 337                                         { }
 338                                 else if(startsWith(v, "weapon_"))
 339                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 340                                 else if(startsWith(v, "turret_"))
 341                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 342                                 else if(startsWith(v, "vehicle_"))
 343                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 344                                 else if(v == "target_music" || v == "trigger_music")
 345                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 346                         }
 347                 }
 348         }
 349         if(inWorldspawn)
 350         {
 351                 print(fn, " ended still in worldspawn, BUG\n");
 352                 return 0;
 353         }
 354         diameter = vlen(mapMaxs - mapMins);
 355
 356         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 357         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 358         {
 359                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 360                 // as the map is too symmetric for them.
 361         }
 362         else
 363         {
 364                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 365                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 366                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 367
 368                 if(spawnpoints >= 8  && diameter > 4096) {
 369                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 370                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 371                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 372                 }
 373                 if(spawnpoints >= 12 && diameter > 5120)
 374                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 375         }
 376
 377         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 378         if(!spawnplaces)
 379         {
 380                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 381                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 382         }
 383
 384         dprint("-> diameter ",    ftos(diameter));
 385         dprint(";  spawnpoints ", ftos(spawnpoints));
 386         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 387
 388         fclose(fh);
 389
 390         return r;
 391 }
 392
 393 void _MapInfo_Map_Reset()
 394 {
 395         MapInfo_Map_title = "<TITLE>";
 396         MapInfo_Map_titlestring = "<TITLE>";
 397         MapInfo_Map_description = "<DESCRIPTION>";
 398         MapInfo_Map_author = "<AUTHOR>";
 399         MapInfo_Map_supportedGametypes = 0;
 400         MapInfo_Map_supportedFeatures = 0;
 401         MapInfo_Map_flags = 0;
 402         MapInfo_Map_clientstuff = "";
 403         MapInfo_Map_fog = "";
 404         MapInfo_Map_mins = '0 0 0';
 405         MapInfo_Map_maxs = '0 0 0';
 406 }
 407
 408 string _MapInfo_GetDefault(float t)
 409 {
 410         switch(t)
 411         {
 412                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 413                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 414                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 415                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 416                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 417                 case MAPINFO_TYPE_CA:              return "10 20 0";
 418                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 419                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 420                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 421                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 422                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 423                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 424                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 425                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 426                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 427                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 428                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 429                 default:                           return "";
 430         }
 431 }
 432
 433 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 434 {
 435         string sa;
 436         MapInfo_Map_supportedGametypes |= pThisType;
 437         if(!(pThisType & pWantedType))
 438                 return;
 439
 440         if(load_default)
 441                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 442
 443         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 444         {
 445                 cvar_set("fraglimit", "0");
 446         }
 447         else
 448         {
 449                 sa = car(s);
 450                 if(sa != "")
 451                         cvar_set("fraglimit", sa);
 452                 s = cdr(s);
 453         }
 454
 455         sa = car(s);
 456         if(sa != "")
 457                 cvar_set("timelimit", sa);
 458         s = cdr(s);
 459
 460         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 461         {
 462                 sa = car(s);
 463                 if(sa != "")
 464                         cvar_set("g_tdm_teams", sa);
 465                 s = cdr(s);
 466         }
 467
 468         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 469         {
 470                 sa = car(s);
 471                 if(sa != "")
 472                         cvar_set("g_keyhunt_teams", sa);
 473                 s = cdr(s);
 474         }
 475
 476         if(pWantedType == MAPINFO_TYPE_CA)
 477         {
 478                 sa = car(s);
 479                 if(sa != "")
 480                         cvar_set("g_ca_teams", sa);
 481                 s = cdr(s);
 482         }
 483
 484         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 485         {
 486                 sa = car(s);
 487                 if(sa != "")
 488                         cvar_set("g_freezetag_teams", sa);
 489                 s = cdr(s);
 490         }
 491
 492         if(pWantedType == MAPINFO_TYPE_CTF)
 493         {
 494                 sa = car(s);
 495                 if(sa != "")
 496                         cvar_set("fraglimit", sa);
 497                 s = cdr(s);
 498         }
 499
 500         /* keepaway wuz here
 501         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 502         {
 503                 sa = car(s);
 504                 if(sa != "")
 505                         cvar_set("fraglimit", sa);
 506                 s = cdr(s);
 507         }
 508         */
 509
 510         // rc = timelimit timelimit_qualification laps laps_teamplay
 511         if(pWantedType == MAPINFO_TYPE_RACE)
 512         {
 513                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 514                 cvar_set("g_race_qualifying_timelimit", sa);
 515                 s = cdr(s);
 516
 517                 sa = car(s);
 518                 if(sa != "")
 519                         if(cvar("g_race_teams") < 2)
 520                                 cvar_set("fraglimit", sa);
 521                 s = cdr(s);
 522
 523                 sa = car(s);
 524                 if(sa != "")
 525                         if(cvar("g_race_teams") >= 2)
 526                                 cvar_set("fraglimit", sa);
 527                 s = cdr(s);
 528         }
 529
 530         if(pWantedType == MAPINFO_TYPE_CTS)
 531         {
 532                 sa = car(s);
 533
 534                 // this is the skill of the map
 535                 // not parsed by anything yet
 536                 // for map databases
 537                 //if(sa != "")
 538                 //      cvar_set("fraglimit", sa);
 539
 540                 s = cdr(s);
 541         }
 542
 543         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 544         {
 545                 cvar_set("leadlimit", "0");
 546         }
 547         else
 548         {
 549                 sa = car(s);
 550                 if(sa != "")
 551                         cvar_set("leadlimit", sa);
 552                 s = cdr(s);
 553         }
 554 }
 555
 556 string _MapInfo_GetDefaultEx(float t)
 557 {
 558         entity e;
 559         for(e = MapInfo_Type_first; e; e = e.enemy)
 560                 if(t == e.items)
 561                         return e.model2;
 562         return "";
 563 }
 564
 565 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 566 {
 567         string sa, k, v;
 568         float p;
 569         string fraglimit_normal;
 570         string fraglimit_teams;
 571
 572         MapInfo_Map_supportedGametypes |= pThisType;
 573         if(!(pThisType & pWantedType))
 574                 return;
 575
 576         // reset all the cvars to their defaults
 577
 578         cvar_set("timelimit", cvar_defstring("timelimit"));
 579         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 580         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 581         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 582         cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 583         cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 584         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 585         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 586         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 587
 588         fraglimit_normal = string_null;
 589         fraglimit_teams = string_null;
 590
 591         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 592         while(s != "")
 593         {
 594                 sa = car(s);
 595                 s = cdr(s);
 596
 597                 if(sa == "")
 598                         continue;
 599
 600                 p = strstrofs(sa, "=", 0);
 601                 if(p < 0)
 602                 {
 603                         k = "timelimit";
 604                         v = s;
 605                 }
 606                 else
 607                 {
 608                         k = substring(sa, 0, p);
 609                         v = substring(sa, p+1, -1);
 610                 }
 611
 612                 if(k == "timelimit")
 613                 {
 614                         cvar_set("timelimit", v);
 615                 }
 616                 else if(k == "leadlimit")
 617                 {
 618                         cvar_set("leadlimit", v);
 619                 }
 620                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 621                 {
 622                         fraglimit_normal = v;
 623                 }
 624                 else if(k == "teampointlimit" || k == "teamlaplimit")
 625                 {
 626                         fraglimit_teams = v;
 627                 }
 628                 else if(k == "teams")
 629                 {
 630                         cvar_set("g_tdm_teams", v);
 631                         cvar_set("g_ca_teams", v);
 632                         cvar_set("g_freezetag_teams", v);
 633                         cvar_set("g_keyhunt_teams", v);
 634                         cvar_set("g_domination_default_teams", v);
 635                 }
 636                 else if(k == "qualifying_timelimit")
 637                 {
 638                         cvar_set("g_race_qualifying_timelimit", v);
 639                 }
 640                 else if(k == "skill")
 641                 {
 642                         // ignore
 643                 }
 644                 else
 645                 {
 646                         print("Invalid gametype key in mapinfo: ", k, "\n");
 647                 }
 648         }
 649
 650         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 651         {
 652                 if(fraglimit_teams)
 653                         cvar_set("fraglimit", fraglimit_teams);
 654         }
 655         else
 656         {
 657                 if(fraglimit_normal)
 658                         cvar_set("fraglimit", fraglimit_normal);
 659         }
 660 }
 661
 662 float MapInfo_Type_FromString(string t)
 663 {
 664         entity e;
 665         if(t == "nexball")
 666         {
 667                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 668                 t = "nb";
 669                 print("'. Should use '", t, "'.\n");
 670         }
 671         if(t == "freezetag")
 672         {
 673                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 674                 t = "ft";
 675                 print("'. Should use '", t, "'.\n");
 676         }
 677         if(t == "keepaway")
 678         {
 679                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 680                 t = "ka";
 681                 print("'. Should use '", t, "'.\n");
 682         }
 683         if(t == "all")
 684                 return MAPINFO_TYPE_ALL;
 685         for(e = MapInfo_Type_first; e; e = e.enemy)
 686                 if(t == e.mdl)
 687                         return e.items;
 688         return 0;
 689 }
 690
 691 string MapInfo_Type_ToString(float t)
 692 {
 693         entity e;
 694         if(t == MAPINFO_TYPE_ALL)
 695                 return "all";
 696         for(e = MapInfo_Type_first; e; e = e.enemy)
 697                 if(t == e.items)
 698                         return e.mdl;
 699         return "";
 700 }
 701
 702 string MapInfo_Type_ToText(float t)
 703 {
 704         entity e;
 705         for(e = MapInfo_Type_first; e; e = e.enemy)
 706                 if(t == e.items)
 707                         return e.message;
 708         /* xgettext:no-c-format */
 709         return _("@!#%'n Tuba Throwing");
 710 }
 711
 712 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 713 {
 714         string t;
 715         float fh, o;
 716         t = car(s); s = cdr(s);
 717
 718         // limited support of "" and comments
 719         //   remove trailing and leading " of t
 720         if(substring(t, 0, 1) == "\"")
 721         {
 722                 if(substring(t, -1, 1) == "\"")
 723                         t = substring(t, 1, -2);
 724         }
 725
 726         //   remove leading " of s
 727         if(substring(s, 0, 1) == "\"")
 728         {
 729                 s = substring(s, 1, -1);
 730         }
 731         //   remove trailing " of s, and all that follows (cvar description)
 732         o = strstrofs(s, "\"", 0);
 733         if(o >= 0)
 734                 s = substring(s, 0, o);
 735
 736         //   remove // comments
 737         o = strstrofs(s, "//", 0);
 738         if(o >= 0)
 739                 s = substring(s, 0, o);
 740
 741         //   remove trailing spaces
 742         while(substring(s, -1, 1) == " ")
 743                 s = substring(s, 0, -2);
 744
 745         if(t == "#include")
 746         {
 747                 if(recurse > 0)
 748                 {
 749                         fh = fopen(s, FILE_READ);
 750                         if(fh < 0)
 751                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 752                         else
 753                         {
 754                                 for(;;)
 755                                 {
 756                                         if (!((s = fgets(fh))))
 757                                                 break;
 758
 759                                         // catch different sorts of comments
 760                                         if(s == "")                    // empty lines
 761                                                 continue;
 762                                         if(substring(s, 0, 1) == "#")  // UNIX style
 763                                                 continue;
 764                                         if(substring(s, 0, 2) == "//") // C++ style
 765                                                 continue;
 766                                         if(substring(s, 0, 1) == "_")  // q3map style
 767                                                 continue;
 768
 769                                         if(substring(s, 0, 4) == "set ")
 770                                                 s = substring(s, 4, -1);
 771                                         if(substring(s, 0, 5) == "seta ")
 772                                                 s = substring(s, 5, -1);
 773
 774                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 775                                 }
 776                                 fclose(fh);
 777                         }
 778                 }
 779                 else
 780                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 781         }
 782         else if(t == "")
 783                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 784         else if (!cvar_value_issafe(t))
 785                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 786         else if (!cvar_value_issafe(s))
 787                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 788         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 789                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 790         else if(matchacl(acl, t) <= 0)
 791                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 792         else
 793         {
 794                 if(type == 0) // server set
 795                 {
 796                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 797                         if(cvar("g_campaign"))
 798                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 799                         else
 800                                 cvar_settemp(t, s);
 801                 }
 802                 else
 803                 {
 804                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 805                         MapInfo_Map_clientstuff = strcat(
 806                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 807                                         );
 808                 }
 809         }
 810 }
 811
 812 float MapInfo_isRedundant(string fn, string t)
 813 {
 814         // normalize file name
 815         fn = strreplace("_", "-", fn);
 816
 817         // normalize visible title
 818         t = strreplace(": ", "-", t);
 819         t = strreplace(":", "-", t);
 820         t = strreplace(" ", "-", t);
 821         t = strreplace("_", "-", t);
 822         t = strreplace("'", "-", t);
 823
 824         if(!strcasecmp(fn, t))
 825                 return TRUE;
 826
 827         // we allow the visible title to have punctuation the file name does
 828         // not, but not vice versa
 829         t = strreplace("-", "", t);
 830
 831         if(!strcasecmp(fn, t))
 832                 return TRUE;
 833
 834         return FALSE;
 835 }
 836
 837 // load info about a map by name into the MapInfo_Map_* globals
 838 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 839 {
 840         string fn;
 841         string s, t;
 842         float fh;
 843         float r, f, n, i, p;
 844         string acl;
 845
 846         acl = MAPINFO_SETTEMP_ACL_USER;
 847
 848         if(strstrofs(pFilename, "/", 0) >= 0)
 849         {
 850                 print("Invalid character in map name, ignored\n");
 851                 return 0;
 852         }
 853
 854         if(pGametypeToSet == 0)
 855                 if(MapInfo_Cache_Retrieve(pFilename))
 856                         return 1;
 857
 858         r = 1;
 859
 860         MapInfo_Map_bspname = pFilename;
 861
 862         // default all generic fields so they have "good" values in case something fails
 863         fn = strcat("maps/", pFilename, ".mapinfo");
 864         fh = fopen(fn, FILE_READ);
 865         if(fh < 0)
 866         {
 867                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 868                 fh = fopen(fn, FILE_READ);
 869                 if(fh < 0)
 870                 {
 871                         if(!pAllowGenerate)
 872                                 return 0;
 873                         _MapInfo_Map_Reset();
 874                         r = _MapInfo_Generate(pFilename);
 875                         if(!r)
 876                                 return 0;
 877                         fh = fopen(fn, FILE_WRITE);
 878                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 879                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 880                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 881                         if(_MapInfo_Map_worldspawn_music != "")
 882                         {
 883                                 if(
 884                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 885                                         ||
 886                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 887                                 )
 888                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 889                                 else
 890                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 891                         }
 892                         else
 893                         {
 894                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 895                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 896                                 for(;;)
 897                                 {
 898                                         i = floor(random() * n);
 899                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 900                                                 break;
 901                                 }
 902                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 903                         }
 904                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 905                                 fputs(fh, "has weapons\n");
 906                         else
 907                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 908                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 909                                 fputs(fh, "has turrets\n");
 910                         else
 911                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 912                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 913                                 fputs(fh, "has vehicles\n");
 914                         else
 915                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 916                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 917                                 fputs(fh, "frustrating\n");
 918
 919                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 920                                 if(MapInfo_Map_supportedGametypes & i)
 921                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 922
 923                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 924                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 925
 926                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 927                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 928                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 929                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 930                         fputs(fh, "// optional: hidden\n");
 931
 932                         fclose(fh);
 933                         r = 2;
 934                         // return r;
 935                         fh = fopen(fn, FILE_READ);
 936                         if(fh < 0)
 937                                 error("... but I just wrote it!");
 938                 }
 939
 940                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 941         }
 942
 943         _MapInfo_Map_Reset();
 944         for(;;)
 945         {
 946                 if (!((s = fgets(fh))))
 947                         break;
 948
 949                 // catch different sorts of comments
 950                 if(s == "")                    // empty lines
 951                         continue;
 952                 if(substring(s, 0, 1) == "#")  // UNIX style
 953                         continue;
 954                 if(substring(s, 0, 2) == "//") // C++ style
 955                         continue;
 956                 if(substring(s, 0, 1) == "_")  // q3map style
 957                         continue;
 958
 959                 p = strstrofs(s, "//", 0);
 960                 if(p >= 0)
 961                         s = substring(s, 0, p);
 962
 963                 t = car(s); s = cdr(s);
 964                 if(t == "title")
 965                         MapInfo_Map_title = s;
 966                 else if(t == "description")
 967                         MapInfo_Map_description = s;
 968                 else if(t == "author")
 969                         MapInfo_Map_author = s;
 970                 else if(t == "has")
 971                 {
 972                         t = car(s); // s = cdr(s);
 973                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 974                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 975                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 976                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 977                         else
 978                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 979                 }
 980                 else if(t == "hidden")
 981                 {
 982                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 983                 }
 984                 else if(t == "forbidden")
 985                 {
 986                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 987                 }
 988                 else if(t == "frustrating")
 989                 {
 990                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 991                 }
 992                 else if(t == "noautomaplist")
 993                 {
 994                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 995                 }
 996                 else if(t == "type")
 997                 {
 998                         t = car(s); s = cdr(s);
 999                         f = MapInfo_Type_FromString(t);
1000                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1001                         if(f)
1002                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
1003                         else
1004                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1005                 }
1006                 else if(t == "gametype")
1007                 {
1008                         t = car(s); s = cdr(s);
1009                         f = MapInfo_Type_FromString(t);
1010                         if(f)
1011                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1012                         else
1013                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1014                 }
1015                 else if(t == "size")
1016                 {
1017                         float a, b, c, d, e;
1018                         t = car(s); s = cdr(s); a = stof(t);
1019                         t = car(s); s = cdr(s); b = stof(t);
1020                         t = car(s); s = cdr(s); c = stof(t);
1021                         t = car(s); s = cdr(s); d = stof(t);
1022                         t = car(s); s = cdr(s); e = stof(t);
1023                         if(s == "")
1024                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1025                         else
1026                         {
1027                                 t = car(s); s = cdr(s); f = stof(t);
1028                                 if(s != "")
1029                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1030                                 else
1031                                 {
1032                                         if(a >= d || b >= e || c >= f)
1033                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1034                                         else
1035                                         {
1036                                                 MapInfo_Map_mins_x = a;
1037                                                 MapInfo_Map_mins_y = b;
1038                                                 MapInfo_Map_mins_z = c;
1039                                                 MapInfo_Map_maxs_x = d;
1040                                                 MapInfo_Map_maxs_y = e;
1041                                                 MapInfo_Map_maxs_z = f;
1042                                         }
1043                                 }
1044                         }
1045                 }
1046                 else if(t == "settemp_for_type")
1047                 {
1048                         t = car(s); s = cdr(s);
1049                         if((f = MapInfo_Type_FromString(t)))
1050                         {
1051                                 if(f & pGametypeToSet)
1052                                 {
1053                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1054                                 }
1055                         }
1056                         else
1057                         {
1058                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1059                         }
1060                 }
1061                 else if(t == "clientsettemp_for_type")
1062                 {
1063                         t = car(s); s = cdr(s);
1064                         if((f = MapInfo_Type_FromString(t)))
1065                         {
1066                                 if(f & pGametypeToSet)
1067                                 {
1068                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1069                                 }
1070                         }
1071                         else
1072                         {
1073                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1074                         }
1075                 }
1076                 else if(t == "fog")
1077                 {
1078                         if (!cvar_value_issafe(s))
1079                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1080                         else
1081                                 MapInfo_Map_fog = s;
1082                 }
1083                 else if(t == "cdtrack")
1084                 {
1085                         t = car(s); s = cdr(s);
1086                         if(pGametypeToSet) // FIXME is this check right here?
1087                         {
1088                                 if (!cvar_value_issafe(t))
1089                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1090                                 else
1091                                         MapInfo_Map_clientstuff = strcat(
1092                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1093                                         );
1094                         }
1095                 }
1096                 else
1097                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1098         }
1099         fclose(fh);
1100
1101         if(MapInfo_Map_title == "<TITLE>")
1102                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1103         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1104                 MapInfo_Map_titlestring = MapInfo_Map_title;
1105         else
1106                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1107
1108         MapInfo_Cache_Store();
1109         if(MapInfo_Map_supportedGametypes != 0)
1110                 return r;
1111         dprint("Map ", pFilename, " supports no game types, ignored\n");
1112         return 0;
1113 }
1114 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1115 {
1116         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1117
1118         if(cvar("g_tdm_on_dm_maps"))
1119         {
1120                 // if this is set, all DM maps support TDM too
1121                 if (!(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH))
1122                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1123                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1124         }
1125
1126         if(pGametypeToSet)
1127         {
1128                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1129                 {
1130                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1131                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1132                         //return;
1133                 }
1134         }
1135
1136         return r;
1137 }
1138
1139 float MapInfo_FindName(string s)
1140 {
1141         // if there is exactly one map of prefix s, return it
1142         // if not, return the null string
1143         // note that DP sorts glob results... so I can use a binary search
1144         float l, r, m, cmp;
1145         l = 0;
1146         r = MapInfo_count;
1147         // invariants: r is behind s, l-1 is equal or before
1148         while(l != r)
1149         {
1150                 m = floor((l + r) / 2);
1151                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1152                 cmp = strcasecmp(MapInfo_FindName_match, s);
1153                 if(cmp == 0)
1154                         return m; // found and good
1155                 if(cmp < 0)
1156                         l = m + 1; // l-1 is before s
1157                 else
1158                         r = m; // behind s
1159         }
1160         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1161         MapInfo_FindName_firstResult = l;
1162         // r == l, so: l is behind s, l-1 is before
1163         // SO: if there is any, l is the one with the right prefix
1164         //     and l+1 may be one too
1165         if(l == MapInfo_count)
1166         {
1167                 MapInfo_FindName_match = string_null;
1168                 MapInfo_FindName_firstResult = -1;
1169                 return -1; // no MapInfo_FindName_match, behind last item
1170         }
1171         if(!startsWithNocase(MapInfo_FindName_match, s))
1172         {
1173                 MapInfo_FindName_match = string_null;
1174                 MapInfo_FindName_firstResult = -1;
1175                 return -1; // wrong prefix
1176         }
1177         if(l == MapInfo_count - 1)
1178                 return l; // last one, nothing can follow => unique
1179         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1180         {
1181                 MapInfo_FindName_match = string_null;
1182                 return -1; // ambigous MapInfo_FindName_match
1183         }
1184         return l;
1185 }
1186
1187 string MapInfo_FixName(string s)
1188 {
1189         MapInfo_FindName(s);
1190         return MapInfo_FindName_match;
1191 }
1192
1193 float MapInfo_CurrentFeatures()
1194 {
1195         float req;
1196         req = 0;
1197         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1198                 req |= MAPINFO_FEATURE_WEAPONS;
1199         return req;
1200 }
1201
1202 float MapInfo_CurrentGametype()
1203 {
1204         float prev;
1205         entity e;
1206         prev = cvar("gamecfg");
1207         for(e = MapInfo_Type_first; e; e = e.enemy)
1208                 if(cvar(e.netname))
1209                         if(prev != e.items)
1210                                 return e.items;
1211         if(prev)
1212                 return prev;
1213         return MAPINFO_TYPE_DEATHMATCH;
1214 }
1215
1216 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1217 {
1218         if(!MapInfo_Get_ByName(s, 1, 0))
1219                 return 0;
1220         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1221                 return 0;
1222         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1223                 return 0;
1224         return 1;
1225 }
1226
1227 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1228 {
1229         float r;
1230         r = _MapInfo_CheckMap(s);
1231         MapInfo_ClearTemps();
1232         return r;
1233 }
1234
1235 void MapInfo_SwitchGameType(float t)
1236 {
1237         entity e;
1238         for(e = MapInfo_Type_first; e; e = e.enemy)
1239                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1240 }
1241
1242 void MapInfo_LoadMap(string s, float reinit)
1243 {
1244         MapInfo_Map_supportedGametypes = 0;
1245         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1246         //if(!MapInfo_CheckMap(s))
1247         //{
1248         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1249         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1250         //}
1251
1252         cvar_settemp_restore();
1253         if(reinit)
1254                 localcmd(strcat("\nmap ", s, "\n"));
1255         else
1256                 localcmd(strcat("\nchangelevel ", s, "\n"));
1257 }
1258
1259 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1260 {
1261         string out;
1262         float i;
1263
1264         // to make absolutely sure:
1265         MapInfo_Enumerate();
1266         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1267
1268         out = "";
1269         for(i = 0; i < MapInfo_count; ++i)
1270                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1271         return substring(out, 1, strlen(out) - 1);
1272 }
1273
1274 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1275 {
1276         string out;
1277         float i;
1278
1279         // to make absolutely sure:
1280         MapInfo_Enumerate();
1281         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1282
1283         out = "";
1284         for(i = 0; i < MapInfo_count; ++i)
1285                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1286
1287         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1288
1289         return substring(out, 1, strlen(out) - 1);
1290 }
1291
1292 void MapInfo_LoadMapSettings_SaveGameType(float t)
1293 {
1294         MapInfo_SwitchGameType(t);
1295         cvar_set("gamecfg", ftos(t));
1296         MapInfo_LoadedGametype = t;
1297 }
1298
1299 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1300 {
1301         float t;
1302
1303         t = MapInfo_CurrentGametype();
1304         MapInfo_LoadMapSettings_SaveGameType(t);
1305
1306         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1307         {
1308                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1309                 {
1310                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1311                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1312                         return; // do not call Get_ByName!
1313                 }
1314
1315                 if(MapInfo_Map_supportedGametypes == 0)
1316                 {
1317                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1318                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1319                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1320                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1321                         return; // do not call Get_ByName!
1322                 }
1323
1324                 t = 1;
1325                 while(!(MapInfo_Map_supportedGametypes & 1))
1326                 {
1327                         t *= 2;
1328                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1329                 }
1330
1331                 // t is now a supported mode!
1332                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1333                 MapInfo_LoadMapSettings_SaveGameType(t);
1334         }
1335         MapInfo_Get_ByName(s, 1, t);
1336 }
1337
1338 void MapInfo_ClearTemps()
1339 {
1340         MapInfo_Map_bspname = string_null;
1341         MapInfo_Map_title = string_null;
1342         MapInfo_Map_titlestring = string_null;
1343         MapInfo_Map_description = string_null;
1344         MapInfo_Map_author = string_null;
1345         MapInfo_Map_clientstuff = string_null;
1346         MapInfo_Map_supportedGametypes = 0;
1347         MapInfo_Map_supportedFeatures = 0;
1348 }
1349
1350 void MapInfo_Shutdown()
1351 {
1352         MapInfo_ClearTemps();
1353         MapInfo_Filter_Free();
1354         MapInfo_Cache_Destroy();
1355         if(_MapInfo_globopen)
1356         {
1357                 search_end(_MapInfo_globhandle);
1358                 _MapInfo_globhandle = -1;
1359                 _MapInfo_globopen = FALSE;
1360         }
1361 }
1362
1363 float MapInfo_ForbiddenFlags()
1364 {
1365         float f;
1366         f = MAPINFO_FLAG_FORBIDDEN;
1367
1368 #ifndef MENUQC
1369         if (!cvar("g_maplist_allow_hidden"))
1370 #endif
1371                 f |= MAPINFO_FLAG_HIDDEN;
1372
1373         if (!cvar("g_maplist_allow_frustrating"))
1374                 f |= MAPINFO_FLAG_FRUSTRATING;
1375
1376         return f;
1377 }
1378
1379 float MapInfo_RequiredFlags()
1380 {
1381         float f;
1382         f = 0;
1383
1384         if(cvar("g_maplist_allow_frustrating") > 1)
1385                 f |= MAPINFO_FLAG_FRUSTRATING;
1386
1387         return f;
1388 }