257e5e40f185ddc0bf254b9dc11d926258365cc2
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mapinfo.qc
1 #include "mapinfo.qh"
2 #if defined(CSQC)
3     #include "../client/defs.qh"
4     #include "util.qh"
5     #include <common/weapons/_all.qh>
6 #elif defined(MENUQC)
7 #elif defined(SVQC)
8     #include "util.qh"
9     #include <common/monsters/_mod.qh>
10 #endif
11
12 #ifdef MENUQC
13 #define WARN_COND false
14 #else
15 bool autocvar_g_mapinfo_ignore_warnings;
16 #define WARN_COND (!autocvar_g_mapinfo_ignore_warnings && MapInfo_Map_bspname == mi_shortname)
17 #endif
18
19 // generic string stuff
20
21 int _MapInfo_Cache_Active;
22 int _MapInfo_Cache_DB_NameToIndex;
23 int _MapInfo_Cache_Buf_IndexToMapData;
24
25 void MapInfo_Cache_Destroy()
26 {
27         if(!_MapInfo_Cache_Active)
28                 return;
29
30         db_close(_MapInfo_Cache_DB_NameToIndex);
31         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
32         _MapInfo_Cache_Active = 0;
33 }
34
35 void MapInfo_Cache_Create()
36 {
37         MapInfo_Cache_Destroy();
38         _MapInfo_Cache_DB_NameToIndex = db_create();
39         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
40         _MapInfo_Cache_Active = 1;
41 }
42
43 void MapInfo_Cache_Invalidate()
44 {
45         if(!_MapInfo_Cache_Active)
46                 return;
47
48         MapInfo_Cache_Create();
49 }
50
51 void MapInfo_Cache_Store()
52 {
53         float i;
54         string s;
55         if(!_MapInfo_Cache_Active)
56                 return;
57
58         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
59         if(s == "")
60         {
61                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
62                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
63         }
64         else
65                 i = stof(s);
66
67         // now store all the stuff
68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
75         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
76 }
77
78 float MapInfo_Cache_Retrieve(string map)
79 {
80         float i;
81         string s;
82         if(!_MapInfo_Cache_Active)
83                 return 0;
84
85         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
86         if(s == "")
87                 return 0;
88         i = stof(s);
89
90         // now retrieve all the stuff
91         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
92         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
93         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
94         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
95         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
96         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
97         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
98         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
99
100         return 1;
101 }
102
103 // GLOB HANDLING (for all BSP files)
104 float _MapInfo_globopen;
105 float _MapInfo_globcount;
106 float _MapInfo_globhandle;
107 string _MapInfo_GlobItem(float i)
108 {
109         string s;
110         if(!_MapInfo_globopen)
111                 return string_null;
112         s = search_getfilename(_MapInfo_globhandle, i);
113         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
114 }
115
116 void MapInfo_Enumerate()
117 {
118         if(_MapInfo_globopen)
119         {
120                 search_end(_MapInfo_globhandle);
121                 _MapInfo_globopen = 0;
122         }
123         MapInfo_Cache_Invalidate();
124         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
125         if(_MapInfo_globhandle >= 0)
126         {
127                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
128                 _MapInfo_globopen = 1;
129         }
130         else
131                 _MapInfo_globcount = 0;
132 }
133
134 // filter the info by game type mask (updates MapInfo_count)
135 //
136 float _MapInfo_filtered;
137 float _MapInfo_filtered_allocated;
138 float MapInfo_FilterList_Lookup(float i)
139 {
140         return stof(bufstr_get(_MapInfo_filtered, i));
141 }
142
143 void _MapInfo_FilterList_swap(float i, float j, entity pass)
144 {
145         string h;
146         h = bufstr_get(_MapInfo_filtered, i);
147         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
148         bufstr_set(_MapInfo_filtered, j, h);
149 }
150
151 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
152 {
153         string a, b;
154         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
155         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
156         return strcasecmp(a, b);
157 }
158
159 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
160 {
161         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
162 }
163 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
164 {
165         float i, j;
166         if (!_MapInfo_filtered_allocated)
167         {
168                 _MapInfo_filtered_allocated = 1;
169                 _MapInfo_filtered = buf_create();
170         }
171         MapInfo_count = 0;
172         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
173         {
174                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
175                         if(pAbortOnGenerate)
176                         {
177                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
178                                 MapInfo_progress = i / _MapInfo_globcount;
179                                 return 0;
180                         }
181                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
182                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
183                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
184                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
185                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
186         }
187         MapInfo_count = j + 1;
188         MapInfo_ClearTemps();
189
190         // sometimes the glob isn't sorted nicely, so fix it here...
191         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
192
193         return 1;
194 }
195 void MapInfo_FilterString(string sf)
196 {
197         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
198         float i, j;
199         string title;
200
201         for(i = 0, j = -1; i < MapInfo_count; ++i)
202         {
203                 if (MapInfo_Get_ByID(i))
204                 {
205                         // prepare for keyword filter
206                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
207                                 title = MapInfo_Map_title;
208                         else
209                                 title = MapInfo_Map_bspname;
210                         // keyword filter
211                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
212                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
213                 }
214         }
215         MapInfo_count = j + 1;
216         MapInfo_ClearTemps();
217
218         // sometimes the glob isn't sorted nicely, so fix it here...
219         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
220 }
221
222 void MapInfo_Filter_Free()
223 {
224         if(_MapInfo_filtered_allocated)
225         {
226                 buf_del(_MapInfo_filtered);
227                 _MapInfo_filtered_allocated = 0;
228         }
229 }
230
231 // load info about the i-th map into the MapInfo_Map_* globals
232 string MapInfo_BSPName_ByID(float i)
233 {
234         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
235 }
236
237 string unquote(string s)
238 {
239         float l = strlen(s);
240         for(float i = 0; i < l; ++i)
241         {
242                 string ch = substring(s, i, 1);
243                 if((ch != " ") && (ch != "\""))
244                 {
245                         for(float j = l - i - 1; j > 0; --j)
246                         {
247                                 ch = substring(s, i+j, 1);
248                                 if(ch != " ") if(ch != "\"")
249                                         return substring(s, i, j+1);
250                         }
251                         return substring(s, i, 1);
252                 }
253         }
254         return "";
255 }
256
257 float MapInfo_Get_ByID(float i)
258 {
259         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL))
260                 return 1;
261         return 0;
262 }
263
264 string _MapInfo_Map_worldspawn_music;
265
266 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
267 {
268         string fn;
269         float fh;
270         string s, k, v;
271         vector o;
272         float i;
273         float inWorldspawn;
274         float r;
275         float diameter, spawnpoints;
276         float spawnplaces;
277
278         vector mapMins, mapMaxs;
279
280         r = 1;
281         fn = strcat("maps/", pFilename, ".ent");
282         fh = fopen(fn, FILE_READ);
283         if(fh < 0)
284         {
285                 r = 2;
286                 fn = strcat("maps/", pFilename, ".bsp");
287                 fh = fopen(fn, FILE_READ);
288         }
289         if(fh < 0)
290                 return 0;
291         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
292
293         inWorldspawn = 2;
294         MapInfo_Map_flags = 0;
295         MapInfo_Map_supportedGametypes = 0;
296         spawnpoints = 0;
297         spawnplaces = 0;
298         _MapInfo_Map_worldspawn_music = "";
299         mapMins = '0 0 0';
300         mapMaxs = '0 0 0';
301
302         for (;;)
303         {
304                 if (!((s = fgets(fh))))
305                         break;
306                 if(inWorldspawn == 1)
307                         if(startsWith(s, "}"))
308                                 inWorldspawn = 0;
309                 k = unquote(car(s));
310                 v = unquote(cdr(s));
311                 if(inWorldspawn)
312                 {
313                         if(k == "classname" && v == "worldspawn")
314                                 inWorldspawn = 1;
315                         else if(k == "author")
316                                 MapInfo_Map_author = v;
317                         else if(k == "_description")
318                                 MapInfo_Map_description = v;
319                         else if(k == "music")
320                                 _MapInfo_Map_worldspawn_music = v;
321                         else if(k == "noise")
322                                 _MapInfo_Map_worldspawn_music = v;
323                         else if(k == "message")
324                         {
325                                 i = strstrofs(v, " by ", 0);
326                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
327                                 {
328                                         MapInfo_Map_title = substring(v, 0, i);
329                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
330                                 }
331                                 else
332                                         MapInfo_Map_title = v;
333                         }
334                 }
335                 else
336                 {
337                         if(k == "origin")
338                         {
339                                 o = stov(strcat("'", v, "'"));
340                                 mapMins.x = min(mapMins.x, o.x);
341                                 mapMins.y = min(mapMins.y, o.y);
342                                 mapMins.z = min(mapMins.z, o.z);
343                                 mapMaxs.x = max(mapMaxs.x, o.x);
344                                 mapMaxs.y = max(mapMaxs.y, o.y);
345                                 mapMaxs.z = max(mapMaxs.z, o.z);
346                         }
347                         else if(k == "race_place")
348                         {
349                                 if(stof(v) > 0)
350                                         spawnplaces = 1;
351                         }
352                         else if(k == "classname")
353                         {
354                                 if(v == "info_player_team1")
355                                         ++spawnpoints;
356                                 else if(v == "info_player_team2")
357                                         ++spawnpoints;
358                                 else if(v == "info_player_start")
359                                         ++spawnpoints;
360                                 else if(v == "info_player_deathmatch")
361                                         ++spawnpoints;
362                                 else if(v == "weapon_nex")
363                                         { }
364                                 else if(v == "weapon_railgun")
365                                         { }
366                                 else if(startsWith(v, "weapon_"))
367                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
368                                 else if(startsWith(v, "turret_"))
369                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
370                                 else if(startsWith(v, "vehicle_"))
371                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
372                                 else if(startsWith(v, "monster_"))
373                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
374                                 else if(v == "target_music" || v == "trigger_music")
375                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
376                                 else
377                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
378                         }
379                 }
380         }
381         if(inWorldspawn)
382         {
383                 LOG_WARN(fn, " ended still in worldspawn, BUG");
384                 return 0;
385         }
386         diameter = vlen(mapMaxs - mapMins);
387
388         int twoBaseModes = 0;
389         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
390         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
391         {
392                 // we have a symmetrical map, don't add the modes without bases
393         }
394         else
395         {
396                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
397         }
398
399         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
400         if(!spawnplaces)
401         {
402                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
403                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
404         }
405
406         LOG_TRACE("-> diameter ",    ftos(diameter));
407         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
408         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
409
410         fclose(fh);
411
412         return r;
413 }
414
415 void _MapInfo_Map_Reset()
416 {
417         MapInfo_Map_title = "<TITLE>";
418         MapInfo_Map_titlestring = "<TITLE>";
419         MapInfo_Map_description = "<DESCRIPTION>";
420         MapInfo_Map_author = "<AUTHOR>";
421         MapInfo_Map_supportedGametypes = 0;
422         MapInfo_Map_supportedFeatures = 0;
423         MapInfo_Map_flags = 0;
424         MapInfo_Map_clientstuff = "";
425         MapInfo_Map_fog = "";
426         MapInfo_Map_mins = '0 0 0';
427         MapInfo_Map_maxs = '0 0 0';
428 }
429
430 string _MapInfo_GetDefault(Gametype t)
431 {
432         return t.m_legacydefaults;
433 }
434
435 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
436 {
437         string sa;
438         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
439         if(!(pThisType.m_flags & pWantedType.m_flags))
440                 return;
441
442         if(load_default)
443                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
444
445         if(!pWantedType.frags) // these modes don't use fraglimit
446         {
447                 cvar_set("fraglimit", "0");
448         }
449         else
450         {
451                 sa = car(s);
452                 if(sa != "")
453                         cvar_set("fraglimit", sa);
454                 s = cdr(s);
455         }
456
457         sa = car(s);
458         if(sa != "")
459                 cvar_set("timelimit", sa);
460         s = cdr(s);
461
462         if(pWantedType.m_setTeams)
463         {
464                 sa = car(s);
465                 if(sa != "")
466                         pWantedType.m_setTeams(sa);
467                 s = cdr(s);
468         }
469
470         // rc = timelimit timelimit_qualification laps laps_teamplay
471         if(pWantedType == MAPINFO_TYPE_RACE)
472         {
473                 cvar_set("fraglimit", "0"); // special case!
474
475                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
476                 cvar_set("g_race_qualifying_timelimit", sa);
477                 s = cdr(s);
478
479                 sa = car(s);
480                 if(sa != "")
481                         if(cvar("g_race_teams") < 2)
482                                 cvar_set("fraglimit", sa);
483                 s = cdr(s);
484
485                 sa = car(s);
486                 if(sa != "")
487                         if(cvar("g_race_teams") >= 2)
488                                 cvar_set("fraglimit", sa);
489                 s = cdr(s);
490         }
491
492         if(!pWantedType.frags) // these modes don't use fraglimit
493         {
494                 cvar_set("leadlimit", "0");
495         }
496         else
497         {
498                 sa = car(s);
499                 if(sa != "")
500                         cvar_set("leadlimit", sa);
501                 s = cdr(s);
502         }
503 }
504
505 string _MapInfo_GetDefaultEx(Gametype t)
506 {
507         return t ? t.model2 : "";
508 }
509
510 float _MapInfo_GetTeamPlayBool(Gametype t)
511 {
512         return t ? t.team : false;
513 }
514
515 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
516 {
517         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
518         if (!(pThisType.m_flags & pWantedType.m_flags))
519                 return;
520
521         // reset all the cvars to their defaults
522
523         cvar_set("timelimit", cvar_defstring("timelimit"));
524         cvar_set("leadlimit", cvar_defstring("leadlimit"));
525         cvar_set("fraglimit", cvar_defstring("fraglimit"));
526         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
527
528         string fraglimit_normal = string_null;
529         string fraglimit_teams = string_null;
530
531         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
532                 string sa = car(s);
533                 if (sa == "") continue;
534                 int p = strstrofs(sa, "=", 0);
535                 if (p < 0) {
536                         if(WARN_COND)
537                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
538                         continue;
539                 }
540                 string k = substring(sa, 0, p);
541                 string v = substring(sa, p + 1, -1);
542                 bool handled = true;
543                 switch (k) {
544                         case "timelimit":
545                         {
546                                 cvar_set("timelimit", v);
547                                 break;
548                         }
549                         case "leadlimit":
550                         {
551                                 cvar_set("leadlimit", v);
552                                 break;
553                         }
554                         case "pointlimit":
555                         case "fraglimit":
556                         case "lives":
557                         case "laplimit":
558                         case "caplimit":
559                         {
560                                 fraglimit_normal = v;
561                                 break;
562                         }
563                         case "teampointlimit":
564                         case "teamlaplimit":
565                         {
566                                 fraglimit_teams = v;
567                                 break;
568                         }
569                         default:
570                         {
571                             handled = false;
572                             break;
573                         }
574                 }
575                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
576                 if (!handled && WARN_COND)
577             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
578         }
579
580         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
581         {
582                 if(fraglimit_teams)
583                         cvar_set("fraglimit", fraglimit_teams);
584         }
585         else
586         {
587                 if(fraglimit_normal)
588                         cvar_set("fraglimit", fraglimit_normal);
589         }
590 }
591
592 Gametype MapInfo_Type_FromString(string gtype)
593 {
594         string replacement = "";
595         switch (gtype)
596         {
597                 case "nexball":   replacement = "nb"; break;
598                 case "freezetag": replacement = "ft"; break;
599                 case "keepaway":  replacement = "ka"; break;
600                 case "invasion":  replacement = "inv"; break;
601                 case "assault":   replacement = "as"; break;
602                 case "race":      replacement = "rc"; break;
603         }
604         if (replacement != "" && WARN_COND)
605         {
606                 LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, gtype, replacement);
607                 gtype = replacement;
608         }
609         FOREACH(Gametypes, it.mdl == gtype, return it);
610         return NULL;
611 }
612
613 string MapInfo_Type_Description(Gametype t)
614 {
615         return t ? t.gametype_description : "";
616 }
617
618 string MapInfo_Type_ToString(Gametype t)
619 {
620         return t ? t.mdl : "";
621 }
622
623 string MapInfo_Type_ToText(Gametype t)
624 {
625         /* xgettext:no-c-format */
626         return t ? t.message : _("@!#%'n Tuba Throwing");
627 }
628
629 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
630 {
631         string t;
632         float fh, o;
633         t = car(s); s = cdr(s);
634
635         // limited support of "" and comments
636         //   remove trailing and leading " of t
637         if(substring(t, 0, 1) == "\"")
638         {
639                 if(substring(t, -1, 1) == "\"")
640                         t = substring(t, 1, -2);
641         }
642
643         //   remove leading " of s
644         if(substring(s, 0, 1) == "\"")
645         {
646                 s = substring(s, 1, -1);
647         }
648         //   remove trailing " of s, and all that follows (cvar description)
649         o = strstrofs(s, "\"", 0);
650         if(o >= 0)
651                 s = substring(s, 0, o);
652
653         //   remove // comments
654         o = strstrofs(s, "//", 0);
655         if(o >= 0)
656                 s = substring(s, 0, o);
657
658         //   remove trailing spaces
659         while(substring(s, -1, 1) == " ")
660                 s = substring(s, 0, -2);
661
662         if(t == "#include")
663         {
664                 if(recurse > 0)
665                 {
666                         fh = fopen(s, FILE_READ);
667                         if(fh < 0)
668                         {
669                                 if(WARN_COND)
670                                         LOG_WARN("Map ", pFilename, " references not existing config file ", s);
671                         }
672                         else
673                         {
674                                 for (;;)
675                                 {
676                                         if (!((s = fgets(fh))))
677                                                 break;
678
679                                         // catch different sorts of comments
680                                         if(s == "")                    // empty lines
681                                                 continue;
682                                         if(substring(s, 0, 1) == "#")  // UNIX style
683                                                 continue;
684                                         if(substring(s, 0, 2) == "//") // C++ style
685                                                 continue;
686                                         if(substring(s, 0, 1) == "_")  // q3map style
687                                                 continue;
688
689                                         if(substring(s, 0, 4) == "set ")
690                                                 s = substring(s, 4, -1);
691                                         if(substring(s, 0, 5) == "seta ")
692                                                 s = substring(s, 5, -1);
693
694                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
695                                 }
696                                 fclose(fh);
697                         }
698                 }
699                 else if(WARN_COND)
700                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
701         }
702         else if(t == ""
703                 || !cvar_value_issafe(t)
704                 || !cvar_value_issafe(s)
705                 || matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
706         {
707                 if (WARN_COND)
708                         LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
709         }
710         else if(matchacl(acl, t) <= 0)
711         {
712                 if (WARN_COND)
713                         LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
714         }
715         else
716         {
717                 if(type == 0) // server set
718                 {
719                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
720                 #if 0
721                         if(cvar("g_campaign"))
722                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
723                         else
724                 #endif
725                                 cvar_settemp(t, s);
726                 }
727                 else
728                 {
729                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
730                         MapInfo_Map_clientstuff = strcat(
731                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
732                                         );
733                 }
734         }
735 }
736
737 float MapInfo_isRedundant(string fn, string t)
738 {
739         // normalize file name
740         fn = strreplace("_", "", fn);
741         fn = strreplace("-", "", fn);
742
743         // normalize visible title
744         t = strreplace(":", "", t);
745         t = strreplace(" ", "", t);
746         t = strreplace("_", "", t);
747         t = strreplace("-", "", t);
748         t = strreplace("'", "", t);
749         t = strdecolorize(t);
750
751         // we allow the visible title to have punctuation the file name does
752         // not, but not vice versa
753         if(!strcasecmp(fn, t))
754                 return true;
755
756         return false;
757 }
758
759 // load info about a map by name into the MapInfo_Map_* globals
760 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
761 {
762         string fn;
763         string s, t;
764         float fh;
765         int f, i;
766         float r, n, p;
767         string acl;
768
769         acl = MAPINFO_SETTEMP_ACL_USER;
770
771         if(strstrofs(pFilename, "/", 0) >= 0)
772         {
773                 LOG_WARN("Invalid character in map name, ignored");
774                 return 0;
775         }
776
777         if(pGametypeToSet == NULL)
778                 if(MapInfo_Cache_Retrieve(pFilename))
779                         return 1;
780
781         r = 1;
782
783         MapInfo_Map_bspname = pFilename;
784
785         // default all generic fields so they have "good" values in case something fails
786         fn = strcat("maps/", pFilename, ".mapinfo");
787         fh = fopen(fn, FILE_READ);
788         if(fh < 0)
789         {
790                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
791                 fh = fopen(fn, FILE_READ);
792                 if(fh < 0)
793                 {
794                         if(!pAllowGenerate)
795                                 return 0;
796                         _MapInfo_Map_Reset();
797                         r = _MapInfo_Generate(pFilename);
798                         if(!r)
799                                 return 0;
800                         fh = fopen(fn, FILE_WRITE);
801                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
802                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
803                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
804                         if(_MapInfo_Map_worldspawn_music != "")
805                         {
806                                 if(
807                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
808                                         ||
809                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
810                                 )
811                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
812                                 else
813                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
814                         }
815                         else
816                         {
817                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
818                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
819                                 for (;;)
820                                 {
821                                         i = floor(random() * n);
822                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
823                                                 break;
824                                 }
825                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
826                         }
827                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
828                                 fputs(fh, "has weapons\n");
829                         else
830                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
831                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
832                                 fputs(fh, "has turrets\n");
833                         else
834                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
835                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
836                                 fputs(fh, "has vehicles\n");
837                         else
838                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
839                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
840                                 fputs(fh, "frustrating\n");
841
842                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
843                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
844                         });
845
846                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
847                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
848                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
849                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
850                         fputs(fh, "// optional: hidden\n");
851
852                         fclose(fh);
853                         r = 2;
854                         // return r;
855                         fh = fopen(fn, FILE_READ);
856                         if(fh < 0)
857                                 error("... but I just wrote it!");
858                 }
859
860                 if(WARN_COND)
861                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
862         }
863
864         _MapInfo_Map_Reset();
865         for (;;)
866         {
867                 if (!((s = fgets(fh))))
868                         break;
869
870                 // catch different sorts of comments
871                 if(s == "")                    // empty lines
872                         continue;
873                 if(substring(s, 0, 1) == "#")  // UNIX style
874                         continue;
875                 if(substring(s, 0, 2) == "//") // C++ style
876                         continue;
877                 if(substring(s, 0, 1) == "_")  // q3map style
878                         continue;
879
880                 p = strstrofs(s, "//", 0);
881                 if(p >= 0)
882                         s = substring(s, 0, p);
883
884                 t = car(s); s = cdr(s);
885                 if(t == "title")
886                         MapInfo_Map_title = s;
887                 else if(t == "description")
888                         MapInfo_Map_description = s;
889                 else if(t == "author")
890                         MapInfo_Map_author = s;
891                 else if(t == "has")
892                 {
893                         t = car(s); // s = cdr(s);
894                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
895                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
896                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
897                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
898                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
899                         else if(WARN_COND)
900                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
901                 }
902                 else if(t == "hidden")
903                 {
904                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
905                 }
906                 else if(t == "forbidden")
907                 {
908                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
909                 }
910                 else if(t == "frustrating")
911                 {
912                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
913                 }
914                 else if(t == "noautomaplist")
915                 {
916                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
917                 }
918                 else if(t == "gameversion_min")
919                 {
920                         if (cvar("gameversion") < stof(s))
921                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
922                 }
923                 else if(t == "type")
924                 {
925                         t = car(s); s = cdr(s);
926                         Gametype f = MapInfo_Type_FromString(t);
927                         //if(WARN_COND)
928                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
929                         if(f)
930                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
931                         else if(WARN_COND)
932                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
933                 }
934                 else if(t == "gametype")
935                 {
936                         t = car(s); s = cdr(s);
937                         Gametype f = MapInfo_Type_FromString(t);
938                         if(f)
939                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
940                         else if(WARN_COND)
941                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
942                 }
943                 else if(t == "size")
944                 {
945                         float a, b, c, d, e;
946                         t = car(s); s = cdr(s); a = stof(t);
947                         t = car(s); s = cdr(s); b = stof(t);
948                         t = car(s); s = cdr(s); c = stof(t);
949                         t = car(s); s = cdr(s); d = stof(t);
950                         t = car(s); s = cdr(s); e = stof(t);
951                         if(s == "")
952                         {
953                                 if(WARN_COND)
954                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
955                         }
956                         else
957                         {
958                                 t = car(s); s = cdr(s); f = stof(t);
959                                 if(s != "")
960                                 {
961                                         if(WARN_COND)
962                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
963                                 }
964                                 else
965                                 {
966                                         if(a >= d || b >= e || c >= f)
967                                         {
968                                                 if(WARN_COND)
969                                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
970                                         }
971                                         else
972                                         {
973                                                 MapInfo_Map_mins.x = a;
974                                                 MapInfo_Map_mins.y = b;
975                                                 MapInfo_Map_mins.z = c;
976                                                 MapInfo_Map_maxs.x = d;
977                                                 MapInfo_Map_maxs.y = e;
978                                                 MapInfo_Map_maxs.z = f;
979                                         }
980                                 }
981                         }
982                 }
983                 else if(t == "settemp_for_type")
984                 {
985                         t = car(s); s = cdr(s);
986                         bool all = t == "all";
987                         Gametype f = NULL;
988                         if(all || (f = MapInfo_Type_FromString(t)))
989                         {
990                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
991                                 {
992                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
993                                 }
994                         }
995                         else
996                         {
997                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
998                         }
999                 }
1000                 else if(t == "clientsettemp_for_type")
1001                 {
1002                         t = car(s); s = cdr(s);
1003                         bool all = t == "all";
1004                         Gametype f = NULL;
1005                         if(all || (f = MapInfo_Type_FromString(t)))
1006                         {
1007                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1008                                 {
1009                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1010                                 }
1011                         }
1012                         else
1013                         {
1014                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1015                         }
1016                 }
1017                 else if(t == "fog")
1018                 {
1019                         if (!cvar_value_issafe(s))
1020                         {
1021                                 if(WARN_COND)
1022                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1023                         }
1024                         else
1025                                 MapInfo_Map_fog = s;
1026                 }
1027                 else if(t == "cdtrack")
1028                 {
1029                         t = car(s); s = cdr(s);
1030                         // We do this only if pGametypeToSet even though this
1031                         // content is theoretically game type independent,
1032                         // because MapInfo_Map_clientstuff contains otherwise
1033                         // game type dependent stuff. That way this value stays
1034                         // empty when not setting a game type to not set any
1035                         // false expectations.
1036                         if(pGametypeToSet)
1037                         {
1038                                 if (!cvar_value_issafe(t))
1039                                 {
1040                                         if(WARN_COND)
1041                                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1042                                 }
1043                                 else
1044                                         MapInfo_Map_clientstuff = strcat(
1045                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1046                                         );
1047                         }
1048                 }
1049                 else if(WARN_COND)
1050                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1051         }
1052         fclose(fh);
1053
1054         if(MapInfo_Map_title == "<TITLE>")
1055                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1056         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1057                 MapInfo_Map_titlestring = MapInfo_Map_title;
1058         else
1059                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1060
1061         MapInfo_Cache_Store();
1062         if(MapInfo_Map_supportedGametypes != 0)
1063                 return r;
1064         if (WARN_COND)
1065                 LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1066         return 0;
1067 }
1068 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1069 {
1070         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1071
1072         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1073
1074         if(pGametypeToSet)
1075         {
1076                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1077                 {
1078                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1079                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1080                         //return;
1081                 }
1082         }
1083
1084         return r;
1085 }
1086
1087 float MapInfo_FindName(string s)
1088 {
1089         // if there is exactly one map of prefix s, return it
1090         // if not, return the null string
1091         // note that DP sorts glob results... so I can use a binary search
1092         float l, r, m, cmp;
1093         l = 0;
1094         r = MapInfo_count;
1095         // invariants: r is behind s, l-1 is equal or before
1096         while(l != r)
1097         {
1098                 m = floor((l + r) / 2);
1099                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1100                 cmp = strcasecmp(MapInfo_FindName_match, s);
1101                 if(cmp == 0)
1102                         return m; // found and good
1103                 if(cmp < 0)
1104                         l = m + 1; // l-1 is before s
1105                 else
1106                         r = m; // behind s
1107         }
1108         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1109         MapInfo_FindName_firstResult = l;
1110         // r == l, so: l is behind s, l-1 is before
1111         // SO: if there is any, l is the one with the right prefix
1112         //     and l+1 may be one too
1113         if(l == MapInfo_count)
1114         {
1115                 MapInfo_FindName_match = string_null;
1116                 MapInfo_FindName_firstResult = -1;
1117                 return -1; // no MapInfo_FindName_match, behind last item
1118         }
1119         if(!startsWithNocase(MapInfo_FindName_match, s))
1120         {
1121                 MapInfo_FindName_match = string_null;
1122                 MapInfo_FindName_firstResult = -1;
1123                 return -1; // wrong prefix
1124         }
1125         if(l == MapInfo_count - 1)
1126                 return l; // last one, nothing can follow => unique
1127         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1128         {
1129                 MapInfo_FindName_match = string_null;
1130                 return -1; // ambigous MapInfo_FindName_match
1131         }
1132         return l;
1133 }
1134
1135 string MapInfo_FixName(string s)
1136 {
1137         MapInfo_FindName(s);
1138         return MapInfo_FindName_match;
1139 }
1140
1141 int MapInfo_CurrentFeatures()
1142 {
1143         int req = 0;
1144     // TODO: find a better way to check if weapons are required on the map
1145         if(!(cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") 
1146                 || cvar("g_race") || cvar("g_cts") || cvar("g_nexball") || cvar("g_ca") || cvar("g_freezetag") || cvar("g_lms")))
1147                 req |= MAPINFO_FEATURE_WEAPONS;
1148         return req;
1149 }
1150
1151 Gametype MapInfo_CurrentGametype()
1152 {
1153         Gametype prev = Gametypes_from(cvar("gamecfg"));
1154         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1155         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1156 }
1157
1158 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1159 {
1160         if(!MapInfo_Get_ByName(s, 1, NULL))
1161                 return 0;
1162         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1163                 return 0;
1164         if (gametype_only)
1165                 return 1;
1166         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1167                 return 0;
1168         return 1;
1169 }
1170
1171 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1172 {
1173         float r;
1174         r = _MapInfo_CheckMap(s, false);
1175         MapInfo_ClearTemps();
1176         return r;
1177 }
1178
1179 void MapInfo_SwitchGameType(Gametype t)
1180 {
1181         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1182 }
1183
1184 void MapInfo_LoadMap(string s, float reinit)
1185 {
1186         MapInfo_Map_supportedGametypes = 0;
1187         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1188         //if(!MapInfo_CheckMap(s))
1189         //{
1190         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1191         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1192         //}
1193
1194         LOG_INFO("Switching to map ", s);
1195
1196         cvar_settemp_restore();
1197         if(reinit)
1198                 localcmd(strcat("\nmap ", s, "\n"));
1199         else
1200                 localcmd(strcat("\nchangelevel ", s, "\n"));
1201 }
1202
1203 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1204 {
1205         string out;
1206
1207         // to make absolutely sure:
1208         MapInfo_Enumerate();
1209         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1210
1211         out = "";
1212         for(float i = 0; i < MapInfo_count; ++i)
1213                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1214         return substring(out, 1, strlen(out) - 1);
1215 }
1216
1217 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1218 {
1219         string out;
1220
1221         // to make absolutely sure:
1222         MapInfo_Enumerate();
1223         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1224
1225         out = "";
1226         for(float i = 0; i < MapInfo_count; ++i)
1227                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1228
1229         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1230
1231         return substring(out, 1, strlen(out) - 1);
1232 }
1233
1234 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1235 {
1236         MapInfo_SwitchGameType(t);
1237         cvar_set("gamecfg", ftos(t.m_id));
1238         MapInfo_LoadedGametype = t;
1239 }
1240
1241 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1242 {
1243         Gametype t = MapInfo_CurrentGametype();
1244         MapInfo_LoadMapSettings_SaveGameType(t);
1245
1246         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1247         {
1248                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1249                 {
1250                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1251                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1252                         return; // do not call Get_ByName!
1253                 }
1254
1255                 if(MapInfo_Map_supportedGametypes == 0)
1256                 {
1257                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.");
1258                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH.m_flags;
1259                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1260                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1261                         return; // do not call Get_ByName!
1262                 }
1263
1264                 int _t = 1;
1265                 while(!(MapInfo_Map_supportedGametypes & 1))
1266                 {
1267                         _t <<= 1;
1268                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1269                 }
1270                 Gametype t_prev = t;
1271                 FOREACH(Gametypes, it.m_flags == _t, { t = it; break; });
1272
1273                 // t is now a supported mode!
1274                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1275                 MapInfo_LoadMapSettings_SaveGameType(t);
1276         }
1277         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1278                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1279         }
1280         MapInfo_Get_ByName(s, 1, t);
1281 }
1282
1283 void MapInfo_ClearTemps()
1284 {
1285         MapInfo_Map_bspname = string_null;
1286         MapInfo_Map_title = string_null;
1287         MapInfo_Map_titlestring = string_null;
1288         MapInfo_Map_description = string_null;
1289         MapInfo_Map_author = string_null;
1290         MapInfo_Map_clientstuff = string_null;
1291         MapInfo_Map_supportedGametypes = 0;
1292         MapInfo_Map_supportedFeatures = 0;
1293 }
1294
1295 void MapInfo_Shutdown()
1296 {
1297         MapInfo_ClearTemps();
1298         MapInfo_Filter_Free();
1299         MapInfo_Cache_Destroy();
1300         if(_MapInfo_globopen)
1301         {
1302                 search_end(_MapInfo_globhandle);
1303                 _MapInfo_globhandle = -1;
1304                 _MapInfo_globopen = false;
1305         }
1306 }
1307
1308 int MapInfo_ForbiddenFlags()
1309 {
1310         int f = MAPINFO_FLAG_FORBIDDEN;
1311
1312 #ifdef GAMEQC
1313         if (!cvar("g_maplist_allow_hidden"))
1314 #endif
1315                 f |= MAPINFO_FLAG_HIDDEN;
1316
1317         if (!cvar("g_maplist_allow_frustrating"))
1318                 f |= MAPINFO_FLAG_FRUSTRATING;
1319
1320         return f;
1321 }
1322
1323 int MapInfo_RequiredFlags()
1324 {
1325         int f = 0;
1326
1327         if(cvar("g_maplist_allow_frustrating") > 1)
1328                 f |= MAPINFO_FLAG_FRUSTRATING;
1329
1330         return f;
1331 }