qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(s == "")
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(s == "")
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         if(!_MapInfo_globopen)
  93                 return string_null;
  94         s = search_getfilename(_MapInfo_globhandle, i);
  95         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  96 }
  97
  98 void MapInfo_Enumerate()
  99 {
 100         if(_MapInfo_globopen)
 101         {
 102                 search_end(_MapInfo_globhandle);
 103                 _MapInfo_globopen = 0;
 104         }
 105         MapInfo_Cache_Invalidate();
 106         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 107         if(_MapInfo_globhandle >= 0)
 108         {
 109                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 110                 _MapInfo_globopen = 1;
 111         }
 112         else
 113                 _MapInfo_globcount = 0;
 114 }
 115
 116 // filter the info by game type mask (updates MapInfo_count)
 117 //
 118 float _MapInfo_filtered;
 119 float _MapInfo_filtered_allocated;
 120 float MapInfo_FilterList_Lookup(float i)
 121 {
 122         return stof(bufstr_get(_MapInfo_filtered, i));
 123 }
 124
 125 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 126 {
 127         string h;
 128         h = bufstr_get(_MapInfo_filtered, i);
 129         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 130         bufstr_set(_MapInfo_filtered, j, h);
 131 }
 132
 133 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 134 {
 135         string a, b;
 136         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 137         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 138         return strcasecmp(a, b);
 139 }
 140
 141 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 142 {
 143         float i, j;
 144         if (!_MapInfo_filtered_allocated)
 145         {
 146                 _MapInfo_filtered_allocated = 1;
 147                 _MapInfo_filtered = buf_create();
 148         }
 149         MapInfo_count = 0;
 150         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 151         {
 152                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 153                         if(pAbortOnGenerate)
 154                         {
 155                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 156                                 MapInfo_progress = i / _MapInfo_globcount;
 157                                 return 0;
 158                         }
 159                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 160                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 161                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 162                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 163                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 164         }
 165         MapInfo_count = j + 1;
 166         MapInfo_ClearTemps();
 167
 168         // sometimes the glob isn't sorted nicely, so fix it here...
 169         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 170
 171         return 1;
 172 }
 173
 174 void MapInfo_Filter_Free()
 175 {
 176         if(_MapInfo_filtered_allocated)
 177         {
 178                 buf_del(_MapInfo_filtered);
 179                 _MapInfo_filtered_allocated = 0;
 180         }
 181 }
 182
 183 // load info about the i-th map into the MapInfo_Map_* globals
 184 string MapInfo_BSPName_ByID(float i)
 185 {
 186         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 187 }
 188
 189 string unquote(string s)
 190 {
 191         float i, j, l;
 192         l = strlen(s);
 193         j = -1;
 194         for(i = 0; i < l; ++i)
 195         {
 196                 string ch;
 197                 ch = substring(s, i, 1);
 198                 if(ch != " ") if(ch != "\"")
 199                 {
 200                         for(j = strlen(s) - i - 1; j > 0; --j)
 201                         {
 202                                 ch = substring(s, i+j, 1);
 203                                 if(ch != " ") if(ch != "\"")
 204                                         return substring(s, i, j+1);
 205                         }
 206                         return substring(s, i, 1);
 207                 }
 208         }
 209         return "";
 210 }
 211
 212 float MapInfo_Get_ByID(float i)
 213 {
 214         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 215                 return 1;
 216         return 0;
 217 }
 218
 219 string _MapInfo_Map_worldspawn_music;
 220
 221 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 222 {
 223         string fn;
 224         float fh;
 225         string s, k, v;
 226         vector o;
 227         float i;
 228         float inWorldspawn;
 229         float r;
 230         float twoBaseModes;
 231         float diameter, spawnpoints;
 232         float spawnplaces;
 233
 234         vector mapMins, mapMaxs;
 235
 236         r = 1;
 237         fn = strcat("maps/", pFilename, ".ent");
 238         fh = fopen(fn, FILE_READ);
 239         if(fh < 0)
 240         {
 241                 r = 2;
 242                 fn = strcat("maps/", pFilename, ".bsp");
 243                 fh = fopen(fn, FILE_READ);
 244         }
 245         if(fh < 0)
 246                 return 0;
 247         print("Analyzing ", fn, " to generate initial mapinfo\n");
 248
 249         inWorldspawn = 2;
 250         MapInfo_Map_flags = 0;
 251         MapInfo_Map_supportedGametypes = 0;
 252         spawnpoints = 0;
 253         spawnplaces = 0;
 254         _MapInfo_Map_worldspawn_music = "";
 255         mapMins = '0 0 0';
 256         mapMaxs = '0 0 0';
 257
 258         for(;;)
 259         {
 260                 if (!((s = fgets(fh))))
 261                         break;
 262                 if(inWorldspawn == 1)
 263                         if(startsWith(s, "}"))
 264                                 inWorldspawn = 0;
 265                 k = unquote(car(s));
 266                 v = unquote(cdr(s));
 267                 if(inWorldspawn)
 268                 {
 269                         if(k == "classname" && v == "worldspawn")
 270                                 inWorldspawn = 1;
 271                         else if(k == "author")
 272                                 MapInfo_Map_author = v;
 273                         else if(k == "_description")
 274                                 MapInfo_Map_description = v;
 275                         else if(k == "music")
 276                                 _MapInfo_Map_worldspawn_music = v;
 277                         else if(k == "noise")
 278                                 _MapInfo_Map_worldspawn_music = v;
 279                         else if(k == "message")
 280                         {
 281                                 i = strstrofs(v, " by ", 0);
 282                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 283                                 {
 284                                         MapInfo_Map_title = substring(v, 0, i);
 285                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 286                                 }
 287                                 else
 288                                         MapInfo_Map_title = v;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if(k == "origin")
 294                         {
 295                                 o = stov(strcat("'", v, "'"));
 296                                 mapMins_x = min(mapMins_x, o_x);
 297                                 mapMins_y = min(mapMins_y, o_y);
 298                                 mapMins_z = min(mapMins_z, o_z);
 299                                 mapMaxs_x = max(mapMaxs_x, o_x);
 300                                 mapMaxs_y = max(mapMaxs_y, o_y);
 301                                 mapMaxs_z = max(mapMaxs_z, o_z);
 302                         }
 303                         else if(k == "race_place")
 304                         {
 305                                 if(stof(v) > 0)
 306                                         spawnplaces = 1;
 307                         }
 308                         else if(k == "classname")
 309                         {
 310                                 if(v == "dom_controlpoint")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 312                                 else if(v == "item_flag_team2")
 313                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 314                                 else if(v == "team_CTF_blueflag")
 315                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 316                                 else if(v == "invasion_spawnpoint")
 317                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_INVASION;
 318                                 else if(v == "target_assault_roundend")
 319                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 320                                 else if(v == "onslaught_generator")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 322                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 323                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 324                                 else if(v == "info_player_team1")
 325                                         ++spawnpoints;
 326                                 else if(v == "info_player_team2")
 327                                         ++spawnpoints;
 328                                 else if(v == "info_player_start")
 329                                         ++spawnpoints;
 330                                 else if(v == "info_player_deathmatch")
 331                                         ++spawnpoints;
 332                                 else if(v == "trigger_race_checkpoint")
 333                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 334                                 else if(v == "target_startTimer")
 335                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 336                                 else if(v == "weapon_nex")
 337                                         { }
 338                                 else if(v == "weapon_railgun")
 339                                         { }
 340                                 else if(startsWith(v, "weapon_"))
 341                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 342                                 else if(startsWith(v, "turret_"))
 343                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 344                                 else if(startsWith(v, "vehicle_"))
 345                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 346                                 else if(startsWith(v, "monster_"))
 347                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 348                                 else if(v == "target_music" || v == "trigger_music")
 349                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 350                         }
 351                 }
 352         }
 353         if(inWorldspawn)
 354         {
 355                 print(fn, " ended still in worldspawn, BUG\n");
 356                 return 0;
 357         }
 358         diameter = vlen(mapMaxs - mapMins);
 359
 360         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 361         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 362         {
 363                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 364                 // as the map is too symmetric for them.
 365         }
 366         else
 367         {
 368                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 369                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 370                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 371
 372                 if(spawnpoints >= 8  && diameter > 4096) {
 373                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 374                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 375                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 376                 }
 377                 if(spawnpoints >= 12 && diameter > 5120)
 378                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 379         }
 380
 381         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 382         if(!spawnplaces)
 383         {
 384                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 385                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 386         }
 387
 388         dprint("-> diameter ",    ftos(diameter));
 389         dprint(";  spawnpoints ", ftos(spawnpoints));
 390         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 391
 392         fclose(fh);
 393
 394         return r;
 395 }
 396
 397 void _MapInfo_Map_Reset()
 398 {
 399         MapInfo_Map_title = "<TITLE>";
 400         MapInfo_Map_titlestring = "<TITLE>";
 401         MapInfo_Map_description = "<DESCRIPTION>";
 402         MapInfo_Map_author = "<AUTHOR>";
 403         MapInfo_Map_supportedGametypes = 0;
 404         MapInfo_Map_supportedFeatures = 0;
 405         MapInfo_Map_flags = 0;
 406         MapInfo_Map_clientstuff = "";
 407         MapInfo_Map_fog = "";
 408         MapInfo_Map_mins = '0 0 0';
 409         MapInfo_Map_maxs = '0 0 0';
 410 }
 411
 412 string _MapInfo_GetDefault(float t)
 413 {
 414         switch(t)
 415         {
 416                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 417                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 418                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 419                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 420                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 421                 case MAPINFO_TYPE_CA:              return "10 20 0";
 422                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 423                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 424                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 425                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 426                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 427                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 428                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 429                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 430                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 431                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 432                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 433                 default:                           return "";
 434         }
 435 }
 436
 437 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 438 {
 439         string sa;
 440         MapInfo_Map_supportedGametypes |= pThisType;
 441         if(!(pThisType & pWantedType))
 442                 return;
 443
 444         if(load_default)
 445                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 446
 447         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 448         {
 449                 cvar_set("fraglimit", "0");
 450         }
 451         else
 452         {
 453                 sa = car(s);
 454                 if(sa != "")
 455                         cvar_set("fraglimit", sa);
 456                 s = cdr(s);
 457         }
 458
 459         sa = car(s);
 460         if(sa != "")
 461                 cvar_set("timelimit", sa);
 462         s = cdr(s);
 463
 464         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 465         {
 466                 sa = car(s);
 467                 if(sa != "")
 468                         cvar_set("g_tdm_teams", sa);
 469                 s = cdr(s);
 470         }
 471
 472         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 473         {
 474                 sa = car(s);
 475                 if(sa != "")
 476                         cvar_set("g_keyhunt_teams", sa);
 477                 s = cdr(s);
 478         }
 479
 480         if(pWantedType == MAPINFO_TYPE_CA)
 481         {
 482                 sa = car(s);
 483                 if(sa != "")
 484                         cvar_set("g_ca_teams", sa);
 485                 s = cdr(s);
 486         }
 487
 488         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 489         {
 490                 sa = car(s);
 491                 if(sa != "")
 492                         cvar_set("g_freezetag_teams", sa);
 493                 s = cdr(s);
 494         }
 495
 496         if(pWantedType == MAPINFO_TYPE_CTF)
 497         {
 498                 sa = car(s);
 499                 if(sa != "")
 500                         cvar_set("fraglimit", sa);
 501                 s = cdr(s);
 502         }
 503
 504         /* keepaway wuz here
 505         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 506         {
 507                 sa = car(s);
 508                 if(sa != "")
 509                         cvar_set("fraglimit", sa);
 510                 s = cdr(s);
 511         }
 512         */
 513
 514         // rc = timelimit timelimit_qualification laps laps_teamplay
 515         if(pWantedType == MAPINFO_TYPE_RACE)
 516         {
 517                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 518                 cvar_set("g_race_qualifying_timelimit", sa);
 519                 s = cdr(s);
 520
 521                 sa = car(s);
 522                 if(sa != "")
 523                         if(cvar("g_race_teams") < 2)
 524                                 cvar_set("fraglimit", sa);
 525                 s = cdr(s);
 526
 527                 sa = car(s);
 528                 if(sa != "")
 529                         if(cvar("g_race_teams") >= 2)
 530                                 cvar_set("fraglimit", sa);
 531                 s = cdr(s);
 532         }
 533
 534         if(pWantedType == MAPINFO_TYPE_CTS)
 535         {
 536                 sa = car(s);
 537
 538                 // this is the skill of the map
 539                 // not parsed by anything yet
 540                 // for map databases
 541                 //if(sa != "")
 542                 //      cvar_set("fraglimit", sa);
 543
 544                 s = cdr(s);
 545         }
 546
 547         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 548         {
 549                 cvar_set("leadlimit", "0");
 550         }
 551         else
 552         {
 553                 sa = car(s);
 554                 if(sa != "")
 555                         cvar_set("leadlimit", sa);
 556                 s = cdr(s);
 557         }
 558 }
 559
 560 string _MapInfo_GetDefaultEx(float t)
 561 {
 562         entity e;
 563         for(e = MapInfo_Type_first; e; e = e.enemy)
 564                 if(t == e.items)
 565                         return e.model2;
 566         return "";
 567 }
 568
 569 float _MapInfo_GetTeamPlayBool(float t)
 570 {
 571         entity e;
 572         for(e = MapInfo_Type_first; e; e = e.enemy)
 573                 if(t == e.items)
 574                         return e.team;
 575         return FALSE;
 576 }
 577
 578 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 579 {
 580         string sa, k, v;
 581         float p;
 582         string fraglimit_normal;
 583         string fraglimit_teams;
 584
 585         MapInfo_Map_supportedGametypes |= pThisType;
 586         if(!(pThisType & pWantedType))
 587                 return;
 588
 589         // reset all the cvars to their defaults
 590
 591         cvar_set("timelimit", cvar_defstring("timelimit"));
 592         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 593         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 594         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 595         cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 596         cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 597         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 598         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 599         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 600
 601         fraglimit_normal = string_null;
 602         fraglimit_teams = string_null;
 603
 604         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 605         while(s != "")
 606         {
 607                 sa = car(s);
 608                 s = cdr(s);
 609
 610                 if(sa == "")
 611                         continue;
 612
 613                 p = strstrofs(sa, "=", 0);
 614                 if(p < 0)
 615                 {
 616                         print("Invalid gametype setting in mapinfo for gametype ", MapInfo_Type_ToString(pWantedType), ": ", sa, "\n");
 617                         continue;
 618                 }
 619                 k = substring(sa, 0, p);
 620                 v = substring(sa, p+1, -1);
 621
 622                 if(k == "timelimit")
 623                 {
 624                         cvar_set("timelimit", v);
 625                 }
 626                 else if(k == "leadlimit")
 627                 {
 628                         cvar_set("leadlimit", v);
 629                 }
 630                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 631                 {
 632                         fraglimit_normal = v;
 633                 }
 634                 else if(k == "teampointlimit" || k == "teamlaplimit")
 635                 {
 636                         fraglimit_teams = v;
 637                 }
 638                 else if(k == "teams")
 639                 {
 640                         cvar_set("g_tdm_teams", v);
 641                         cvar_set("g_ca_teams", v);
 642                         cvar_set("g_freezetag_teams", v);
 643                         cvar_set("g_keyhunt_teams", v);
 644                         cvar_set("g_domination_default_teams", v);
 645                         cvar_set("g_invasion_teams", v);
 646                 }
 647                 else if(k == "qualifying_timelimit")
 648                 {
 649                         cvar_set("g_race_qualifying_timelimit", v);
 650                 }
 651                 else if(k == "skill")
 652                 {
 653                         // ignore
 654                 }
 655                 else
 656                 {
 657                         print("Invalid gametype setting in mapinfo for gametype ", MapInfo_Type_ToString(pWantedType), ": ", sa, "\n");
 658                 }
 659         }
 660
 661         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 662         {
 663                 if(fraglimit_teams)
 664                         cvar_set("fraglimit", fraglimit_teams);
 665         }
 666         else
 667         {
 668                 if(fraglimit_normal)
 669                         cvar_set("fraglimit", fraglimit_normal);
 670         }
 671 }
 672
 673 float MapInfo_Type_FromString(string t)
 674 {
 675         entity e;
 676         if(t == "nexball")
 677         {
 678                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 679                 t = "nb";
 680                 print("'. Should use '", t, "'.\n");
 681         }
 682         if(t == "freezetag")
 683         {
 684                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 685                 t = "ft";
 686                 print("'. Should use '", t, "'.\n");
 687         }
 688         if(t == "keepaway")
 689         {
 690                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 691                 t = "ka";
 692                 print("'. Should use '", t, "'.\n");
 693         }
 694         if(t == "invasion")
 695         {
 696                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 697                 t = "inv";
 698                 print("'. Should use '", t, "'.\n");
 699         }
 700         if(t == "assault")
 701         {
 702                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 703                 t = "as";
 704                 print("'. Should use '", t, "'.\n");
 705         }
 706         if(t == "race")
 707         {
 708                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 709                 t = "rc";
 710                 print("'. Should use '", t, "'.\n");
 711         }
 712         if(t == "all")
 713                 return MAPINFO_TYPE_ALL;
 714         for(e = MapInfo_Type_first; e; e = e.enemy)
 715                 if(t == e.mdl)
 716                         return e.items;
 717         return 0;
 718 }
 719
 720 string MapInfo_Type_Description(float t)
 721 {
 722         entity e;
 723         for(e = MapInfo_Type_first; e; e = e.enemy)
 724                 if(t == e.items)
 725                         return e.gametype_description;
 726         return "";
 727 }
 728
 729 string MapInfo_Type_ToString(float t)
 730 {
 731         entity e;
 732         if(t == MAPINFO_TYPE_ALL)
 733                 return "all";
 734         for(e = MapInfo_Type_first; e; e = e.enemy)
 735                 if(t == e.items)
 736                         return e.mdl;
 737         return "";
 738 }
 739
 740 string MapInfo_Type_ToText(float t)
 741 {
 742         entity e;
 743         for(e = MapInfo_Type_first; e; e = e.enemy)
 744                 if(t == e.items)
 745                         return e.message;
 746         /* xgettext:no-c-format */
 747         return _("@!#%'n Tuba Throwing");
 748 }
 749
 750 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 751 {
 752         string t;
 753         float fh, o;
 754         t = car(s); s = cdr(s);
 755
 756         // limited support of "" and comments
 757         //   remove trailing and leading " of t
 758         if(substring(t, 0, 1) == "\"")
 759         {
 760                 if(substring(t, -1, 1) == "\"")
 761                         t = substring(t, 1, -2);
 762         }
 763
 764         //   remove leading " of s
 765         if(substring(s, 0, 1) == "\"")
 766         {
 767                 s = substring(s, 1, -1);
 768         }
 769         //   remove trailing " of s, and all that follows (cvar description)
 770         o = strstrofs(s, "\"", 0);
 771         if(o >= 0)
 772                 s = substring(s, 0, o);
 773
 774         //   remove // comments
 775         o = strstrofs(s, "//", 0);
 776         if(o >= 0)
 777                 s = substring(s, 0, o);
 778
 779         //   remove trailing spaces
 780         while(substring(s, -1, 1) == " ")
 781                 s = substring(s, 0, -2);
 782
 783         if(t == "#include")
 784         {
 785                 if(recurse > 0)
 786                 {
 787                         fh = fopen(s, FILE_READ);
 788                         if(fh < 0)
 789                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 790                         else
 791                         {
 792                                 for(;;)
 793                                 {
 794                                         if (!((s = fgets(fh))))
 795                                                 break;
 796
 797                                         // catch different sorts of comments
 798                                         if(s == "")                    // empty lines
 799                                                 continue;
 800                                         if(substring(s, 0, 1) == "#")  // UNIX style
 801                                                 continue;
 802                                         if(substring(s, 0, 2) == "//") // C++ style
 803                                                 continue;
 804                                         if(substring(s, 0, 1) == "_")  // q3map style
 805                                                 continue;
 806
 807                                         if(substring(s, 0, 4) == "set ")
 808                                                 s = substring(s, 4, -1);
 809                                         if(substring(s, 0, 5) == "seta ")
 810                                                 s = substring(s, 5, -1);
 811
 812                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 813                                 }
 814                                 fclose(fh);
 815                         }
 816                 }
 817                 else
 818                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 819         }
 820         else if(t == "")
 821                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 822         else if (!cvar_value_issafe(t))
 823                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 824         else if (!cvar_value_issafe(s))
 825                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 826         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 827                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 828         else if(matchacl(acl, t) <= 0)
 829                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 830         else
 831         {
 832                 if(type == 0) // server set
 833                 {
 834                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 835                         if(cvar("g_campaign"))
 836                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 837                         else
 838                                 cvar_settemp(t, s);
 839                 }
 840                 else
 841                 {
 842                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 843                         MapInfo_Map_clientstuff = strcat(
 844                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 845                                         );
 846                 }
 847         }
 848 }
 849
 850 float MapInfo_isRedundant(string fn, string t)
 851 {
 852         // normalize file name
 853         fn = strreplace("_", "-", fn);
 854
 855         // normalize visible title
 856         t = strreplace(": ", "-", t);
 857         t = strreplace(":", "-", t);
 858         t = strreplace(" ", "-", t);
 859         t = strreplace("_", "-", t);
 860         t = strreplace("'", "-", t);
 861
 862         if(!strcasecmp(fn, t))
 863                 return TRUE;
 864
 865         // we allow the visible title to have punctuation the file name does
 866         // not, but not vice versa
 867         t = strreplace("-", "", t);
 868
 869         if(!strcasecmp(fn, t))
 870                 return TRUE;
 871
 872         return FALSE;
 873 }
 874
 875 // load info about a map by name into the MapInfo_Map_* globals
 876 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 877 {
 878         string fn;
 879         string s, t;
 880         float fh;
 881         float r, f, n, i, p;
 882         string acl;
 883
 884         acl = MAPINFO_SETTEMP_ACL_USER;
 885
 886         if(strstrofs(pFilename, "/", 0) >= 0)
 887         {
 888                 print("Invalid character in map name, ignored\n");
 889                 return 0;
 890         }
 891
 892         if(pGametypeToSet == 0)
 893                 if(MapInfo_Cache_Retrieve(pFilename))
 894                         return 1;
 895
 896         r = 1;
 897
 898         MapInfo_Map_bspname = pFilename;
 899
 900         // default all generic fields so they have "good" values in case something fails
 901         fn = strcat("maps/", pFilename, ".mapinfo");
 902         fh = fopen(fn, FILE_READ);
 903         if(fh < 0)
 904         {
 905                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 906                 fh = fopen(fn, FILE_READ);
 907                 if(fh < 0)
 908                 {
 909                         if(!pAllowGenerate)
 910                                 return 0;
 911                         _MapInfo_Map_Reset();
 912                         r = _MapInfo_Generate(pFilename);
 913                         if(!r)
 914                                 return 0;
 915                         fh = fopen(fn, FILE_WRITE);
 916                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 917                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 918                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 919                         if(_MapInfo_Map_worldspawn_music != "")
 920                         {
 921                                 if(
 922                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 923                                         ||
 924                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 925                                 )
 926                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 927                                 else
 928                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 929                         }
 930                         else
 931                         {
 932                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 933                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 934                                 for(;;)
 935                                 {
 936                                         i = floor(random() * n);
 937                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 938                                                 break;
 939                                 }
 940                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 941                         }
 942                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 943                                 fputs(fh, "has weapons\n");
 944                         else
 945                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 946                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 947                                 fputs(fh, "has turrets\n");
 948                         else
 949                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 950                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 951                                 fputs(fh, "has vehicles\n");
 952                         else
 953                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 954                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 955                                 fputs(fh, "frustrating\n");
 956
 957                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 958                                 if(MapInfo_Map_supportedGametypes & i)
 959                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 960
 961                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 962                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 963
 964                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 965                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 966                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 967                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 968                         fputs(fh, "// optional: hidden\n");
 969
 970                         fclose(fh);
 971                         r = 2;
 972                         // return r;
 973                         fh = fopen(fn, FILE_READ);
 974                         if(fh < 0)
 975                                 error("... but I just wrote it!");
 976                 }
 977
 978                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 979         }
 980
 981         _MapInfo_Map_Reset();
 982         for(;;)
 983         {
 984                 if (!((s = fgets(fh))))
 985                         break;
 986
 987                 // catch different sorts of comments
 988                 if(s == "")                    // empty lines
 989                         continue;
 990                 if(substring(s, 0, 1) == "#")  // UNIX style
 991                         continue;
 992                 if(substring(s, 0, 2) == "//") // C++ style
 993                         continue;
 994                 if(substring(s, 0, 1) == "_")  // q3map style
 995                         continue;
 996
 997                 p = strstrofs(s, "//", 0);
 998                 if(p >= 0)
 999                         s = substring(s, 0, p);
1000
1001                 t = car(s); s = cdr(s);
1002                 if(t == "title")
1003                         MapInfo_Map_title = s;
1004                 else if(t == "description")
1005                         MapInfo_Map_description = s;
1006                 else if(t == "author")
1007                         MapInfo_Map_author = s;
1008                 else if(t == "has")
1009                 {
1010                         t = car(s); // s = cdr(s);
1011                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1012                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1013                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1014                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1015                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1016                         else
1017                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
1018                 }
1019                 else if(t == "hidden")
1020                 {
1021                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1022                 }
1023                 else if(t == "forbidden")
1024                 {
1025                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1026                 }
1027                 else if(t == "frustrating")
1028                 {
1029                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1030                 }
1031                 else if(t == "noautomaplist")
1032                 {
1033                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1034                 }
1035                 else if(t == "type")
1036                 {
1037                         t = car(s); s = cdr(s);
1038                         f = MapInfo_Type_FromString(t);
1039                         dprint("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1040                         if(f)
1041                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
1042                         else
1043                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1044                 }
1045                 else if(t == "gametype")
1046                 {
1047                         t = car(s); s = cdr(s);
1048                         f = MapInfo_Type_FromString(t);
1049                         if(f)
1050                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1051                         else
1052                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1053                 }
1054                 else if(t == "size")
1055                 {
1056                         float a, b, c, d, e;
1057                         t = car(s); s = cdr(s); a = stof(t);
1058                         t = car(s); s = cdr(s); b = stof(t);
1059                         t = car(s); s = cdr(s); c = stof(t);
1060                         t = car(s); s = cdr(s); d = stof(t);
1061                         t = car(s); s = cdr(s); e = stof(t);
1062                         if(s == "")
1063                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1064                         else
1065                         {
1066                                 t = car(s); s = cdr(s); f = stof(t);
1067                                 if(s != "")
1068                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1069                                 else
1070                                 {
1071                                         if(a >= d || b >= e || c >= f)
1072                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1073                                         else
1074                                         {
1075                                                 MapInfo_Map_mins_x = a;
1076                                                 MapInfo_Map_mins_y = b;
1077                                                 MapInfo_Map_mins_z = c;
1078                                                 MapInfo_Map_maxs_x = d;
1079                                                 MapInfo_Map_maxs_y = e;
1080                                                 MapInfo_Map_maxs_z = f;
1081                                         }
1082                                 }
1083                         }
1084                 }
1085                 else if(t == "settemp_for_type")
1086                 {
1087                         t = car(s); s = cdr(s);
1088                         if((f = MapInfo_Type_FromString(t)))
1089                         {
1090                                 if(f & pGametypeToSet)
1091                                 {
1092                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1093                                 }
1094                         }
1095                         else
1096                         {
1097                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1098                         }
1099                 }
1100                 else if(t == "clientsettemp_for_type")
1101                 {
1102                         t = car(s); s = cdr(s);
1103                         if((f = MapInfo_Type_FromString(t)))
1104                         {
1105                                 if(f & pGametypeToSet)
1106                                 {
1107                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1108                                 }
1109                         }
1110                         else
1111                         {
1112                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1113                         }
1114                 }
1115                 else if(t == "fog")
1116                 {
1117                         if (!cvar_value_issafe(s))
1118                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1119                         else
1120                                 MapInfo_Map_fog = s;
1121                 }
1122                 else if(t == "cdtrack")
1123                 {
1124                         t = car(s); s = cdr(s);
1125                         if(pGametypeToSet) // FIXME is this check right here?
1126                         {
1127                                 if (!cvar_value_issafe(t))
1128                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1129                                 else
1130                                         MapInfo_Map_clientstuff = strcat(
1131                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1132                                         );
1133                         }
1134                 }
1135                 else
1136                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1137         }
1138         fclose(fh);
1139
1140         if(MapInfo_Map_title == "<TITLE>")
1141                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1142         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1143                 MapInfo_Map_titlestring = MapInfo_Map_title;
1144         else
1145                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1146
1147         MapInfo_Cache_Store();
1148         if(MapInfo_Map_supportedGametypes != 0)
1149                 return r;
1150         dprint("Map ", pFilename, " supports no game types, ignored\n");
1151         return 0;
1152 }
1153 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1154 {
1155         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1156
1157         if(cvar("g_tdm_on_dm_maps"))
1158         {
1159                 // if this is set, all DM maps support TDM too
1160                 if (!(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH))
1161                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1162                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1163         }
1164
1165         if(pGametypeToSet)
1166         {
1167                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1168                 {
1169                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1170                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1171                         //return;
1172                 }
1173         }
1174
1175         return r;
1176 }
1177
1178 float MapInfo_FindName(string s)
1179 {
1180         // if there is exactly one map of prefix s, return it
1181         // if not, return the null string
1182         // note that DP sorts glob results... so I can use a binary search
1183         float l, r, m, cmp;
1184         l = 0;
1185         r = MapInfo_count;
1186         // invariants: r is behind s, l-1 is equal or before
1187         while(l != r)
1188         {
1189                 m = floor((l + r) / 2);
1190                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1191                 cmp = strcasecmp(MapInfo_FindName_match, s);
1192                 if(cmp == 0)
1193                         return m; // found and good
1194                 if(cmp < 0)
1195                         l = m + 1; // l-1 is before s
1196                 else
1197                         r = m; // behind s
1198         }
1199         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1200         MapInfo_FindName_firstResult = l;
1201         // r == l, so: l is behind s, l-1 is before
1202         // SO: if there is any, l is the one with the right prefix
1203         //     and l+1 may be one too
1204         if(l == MapInfo_count)
1205         {
1206                 MapInfo_FindName_match = string_null;
1207                 MapInfo_FindName_firstResult = -1;
1208                 return -1; // no MapInfo_FindName_match, behind last item
1209         }
1210         if(!startsWithNocase(MapInfo_FindName_match, s))
1211         {
1212                 MapInfo_FindName_match = string_null;
1213                 MapInfo_FindName_firstResult = -1;
1214                 return -1; // wrong prefix
1215         }
1216         if(l == MapInfo_count - 1)
1217                 return l; // last one, nothing can follow => unique
1218         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1219         {
1220                 MapInfo_FindName_match = string_null;
1221                 return -1; // ambigous MapInfo_FindName_match
1222         }
1223         return l;
1224 }
1225
1226 string MapInfo_FixName(string s)
1227 {
1228         MapInfo_FindName(s);
1229         return MapInfo_FindName_match;
1230 }
1231
1232 float MapInfo_CurrentFeatures()
1233 {
1234         float req;
1235         req = 0;
1236         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1237                 req |= MAPINFO_FEATURE_WEAPONS;
1238         return req;
1239 }
1240
1241 float MapInfo_CurrentGametype()
1242 {
1243         float prev;
1244         entity e;
1245         prev = cvar("gamecfg");
1246         for(e = MapInfo_Type_first; e; e = e.enemy)
1247                 if(cvar(e.netname))
1248                         if(prev != e.items)
1249                                 return e.items;
1250         if(prev)
1251                 return prev;
1252         return MAPINFO_TYPE_DEATHMATCH;
1253 }
1254
1255 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1256 {
1257         if(!MapInfo_Get_ByName(s, 1, 0))
1258                 return 0;
1259         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1260                 return 0;
1261         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1262                 return 0;
1263         return 1;
1264 }
1265
1266 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1267 {
1268         float r;
1269         r = _MapInfo_CheckMap(s);
1270         MapInfo_ClearTemps();
1271         return r;
1272 }
1273
1274 void MapInfo_SwitchGameType(float t)
1275 {
1276         entity e;
1277         for(e = MapInfo_Type_first; e; e = e.enemy)
1278                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1279 }
1280
1281 void MapInfo_LoadMap(string s, float reinit)
1282 {
1283         MapInfo_Map_supportedGametypes = 0;
1284         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1285         //if(!MapInfo_CheckMap(s))
1286         //{
1287         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1288         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1289         //}
1290
1291         cvar_settemp_restore();
1292         if(reinit)
1293                 localcmd(strcat("\nmap ", s, "\n"));
1294         else
1295                 localcmd(strcat("\nchangelevel ", s, "\n"));
1296 }
1297
1298 string MapInfo_ListAllowedMaps(float type, float pRequiredFlags, float pForbiddenFlags)
1299 {
1300         string out;
1301         float i;
1302
1303         // to make absolutely sure:
1304         MapInfo_Enumerate();
1305         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1306
1307         out = "";
1308         for(i = 0; i < MapInfo_count; ++i)
1309                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1310         return substring(out, 1, strlen(out) - 1);
1311 }
1312
1313 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1314 {
1315         string out;
1316         float i;
1317
1318         // to make absolutely sure:
1319         MapInfo_Enumerate();
1320         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1321
1322         out = "";
1323         for(i = 0; i < MapInfo_count; ++i)
1324                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1325
1326         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1327
1328         return substring(out, 1, strlen(out) - 1);
1329 }
1330
1331 void MapInfo_LoadMapSettings_SaveGameType(float t)
1332 {
1333         MapInfo_SwitchGameType(t);
1334         cvar_set("gamecfg", ftos(t));
1335         MapInfo_LoadedGametype = t;
1336 }
1337
1338 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1339 {
1340         float t;
1341
1342         t = MapInfo_CurrentGametype();
1343         MapInfo_LoadMapSettings_SaveGameType(t);
1344
1345         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1346         {
1347                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1348                 {
1349                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1350                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1351                         return; // do not call Get_ByName!
1352                 }
1353
1354                 if(MapInfo_Map_supportedGametypes == 0)
1355                 {
1356                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1357                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1358                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1359                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1360                         return; // do not call Get_ByName!
1361                 }
1362
1363                 t = 1;
1364                 while(!(MapInfo_Map_supportedGametypes & 1))
1365                 {
1366                         t *= 2;
1367                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1368                 }
1369
1370                 // t is now a supported mode!
1371                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1372                 MapInfo_LoadMapSettings_SaveGameType(t);
1373         }
1374         MapInfo_Get_ByName(s, 1, t);
1375 }
1376
1377 void MapInfo_ClearTemps()
1378 {
1379         MapInfo_Map_bspname = string_null;
1380         MapInfo_Map_title = string_null;
1381         MapInfo_Map_titlestring = string_null;
1382         MapInfo_Map_description = string_null;
1383         MapInfo_Map_author = string_null;
1384         MapInfo_Map_clientstuff = string_null;
1385         MapInfo_Map_supportedGametypes = 0;
1386         MapInfo_Map_supportedFeatures = 0;
1387 }
1388
1389 void MapInfo_Shutdown()
1390 {
1391         MapInfo_ClearTemps();
1392         MapInfo_Filter_Free();
1393         MapInfo_Cache_Destroy();
1394         if(_MapInfo_globopen)
1395         {
1396                 search_end(_MapInfo_globhandle);
1397                 _MapInfo_globhandle = -1;
1398                 _MapInfo_globopen = FALSE;
1399         }
1400 }
1401
1402 float MapInfo_ForbiddenFlags()
1403 {
1404         float f;
1405         f = MAPINFO_FLAG_FORBIDDEN;
1406
1407 #ifndef MENUQC
1408         if (!cvar("g_maplist_allow_hidden"))
1409 #endif
1410                 f |= MAPINFO_FLAG_HIDDEN;
1411
1412         if (!cvar("g_maplist_allow_frustrating"))
1413                 f |= MAPINFO_FLAG_FRUSTRATING;
1414
1415         return f;
1416 }
1417
1418 float MapInfo_RequiredFlags()
1419 {
1420         float f;
1421         f = 0;
1422
1423         if(cvar("g_maplist_allow_frustrating") > 1)
1424                 f |= MAPINFO_FLAG_FRUSTRATING;
1425
1426         return f;
1427 }