fix starting the gametype
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mapinfo.qc
1 // generic string stuff
2
3 float _MapInfo_Cache_Active;
4 float _MapInfo_Cache_DB_NameToIndex;
5 float _MapInfo_Cache_Buf_IndexToMapData;
6
7 void MapInfo_Cache_Destroy()
8 {
9         if(!_MapInfo_Cache_Active)
10                 return;
11
12         db_close(_MapInfo_Cache_DB_NameToIndex);
13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
14         _MapInfo_Cache_Active = 0;
15 }
16
17 void MapInfo_Cache_Create()
18 {
19         MapInfo_Cache_Destroy();
20         _MapInfo_Cache_DB_NameToIndex = db_create();
21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
22         _MapInfo_Cache_Active = 1;
23 }
24
25 void MapInfo_Cache_Invalidate()
26 {
27         if(!_MapInfo_Cache_Active)
28                 return;
29
30         MapInfo_Cache_Create();
31 }
32
33 void MapInfo_Cache_Store()
34 {
35         float i;
36         string s;
37         if(!_MapInfo_Cache_Active)
38                 return;
39
40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
41         if(!s) // empty string is NOT valid here!
42         {
43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
45         }
46         else
47                 i = stof(s);
48
49         // now store all the stuff
50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
57 }
58
59 float MapInfo_Cache_Retrieve(string map)
60 {
61         float i;
62         string s;
63         if(!_MapInfo_Cache_Active)
64                 return 0;
65
66         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
67         if(!s)
68                 return 0;
69         i = stof(s);
70
71         // now retrieve all the stuff
72         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
73         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
74         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
75         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
76         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
77         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
78         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
79         return 1;
80 }
81
82 // GLOB HANDLING (for all BSP files)
83 float _MapInfo_globopen;
84 float _MapInfo_globcount; 
85 float _MapInfo_globhandle;
86 string _MapInfo_GlobItem(float i)
87 {
88         string s;
89         s = search_getfilename(_MapInfo_globhandle, i);
90         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
91 }
92
93 void MapInfo_Enumerate()
94 {
95         if(_MapInfo_globopen)
96                 search_end(_MapInfo_globhandle);
97         MapInfo_Cache_Invalidate();
98         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
99         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
100         _MapInfo_globopen = 1;
101 }
102
103 // filter the info by game type mask (updates MapInfo_count)
104 //
105 float _MapInfo_filtered;
106 float _MapInfo_filtered_allocated;
107 float MapInfo_FilterList_Lookup(float i)
108 {
109         return stof(bufstr_get(_MapInfo_filtered, i));
110 }
111
112 void _MapInfo_FilterList_swap(float i, float j, entity pass)
113 {
114         string h;
115         h = bufstr_get(_MapInfo_filtered, i);
116         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
117         bufstr_set(_MapInfo_filtered, j, h);
118 }
119
120 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
121 {
122         string a, b;
123         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
124         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
125         return strcasecmp(a, b);
126 }
127
128 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
129 {
130         float i, j;
131         if not(_MapInfo_filtered_allocated)
132         {
133                 _MapInfo_filtered_allocated = 1;
134                 _MapInfo_filtered = buf_create();
135         }
136         MapInfo_count = 0;
137         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
138         {
139                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
140                         if(pAbortOnGenerate)
141                         {
142                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
143                                 MapInfo_progress = i / _MapInfo_globcount;
144                                 return 0;
145                         }
146                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
147                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
148                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
149                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
150                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
151         }
152         MapInfo_count = j + 1;
153         MapInfo_ClearTemps();
154         
155         // sometimes the glob isn't sorted nicely, so fix it here...
156         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
157
158         return 1;
159 }
160
161 void MapInfo_Filter_Free()
162 {
163         if(_MapInfo_filtered_allocated)
164         {
165                 buf_del(_MapInfo_filtered);
166                 _MapInfo_filtered_allocated = 0;
167         }
168 }
169
170 // load info about the i-th map into the MapInfo_Map_* globals
171 string MapInfo_BSPName_ByID(float i)
172 {
173         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
174 }
175
176 string unquote(string s)
177 {
178         float i, j, l;
179         l = strlen(s);
180         j = -1;
181         for(i = 0; i < l; ++i)
182         {
183                 string ch;
184                 ch = substring(s, i, 1);
185                 if(ch != " ") if(ch != "\"")
186                 {
187                         for(j = strlen(s) - i - 1; j > 0; --j)
188                         {
189                                 ch = substring(s, i+j, 1);
190                                 if(ch != " ") if(ch != "\"")
191                                         return substring(s, i, j+1);
192                         }
193                         return substring(s, i, 1);
194                 }
195         }
196         return "";
197 }
198
199 float MapInfo_Get_ByID(float i)
200 {
201         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
202                 return 1;
203         return 0;
204 }
205
206 string _MapInfo_Map_worldspawn_music;
207
208 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
209 {
210         string fn;
211         float fh;
212         string s, k, v;
213         vector o;
214         float i;
215         float inWorldspawn;
216         float r;
217         float twoBaseModes;
218         float diameter, spawnpoints;
219         float spawnplaces;
220
221         vector mapMins, mapMaxs;
222
223         r = 1;
224         fn = strcat("maps/", pFilename, ".ent");
225         fh = fopen(fn, FILE_READ);
226         if(fh < 0)
227         {
228                 r = 2;
229                 fn = strcat("maps/", pFilename, ".bsp");
230                 fh = fopen(fn, FILE_READ);
231         }
232         if(fh < 0)
233                 return 0;
234         print("Analyzing ", fn, " to generate initial mapinfo\n");
235
236         inWorldspawn = 2;
237         MapInfo_Map_flags = 0;
238         MapInfo_Map_supportedGametypes = 0;
239         spawnpoints = 0;
240         spawnplaces = 0;
241         _MapInfo_Map_worldspawn_music = "";
242
243         for(;;)
244         {
245                 if not((s = fgets(fh)))
246                         break;
247                 if(inWorldspawn == 1)
248                         if(startsWith(s, "}"))
249                                 inWorldspawn = 0;
250                 k = unquote(car(s));
251                 v = unquote(cdr(s));
252                 if(inWorldspawn)
253                 {
254                         if(k == "classname" && v == "worldspawn")
255                                 inWorldspawn = 1;
256                         else if(k == "author")
257                                 MapInfo_Map_author = v;
258                         else if(k == "_description")
259                                 MapInfo_Map_description = v;
260                         else if(k == "music")
261                                 _MapInfo_Map_worldspawn_music = v;
262                         else if(k == "noise")
263                                 _MapInfo_Map_worldspawn_music = v;
264                         else if(k == "message")
265                         {
266                                 i = strstrofs(v, " by ", 0);
267                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
268                                 {
269                                         MapInfo_Map_title = substring(v, 0, i);
270                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
271                                 }
272                                 else
273                                         MapInfo_Map_title = v;
274                         }
275                 }
276                 else
277                 {
278                         if(k == "origin")
279                         {
280                                 o = stov(strcat("'", v, "'"));
281                                 mapMins_x = min(mapMins_x, o_x);
282                                 mapMins_y = min(mapMins_y, o_y);
283                                 mapMins_z = min(mapMins_z, o_z);
284                                 mapMaxs_x = max(mapMaxs_x, o_x);
285                                 mapMaxs_y = max(mapMaxs_y, o_y);
286                                 mapMaxs_z = max(mapMaxs_z, o_z);
287                         }
288                         else if(k == "race_place")
289                         {
290                                 if(stof(v) > 0)
291                                         spawnplaces = 1;
292                         }
293                         else if(k == "classname")
294                         {
295                                 if(v == "dom_controlpoint")
296                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
297                                 else if(v == "item_flag_team2")
298                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
299                                 else if(v == "team_CTF_blueflag")
300                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
301                                 else if(v == "runematch_spawn_point")
302                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
303                                 else if(v == "target_assault_roundend")
304                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
305                                 else if(v == "onslaught_generator")
306                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
307                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
308                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
309                                 else if(v == "info_player_team1")
310                                         ++spawnpoints;
311                                 else if(v == "info_player_team2")
312                                         ++spawnpoints;
313                                 else if(v == "info_player_start")
314                                         ++spawnpoints;
315                                 else if(v == "info_player_deathmatch")
316                                         ++spawnpoints;
317                                 else if(v == "trigger_race_checkpoint")
318                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
319                                 else if(v == "target_startTimer")
320                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
321                                 else if(v == "weapon_nex")
322                                         { }
323                                 else if(v == "weapon_railgun")
324                                         { }
325                                 else if(startsWith(v, "weapon_"))
326                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
327                                 else if(v == "target_music" || v == "trigger_music")
328                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
329                         }
330                 }
331         }
332         if(inWorldspawn)
333         {
334                 print(fn, " ended still in worldspawn, BUG\n");
335                 return 0;
336         }
337         diameter = vlen(mapMaxs - mapMins);
338
339         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
340         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
341         {
342                 // we have a CTF-only or Assault-only map. Don't add other modes then,
343                 // as the map is too symmetric for them.
344         }
345         else
346         {
347                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
348                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
349                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
350
351                 if(spawnpoints >= 8  && diameter > 4096) {
352                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
353                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
354                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
355                 }
356                 if(                     diameter < 4096)
357                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
358                 if(spawnpoints >= 12 && diameter > 5120)
359                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
360         }
361
362         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
363         if(!spawnplaces)
364         {
365                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
366                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
367         }
368
369         dprint("-> diameter ",    ftos(diameter));
370         dprint(";  spawnpoints ", ftos(spawnpoints));
371         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
372
373         fclose(fh);
374
375         return r;
376 }
377
378 void _MapInfo_Map_Reset()
379 {
380         MapInfo_Map_title = "<TITLE>";
381         MapInfo_Map_description = "<DESCRIPTION>";
382         MapInfo_Map_author = "<AUTHOR>";
383         MapInfo_Map_supportedGametypes = 0;
384         MapInfo_Map_supportedFeatures = 0;
385         MapInfo_Map_flags = 0;
386         MapInfo_Map_clientstuff = "";
387         MapInfo_Map_fog = "";
388         MapInfo_Map_mins = '0 0 0';
389         MapInfo_Map_maxs = '0 0 0';
390 }
391
392 string _MapInfo_GetDefault(float t)
393 {
394         switch(t)
395         {
396                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
397                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
398                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
399                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
400                 case MAPINFO_TYPE_RUNEMATCH:       return "200 20 0";
401                 case MAPINFO_TYPE_LMS:             return "9 20 0";
402                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
403                 case MAPINFO_TYPE_CA:              return "10 20 0";
404                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
405                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
406                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
407                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
408                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
409                 case MAPINFO_TYPE_CTS:             return "20 0 0";
410                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
411                 default:                           return "";
412         }
413 }
414
415 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
416 {
417         string sa;
418         MapInfo_Map_supportedGametypes |= pThisType;
419         if(!(pThisType & pWantedType))
420                 return;
421
422         if(load_default)
423                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
424         
425         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
426         {
427                 cvar_set("fraglimit", "0");
428         }
429         else
430         {
431                 sa = car(s);
432                 if(sa != "")
433                         cvar_set("fraglimit", sa);
434                 s = cdr(s);
435         }
436
437         sa = car(s);
438         if(sa != "")
439                 cvar_set("timelimit", sa);
440         s = cdr(s);
441
442         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
443         {
444                 sa = car(s);
445                 if(sa != "")
446                         cvar_set("g_tdm_teams", sa);
447                 s = cdr(s);
448         }
449
450         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
451         {
452                 sa = car(s);
453                 if(sa != "")
454                         cvar_set("g_keyhunt_teams", sa);
455                 s = cdr(s);
456         }
457
458         if(pWantedType == MAPINFO_TYPE_CTF)
459         {
460                 sa = car(s);
461                 if(sa != "")
462                         if(cvar("g_ctf_win_mode") < 2)
463                                 cvar_set("fraglimit", sa);
464                 s = cdr(s);
465         }
466
467         // rc = timelimit timelimit_qualification laps laps_teamplay
468         if(pWantedType == MAPINFO_TYPE_RACE)
469         {
470                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
471                 cvar_set("g_race_qualifying_timelimit", sa);
472                 s = cdr(s);
473
474                 sa = car(s);
475                 if(sa != "")
476                         if(cvar("g_race_teams") < 2)
477                                 cvar_set("fraglimit", sa);
478                 s = cdr(s);
479
480                 sa = car(s);
481                 if(sa != "")
482                         if(cvar("g_race_teams") >= 2)
483                                 cvar_set("fraglimit", sa);
484                 s = cdr(s);
485         }
486
487         if(pWantedType == MAPINFO_TYPE_CTS)
488         {
489                 sa = car(s);
490
491                 // this is the skill of the map
492                 // not parsed by anything yet
493                 // for map databases
494                 //if(sa != "")
495                 //      cvar_set("fraglimit", sa);
496
497                 s = cdr(s);
498         }
499
500         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
501         {
502                 cvar_set("leadlimit", "0");
503         }
504         else
505         {
506                 sa = car(s);
507                 if(sa != "")
508                         cvar_set("leadlimit", sa);
509                 s = cdr(s);
510         }
511 }
512
513 string _MapInfo_GetDefaultEx(float t)
514 {
515         switch(t)
516         {
517                 case MAPINFO_TYPE_DEATHMATCH:      return "timelimit=20 pointlimit=30 leadlimit=0";
518                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "timelimit=20 pointlimit=50 teams=2 leadlimit=0";
519                 case MAPINFO_TYPE_DOMINATION:      return "timelimit=20 pointlimit=200 teams=2 leadlimit=0";
520                 case MAPINFO_TYPE_CTF:             return "timelimit=20 pointlimit=300 caplimit=10 leadlimit=0";
521                 case MAPINFO_TYPE_RUNEMATCH:       return "timelimit=20 pointlimit=200 leadlimit=0";
522                 case MAPINFO_TYPE_LMS:             return "timelimit=20 lives=9 leadlimit=0";
523                 case MAPINFO_TYPE_ARENA:           return "timelimit=20 pointlimit=10 leadlimit=0";
524                 case MAPINFO_TYPE_CA:              return "timelimit=20 pointlimit=10 leadlimit=0";
525                 case MAPINFO_TYPE_KEYHUNT:         return "timelimit=20 pointlimit=1000 teams=3 leadlimit=0";
526                 case MAPINFO_TYPE_ASSAULT:         return "timelimit=20";
527                 case MAPINFO_TYPE_RACE:            return "timelimit=20 qualifying_timelimit=5 laplimit=7 teamlaplimit=15 leadlimit=0";
528                 case MAPINFO_TYPE_ONSLAUGHT:       return "timelimit=20";
529                 case MAPINFO_TYPE_NEXBALL:         return "timelimit=20 pointlimit=5 leadlimit=0";
530                 case MAPINFO_TYPE_CTS:             return "timelimit=20 skill=-1";
531                 case MAPINFO_TYPE_FREEZETAG:       return "timelimit=20 pointlimit=10 teams=2 leadlimit=0";
532                 default:                           return "";
533         }
534 }
535
536 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
537 {
538         string sa, k, v;
539         float p;
540         string fraglimit_normal;
541         string fraglimit_caps;
542         string fraglimit_teams;
543
544         MapInfo_Map_supportedGametypes |= pThisType;
545         if(!(pThisType & pWantedType))
546                 return;
547
548         // reset all the cvars to their defaults
549
550         cvar_set("timelimit", cvar_defstring("timelimit"));
551         cvar_set("leadlimit", cvar_defstring("leadlimit"));
552         cvar_set("fraglimit", cvar_defstring("fraglimit"));
553         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
554         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
555         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
556         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
557
558         fraglimit_normal = string_null;
559         fraglimit_caps = string_null;
560         fraglimit_teams = string_null;
561
562         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
563         while(s != "")
564         {
565                 sa = car(s);
566                 s = cdr(s);
567
568                 if(sa == "")
569                         continue;
570
571                 p = strstrofs(sa, "=", 0);
572                 if(p < 0)
573                 {
574                         k = "timelimit";
575                         v = s;
576                 }
577                 else
578                 {
579                         k = substring(sa, 0, p);
580                         v = substring(sa, p+1, -1);
581                 }
582
583                 if(k == "timelimit")
584                 {
585                         cvar_set("timelimit", v);
586                 }
587                 else if(k == "leadlimit")
588                 {
589                         cvar_set("leadlimit", v);
590                 }
591                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit")
592                 {
593                         fraglimit_normal = v;
594                 }
595                 else if(k == "caplimit")
596                 {
597                         fraglimit_caps = v;
598                 }
599                 else if(k == "teampointlimit" || k == "teamlaplimit")
600                 {
601                         fraglimit_teams = v;
602                 }
603                 else if(k == "teams")
604                 {
605                         cvar_set("g_tdm_teams", v);
606                         cvar_set("g_keyhunt_teams", v);
607                         cvar_set("g_domination_default_teams", v);
608                 }
609                 else if(k == "qualifying_timelimit")
610                 {
611                         cvar_set("g_race_qualifying_timelimit", v);
612                 }
613                 else if(k == "skill")
614                 {
615                         // ignore
616                 }
617                 else
618                 {
619                         print("Invalid gametype key in mapinfo: ", k, "\n");
620                 }
621         }
622
623         if(pWantedType == MAPINFO_TYPE_CTF && cvar("g_ctf_win_mode") < 2)
624         {
625                 if(fraglimit_caps)
626                         cvar_set("fraglimit", fraglimit_caps);
627         }
628         else if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
629         {
630                 if(fraglimit_teams)
631                         cvar_set("fraglimit", fraglimit_teams);
632         }
633         else
634         {
635                 if(fraglimit_normal)
636                         cvar_set("fraglimit", fraglimit_normal);
637         }
638 }
639
640 float MapInfo_Type_FromString(string t)
641 {
642         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
643         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
644         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
645         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
646         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
647         else if(t == "lms")     return MAPINFO_TYPE_LMS;
648         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
649         else if(t == "ca")      return MAPINFO_TYPE_CA;
650         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
651         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
652         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
653         else if(t == "rc")      return MAPINFO_TYPE_RACE;
654         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
655         else if(t == "cts")     return MAPINFO_TYPE_CTS;
656         else if(t == "freezetag")       return MAPINFO_TYPE_FREEZETAG;
657         else if(t == "all")     return MAPINFO_TYPE_ALL;
658         else                    return 0;
659 }
660
661 string MapInfo_Type_ToString(float t)
662 {
663         if     (t == MAPINFO_TYPE_DEATHMATCH)      return "dm";
664         else if(t == MAPINFO_TYPE_TEAM_DEATHMATCH) return "tdm";
665         else if(t == MAPINFO_TYPE_DOMINATION)      return "dom";
666         else if(t == MAPINFO_TYPE_CTF)             return "ctf";
667         else if(t == MAPINFO_TYPE_RUNEMATCH)       return "rune";
668         else if(t == MAPINFO_TYPE_LMS)             return "lms";
669         else if(t == MAPINFO_TYPE_ARENA)           return "arena";
670         else if(t == MAPINFO_TYPE_CA)              return "ca";
671         else if(t == MAPINFO_TYPE_KEYHUNT)         return "kh";
672         else if(t == MAPINFO_TYPE_ASSAULT)         return "as";
673         else if(t == MAPINFO_TYPE_ONSLAUGHT)       return "ons";
674         else if(t == MAPINFO_TYPE_RACE)            return "rc";
675         else if(t == MAPINFO_TYPE_NEXBALL)         return "nexball";
676         else if(t == MAPINFO_TYPE_CTS)             return "cts";
677         else if(t == MAPINFO_TYPE_FREEZETAG)       return "freezetag";
678         else if(t == MAPINFO_TYPE_ALL)             return "all";
679         else                                       return "";
680 }
681
682 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
683 {
684         string t;
685         float fh, o;
686         t = car(s); s = cdr(s);
687
688         // limited support of "" and comments
689         //   remove trailing and leading " of t
690         if(substring(t, 0, 1) == "\"")
691         {
692                 if(substring(t, -1, 1) == "\"")
693                         t = substring(t, 1, -2);
694         }
695
696         //   remove leading " of s
697         if(substring(s, 0, 1) == "\"")
698         {
699                 s = substring(s, 1, -1);
700         }
701         //   remove trailing " of s, and all that follows (cvar description)
702         o = strstrofs(s, "\"", 0);
703         if(o >= 0)
704                 s = substring(s, 0, o);
705         
706         //   remove // comments
707         o = strstrofs(s, "//", 0);
708         if(o >= 0)
709                 s = substring(s, 0, o);
710         
711         //   remove trailing spaces
712         while(substring(s, -1, 1) == " ")
713                 s = substring(s, 0, -2);
714
715         if(t == "#include")
716         {
717                 if(recurse > 0)
718                 {
719                         fh = fopen(s, FILE_READ);
720                         if(fh < 0)
721                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
722                         else
723                         {
724                                 for(;;)
725                                 {
726                                         if not((s = fgets(fh)))
727                                                 break;
728
729                                         // catch different sorts of comments
730                                         if(s == "")                    // empty lines
731                                                 continue;
732                                         if(substring(s, 0, 1) == "#")  // UNIX style
733                                                 continue;
734                                         if(substring(s, 0, 2) == "//") // C++ style
735                                                 continue;
736                                         if(substring(s, 0, 1) == "_")  // q3map style
737                                                 continue;
738
739                                         if(substring(s, 0, 4) == "set ")
740                                                 s = substring(s, 4, -1);
741                                         if(substring(s, 0, 5) == "seta ")
742                                                 s = substring(s, 5, -1);
743
744                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
745                                 }
746                                 fclose(fh);
747                         }
748                 }
749                 else
750                         print("Map ", pFilename, " uses too many levels of inclusion\n");
751         }
752         else if(t == "")
753                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
754         else if not(cvar_value_issafe(t))
755                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
756         else if not (cvar_value_issafe(s))
757                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
758         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
759                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
760         else if(matchacl(acl, t) <= 0)
761                 print("Map ", pFilename, " contains a denied setting, ignored\n");
762         else
763         {
764                 if(type == 0) // server set
765                 {
766                         dprint("Applying temporary setting ", t, " := ", s, "\n");
767                         if(cvar("g_campaign"))
768                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
769                         else
770                                 cvar_settemp(t, s);
771                 }
772                 else
773                 {
774                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
775                         MapInfo_Map_clientstuff = strcat(
776                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
777                                         );
778                 }
779         }
780 }
781
782 // load info about a map by name into the MapInfo_Map_* globals
783 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
784 {
785         string fn;
786         string s, t;
787         float fh, fh2;
788         float r, f, n, i, p;
789         string acl;
790
791         acl = MAPINFO_SETTEMP_ACL_USER;
792
793         if(strstrofs(pFilename, "/", 0) >= 0)
794         {
795                 print("Invalid character in map name, ignored\n");
796                 return 0;
797         }
798
799         if(pGametypeToSet == 0)
800                 if(MapInfo_Cache_Retrieve(pFilename))
801                         return 1;
802
803         r = 1;
804
805         MapInfo_Map_bspname = pFilename;
806
807         // default all generic fields so they have "good" values in case something fails
808         fn = strcat("maps/", pFilename, ".mapinfo");
809         fh = fopen(fn, FILE_READ);
810         if(fh < 0)
811         {
812                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
813                 fh = fopen(fn, FILE_READ);
814                 if(fh < 0)
815                 {
816                         if(!pAllowGenerate)
817                                 return 0;
818                         _MapInfo_Map_Reset();
819                         r = _MapInfo_Generate(pFilename);
820                         if(!r)
821                                 return 0;
822                         fh = fopen(fn, FILE_WRITE);
823                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
824                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
825                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
826                         if(_MapInfo_Map_worldspawn_music != "")
827                         {
828                                 if(
829                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
830                                         ||
831                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
832                                 )
833                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
834                                 else
835                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
836                         }
837                         else
838                         {
839                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
840                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
841                                 for(;;)
842                                 {
843                                         i = floor(random() * n);
844                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
845                                                 break;
846                                 }
847                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
848                         }
849                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
850                                 fputs(fh, "has weapons\n");
851                         else
852                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
853                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
854                                 fputs(fh, "frustrating\n");
855
856                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
857                                 if(MapInfo_Map_supportedGametypes & i)
858                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
859
860                         fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
861                         if(fh2 >= 0)
862                         {
863                                 fclose(fh2);
864                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
865                         }
866
867                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
868                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
869                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
870                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
871                         fputs(fh, "// optional: hidden\n");
872
873                         fclose(fh);
874                         r = 2;
875                         // return r;
876                         fh = fopen(fn, FILE_READ);
877                         if(fh < 0)
878                                 error("... but I just wrote it!");
879                 }
880
881                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
882         }
883
884         _MapInfo_Map_Reset();
885         for(;;)
886         {
887                 if not((s = fgets(fh)))
888                         break;
889
890                 // catch different sorts of comments
891                 if(s == "")                    // empty lines
892                         continue;
893                 if(substring(s, 0, 1) == "#")  // UNIX style
894                         continue;
895                 if(substring(s, 0, 2) == "//") // C++ style
896                         continue;
897                 if(substring(s, 0, 1) == "_")  // q3map style
898                         continue;
899
900                 p = strstrofs(s, "//", 0);
901                 if(p >= 0)
902                         s = substring(s, 0, p);
903
904                 t = car(s); s = cdr(s);
905                 if(t == "title")
906                         MapInfo_Map_title = s;
907                 else if(t == "description")
908                         MapInfo_Map_description = s;
909                 else if(t == "author")
910                         MapInfo_Map_author = s;
911                 else if(t == "has")
912                 {
913                         t = car(s); s = cdr(s);
914                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
915                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
916                         else
917                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
918                 }
919                 else if(t == "hidden")
920                 {
921                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
922                 }
923                 else if(t == "forbidden")
924                 {
925                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
926                 }
927                 else if(t == "frustrating")
928                 {
929                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
930                 }
931                 else if(t == "type")
932                 {
933                         t = car(s); s = cdr(s);
934                         f = MapInfo_Type_FromString(t);
935                         if(f)
936                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
937                         else
938                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
939                 }
940                 else if(t == "gametype")
941                 {
942                         t = car(s); s = cdr(s);
943                         f = MapInfo_Type_FromString(t);
944                         if(f)
945                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
946                         else
947                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
948                 }
949                 else if(t == "size")
950                 {
951                         float a, b, c, d, e;
952                         t = car(s); s = cdr(s); a = stof(t);
953                         t = car(s); s = cdr(s); b = stof(t);
954                         t = car(s); s = cdr(s); c = stof(t);
955                         t = car(s); s = cdr(s); d = stof(t);
956                         t = car(s); s = cdr(s); e = stof(t);
957                         if(s == "")
958                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
959                         else
960                         {
961                                 t = car(s); s = cdr(s); f = stof(t);
962                                 if(s != "")
963                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
964                                 else
965                                 {
966                                         if(a >= d || b >= e || c >= f)
967                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
968                                         else
969                                         {
970                                                 MapInfo_Map_mins_x = a;
971                                                 MapInfo_Map_mins_y = b;
972                                                 MapInfo_Map_mins_z = c;
973                                                 MapInfo_Map_maxs_x = d;
974                                                 MapInfo_Map_maxs_y = e;
975                                                 MapInfo_Map_maxs_z = f;
976                                         }
977                                 }
978                         }
979                 }
980                 else if(t == "settemp_for_type")
981                 {
982                         t = car(s); s = cdr(s);
983                         if((f = MapInfo_Type_FromString(t)))
984                         {
985                                 if(f & pGametypeToSet)
986                                 {
987                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
988                                 }
989                         }
990                         else
991                         {
992                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
993                         }
994                 }
995                 else if(t == "clientsettemp_for_type")
996                 {
997                         t = car(s); s = cdr(s);
998                         if((f = MapInfo_Type_FromString(t)))
999                         {
1000                                 if(f & pGametypeToSet)
1001                                 {
1002                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1003                                 }
1004                         }
1005                         else
1006                         {
1007                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1008                         }
1009                 }
1010                 else if(t == "fog")
1011                 {
1012                         if not(cvar_value_issafe(t))
1013                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1014                         else
1015                                 MapInfo_Map_fog = s;
1016                 }
1017                 else if(t == "cdtrack")
1018                 {
1019                         if(pGametypeToSet)
1020                         {
1021                                 if not(cvar_value_issafe(t))
1022                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1023                                 else
1024                                         MapInfo_Map_clientstuff = strcat(
1025                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
1026                                         );
1027                         }
1028                 }
1029                 else
1030                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1031         }
1032         fclose(fh);
1033
1034         if(pGametypeToSet)
1035         {
1036                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1037                 {
1038                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1039                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1040                         //return;
1041                 }
1042         }
1043
1044         MapInfo_Cache_Store();
1045         if(MapInfo_Map_supportedGametypes != 0)
1046                 return r;
1047         dprint("Map ", pFilename, " supports no game types, ignored\n");
1048         return 0;
1049 }
1050
1051 float MapInfo_FindName(string s)
1052 {
1053         // if there is exactly one map of prefix s, return it
1054         // if not, return the null string
1055         // note that DP sorts glob results... so I can use a binary search
1056         float l, r, m, cmp;
1057         l = 0;
1058         r = MapInfo_count;
1059         // invariants: r is behind s, l-1 is equal or before
1060         while(l != r)
1061         {
1062                 m = floor((l + r) / 2);
1063                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1064                 cmp = strcasecmp(MapInfo_FindName_match, s);
1065                 if(cmp == 0)
1066                         return m; // found and good
1067                 if(cmp < 0)
1068                         l = m + 1; // l-1 is before s
1069                 else
1070                         r = m; // behind s
1071         }
1072         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1073         MapInfo_FindName_firstResult = l;
1074         // r == l, so: l is behind s, l-1 is before
1075         // SO: if there is any, l is the one with the right prefix
1076         //     and l+1 may be one too
1077         if(l == MapInfo_count)
1078         {
1079                 MapInfo_FindName_match = string_null;
1080                 MapInfo_FindName_firstResult = -1;
1081                 return -1; // no MapInfo_FindName_match, behind last item
1082         }
1083         if(!startsWithNocase(MapInfo_FindName_match, s))
1084         {
1085                 MapInfo_FindName_match = string_null;
1086                 MapInfo_FindName_firstResult = -1;
1087                 return -1; // wrong prefix
1088         }
1089         if(l == MapInfo_count - 1)
1090                 return l; // last one, nothing can follow => unique
1091         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1092         {
1093                 MapInfo_FindName_match = string_null;
1094                 return -1; // ambigous MapInfo_FindName_match
1095         }
1096         return l;
1097 }
1098
1099 string MapInfo_FixName(string s)
1100 {
1101         MapInfo_FindName(s);
1102         return MapInfo_FindName_match;
1103 }
1104
1105 float MapInfo_CurrentFeatures()
1106 {
1107         float req;
1108         req = 0;
1109         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1110                 req |= MAPINFO_FEATURE_WEAPONS;
1111         return req;
1112 }
1113
1114 float MapInfo_CurrentGametype()
1115 {
1116         if(cvar("g_domination"))
1117                 return MAPINFO_TYPE_DOMINATION;
1118         else if(cvar("g_ctf"))
1119                 return MAPINFO_TYPE_CTF;
1120         else if(cvar("g_runematch"))
1121                 return MAPINFO_TYPE_RUNEMATCH;
1122         else if(cvar("g_tdm"))
1123                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
1124         else if(cvar("g_assault"))
1125                 return MAPINFO_TYPE_ASSAULT;
1126         else if(cvar("g_lms"))
1127                 return MAPINFO_TYPE_LMS;
1128         else if(cvar("g_arena"))
1129                 return MAPINFO_TYPE_ARENA;
1130         else if(cvar("g_ca"))
1131                 return MAPINFO_TYPE_CA; 
1132         else if(cvar("g_keyhunt"))
1133                 return MAPINFO_TYPE_KEYHUNT;
1134         else if(cvar("g_onslaught"))
1135                 return MAPINFO_TYPE_ONSLAUGHT;
1136         else if(cvar("g_race"))
1137                 return MAPINFO_TYPE_RACE;
1138         else if(cvar("g_nexball"))
1139                 return MAPINFO_TYPE_NEXBALL;
1140         else if(cvar("g_cts"))
1141                 return MAPINFO_TYPE_CTS;
1142         else if(cvar("g_freezetag"))
1143                 return MAPINFO_TYPE_FREEZETAG;
1144         else
1145                 return MAPINFO_TYPE_DEATHMATCH;
1146 }
1147
1148 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1149 {
1150         if(!MapInfo_Get_ByName(s, 1, 0))
1151                 return 0;
1152         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1153                 return 0;
1154         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1155                 return 0;
1156         return 1;
1157 }
1158
1159 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1160 {
1161         float r;
1162         r = _MapInfo_CheckMap(s);
1163         MapInfo_ClearTemps();
1164         return r;
1165 }
1166
1167 string MapInfo_GetGameTypeCvar(float t)
1168 {
1169         switch(t)
1170         {
1171                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
1172                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
1173                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
1174                 case MAPINFO_TYPE_CTF: return "g_ctf";
1175                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
1176                 case MAPINFO_TYPE_LMS: return "g_lms";
1177                 case MAPINFO_TYPE_ARENA: return "g_arena";
1178                 case MAPINFO_TYPE_CA: return "g_ca";
1179                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
1180                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
1181                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
1182                 case MAPINFO_TYPE_RACE: return "g_race";
1183                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
1184                 case MAPINFO_TYPE_FREEZETAG: return "g_freezetag";
1185                 case MAPINFO_TYPE_CTS: return "g_cts";
1186                 default: return "";
1187         }
1188 }
1189
1190 void MapInfo_SwitchGameType(float t)
1191 {
1192         cvar_set("gamecfg",      "0");
1193         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
1194         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
1195         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
1196         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
1197         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
1198         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
1199         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
1200         cvar_set("g_ca",         (t == MAPINFO_TYPE_CA)              ? "1" : "0");
1201         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
1202         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
1203         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
1204         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
1205         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
1206         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
1207         cvar_set("g_freezetag",  (t == MAPINFO_TYPE_FREEZETAG)       ? "1" : "0");
1208 }
1209
1210 void MapInfo_LoadMap(string s)
1211 {
1212         MapInfo_Map_supportedGametypes = 0;
1213         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1214         //if(!MapInfo_CheckMap(s))
1215         //{
1216         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1217         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1218         //}
1219         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1220 }
1221
1222 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1223 {
1224         string out;
1225         float i;
1226
1227         // to make absolutely sure:
1228         MapInfo_Enumerate();
1229         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1230
1231         out = "";
1232         for(i = 0; i < MapInfo_count; ++i)
1233                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1234         return substring(out, 1, strlen(out) - 1);
1235 }
1236
1237 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1238 {
1239         float t, t0;
1240         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1241         {
1242                 if(MapInfo_Map_supportedGametypes == 0)
1243                 {
1244                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1245                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1246                         _MapInfo_Map_ApplyGametypeEx("", t0, t0);
1247                         return; // do not call Get_ByName!
1248                 }
1249
1250                 t = 1;
1251                 while(!(MapInfo_Map_supportedGametypes & 1))
1252                 {
1253                         t *= 2;
1254                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1255                 }
1256                 // t is now a supported mode!
1257                 t0 = MapInfo_CurrentGametype();
1258                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1259                 {
1260                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1261                         cvar_settemp_restore();
1262                         _MapInfo_Map_ApplyGametypeEx("", t0, t0);
1263                         return; // do not call Get_ByName!
1264                 }
1265                 else
1266                 {
1267                         print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1268                         MapInfo_SwitchGameType(t);
1269                 }
1270         }
1271         cvar_settemp_restore();
1272         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1273 }
1274
1275 void MapInfo_ClearTemps()
1276 {
1277         MapInfo_Map_bspname = string_null;
1278         MapInfo_Map_title = string_null;
1279         MapInfo_Map_description = string_null;
1280         MapInfo_Map_author = string_null;
1281         MapInfo_Map_clientstuff = string_null;
1282         MapInfo_Map_supportedGametypes = 0;
1283         MapInfo_Map_supportedFeatures = 0;
1284 }
1285
1286 void MapInfo_Shutdown()
1287 {
1288         MapInfo_ClearTemps();
1289         MapInfo_Filter_Free();
1290         MapInfo_Cache_Destroy();
1291         if(_MapInfo_globopen)
1292         {
1293                 search_end(_MapInfo_globhandle);
1294                 _MapInfo_globhandle = -1;
1295                 _MapInfo_globopen = FALSE;
1296         }
1297 }
1298
1299 float MapInfo_ForbiddenFlags()
1300 {
1301         float f;
1302         f = MAPINFO_FLAG_FORBIDDEN;
1303
1304 #ifndef MENUQC
1305         if not(cvar("g_maplist_allow_hidden"))
1306 #endif
1307                 f |= MAPINFO_FLAG_HIDDEN;
1308
1309         if not(cvar("g_maplist_allow_frustrating"))
1310                 f |= MAPINFO_FLAG_FRUSTRATING;
1311
1312         return f;
1313 }
1314
1315 float MapInfo_RequiredFlags()
1316 {
1317         float f;
1318         f = 0;
1319
1320         if(cvar("g_maplist_allow_frustrating") > 1)
1321                 f |= MAPINFO_FLAG_FRUSTRATING;
1322
1323         return f;
1324 }