qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(s == "")
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(s == "")
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         if(!_MapInfo_globopen)
  93                 return string_null;
  94         s = search_getfilename(_MapInfo_globhandle, i);
  95         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  96 }
  97
  98 void MapInfo_Enumerate()
  99 {
 100         if(_MapInfo_globopen)
 101         {
 102                 search_end(_MapInfo_globhandle);
 103                 _MapInfo_globopen = 0;
 104         }
 105         MapInfo_Cache_Invalidate();
 106         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 107         if(_MapInfo_globhandle >= 0)
 108         {
 109                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 110                 _MapInfo_globopen = 1;
 111         }
 112         else
 113                 _MapInfo_globcount = 0;
 114 }
 115
 116 // filter the info by game type mask (updates MapInfo_count)
 117 //
 118 float _MapInfo_filtered;
 119 float _MapInfo_filtered_allocated;
 120 float MapInfo_FilterList_Lookup(float i)
 121 {
 122         return stof(bufstr_get(_MapInfo_filtered, i));
 123 }
 124
 125 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 126 {
 127         string h;
 128         h = bufstr_get(_MapInfo_filtered, i);
 129         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 130         bufstr_set(_MapInfo_filtered, j, h);
 131 }
 132
 133 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 134 {
 135         string a, b;
 136         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 137         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 138         return strcasecmp(a, b);
 139 }
 140
 141 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 142 {
 143         float i, j;
 144         if not(_MapInfo_filtered_allocated)
 145         {
 146                 _MapInfo_filtered_allocated = 1;
 147                 _MapInfo_filtered = buf_create();
 148         }
 149         MapInfo_count = 0;
 150         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 151         {
 152                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 153                         if(pAbortOnGenerate)
 154                         {
 155                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 156                                 MapInfo_progress = i / _MapInfo_globcount;
 157                                 return 0;
 158                         }
 159                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 160                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 161                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 162                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 163                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 164         }
 165         MapInfo_count = j + 1;
 166         MapInfo_ClearTemps();
 167
 168         // sometimes the glob isn't sorted nicely, so fix it here...
 169         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 170
 171         return 1;
 172 }
 173
 174 void MapInfo_Filter_Free()
 175 {
 176         if(_MapInfo_filtered_allocated)
 177         {
 178                 buf_del(_MapInfo_filtered);
 179                 _MapInfo_filtered_allocated = 0;
 180         }
 181 }
 182
 183 // load info about the i-th map into the MapInfo_Map_* globals
 184 string MapInfo_BSPName_ByID(float i)
 185 {
 186         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 187 }
 188
 189 string unquote(string s)
 190 {
 191         float i, j, l;
 192         l = strlen(s);
 193         j = -1;
 194         for(i = 0; i < l; ++i)
 195         {
 196                 string ch;
 197                 ch = substring(s, i, 1);
 198                 if(ch != " ") if(ch != "\"")
 199                 {
 200                         for(j = strlen(s) - i - 1; j > 0; --j)
 201                         {
 202                                 ch = substring(s, i+j, 1);
 203                                 if(ch != " ") if(ch != "\"")
 204                                         return substring(s, i, j+1);
 205                         }
 206                         return substring(s, i, 1);
 207                 }
 208         }
 209         return "";
 210 }
 211
 212 float MapInfo_Get_ByID(float i)
 213 {
 214         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 215                 return 1;
 216         return 0;
 217 }
 218
 219 string _MapInfo_Map_worldspawn_music;
 220
 221 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 222 {
 223         string fn;
 224         float fh;
 225         string s, k, v;
 226         vector o;
 227         float i;
 228         float inWorldspawn;
 229         float r;
 230         float twoBaseModes;
 231         float diameter, spawnpoints;
 232         float spawnplaces;
 233
 234         vector mapMins, mapMaxs;
 235
 236         r = 1;
 237         fn = strcat("maps/", pFilename, ".ent");
 238         fh = fopen(fn, FILE_READ);
 239         if(fh < 0)
 240         {
 241                 r = 2;
 242                 fn = strcat("maps/", pFilename, ".bsp");
 243                 fh = fopen(fn, FILE_READ);
 244         }
 245         if(fh < 0)
 246                 return 0;
 247         print("Analyzing ", fn, " to generate initial mapinfo\n");
 248
 249         inWorldspawn = 2;
 250         MapInfo_Map_flags = 0;
 251         MapInfo_Map_supportedGametypes = 0;
 252         spawnpoints = 0;
 253         spawnplaces = 0;
 254         _MapInfo_Map_worldspawn_music = "";
 255         mapMins = '0 0 0';
 256         mapMaxs = '0 0 0';
 257
 258         for(;;)
 259         {
 260                 if not((s = fgets(fh)))
 261                         break;
 262                 if(inWorldspawn == 1)
 263                         if(startsWith(s, "}"))
 264                                 inWorldspawn = 0;
 265                 k = unquote(car(s));
 266                 v = unquote(cdr(s));
 267                 if(inWorldspawn)
 268                 {
 269                         if(k == "classname" && v == "worldspawn")
 270                                 inWorldspawn = 1;
 271                         else if(k == "author")
 272                                 MapInfo_Map_author = v;
 273                         else if(k == "_description")
 274                                 MapInfo_Map_description = v;
 275                         else if(k == "music")
 276                                 _MapInfo_Map_worldspawn_music = v;
 277                         else if(k == "noise")
 278                                 _MapInfo_Map_worldspawn_music = v;
 279                         else if(k == "message")
 280                         {
 281                                 i = strstrofs(v, " by ", 0);
 282                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 283                                 {
 284                                         MapInfo_Map_title = substring(v, 0, i);
 285                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 286                                 }
 287                                 else
 288                                         MapInfo_Map_title = v;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if(k == "origin")
 294                         {
 295                                 o = stov(strcat("'", v, "'"));
 296                                 mapMins_x = min(mapMins_x, o_x);
 297                                 mapMins_y = min(mapMins_y, o_y);
 298                                 mapMins_z = min(mapMins_z, o_z);
 299                                 mapMaxs_x = max(mapMaxs_x, o_x);
 300                                 mapMaxs_y = max(mapMaxs_y, o_y);
 301                                 mapMaxs_z = max(mapMaxs_z, o_z);
 302                         }
 303                         else if(k == "race_place")
 304                         {
 305                                 if(stof(v) > 0)
 306                                         spawnplaces = 1;
 307                         }
 308                         else if(k == "classname")
 309                         {
 310                                 if(v == "dom_controlpoint")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 312                                 else if(v == "item_flag_team2")
 313                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 314                                 else if(v == "team_CTF_blueflag")
 315                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 316                                 else if(v == "td_generator" || v == "td_spawnpoint")
 317                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TD;
 318                                 else if(v == "target_assault_roundend")
 319                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 320                                 else if(v == "onslaught_generator")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 322                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 323                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 324                                 else if(v == "info_player_team1")
 325                                         ++spawnpoints;
 326                                 else if(v == "info_player_team2")
 327                                         ++spawnpoints;
 328                                 else if(v == "info_player_start")
 329                                         ++spawnpoints;
 330                                 else if(v == "info_player_deathmatch")
 331                                         ++spawnpoints;
 332                                 else if(v == "trigger_race_checkpoint")
 333                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 334                                 else if(v == "target_startTimer")
 335                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 336                                 else if(v == "weapon_nex")
 337                                         { }
 338                                 else if(v == "weapon_railgun")
 339                                         { }
 340                                 else if(startsWith(v, "weapon_"))
 341                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 342                                 else if(startsWith(v, "turret_"))
 343                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 344                                 else if(startsWith(v, "vehicle_"))
 345                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 346                                 else if(v == "target_music" || v == "trigger_music")
 347                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 348                         }
 349                 }
 350         }
 351         if(inWorldspawn)
 352         {
 353                 print(fn, " ended still in worldspawn, BUG\n");
 354                 return 0;
 355         }
 356         diameter = vlen(mapMaxs - mapMins);
 357
 358         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 359         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 360         {
 361                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 362                 // as the map is too symmetric for them.
 363         }
 364         else
 365         {
 366                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 367                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 368                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 369
 370                 if(spawnpoints >= 8  && diameter > 4096) {
 371                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 372                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 373                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 374                 }
 375                 if(                     diameter < 4096)
 376                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 377                 if(spawnpoints >= 12 && diameter > 5120)
 378                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 379         }
 380
 381         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 382         if(!spawnplaces)
 383         {
 384                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 385                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 386         }
 387
 388         dprint("-> diameter ",    ftos(diameter));
 389         dprint(";  spawnpoints ", ftos(spawnpoints));
 390         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 391
 392         fclose(fh);
 393
 394         return r;
 395 }
 396
 397 void _MapInfo_Map_Reset()
 398 {
 399         MapInfo_Map_title = "<TITLE>";
 400         MapInfo_Map_titlestring = "<TITLE>";
 401         MapInfo_Map_description = "<DESCRIPTION>";
 402         MapInfo_Map_author = "<AUTHOR>";
 403         MapInfo_Map_supportedGametypes = 0;
 404         MapInfo_Map_supportedFeatures = 0;
 405         MapInfo_Map_flags = 0;
 406         MapInfo_Map_clientstuff = "";
 407         MapInfo_Map_fog = "";
 408         MapInfo_Map_mins = '0 0 0';
 409         MapInfo_Map_maxs = '0 0 0';
 410 }
 411
 412 string _MapInfo_GetDefault(float t)
 413 {
 414         switch(t)
 415         {
 416                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 417                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 418                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 419                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 420                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 421                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
 422                 case MAPINFO_TYPE_CA:              return "10 20 0";
 423                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 424                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 425                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 426                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 427                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 428                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 429                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 430                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 431                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 432                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 433                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 434                 default:                           return "";
 435         }
 436 }
 437
 438 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 439 {
 440         string sa;
 441         MapInfo_Map_supportedGametypes |= pThisType;
 442         if(!(pThisType & pWantedType))
 443                 return;
 444
 445         if(load_default)
 446                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 447
 448         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 449         {
 450                 cvar_set("fraglimit", "0");
 451         }
 452         else
 453         {
 454                 sa = car(s);
 455                 if(sa != "")
 456                         cvar_set("fraglimit", sa);
 457                 s = cdr(s);
 458         }
 459
 460         sa = car(s);
 461         if(sa != "")
 462                 cvar_set("timelimit", sa);
 463         s = cdr(s);
 464
 465         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 466         {
 467                 sa = car(s);
 468                 if(sa != "")
 469                         cvar_set("g_tdm_teams", sa);
 470                 s = cdr(s);
 471         }
 472
 473         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 474         {
 475                 sa = car(s);
 476                 if(sa != "")
 477                         cvar_set("g_keyhunt_teams", sa);
 478                 s = cdr(s);
 479         }
 480
 481         if(pWantedType == MAPINFO_TYPE_CA)
 482         {
 483                 sa = car(s);
 484                 if(sa != "")
 485                         cvar_set("g_ca_teams", sa);
 486                 s = cdr(s);
 487         }
 488
 489         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 490         {
 491                 sa = car(s);
 492                 if(sa != "")
 493                         cvar_set("g_freezetag_teams", sa);
 494                 s = cdr(s);
 495         }
 496
 497         if(pWantedType == MAPINFO_TYPE_CTF)
 498         {
 499                 sa = car(s);
 500                 if(sa != "")
 501                         cvar_set("fraglimit", sa);
 502                 s = cdr(s);
 503         }
 504
 505         /* keepaway wuz here
 506         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 507         {
 508                 sa = car(s);
 509                 if(sa != "")
 510                         cvar_set("fraglimit", sa);
 511                 s = cdr(s);
 512         }
 513         */
 514
 515         // rc = timelimit timelimit_qualification laps laps_teamplay
 516         if(pWantedType == MAPINFO_TYPE_RACE)
 517         {
 518                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 519                 cvar_set("g_race_qualifying_timelimit", sa);
 520                 s = cdr(s);
 521
 522                 sa = car(s);
 523                 if(sa != "")
 524                         if(cvar("g_race_teams") < 2)
 525                                 cvar_set("fraglimit", sa);
 526                 s = cdr(s);
 527
 528                 sa = car(s);
 529                 if(sa != "")
 530                         if(cvar("g_race_teams") >= 2)
 531                                 cvar_set("fraglimit", sa);
 532                 s = cdr(s);
 533         }
 534
 535         if(pWantedType == MAPINFO_TYPE_CTS)
 536         {
 537                 sa = car(s);
 538
 539                 // this is the skill of the map
 540                 // not parsed by anything yet
 541                 // for map databases
 542                 //if(sa != "")
 543                 //      cvar_set("fraglimit", sa);
 544
 545                 s = cdr(s);
 546         }
 547
 548         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 549         {
 550                 cvar_set("leadlimit", "0");
 551         }
 552         else
 553         {
 554                 sa = car(s);
 555                 if(sa != "")
 556                         cvar_set("leadlimit", sa);
 557                 s = cdr(s);
 558         }
 559 }
 560
 561 string _MapInfo_GetDefaultEx(float t)
 562 {
 563         entity e;
 564         for(e = MapInfo_Type_first; e; e = e.enemy)
 565                 if(t == e.items)
 566                         return e.model2;
 567         return "";
 568 }
 569
 570 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 571 {
 572         string sa, k, v;
 573         float p;
 574         string fraglimit_normal;
 575         string fraglimit_teams;
 576
 577         MapInfo_Map_supportedGametypes |= pThisType;
 578         if(!(pThisType & pWantedType))
 579                 return;
 580
 581         // reset all the cvars to their defaults
 582
 583         cvar_set("timelimit", cvar_defstring("timelimit"));
 584         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 585         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 586         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 587         cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 588         cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 589         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 590         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 591         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 592
 593         fraglimit_normal = string_null;
 594         fraglimit_teams = string_null;
 595
 596         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 597         while(s != "")
 598         {
 599                 sa = car(s);
 600                 s = cdr(s);
 601
 602                 if(sa == "")
 603                         continue;
 604
 605                 p = strstrofs(sa, "=", 0);
 606                 if(p < 0)
 607                 {
 608                         k = "timelimit";
 609                         v = s;
 610                 }
 611                 else
 612                 {
 613                         k = substring(sa, 0, p);
 614                         v = substring(sa, p+1, -1);
 615                 }
 616
 617                 if(k == "timelimit")
 618                 {
 619                         cvar_set("timelimit", v);
 620                 }
 621                 else if(k == "leadlimit")
 622                 {
 623                         cvar_set("leadlimit", v);
 624                 }
 625                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 626                 {
 627                         fraglimit_normal = v;
 628                 }
 629                 else if(k == "teampointlimit" || k == "teamlaplimit")
 630                 {
 631                         fraglimit_teams = v;
 632                 }
 633                 else if(k == "teams")
 634                 {
 635                         cvar_set("g_tdm_teams", v);
 636                         cvar_set("g_ca_teams", v);
 637                         cvar_set("g_freezetag_teams", v);
 638                         cvar_set("g_keyhunt_teams", v);
 639                         cvar_set("g_domination_default_teams", v);
 640                 }
 641                 else if(k == "qualifying_timelimit")
 642                 {
 643                         cvar_set("g_race_qualifying_timelimit", v);
 644                 }
 645                 else if(k == "skill")
 646                 {
 647                         // ignore
 648                 }
 649                 else
 650                 {
 651                         print("Invalid gametype key in mapinfo: ", k, "\n");
 652                 }
 653         }
 654
 655         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 656         {
 657                 if(fraglimit_teams)
 658                         cvar_set("fraglimit", fraglimit_teams);
 659         }
 660         else
 661         {
 662                 if(fraglimit_normal)
 663                         cvar_set("fraglimit", fraglimit_normal);
 664         }
 665 }
 666
 667 float MapInfo_Type_FromString(string t)
 668 {
 669         entity e;
 670         if(t == "nexball")
 671         {
 672                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 673                 t = "nb";
 674                 print("'. Should use '", t, "'.\n");
 675         }
 676         if(t == "freezetag")
 677         {
 678                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 679                 t = "ft";
 680                 print("'. Should use '", t, "'.\n");
 681         }
 682         if(t == "keepaway")
 683         {
 684                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 685                 t = "ka";
 686                 print("'. Should use '", t, "'.\n");
 687         }
 688         if(t == "all")
 689                 return MAPINFO_TYPE_ALL;
 690         for(e = MapInfo_Type_first; e; e = e.enemy)
 691                 if(t == e.mdl)
 692                         return e.items;
 693         return 0;
 694 }
 695
 696 string MapInfo_Type_ToString(float t)
 697 {
 698         entity e;
 699         if(t == MAPINFO_TYPE_ALL)
 700                 return "all";
 701         for(e = MapInfo_Type_first; e; e = e.enemy)
 702                 if(t == e.items)
 703                         return e.mdl;
 704         return "";
 705 }
 706
 707 string MapInfo_Type_ToText(float t)
 708 {
 709         entity e;
 710         for(e = MapInfo_Type_first; e; e = e.enemy)
 711                 if(t == e.items)
 712                         return e.message;
 713         return _("@!#%'n Tuba Throwing");
 714 }
 715
 716 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 717 {
 718         string t;
 719         float fh, o;
 720         t = car(s); s = cdr(s);
 721
 722         // limited support of "" and comments
 723         //   remove trailing and leading " of t
 724         if(substring(t, 0, 1) == "\"")
 725         {
 726                 if(substring(t, -1, 1) == "\"")
 727                         t = substring(t, 1, -2);
 728         }
 729
 730         //   remove leading " of s
 731         if(substring(s, 0, 1) == "\"")
 732         {
 733                 s = substring(s, 1, -1);
 734         }
 735         //   remove trailing " of s, and all that follows (cvar description)
 736         o = strstrofs(s, "\"", 0);
 737         if(o >= 0)
 738                 s = substring(s, 0, o);
 739
 740         //   remove // comments
 741         o = strstrofs(s, "//", 0);
 742         if(o >= 0)
 743                 s = substring(s, 0, o);
 744
 745         //   remove trailing spaces
 746         while(substring(s, -1, 1) == " ")
 747                 s = substring(s, 0, -2);
 748
 749         if(t == "#include")
 750         {
 751                 if(recurse > 0)
 752                 {
 753                         fh = fopen(s, FILE_READ);
 754                         if(fh < 0)
 755                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 756                         else
 757                         {
 758                                 for(;;)
 759                                 {
 760                                         if not((s = fgets(fh)))
 761                                                 break;
 762
 763                                         // catch different sorts of comments
 764                                         if(s == "")                    // empty lines
 765                                                 continue;
 766                                         if(substring(s, 0, 1) == "#")  // UNIX style
 767                                                 continue;
 768                                         if(substring(s, 0, 2) == "//") // C++ style
 769                                                 continue;
 770                                         if(substring(s, 0, 1) == "_")  // q3map style
 771                                                 continue;
 772
 773                                         if(substring(s, 0, 4) == "set ")
 774                                                 s = substring(s, 4, -1);
 775                                         if(substring(s, 0, 5) == "seta ")
 776                                                 s = substring(s, 5, -1);
 777
 778                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 779                                 }
 780                                 fclose(fh);
 781                         }
 782                 }
 783                 else
 784                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 785         }
 786         else if(t == "")
 787                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 788         else if not(cvar_value_issafe(t))
 789                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 790         else if not (cvar_value_issafe(s))
 791                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 792         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 793                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 794         else if(matchacl(acl, t) <= 0)
 795                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 796         else
 797         {
 798                 if(type == 0) // server set
 799                 {
 800                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 801                         if(cvar("g_campaign"))
 802                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 803                         else
 804                                 cvar_settemp(t, s);
 805                 }
 806                 else
 807                 {
 808                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 809                         MapInfo_Map_clientstuff = strcat(
 810                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 811                                         );
 812                 }
 813         }
 814 }
 815
 816 float MapInfo_isRedundant(string fn, string t)
 817 {
 818         // normalize file name
 819         fn = strreplace("_", "-", fn);
 820
 821         // normalize visible title
 822         t = strreplace(": ", "-", t);
 823         t = strreplace(":", "-", t);
 824         t = strreplace(" ", "-", t);
 825         t = strreplace("_", "-", t);
 826         t = strreplace("'", "-", t);
 827
 828         if(!strcasecmp(fn, t))
 829                 return TRUE;
 830
 831         // we allow the visible title to have punctuation the file name does
 832         // not, but not vice versa
 833         t = strreplace("-", "", t);
 834
 835         if(!strcasecmp(fn, t))
 836                 return TRUE;
 837
 838         return FALSE;
 839 }
 840
 841 // load info about a map by name into the MapInfo_Map_* globals
 842 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 843 {
 844         string fn;
 845         string s, t;
 846         float fh;
 847         float r, f, n, i, p;
 848         string acl;
 849
 850         acl = MAPINFO_SETTEMP_ACL_USER;
 851
 852         if(strstrofs(pFilename, "/", 0) >= 0)
 853         {
 854                 print("Invalid character in map name, ignored\n");
 855                 return 0;
 856         }
 857
 858         if(pGametypeToSet == 0)
 859                 if(MapInfo_Cache_Retrieve(pFilename))
 860                         return 1;
 861
 862         r = 1;
 863
 864         MapInfo_Map_bspname = pFilename;
 865
 866         // default all generic fields so they have "good" values in case something fails
 867         fn = strcat("maps/", pFilename, ".mapinfo");
 868         fh = fopen(fn, FILE_READ);
 869         if(fh < 0)
 870         {
 871                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 872                 fh = fopen(fn, FILE_READ);
 873                 if(fh < 0)
 874                 {
 875                         if(!pAllowGenerate)
 876                                 return 0;
 877                         _MapInfo_Map_Reset();
 878                         r = _MapInfo_Generate(pFilename);
 879                         if(!r)
 880                                 return 0;
 881                         fh = fopen(fn, FILE_WRITE);
 882                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 883                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 884                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 885                         if(_MapInfo_Map_worldspawn_music != "")
 886                         {
 887                                 if(
 888                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 889                                         ||
 890                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 891                                 )
 892                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 893                                 else
 894                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 895                         }
 896                         else
 897                         {
 898                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 899                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 900                                 for(;;)
 901                                 {
 902                                         i = floor(random() * n);
 903                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 904                                                 break;
 905                                 }
 906                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 907                         }
 908                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 909                                 fputs(fh, "has weapons\n");
 910                         else
 911                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 912                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 913                                 fputs(fh, "has turrets\n");
 914                         else
 915                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 916                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 917                                 fputs(fh, "has weapons\n");
 918                         else
 919                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 920                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 921                                 fputs(fh, "frustrating\n");
 922
 923                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 924                                 if(MapInfo_Map_supportedGametypes & i)
 925                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 926
 927                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 928                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 929
 930                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 931                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 932                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 933                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 934                         fputs(fh, "// optional: hidden\n");
 935
 936                         fclose(fh);
 937                         r = 2;
 938                         // return r;
 939                         fh = fopen(fn, FILE_READ);
 940                         if(fh < 0)
 941                                 error("... but I just wrote it!");
 942                 }
 943
 944                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 945         }
 946
 947         _MapInfo_Map_Reset();
 948         for(;;)
 949         {
 950                 if not((s = fgets(fh)))
 951                         break;
 952
 953                 // catch different sorts of comments
 954                 if(s == "")                    // empty lines
 955                         continue;
 956                 if(substring(s, 0, 1) == "#")  // UNIX style
 957                         continue;
 958                 if(substring(s, 0, 2) == "//") // C++ style
 959                         continue;
 960                 if(substring(s, 0, 1) == "_")  // q3map style
 961                         continue;
 962
 963                 p = strstrofs(s, "//", 0);
 964                 if(p >= 0)
 965                         s = substring(s, 0, p);
 966
 967                 t = car(s); s = cdr(s);
 968                 if(t == "title")
 969                         MapInfo_Map_title = s;
 970                 else if(t == "description")
 971                         MapInfo_Map_description = s;
 972                 else if(t == "author")
 973                         MapInfo_Map_author = s;
 974                 else if(t == "has")
 975                 {
 976                         t = car(s); // s = cdr(s);
 977                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 978                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 979                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 980                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 981                         else
 982                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 983                 }
 984                 else if(t == "hidden")
 985                 {
 986                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 987                 }
 988                 else if(t == "forbidden")
 989                 {
 990                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 991                 }
 992                 else if(t == "frustrating")
 993                 {
 994                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 995                 }
 996                 else if(t == "type")
 997                 {
 998                         t = car(s); s = cdr(s);
 999                         f = MapInfo_Type_FromString(t);
1000                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1001                         if(f)
1002                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
1003                         else
1004                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1005                 }
1006                 else if(t == "gametype")
1007                 {
1008                         t = car(s); s = cdr(s);
1009                         f = MapInfo_Type_FromString(t);
1010                         if(f)
1011                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1012                         else
1013                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1014                 }
1015                 else if(t == "size")
1016                 {
1017                         float a, b, c, d, e;
1018                         t = car(s); s = cdr(s); a = stof(t);
1019                         t = car(s); s = cdr(s); b = stof(t);
1020                         t = car(s); s = cdr(s); c = stof(t);
1021                         t = car(s); s = cdr(s); d = stof(t);
1022                         t = car(s); s = cdr(s); e = stof(t);
1023                         if(s == "")
1024                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1025                         else
1026                         {
1027                                 t = car(s); s = cdr(s); f = stof(t);
1028                                 if(s != "")
1029                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1030                                 else
1031                                 {
1032                                         if(a >= d || b >= e || c >= f)
1033                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1034                                         else
1035                                         {
1036                                                 MapInfo_Map_mins_x = a;
1037                                                 MapInfo_Map_mins_y = b;
1038                                                 MapInfo_Map_mins_z = c;
1039                                                 MapInfo_Map_maxs_x = d;
1040                                                 MapInfo_Map_maxs_y = e;
1041                                                 MapInfo_Map_maxs_z = f;
1042                                         }
1043                                 }
1044                         }
1045                 }
1046                 else if(t == "settemp_for_type")
1047                 {
1048                         t = car(s); s = cdr(s);
1049                         if((f = MapInfo_Type_FromString(t)))
1050                         {
1051                                 if(f & pGametypeToSet)
1052                                 {
1053                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1054                                 }
1055                         }
1056                         else
1057                         {
1058                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1059                         }
1060                 }
1061                 else if(t == "clientsettemp_for_type")
1062                 {
1063                         t = car(s); s = cdr(s);
1064                         if((f = MapInfo_Type_FromString(t)))
1065                         {
1066                                 if(f & pGametypeToSet)
1067                                 {
1068                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1069                                 }
1070                         }
1071                         else
1072                         {
1073                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1074                         }
1075                 }
1076                 else if(t == "fog")
1077                 {
1078                         if not(cvar_value_issafe(t))
1079                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1080                         else
1081                                 MapInfo_Map_fog = s;
1082                 }
1083                 else if(t == "cdtrack")
1084                 {
1085                         if(pGametypeToSet)
1086                         {
1087                                 if not(cvar_value_issafe(t))
1088                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1089                                 else
1090                                         MapInfo_Map_clientstuff = strcat(
1091                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
1092                                         );
1093                         }
1094                 }
1095                 else
1096                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1097         }
1098         fclose(fh);
1099
1100         if(MapInfo_Map_title == "<TITLE>")
1101                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1102         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1103                 MapInfo_Map_titlestring = MapInfo_Map_title;
1104         else
1105                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1106
1107         MapInfo_Cache_Store();
1108         if(MapInfo_Map_supportedGametypes != 0)
1109                 return r;
1110         dprint("Map ", pFilename, " supports no game types, ignored\n");
1111         return 0;
1112 }
1113 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1114 {
1115         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1116
1117         if(cvar("g_tdm_on_dm_maps"))
1118         {
1119                 // if this is set, all DM maps support TDM too
1120                 if not(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH)
1121                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1122                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1123         }
1124
1125         if(pGametypeToSet)
1126         {
1127                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1128                 {
1129                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1130                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1131                         //return;
1132                 }
1133         }
1134
1135         return r;
1136 }
1137
1138 float MapInfo_FindName(string s)
1139 {
1140         // if there is exactly one map of prefix s, return it
1141         // if not, return the null string
1142         // note that DP sorts glob results... so I can use a binary search
1143         float l, r, m, cmp;
1144         l = 0;
1145         r = MapInfo_count;
1146         // invariants: r is behind s, l-1 is equal or before
1147         while(l != r)
1148         {
1149                 m = floor((l + r) / 2);
1150                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1151                 cmp = strcasecmp(MapInfo_FindName_match, s);
1152                 if(cmp == 0)
1153                         return m; // found and good
1154                 if(cmp < 0)
1155                         l = m + 1; // l-1 is before s
1156                 else
1157                         r = m; // behind s
1158         }
1159         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1160         MapInfo_FindName_firstResult = l;
1161         // r == l, so: l is behind s, l-1 is before
1162         // SO: if there is any, l is the one with the right prefix
1163         //     and l+1 may be one too
1164         if(l == MapInfo_count)
1165         {
1166                 MapInfo_FindName_match = string_null;
1167                 MapInfo_FindName_firstResult = -1;
1168                 return -1; // no MapInfo_FindName_match, behind last item
1169         }
1170         if(!startsWithNocase(MapInfo_FindName_match, s))
1171         {
1172                 MapInfo_FindName_match = string_null;
1173                 MapInfo_FindName_firstResult = -1;
1174                 return -1; // wrong prefix
1175         }
1176         if(l == MapInfo_count - 1)
1177                 return l; // last one, nothing can follow => unique
1178         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1179         {
1180                 MapInfo_FindName_match = string_null;
1181                 return -1; // ambigous MapInfo_FindName_match
1182         }
1183         return l;
1184 }
1185
1186 string MapInfo_FixName(string s)
1187 {
1188         MapInfo_FindName(s);
1189         return MapInfo_FindName_match;
1190 }
1191
1192 float MapInfo_CurrentFeatures()
1193 {
1194         float req;
1195         req = 0;
1196         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1197                 req |= MAPINFO_FEATURE_WEAPONS;
1198         return req;
1199 }
1200
1201 float MapInfo_CurrentGametype()
1202 {
1203         float prev;
1204         entity e;
1205         prev = cvar("gamecfg");
1206         for(e = MapInfo_Type_first; e; e = e.enemy)
1207                 if(cvar(e.netname))
1208                         if(prev != e.items)
1209                                 return e.items;
1210         if(prev)
1211                 return prev;
1212         return MAPINFO_TYPE_DEATHMATCH;
1213 }
1214
1215 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1216 {
1217         if(!MapInfo_Get_ByName(s, 1, 0))
1218                 return 0;
1219         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1220                 return 0;
1221         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1222                 return 0;
1223         return 1;
1224 }
1225
1226 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1227 {
1228         float r;
1229         r = _MapInfo_CheckMap(s);
1230         MapInfo_ClearTemps();
1231         return r;
1232 }
1233
1234 void MapInfo_SwitchGameType(float t)
1235 {
1236         entity e;
1237         for(e = MapInfo_Type_first; e; e = e.enemy)
1238                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1239 }
1240
1241 void MapInfo_LoadMap(string s, float reinit)
1242 {
1243         MapInfo_Map_supportedGametypes = 0;
1244         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1245         //if(!MapInfo_CheckMap(s))
1246         //{
1247         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1248         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1249         //}
1250
1251         cvar_settemp_restore();
1252         if(reinit)
1253                 localcmd(strcat("\nmap ", s, "\n"));
1254         else
1255                 localcmd(strcat("\nchangelevel ", s, "\n"));
1256 }
1257
1258 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1259 {
1260         string out;
1261         float i;
1262
1263         // to make absolutely sure:
1264         MapInfo_Enumerate();
1265         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1266
1267         out = "";
1268         for(i = 0; i < MapInfo_count; ++i)
1269                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1270         return substring(out, 1, strlen(out) - 1);
1271 }
1272
1273 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1274 {
1275         string out;
1276         float i;
1277
1278         // to make absolutely sure:
1279         MapInfo_Enumerate();
1280         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1281
1282         out = "";
1283         for(i = 0; i < MapInfo_count; ++i)
1284                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1285
1286         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1287
1288         return substring(out, 1, strlen(out) - 1);
1289 }
1290
1291 void MapInfo_LoadMapSettings_SaveGameType(float t)
1292 {
1293         MapInfo_SwitchGameType(t);
1294         cvar_set("gamecfg", ftos(t));
1295         MapInfo_LoadedGametype = t;
1296 }
1297
1298 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1299 {
1300         float t;
1301
1302         t = MapInfo_CurrentGametype();
1303         MapInfo_LoadMapSettings_SaveGameType(t);
1304
1305         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1306         {
1307                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1308                 {
1309                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1310                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1311                         return; // do not call Get_ByName!
1312                 }
1313
1314                 if(MapInfo_Map_supportedGametypes == 0)
1315                 {
1316                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1317                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1318                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1319                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1320                         return; // do not call Get_ByName!
1321                 }
1322
1323                 t = 1;
1324                 while(!(MapInfo_Map_supportedGametypes & 1))
1325                 {
1326                         t *= 2;
1327                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1328                 }
1329
1330                 // t is now a supported mode!
1331                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1332                 MapInfo_LoadMapSettings_SaveGameType(t);
1333         }
1334         MapInfo_Get_ByName(s, 1, t);
1335 }
1336
1337 void MapInfo_ClearTemps()
1338 {
1339         MapInfo_Map_bspname = string_null;
1340         MapInfo_Map_title = string_null;
1341         MapInfo_Map_titlestring = string_null;
1342         MapInfo_Map_description = string_null;
1343         MapInfo_Map_author = string_null;
1344         MapInfo_Map_clientstuff = string_null;
1345         MapInfo_Map_supportedGametypes = 0;
1346         MapInfo_Map_supportedFeatures = 0;
1347 }
1348
1349 void MapInfo_Shutdown()
1350 {
1351         MapInfo_ClearTemps();
1352         MapInfo_Filter_Free();
1353         MapInfo_Cache_Destroy();
1354         if(_MapInfo_globopen)
1355         {
1356                 search_end(_MapInfo_globhandle);
1357                 _MapInfo_globhandle = -1;
1358                 _MapInfo_globopen = FALSE;
1359         }
1360 }
1361
1362 float MapInfo_ForbiddenFlags()
1363 {
1364         float f;
1365         f = MAPINFO_FLAG_FORBIDDEN;
1366
1367 #ifndef MENUQC
1368         if not(cvar("g_maplist_allow_hidden"))
1369 #endif
1370                 f |= MAPINFO_FLAG_HIDDEN;
1371
1372         if not(cvar("g_maplist_allow_frustrating"))
1373                 f |= MAPINFO_FLAG_FRUSTRATING;
1374
1375         return f;
1376 }
1377
1378 float MapInfo_RequiredFlags()
1379 {
1380         float f;
1381         f = 0;
1382
1383         if(cvar("g_maplist_allow_frustrating") > 1)
1384                 f |= MAPINFO_FLAG_FRUSTRATING;
1385
1386         return f;
1387 }