qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(s == "")
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(s == "")
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         if(!_MapInfo_globopen)
  93                 return string_null;
  94         s = search_getfilename(_MapInfo_globhandle, i);
  95         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  96 }
  97
  98 void MapInfo_Enumerate()
  99 {
 100         if(_MapInfo_globopen)
 101         {
 102                 search_end(_MapInfo_globhandle);
 103                 _MapInfo_globopen = 0;
 104         }
 105         MapInfo_Cache_Invalidate();
 106         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 107         if(_MapInfo_globhandle >= 0)
 108         {
 109                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 110                 _MapInfo_globopen = 1;
 111         }
 112         else
 113                 _MapInfo_globcount = 0;
 114 }
 115
 116 // filter the info by game type mask (updates MapInfo_count)
 117 //
 118 float _MapInfo_filtered;
 119 float _MapInfo_filtered_allocated;
 120 float MapInfo_FilterList_Lookup(float i)
 121 {
 122         return stof(bufstr_get(_MapInfo_filtered, i));
 123 }
 124
 125 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 126 {
 127         string h;
 128         h = bufstr_get(_MapInfo_filtered, i);
 129         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 130         bufstr_set(_MapInfo_filtered, j, h);
 131 }
 132
 133 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 134 {
 135         string a, b;
 136         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 137         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 138         return strcasecmp(a, b);
 139 }
 140
 141 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 142 {
 143         float i, j;
 144         if not(_MapInfo_filtered_allocated)
 145         {
 146                 _MapInfo_filtered_allocated = 1;
 147                 _MapInfo_filtered = buf_create();
 148         }
 149         MapInfo_count = 0;
 150         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 151         {
 152                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 153                         if(pAbortOnGenerate)
 154                         {
 155                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 156                                 MapInfo_progress = i / _MapInfo_globcount;
 157                                 return 0;
 158                         }
 159                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 160                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 161                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 162                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 163                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 164         }
 165         MapInfo_count = j + 1;
 166         MapInfo_ClearTemps();
 167
 168         // sometimes the glob isn't sorted nicely, so fix it here...
 169         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 170
 171         return 1;
 172 }
 173
 174 void MapInfo_Filter_Free()
 175 {
 176         if(_MapInfo_filtered_allocated)
 177         {
 178                 buf_del(_MapInfo_filtered);
 179                 _MapInfo_filtered_allocated = 0;
 180         }
 181 }
 182
 183 // load info about the i-th map into the MapInfo_Map_* globals
 184 string MapInfo_BSPName_ByID(float i)
 185 {
 186         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 187 }
 188
 189 string unquote(string s)
 190 {
 191         float i, j, l;
 192         l = strlen(s);
 193         j = -1;
 194         for(i = 0; i < l; ++i)
 195         {
 196                 string ch;
 197                 ch = substring(s, i, 1);
 198                 if(ch != " ") if(ch != "\"")
 199                 {
 200                         for(j = strlen(s) - i - 1; j > 0; --j)
 201                         {
 202                                 ch = substring(s, i+j, 1);
 203                                 if(ch != " ") if(ch != "\"")
 204                                         return substring(s, i, j+1);
 205                         }
 206                         return substring(s, i, 1);
 207                 }
 208         }
 209         return "";
 210 }
 211
 212 float MapInfo_Get_ByID(float i)
 213 {
 214         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 215                 return 1;
 216         return 0;
 217 }
 218
 219 string _MapInfo_Map_worldspawn_music;
 220
 221 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 222 {
 223         string fn;
 224         float fh;
 225         string s, k, v;
 226         vector o;
 227         float i;
 228         float inWorldspawn;
 229         float r;
 230         float twoBaseModes;
 231         float diameter, spawnpoints;
 232         float spawnplaces;
 233
 234         vector mapMins, mapMaxs;
 235
 236         r = 1;
 237         fn = strcat("maps/", pFilename, ".ent");
 238         fh = fopen(fn, FILE_READ);
 239         if(fh < 0)
 240         {
 241                 r = 2;
 242                 fn = strcat("maps/", pFilename, ".bsp");
 243                 fh = fopen(fn, FILE_READ);
 244         }
 245         if(fh < 0)
 246                 return 0;
 247         print("Analyzing ", fn, " to generate initial mapinfo\n");
 248
 249         inWorldspawn = 2;
 250         MapInfo_Map_flags = 0;
 251         MapInfo_Map_supportedGametypes = 0;
 252         spawnpoints = 0;
 253         spawnplaces = 0;
 254         _MapInfo_Map_worldspawn_music = "";
 255         mapMins = '0 0 0';
 256         mapMaxs = '0 0 0';
 257
 258         for(;;)
 259         {
 260                 if not((s = fgets(fh)))
 261                         break;
 262                 if(inWorldspawn == 1)
 263                         if(startsWith(s, "}"))
 264                                 inWorldspawn = 0;
 265                 k = unquote(car(s));
 266                 v = unquote(cdr(s));
 267                 if(inWorldspawn)
 268                 {
 269                         if(k == "classname" && v == "worldspawn")
 270                                 inWorldspawn = 1;
 271                         else if(k == "author")
 272                                 MapInfo_Map_author = v;
 273                         else if(k == "_description")
 274                                 MapInfo_Map_description = v;
 275                         else if(k == "music")
 276                                 _MapInfo_Map_worldspawn_music = v;
 277                         else if(k == "noise")
 278                                 _MapInfo_Map_worldspawn_music = v;
 279                         else if(k == "message")
 280                         {
 281                                 i = strstrofs(v, " by ", 0);
 282                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 283                                 {
 284                                         MapInfo_Map_title = substring(v, 0, i);
 285                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 286                                 }
 287                                 else
 288                                         MapInfo_Map_title = v;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if(k == "origin")
 294                         {
 295                                 o = stov(strcat("'", v, "'"));
 296                                 mapMins_x = min(mapMins_x, o_x);
 297                                 mapMins_y = min(mapMins_y, o_y);
 298                                 mapMins_z = min(mapMins_z, o_z);
 299                                 mapMaxs_x = max(mapMaxs_x, o_x);
 300                                 mapMaxs_y = max(mapMaxs_y, o_y);
 301                                 mapMaxs_z = max(mapMaxs_z, o_z);
 302                         }
 303                         else if(k == "race_place")
 304                         {
 305                                 if(stof(v) > 0)
 306                                         spawnplaces = 1;
 307                         }
 308                         else if(k == "classname")
 309                         {
 310                                 if(v == "dom_controlpoint")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 312                                 else if(v == "item_flag_team2")
 313                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 314                                 else if(v == "team_CTF_blueflag")
 315                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 316                                 else if(v == "target_assault_roundend")
 317                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 318                                 else if(v == "onslaught_generator")
 319                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 320                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 322                                 else if(v == "info_player_team1")
 323                                         ++spawnpoints;
 324                                 else if(v == "info_player_team2")
 325                                         ++spawnpoints;
 326                                 else if(v == "info_player_start")
 327                                         ++spawnpoints;
 328                                 else if(v == "info_player_deathmatch")
 329                                         ++spawnpoints;
 330                                 else if(v == "trigger_race_checkpoint")
 331                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 332                                 else if(v == "target_startTimer")
 333                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 334                                 else if(v == "weapon_nex")
 335                                         { }
 336                                 else if(v == "weapon_railgun")
 337                                         { }
 338                                 else if(startsWith(v, "weapon_"))
 339                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 340                                 else if(startsWith(v, "turret_"))
 341                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 342                                 else if(startsWith(v, "vehicle_"))
 343                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 344                                 else if(v == "target_music" || v == "trigger_music")
 345                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 346                         }
 347                 }
 348         }
 349         if(inWorldspawn)
 350         {
 351                 print(fn, " ended still in worldspawn, BUG\n");
 352                 return 0;
 353         }
 354         diameter = vlen(mapMaxs - mapMins);
 355
 356         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 357         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 358         {
 359                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 360                 // as the map is too symmetric for them.
 361         }
 362         else
 363         {
 364                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 365                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 366                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 367
 368                 if(spawnpoints >= 8  && diameter > 4096) {
 369                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 370                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 371                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 372                 }
 373                 if(                     diameter < 4096)
 374                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 375                 if(spawnpoints >= 12 && diameter > 5120)
 376                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 377         }
 378
 379         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 380         if(!spawnplaces)
 381         {
 382                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 383                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 384         }
 385
 386         dprint("-> diameter ",    ftos(diameter));
 387         dprint(";  spawnpoints ", ftos(spawnpoints));
 388         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 389
 390         fclose(fh);
 391
 392         return r;
 393 }
 394
 395 void _MapInfo_Map_Reset()
 396 {
 397         MapInfo_Map_title = "<TITLE>";
 398         MapInfo_Map_titlestring = "<TITLE>";
 399         MapInfo_Map_description = "<DESCRIPTION>";
 400         MapInfo_Map_author = "<AUTHOR>";
 401         MapInfo_Map_supportedGametypes = 0;
 402         MapInfo_Map_supportedFeatures = 0;
 403         MapInfo_Map_flags = 0;
 404         MapInfo_Map_clientstuff = "";
 405         MapInfo_Map_fog = "";
 406         MapInfo_Map_mins = '0 0 0';
 407         MapInfo_Map_maxs = '0 0 0';
 408 }
 409
 410 string _MapInfo_GetDefault(float t)
 411 {
 412         switch(t)
 413         {
 414                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 415                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 416                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 417                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 418                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 419                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
 420                 case MAPINFO_TYPE_CA:              return "10 20 0";
 421                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 422                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 423                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 424                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 425                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 426                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 427                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 428                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 429                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 430                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 431                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 432                 default:                           return "";
 433         }
 434 }
 435
 436 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 437 {
 438         string sa;
 439         MapInfo_Map_supportedGametypes |= pThisType;
 440         if(!(pThisType & pWantedType))
 441                 return;
 442
 443         if(load_default)
 444                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 445
 446         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 447         {
 448                 cvar_set("fraglimit", "0");
 449         }
 450         else
 451         {
 452                 sa = car(s);
 453                 if(sa != "")
 454                         cvar_set("fraglimit", sa);
 455                 s = cdr(s);
 456         }
 457
 458         sa = car(s);
 459         if(sa != "")
 460                 cvar_set("timelimit", sa);
 461         s = cdr(s);
 462
 463         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 464         {
 465                 sa = car(s);
 466                 if(sa != "")
 467                         cvar_set("g_tdm_teams", sa);
 468                 s = cdr(s);
 469         }
 470
 471         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 472         {
 473                 sa = car(s);
 474                 if(sa != "")
 475                         cvar_set("g_keyhunt_teams", sa);
 476                 s = cdr(s);
 477         }
 478
 479         if(pWantedType == MAPINFO_TYPE_CA)
 480         {
 481                 sa = car(s);
 482                 if(sa != "")
 483                         cvar_set("g_ca_teams", sa);
 484                 s = cdr(s);
 485         }
 486
 487         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 488         {
 489                 sa = car(s);
 490                 if(sa != "")
 491                         cvar_set("g_freezetag_teams", sa);
 492                 s = cdr(s);
 493         }
 494
 495         if(pWantedType == MAPINFO_TYPE_CTF)
 496         {
 497                 sa = car(s);
 498                 if(sa != "")
 499                         cvar_set("fraglimit", sa);
 500                 s = cdr(s);
 501         }
 502
 503         /* keepaway wuz here
 504         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 505         {
 506                 sa = car(s);
 507                 if(sa != "")
 508                         cvar_set("fraglimit", sa);
 509                 s = cdr(s);
 510         }
 511         */
 512
 513         // rc = timelimit timelimit_qualification laps laps_teamplay
 514         if(pWantedType == MAPINFO_TYPE_RACE)
 515         {
 516                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 517                 cvar_set("g_race_qualifying_timelimit", sa);
 518                 s = cdr(s);
 519
 520                 sa = car(s);
 521                 if(sa != "")
 522                         if(cvar("g_race_teams") < 2)
 523                                 cvar_set("fraglimit", sa);
 524                 s = cdr(s);
 525
 526                 sa = car(s);
 527                 if(sa != "")
 528                         if(cvar("g_race_teams") >= 2)
 529                                 cvar_set("fraglimit", sa);
 530                 s = cdr(s);
 531         }
 532
 533         if(pWantedType == MAPINFO_TYPE_CTS)
 534         {
 535                 sa = car(s);
 536
 537                 // this is the skill of the map
 538                 // not parsed by anything yet
 539                 // for map databases
 540                 //if(sa != "")
 541                 //      cvar_set("fraglimit", sa);
 542
 543                 s = cdr(s);
 544         }
 545
 546         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 547         {
 548                 cvar_set("leadlimit", "0");
 549         }
 550         else
 551         {
 552                 sa = car(s);
 553                 if(sa != "")
 554                         cvar_set("leadlimit", sa);
 555                 s = cdr(s);
 556         }
 557 }
 558
 559 string _MapInfo_GetDefaultEx(float t)
 560 {
 561         entity e;
 562         for(e = MapInfo_Type_first; e; e = e.enemy)
 563                 if(t == e.items)
 564                         return e.model2;
 565         return "";
 566 }
 567
 568 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 569 {
 570         string sa, k, v;
 571         float p;
 572         string fraglimit_normal;
 573         string fraglimit_teams;
 574
 575         MapInfo_Map_supportedGametypes |= pThisType;
 576         if(!(pThisType & pWantedType))
 577                 return;
 578
 579         // reset all the cvars to their defaults
 580
 581         cvar_set("timelimit", cvar_defstring("timelimit"));
 582         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 583         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 584         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 585         cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 586         cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 587         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 588         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 589         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 590
 591         fraglimit_normal = string_null;
 592         fraglimit_teams = string_null;
 593
 594         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 595         while(s != "")
 596         {
 597                 sa = car(s);
 598                 s = cdr(s);
 599
 600                 if(sa == "")
 601                         continue;
 602
 603                 p = strstrofs(sa, "=", 0);
 604                 if(p < 0)
 605                 {
 606                         k = "timelimit";
 607                         v = s;
 608                 }
 609                 else
 610                 {
 611                         k = substring(sa, 0, p);
 612                         v = substring(sa, p+1, -1);
 613                 }
 614
 615                 if(k == "timelimit")
 616                 {
 617                         cvar_set("timelimit", v);
 618                 }
 619                 else if(k == "leadlimit")
 620                 {
 621                         cvar_set("leadlimit", v);
 622                 }
 623                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 624                 {
 625                         fraglimit_normal = v;
 626                 }
 627                 else if(k == "teampointlimit" || k == "teamlaplimit")
 628                 {
 629                         fraglimit_teams = v;
 630                 }
 631                 else if(k == "teams")
 632                 {
 633                         cvar_set("g_tdm_teams", v);
 634                         cvar_set("g_ca_teams", v);
 635                         cvar_set("g_freezetag_teams", v);
 636                         cvar_set("g_keyhunt_teams", v);
 637                         cvar_set("g_domination_default_teams", v);
 638                 }
 639                 else if(k == "qualifying_timelimit")
 640                 {
 641                         cvar_set("g_race_qualifying_timelimit", v);
 642                 }
 643                 else if(k == "skill")
 644                 {
 645                         // ignore
 646                 }
 647                 else
 648                 {
 649                         print("Invalid gametype key in mapinfo: ", k, "\n");
 650                 }
 651         }
 652
 653         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 654         {
 655                 if(fraglimit_teams)
 656                         cvar_set("fraglimit", fraglimit_teams);
 657         }
 658         else
 659         {
 660                 if(fraglimit_normal)
 661                         cvar_set("fraglimit", fraglimit_normal);
 662         }
 663 }
 664
 665 float MapInfo_Type_FromString(string t)
 666 {
 667         entity e;
 668         if(t == "nexball")
 669         {
 670                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 671                 t = "nb";
 672                 print("'. Should use '", t, "'.\n");
 673         }
 674         if(t == "freezetag")
 675         {
 676                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 677                 t = "ft";
 678                 print("'. Should use '", t, "'.\n");
 679         }
 680         if(t == "keepaway")
 681         {
 682                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 683                 t = "ka";
 684                 print("'. Should use '", t, "'.\n");
 685         }
 686         if(t == "all")
 687                 return MAPINFO_TYPE_ALL;
 688         for(e = MapInfo_Type_first; e; e = e.enemy)
 689                 if(t == e.mdl)
 690                         return e.items;
 691         return 0;
 692 }
 693
 694 string MapInfo_Type_ToString(float t)
 695 {
 696         entity e;
 697         if(t == MAPINFO_TYPE_ALL)
 698                 return "all";
 699         for(e = MapInfo_Type_first; e; e = e.enemy)
 700                 if(t == e.items)
 701                         return e.mdl;
 702         return "";
 703 }
 704
 705 string MapInfo_Type_ToText(float t)
 706 {
 707         entity e;
 708         for(e = MapInfo_Type_first; e; e = e.enemy)
 709                 if(t == e.items)
 710                         return e.message;
 711         /* xgettext:no-c-format */
 712         return _("@!#%'n Tuba Throwing");
 713 }
 714
 715 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 716 {
 717         string t;
 718         float fh, o;
 719         t = car(s); s = cdr(s);
 720
 721         // limited support of "" and comments
 722         //   remove trailing and leading " of t
 723         if(substring(t, 0, 1) == "\"")
 724         {
 725                 if(substring(t, -1, 1) == "\"")
 726                         t = substring(t, 1, -2);
 727         }
 728
 729         //   remove leading " of s
 730         if(substring(s, 0, 1) == "\"")
 731         {
 732                 s = substring(s, 1, -1);
 733         }
 734         //   remove trailing " of s, and all that follows (cvar description)
 735         o = strstrofs(s, "\"", 0);
 736         if(o >= 0)
 737                 s = substring(s, 0, o);
 738
 739         //   remove // comments
 740         o = strstrofs(s, "//", 0);
 741         if(o >= 0)
 742                 s = substring(s, 0, o);
 743
 744         //   remove trailing spaces
 745         while(substring(s, -1, 1) == " ")
 746                 s = substring(s, 0, -2);
 747
 748         if(t == "#include")
 749         {
 750                 if(recurse > 0)
 751                 {
 752                         fh = fopen(s, FILE_READ);
 753                         if(fh < 0)
 754                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 755                         else
 756                         {
 757                                 for(;;)
 758                                 {
 759                                         if not((s = fgets(fh)))
 760                                                 break;
 761
 762                                         // catch different sorts of comments
 763                                         if(s == "")                    // empty lines
 764                                                 continue;
 765                                         if(substring(s, 0, 1) == "#")  // UNIX style
 766                                                 continue;
 767                                         if(substring(s, 0, 2) == "//") // C++ style
 768                                                 continue;
 769                                         if(substring(s, 0, 1) == "_")  // q3map style
 770                                                 continue;
 771
 772                                         if(substring(s, 0, 4) == "set ")
 773                                                 s = substring(s, 4, -1);
 774                                         if(substring(s, 0, 5) == "seta ")
 775                                                 s = substring(s, 5, -1);
 776
 777                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 778                                 }
 779                                 fclose(fh);
 780                         }
 781                 }
 782                 else
 783                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 784         }
 785         else if(t == "")
 786                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 787         else if not(cvar_value_issafe(t))
 788                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 789         else if not (cvar_value_issafe(s))
 790                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 791         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 792                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 793         else if(matchacl(acl, t) <= 0)
 794                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 795         else
 796         {
 797                 if(type == 0) // server set
 798                 {
 799                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 800                         if(cvar("g_campaign"))
 801                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 802                         else
 803                                 cvar_settemp(t, s);
 804                 }
 805                 else
 806                 {
 807                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 808                         MapInfo_Map_clientstuff = strcat(
 809                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 810                                         );
 811                 }
 812         }
 813 }
 814
 815 float MapInfo_isRedundant(string fn, string t)
 816 {
 817         // normalize file name
 818         fn = strreplace("_", "-", fn);
 819
 820         // normalize visible title
 821         t = strreplace(": ", "-", t);
 822         t = strreplace(":", "-", t);
 823         t = strreplace(" ", "-", t);
 824         t = strreplace("_", "-", t);
 825         t = strreplace("'", "-", t);
 826
 827         if(!strcasecmp(fn, t))
 828                 return TRUE;
 829
 830         // we allow the visible title to have punctuation the file name does
 831         // not, but not vice versa
 832         t = strreplace("-", "", t);
 833
 834         if(!strcasecmp(fn, t))
 835                 return TRUE;
 836
 837         return FALSE;
 838 }
 839
 840 // load info about a map by name into the MapInfo_Map_* globals
 841 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 842 {
 843         string fn;
 844         string s, t;
 845         float fh;
 846         float r, f, n, i, p;
 847         string acl;
 848
 849         acl = MAPINFO_SETTEMP_ACL_USER;
 850
 851         if(strstrofs(pFilename, "/", 0) >= 0)
 852         {
 853                 print("Invalid character in map name, ignored\n");
 854                 return 0;
 855         }
 856
 857         if(pGametypeToSet == 0)
 858                 if(MapInfo_Cache_Retrieve(pFilename))
 859                         return 1;
 860
 861         r = 1;
 862
 863         MapInfo_Map_bspname = pFilename;
 864
 865         // default all generic fields so they have "good" values in case something fails
 866         fn = strcat("maps/", pFilename, ".mapinfo");
 867         fh = fopen(fn, FILE_READ);
 868         if(fh < 0)
 869         {
 870                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 871                 fh = fopen(fn, FILE_READ);
 872                 if(fh < 0)
 873                 {
 874                         if(!pAllowGenerate)
 875                                 return 0;
 876                         _MapInfo_Map_Reset();
 877                         r = _MapInfo_Generate(pFilename);
 878                         if(!r)
 879                                 return 0;
 880                         fh = fopen(fn, FILE_WRITE);
 881                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 882                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 883                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 884                         if(_MapInfo_Map_worldspawn_music != "")
 885                         {
 886                                 if(
 887                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 888                                         ||
 889                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 890                                 )
 891                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 892                                 else
 893                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 894                         }
 895                         else
 896                         {
 897                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 898                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 899                                 for(;;)
 900                                 {
 901                                         i = floor(random() * n);
 902                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 903                                                 break;
 904                                 }
 905                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 906                         }
 907                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 908                                 fputs(fh, "has weapons\n");
 909                         else
 910                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 911                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 912                                 fputs(fh, "has turrets\n");
 913                         else
 914                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 915                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 916                                 fputs(fh, "has vehicles\n");
 917                         else
 918                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 919                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 920                                 fputs(fh, "frustrating\n");
 921
 922                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 923                                 if(MapInfo_Map_supportedGametypes & i)
 924                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 925
 926                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 927                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 928
 929                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 930                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 931                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 932                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 933                         fputs(fh, "// optional: hidden\n");
 934
 935                         fclose(fh);
 936                         r = 2;
 937                         // return r;
 938                         fh = fopen(fn, FILE_READ);
 939                         if(fh < 0)
 940                                 error("... but I just wrote it!");
 941                 }
 942
 943                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 944         }
 945
 946         _MapInfo_Map_Reset();
 947         for(;;)
 948         {
 949                 if not((s = fgets(fh)))
 950                         break;
 951
 952                 // catch different sorts of comments
 953                 if(s == "")                    // empty lines
 954                         continue;
 955                 if(substring(s, 0, 1) == "#")  // UNIX style
 956                         continue;
 957                 if(substring(s, 0, 2) == "//") // C++ style
 958                         continue;
 959                 if(substring(s, 0, 1) == "_")  // q3map style
 960                         continue;
 961
 962                 p = strstrofs(s, "//", 0);
 963                 if(p >= 0)
 964                         s = substring(s, 0, p);
 965
 966                 t = car(s); s = cdr(s);
 967                 if(t == "title")
 968                         MapInfo_Map_title = s;
 969                 else if(t == "description")
 970                         MapInfo_Map_description = s;
 971                 else if(t == "author")
 972                         MapInfo_Map_author = s;
 973                 else if(t == "has")
 974                 {
 975                         t = car(s); // s = cdr(s);
 976                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 977                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 978                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 979                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 980                         else
 981                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 982                 }
 983                 else if(t == "hidden")
 984                 {
 985                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 986                 }
 987                 else if(t == "forbidden")
 988                 {
 989                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 990                 }
 991                 else if(t == "frustrating")
 992                 {
 993                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 994                 }
 995                 else if(t == "noautomaplist")
 996                 {
 997                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 998                 }
 999                 else if(t == "type")
1000                 {
1001                         t = car(s); s = cdr(s);
1002                         f = MapInfo_Type_FromString(t);
1003                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1004                         if(f)
1005                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
1006                         else
1007                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1008                 }
1009                 else if(t == "gametype")
1010                 {
1011                         t = car(s); s = cdr(s);
1012                         f = MapInfo_Type_FromString(t);
1013                         if(f)
1014                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1015                         else
1016                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1017                 }
1018                 else if(t == "size")
1019                 {
1020                         float a, b, c, d, e;
1021                         t = car(s); s = cdr(s); a = stof(t);
1022                         t = car(s); s = cdr(s); b = stof(t);
1023                         t = car(s); s = cdr(s); c = stof(t);
1024                         t = car(s); s = cdr(s); d = stof(t);
1025                         t = car(s); s = cdr(s); e = stof(t);
1026                         if(s == "")
1027                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1028                         else
1029                         {
1030                                 t = car(s); s = cdr(s); f = stof(t);
1031                                 if(s != "")
1032                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1033                                 else
1034                                 {
1035                                         if(a >= d || b >= e || c >= f)
1036                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1037                                         else
1038                                         {
1039                                                 MapInfo_Map_mins_x = a;
1040                                                 MapInfo_Map_mins_y = b;
1041                                                 MapInfo_Map_mins_z = c;
1042                                                 MapInfo_Map_maxs_x = d;
1043                                                 MapInfo_Map_maxs_y = e;
1044                                                 MapInfo_Map_maxs_z = f;
1045                                         }
1046                                 }
1047                         }
1048                 }
1049                 else if(t == "settemp_for_type")
1050                 {
1051                         t = car(s); s = cdr(s);
1052                         if((f = MapInfo_Type_FromString(t)))
1053                         {
1054                                 if(f & pGametypeToSet)
1055                                 {
1056                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1057                                 }
1058                         }
1059                         else
1060                         {
1061                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1062                         }
1063                 }
1064                 else if(t == "clientsettemp_for_type")
1065                 {
1066                         t = car(s); s = cdr(s);
1067                         if((f = MapInfo_Type_FromString(t)))
1068                         {
1069                                 if(f & pGametypeToSet)
1070                                 {
1071                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1072                                 }
1073                         }
1074                         else
1075                         {
1076                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1077                         }
1078                 }
1079                 else if(t == "fog")
1080                 {
1081                         if not(cvar_value_issafe(s))
1082                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1083                         else
1084                                 MapInfo_Map_fog = s;
1085                 }
1086                 else if(t == "cdtrack")
1087                 {
1088                         t = car(s); s = cdr(s);
1089                         if(pGametypeToSet) // FIXME is this check right here?
1090                         {
1091                                 if not(cvar_value_issafe(t))
1092                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1093                                 else
1094                                         MapInfo_Map_clientstuff = strcat(
1095                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1096                                         );
1097                         }
1098                 }
1099                 else
1100                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1101         }
1102         fclose(fh);
1103
1104         if(MapInfo_Map_title == "<TITLE>")
1105                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1106         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1107                 MapInfo_Map_titlestring = MapInfo_Map_title;
1108         else
1109                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1110
1111         MapInfo_Cache_Store();
1112         if(MapInfo_Map_supportedGametypes != 0)
1113                 return r;
1114         dprint("Map ", pFilename, " supports no game types, ignored\n");
1115         return 0;
1116 }
1117 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1118 {
1119         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1120
1121         if(cvar("g_tdm_on_dm_maps"))
1122         {
1123                 // if this is set, all DM maps support TDM too
1124                 if not(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH)
1125                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1126                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1127         }
1128
1129         if(pGametypeToSet)
1130         {
1131                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1132                 {
1133                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1134                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1135                         //return;
1136                 }
1137         }
1138
1139         return r;
1140 }
1141
1142 float MapInfo_FindName(string s)
1143 {
1144         // if there is exactly one map of prefix s, return it
1145         // if not, return the null string
1146         // note that DP sorts glob results... so I can use a binary search
1147         float l, r, m, cmp;
1148         l = 0;
1149         r = MapInfo_count;
1150         // invariants: r is behind s, l-1 is equal or before
1151         while(l != r)
1152         {
1153                 m = floor((l + r) / 2);
1154                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1155                 cmp = strcasecmp(MapInfo_FindName_match, s);
1156                 if(cmp == 0)
1157                         return m; // found and good
1158                 if(cmp < 0)
1159                         l = m + 1; // l-1 is before s
1160                 else
1161                         r = m; // behind s
1162         }
1163         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1164         MapInfo_FindName_firstResult = l;
1165         // r == l, so: l is behind s, l-1 is before
1166         // SO: if there is any, l is the one with the right prefix
1167         //     and l+1 may be one too
1168         if(l == MapInfo_count)
1169         {
1170                 MapInfo_FindName_match = string_null;
1171                 MapInfo_FindName_firstResult = -1;
1172                 return -1; // no MapInfo_FindName_match, behind last item
1173         }
1174         if(!startsWithNocase(MapInfo_FindName_match, s))
1175         {
1176                 MapInfo_FindName_match = string_null;
1177                 MapInfo_FindName_firstResult = -1;
1178                 return -1; // wrong prefix
1179         }
1180         if(l == MapInfo_count - 1)
1181                 return l; // last one, nothing can follow => unique
1182         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1183         {
1184                 MapInfo_FindName_match = string_null;
1185                 return -1; // ambigous MapInfo_FindName_match
1186         }
1187         return l;
1188 }
1189
1190 string MapInfo_FixName(string s)
1191 {
1192         MapInfo_FindName(s);
1193         return MapInfo_FindName_match;
1194 }
1195
1196 float MapInfo_CurrentFeatures()
1197 {
1198         float req;
1199         req = 0;
1200         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1201                 req |= MAPINFO_FEATURE_WEAPONS;
1202         return req;
1203 }
1204
1205 float MapInfo_CurrentGametype()
1206 {
1207         float prev;
1208         entity e;
1209         prev = cvar("gamecfg");
1210         for(e = MapInfo_Type_first; e; e = e.enemy)
1211                 if(cvar(e.netname))
1212                         if(prev != e.items)
1213                                 return e.items;
1214         if(prev)
1215                 return prev;
1216         return MAPINFO_TYPE_DEATHMATCH;
1217 }
1218
1219 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1220 {
1221         if(!MapInfo_Get_ByName(s, 1, 0))
1222                 return 0;
1223         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1224                 return 0;
1225         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1226                 return 0;
1227         return 1;
1228 }
1229
1230 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1231 {
1232         float r;
1233         r = _MapInfo_CheckMap(s);
1234         MapInfo_ClearTemps();
1235         return r;
1236 }
1237
1238 void MapInfo_SwitchGameType(float t)
1239 {
1240         entity e;
1241         for(e = MapInfo_Type_first; e; e = e.enemy)
1242                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1243 }
1244
1245 void MapInfo_LoadMap(string s, float reinit)
1246 {
1247         MapInfo_Map_supportedGametypes = 0;
1248         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1249         //if(!MapInfo_CheckMap(s))
1250         //{
1251         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1252         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1253         //}
1254
1255         cvar_settemp_restore();
1256         if(reinit)
1257                 localcmd(strcat("\nmap ", s, "\n"));
1258         else
1259                 localcmd(strcat("\nchangelevel ", s, "\n"));
1260 }
1261
1262 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1263 {
1264         string out;
1265         float i;
1266
1267         // to make absolutely sure:
1268         MapInfo_Enumerate();
1269         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1270
1271         out = "";
1272         for(i = 0; i < MapInfo_count; ++i)
1273                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1274         return substring(out, 1, strlen(out) - 1);
1275 }
1276
1277 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1278 {
1279         string out;
1280         float i;
1281
1282         // to make absolutely sure:
1283         MapInfo_Enumerate();
1284         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1285
1286         out = "";
1287         for(i = 0; i < MapInfo_count; ++i)
1288                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1289
1290         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1291
1292         return substring(out, 1, strlen(out) - 1);
1293 }
1294
1295 void MapInfo_LoadMapSettings_SaveGameType(float t)
1296 {
1297         MapInfo_SwitchGameType(t);
1298         cvar_set("gamecfg", ftos(t));
1299         MapInfo_LoadedGametype = t;
1300 }
1301
1302 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1303 {
1304         float t;
1305
1306         t = MapInfo_CurrentGametype();
1307         MapInfo_LoadMapSettings_SaveGameType(t);
1308
1309         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1310         {
1311                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1312                 {
1313                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1314                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1315                         return; // do not call Get_ByName!
1316                 }
1317
1318                 if(MapInfo_Map_supportedGametypes == 0)
1319                 {
1320                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1321                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1322                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1323                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1324                         return; // do not call Get_ByName!
1325                 }
1326
1327                 t = 1;
1328                 while(!(MapInfo_Map_supportedGametypes & 1))
1329                 {
1330                         t *= 2;
1331                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1332                 }
1333
1334                 // t is now a supported mode!
1335                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1336                 MapInfo_LoadMapSettings_SaveGameType(t);
1337         }
1338         MapInfo_Get_ByName(s, 1, t);
1339 }
1340
1341 void MapInfo_ClearTemps()
1342 {
1343         MapInfo_Map_bspname = string_null;
1344         MapInfo_Map_title = string_null;
1345         MapInfo_Map_titlestring = string_null;
1346         MapInfo_Map_description = string_null;
1347         MapInfo_Map_author = string_null;
1348         MapInfo_Map_clientstuff = string_null;
1349         MapInfo_Map_supportedGametypes = 0;
1350         MapInfo_Map_supportedFeatures = 0;
1351 }
1352
1353 void MapInfo_Shutdown()
1354 {
1355         MapInfo_ClearTemps();
1356         MapInfo_Filter_Free();
1357         MapInfo_Cache_Destroy();
1358         if(_MapInfo_globopen)
1359         {
1360                 search_end(_MapInfo_globhandle);
1361                 _MapInfo_globhandle = -1;
1362                 _MapInfo_globopen = FALSE;
1363         }
1364 }
1365
1366 float MapInfo_ForbiddenFlags()
1367 {
1368         float f;
1369         f = MAPINFO_FLAG_FORBIDDEN;
1370
1371 #ifndef MENUQC
1372         if not(cvar("g_maplist_allow_hidden"))
1373 #endif
1374                 f |= MAPINFO_FLAG_HIDDEN;
1375
1376         if not(cvar("g_maplist_allow_frustrating"))
1377                 f |= MAPINFO_FLAG_FRUSTRATING;
1378
1379         return f;
1380 }
1381
1382 float MapInfo_RequiredFlags()
1383 {
1384         float f;
1385         f = 0;
1386
1387         if(cvar("g_maplist_allow_frustrating") > 1)
1388                 f |= MAPINFO_FLAG_FRUSTRATING;
1389
1390         return f;
1391 }