qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(s == "")
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(s == "")
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         if(!_MapInfo_globopen)
  93                 return string_null;
  94         s = search_getfilename(_MapInfo_globhandle, i);
  95         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  96 }
  97
  98 void MapInfo_Enumerate()
  99 {
 100         if(_MapInfo_globopen)
 101         {
 102                 search_end(_MapInfo_globhandle);
 103                 _MapInfo_globopen = 0;
 104         }
 105         MapInfo_Cache_Invalidate();
 106         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 107         if(_MapInfo_globhandle >= 0)
 108         {
 109                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 110                 _MapInfo_globopen = 1;
 111         }
 112         else
 113                 _MapInfo_globcount = 0;
 114 }
 115
 116 // filter the info by game type mask (updates MapInfo_count)
 117 //
 118 float _MapInfo_filtered;
 119 float _MapInfo_filtered_allocated;
 120 float MapInfo_FilterList_Lookup(float i)
 121 {
 122         return stof(bufstr_get(_MapInfo_filtered, i));
 123 }
 124
 125 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 126 {
 127         string h;
 128         h = bufstr_get(_MapInfo_filtered, i);
 129         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 130         bufstr_set(_MapInfo_filtered, j, h);
 131 }
 132
 133 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 134 {
 135         string a, b;
 136         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 137         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 138         return strcasecmp(a, b);
 139 }
 140
 141 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 142 {
 143         float i, j;
 144         if not(_MapInfo_filtered_allocated)
 145         {
 146                 _MapInfo_filtered_allocated = 1;
 147                 _MapInfo_filtered = buf_create();
 148         }
 149         MapInfo_count = 0;
 150         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 151         {
 152                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 153                         if(pAbortOnGenerate)
 154                         {
 155                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 156                                 MapInfo_progress = i / _MapInfo_globcount;
 157                                 return 0;
 158                         }
 159                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 160                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 161                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 162                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 163                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 164         }
 165         MapInfo_count = j + 1;
 166         MapInfo_ClearTemps();
 167
 168         // sometimes the glob isn't sorted nicely, so fix it here...
 169         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 170
 171         return 1;
 172 }
 173
 174 void MapInfo_Filter_Free()
 175 {
 176         if(_MapInfo_filtered_allocated)
 177         {
 178                 buf_del(_MapInfo_filtered);
 179                 _MapInfo_filtered_allocated = 0;
 180         }
 181 }
 182
 183 // load info about the i-th map into the MapInfo_Map_* globals
 184 string MapInfo_BSPName_ByID(float i)
 185 {
 186         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 187 }
 188
 189 string unquote(string s)
 190 {
 191         float i, j, l;
 192         l = strlen(s);
 193         j = -1;
 194         for(i = 0; i < l; ++i)
 195         {
 196                 string ch;
 197                 ch = substring(s, i, 1);
 198                 if(ch != " ") if(ch != "\"")
 199                 {
 200                         for(j = strlen(s) - i - 1; j > 0; --j)
 201                         {
 202                                 ch = substring(s, i+j, 1);
 203                                 if(ch != " ") if(ch != "\"")
 204                                         return substring(s, i, j+1);
 205                         }
 206                         return substring(s, i, 1);
 207                 }
 208         }
 209         return "";
 210 }
 211
 212 float MapInfo_Get_ByID(float i)
 213 {
 214         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 215                 return 1;
 216         return 0;
 217 }
 218
 219 string _MapInfo_Map_worldspawn_music;
 220
 221 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 222 {
 223         string fn;
 224         float fh;
 225         string s, k, v;
 226         vector o;
 227         float i;
 228         float inWorldspawn;
 229         float r;
 230         float twoBaseModes;
 231         float diameter, spawnpoints;
 232         float spawnplaces;
 233
 234         vector mapMins, mapMaxs;
 235
 236         r = 1;
 237         fn = strcat("maps/", pFilename, ".ent");
 238         fh = fopen(fn, FILE_READ);
 239         if(fh < 0)
 240         {
 241                 r = 2;
 242                 fn = strcat("maps/", pFilename, ".bsp");
 243                 fh = fopen(fn, FILE_READ);
 244         }
 245         if(fh < 0)
 246                 return 0;
 247         print("Analyzing ", fn, " to generate initial mapinfo\n");
 248
 249         inWorldspawn = 2;
 250         MapInfo_Map_flags = 0;
 251         MapInfo_Map_supportedGametypes = 0;
 252         spawnpoints = 0;
 253         spawnplaces = 0;
 254         _MapInfo_Map_worldspawn_music = "";
 255         mapMins = '0 0 0';
 256         mapMaxs = '0 0 0';
 257
 258         for(;;)
 259         {
 260                 if not((s = fgets(fh)))
 261                         break;
 262                 if(inWorldspawn == 1)
 263                         if(startsWith(s, "}"))
 264                                 inWorldspawn = 0;
 265                 k = unquote(car(s));
 266                 v = unquote(cdr(s));
 267                 if(inWorldspawn)
 268                 {
 269                         if(k == "classname" && v == "worldspawn")
 270                                 inWorldspawn = 1;
 271                         else if(k == "author")
 272                                 MapInfo_Map_author = v;
 273                         else if(k == "_description")
 274                                 MapInfo_Map_description = v;
 275                         else if(k == "music")
 276                                 _MapInfo_Map_worldspawn_music = v;
 277                         else if(k == "noise")
 278                                 _MapInfo_Map_worldspawn_music = v;
 279                         else if(k == "message")
 280                         {
 281                                 i = strstrofs(v, " by ", 0);
 282                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 283                                 {
 284                                         MapInfo_Map_title = substring(v, 0, i);
 285                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 286                                 }
 287                                 else
 288                                         MapInfo_Map_title = v;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if(k == "origin")
 294                         {
 295                                 o = stov(strcat("'", v, "'"));
 296                                 mapMins_x = min(mapMins_x, o_x);
 297                                 mapMins_y = min(mapMins_y, o_y);
 298                                 mapMins_z = min(mapMins_z, o_z);
 299                                 mapMaxs_x = max(mapMaxs_x, o_x);
 300                                 mapMaxs_y = max(mapMaxs_y, o_y);
 301                                 mapMaxs_z = max(mapMaxs_z, o_z);
 302                         }
 303                         else if(k == "race_place")
 304                         {
 305                                 if(stof(v) > 0)
 306                                         spawnplaces = 1;
 307                         }
 308                         else if(k == "classname")
 309                         {
 310                                 if(v == "dom_controlpoint")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 312                                 else if(v == "item_flag_team2")
 313                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 314                                 else if(v == "team_CTF_blueflag")
 315                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 316                                 else if(v == "target_assault_roundend")
 317                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 318                                 else if(v == "onslaught_generator")
 319                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 320                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 322                                 else if(v == "info_player_team1")
 323                                         ++spawnpoints;
 324                                 else if(v == "info_player_team2")
 325                                         ++spawnpoints;
 326                                 else if(v == "info_player_start")
 327                                         ++spawnpoints;
 328                                 else if(v == "info_player_deathmatch")
 329                                         ++spawnpoints;
 330                                 else if(v == "trigger_race_checkpoint")
 331                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 332                                 else if(v == "target_startTimer")
 333                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 334                                 else if(v == "weapon_nex")
 335                                         { }
 336                                 else if(v == "weapon_railgun")
 337                                         { }
 338                                 else if(startsWith(v, "weapon_"))
 339                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 340                                 else if(startsWith(v, "turret_"))
 341                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 342                                 else if(startsWith(v, "vehicle_"))
 343                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 344                                 else if(v == "target_music" || v == "trigger_music")
 345                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 346                         }
 347                 }
 348         }
 349         if(inWorldspawn)
 350         {
 351                 print(fn, " ended still in worldspawn, BUG\n");
 352                 return 0;
 353         }
 354         diameter = vlen(mapMaxs - mapMins);
 355
 356         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 357         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 358         {
 359                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 360                 // as the map is too symmetric for them.
 361         }
 362         else
 363         {
 364                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 365                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 366                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 367
 368                 if(spawnpoints >= 8  && diameter > 4096) {
 369                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 370                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 371                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 372                 }
 373                 if(                     diameter < 4096)
 374                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 375                 if(spawnpoints >= 12 && diameter > 5120)
 376                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 377         }
 378
 379         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 380         if(!spawnplaces)
 381         {
 382                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 383                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 384         }
 385
 386         dprint("-> diameter ",    ftos(diameter));
 387         dprint(";  spawnpoints ", ftos(spawnpoints));
 388         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 389
 390         fclose(fh);
 391
 392         return r;
 393 }
 394
 395 void _MapInfo_Map_Reset()
 396 {
 397         MapInfo_Map_title = "<TITLE>";
 398         MapInfo_Map_titlestring = "<TITLE>";
 399         MapInfo_Map_description = "<DESCRIPTION>";
 400         MapInfo_Map_author = "<AUTHOR>";
 401         MapInfo_Map_supportedGametypes = 0;
 402         MapInfo_Map_supportedFeatures = 0;
 403         MapInfo_Map_flags = 0;
 404         MapInfo_Map_clientstuff = "";
 405         MapInfo_Map_fog = "";
 406         MapInfo_Map_mins = '0 0 0';
 407         MapInfo_Map_maxs = '0 0 0';
 408 }
 409
 410 string _MapInfo_GetDefault(float t)
 411 {
 412         switch(t)
 413         {
 414                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 415                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 416                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 417                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 418                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 419                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
 420                 case MAPINFO_TYPE_CA:              return "10 20 0";
 421                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 422                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 423                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 424                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 425                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 426                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 427                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 428                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 429                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 430                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 431                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 432                 default:                           return "";
 433         }
 434 }
 435
 436 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 437 {
 438         string sa;
 439         MapInfo_Map_supportedGametypes |= pThisType;
 440         if(!(pThisType & pWantedType))
 441                 return;
 442
 443         if(load_default)
 444                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 445
 446         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 447         {
 448                 cvar_set("fraglimit", "0");
 449         }
 450         else
 451         {
 452                 sa = car(s);
 453                 if(sa != "")
 454                         cvar_set("fraglimit", sa);
 455                 s = cdr(s);
 456         }
 457
 458         sa = car(s);
 459         if(sa != "")
 460                 cvar_set("timelimit", sa);
 461         s = cdr(s);
 462
 463         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 464         {
 465                 sa = car(s);
 466                 if(sa != "")
 467                         cvar_set("g_tdm_teams", sa);
 468                 s = cdr(s);
 469         }
 470
 471         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 472         {
 473                 sa = car(s);
 474                 if(sa != "")
 475                         cvar_set("g_keyhunt_teams", sa);
 476                 s = cdr(s);
 477         }
 478
 479         if(pWantedType == MAPINFO_TYPE_CA)
 480         {
 481                 sa = car(s);
 482                 if(sa != "")
 483                         cvar_set("g_ca_teams", sa);
 484                 s = cdr(s);
 485         }
 486
 487         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 488         {
 489                 sa = car(s);
 490                 if(sa != "")
 491                         cvar_set("g_freezetag_teams", sa);
 492                 s = cdr(s);
 493         }
 494
 495         if(pWantedType == MAPINFO_TYPE_CTF)
 496         {
 497                 sa = car(s);
 498                 if(sa != "")
 499                         cvar_set("fraglimit", sa);
 500                 s = cdr(s);
 501         }
 502
 503         /* keepaway wuz here
 504         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 505         {
 506                 sa = car(s);
 507                 if(sa != "")
 508                         cvar_set("fraglimit", sa);
 509                 s = cdr(s);
 510         }
 511         */
 512
 513         // rc = timelimit timelimit_qualification laps laps_teamplay
 514         if(pWantedType == MAPINFO_TYPE_RACE)
 515         {
 516                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 517                 cvar_set("g_race_qualifying_timelimit", sa);
 518                 s = cdr(s);
 519
 520                 sa = car(s);
 521                 if(sa != "")
 522                         if(cvar("g_race_teams") < 2)
 523                                 cvar_set("fraglimit", sa);
 524                 s = cdr(s);
 525
 526                 sa = car(s);
 527                 if(sa != "")
 528                         if(cvar("g_race_teams") >= 2)
 529                                 cvar_set("fraglimit", sa);
 530                 s = cdr(s);
 531         }
 532
 533         if(pWantedType == MAPINFO_TYPE_CTS)
 534         {
 535                 sa = car(s);
 536
 537                 // this is the skill of the map
 538                 // not parsed by anything yet
 539                 // for map databases
 540                 //if(sa != "")
 541                 //      cvar_set("fraglimit", sa);
 542
 543                 s = cdr(s);
 544         }
 545
 546         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 547         {
 548                 cvar_set("leadlimit", "0");
 549         }
 550         else
 551         {
 552                 sa = car(s);
 553                 if(sa != "")
 554                         cvar_set("leadlimit", sa);
 555                 s = cdr(s);
 556         }
 557 }
 558
 559 string _MapInfo_GetDefaultEx(float t)
 560 {
 561         entity e;
 562         for(e = MapInfo_Type_first; e; e = e.enemy)
 563                 if(t == e.items)
 564                         return e.model2;
 565         return "";
 566 }
 567
 568 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 569 {
 570         string sa, k, v;
 571         float p;
 572         string fraglimit_normal;
 573         string fraglimit_teams;
 574
 575         MapInfo_Map_supportedGametypes |= pThisType;
 576         if(!(pThisType & pWantedType))
 577                 return;
 578
 579         // reset all the cvars to their defaults
 580
 581         cvar_set("timelimit", cvar_defstring("timelimit"));
 582         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 583         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 584         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 585         cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 586         cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 587         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 588         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 589         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 590
 591         fraglimit_normal = string_null;
 592         fraglimit_teams = string_null;
 593
 594         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 595         while(s != "")
 596         {
 597                 sa = car(s);
 598                 s = cdr(s);
 599
 600                 if(sa == "")
 601                         continue;
 602
 603                 p = strstrofs(sa, "=", 0);
 604                 if(p < 0)
 605                 {
 606                         k = "timelimit";
 607                         v = s;
 608                 }
 609                 else
 610                 {
 611                         k = substring(sa, 0, p);
 612                         v = substring(sa, p+1, -1);
 613                 }
 614
 615                 if(k == "timelimit")
 616                 {
 617                         cvar_set("timelimit", v);
 618                 }
 619                 else if(k == "leadlimit")
 620                 {
 621                         cvar_set("leadlimit", v);
 622                 }
 623                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 624                 {
 625                         fraglimit_normal = v;
 626                 }
 627                 else if(k == "teampointlimit" || k == "teamlaplimit")
 628                 {
 629                         fraglimit_teams = v;
 630                 }
 631                 else if(k == "teams")
 632                 {
 633                         cvar_set("g_tdm_teams", v);
 634                         cvar_set("g_ca_teams", v);
 635                         cvar_set("g_freezetag_teams", v);
 636                         cvar_set("g_keyhunt_teams", v);
 637                         cvar_set("g_domination_default_teams", v);
 638                 }
 639                 else if(k == "qualifying_timelimit")
 640                 {
 641                         cvar_set("g_race_qualifying_timelimit", v);
 642                 }
 643                 else if(k == "skill")
 644                 {
 645                         // ignore
 646                 }
 647                 else
 648                 {
 649                         print("Invalid gametype key in mapinfo: ", k, "\n");
 650                 }
 651         }
 652
 653         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 654         {
 655                 if(fraglimit_teams)
 656                         cvar_set("fraglimit", fraglimit_teams);
 657         }
 658         else
 659         {
 660                 if(fraglimit_normal)
 661                         cvar_set("fraglimit", fraglimit_normal);
 662         }
 663 }
 664
 665 float MapInfo_Type_FromString(string t)
 666 {
 667         entity e;
 668         if(t == "nexball")
 669         {
 670                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 671                 t = "nb";
 672                 print("'. Should use '", t, "'.\n");
 673         }
 674         if(t == "freezetag")
 675         {
 676                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 677                 t = "ft";
 678                 print("'. Should use '", t, "'.\n");
 679         }
 680         if(t == "keepaway")
 681         {
 682                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 683                 t = "ka";
 684                 print("'. Should use '", t, "'.\n");
 685         }
 686         if(t == "all")
 687                 return MAPINFO_TYPE_ALL;
 688         for(e = MapInfo_Type_first; e; e = e.enemy)
 689                 if(t == e.mdl)
 690                         return e.items;
 691         return 0;
 692 }
 693
 694 string MapInfo_Type_ToString(float t)
 695 {
 696         entity e;
 697         if(t == MAPINFO_TYPE_ALL)
 698                 return "all";
 699         for(e = MapInfo_Type_first; e; e = e.enemy)
 700                 if(t == e.items)
 701                         return e.mdl;
 702         return "";
 703 }
 704
 705 string MapInfo_Type_ToText(float t)
 706 {
 707         entity e;
 708         for(e = MapInfo_Type_first; e; e = e.enemy)
 709                 if(t == e.items)
 710                         return e.message;
 711         return _("@!#%'n Tuba Throwing");
 712 }
 713
 714 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 715 {
 716         string t;
 717         float fh, o;
 718         t = car(s); s = cdr(s);
 719
 720         // limited support of "" and comments
 721         //   remove trailing and leading " of t
 722         if(substring(t, 0, 1) == "\"")
 723         {
 724                 if(substring(t, -1, 1) == "\"")
 725                         t = substring(t, 1, -2);
 726         }
 727
 728         //   remove leading " of s
 729         if(substring(s, 0, 1) == "\"")
 730         {
 731                 s = substring(s, 1, -1);
 732         }
 733         //   remove trailing " of s, and all that follows (cvar description)
 734         o = strstrofs(s, "\"", 0);
 735         if(o >= 0)
 736                 s = substring(s, 0, o);
 737
 738         //   remove // comments
 739         o = strstrofs(s, "//", 0);
 740         if(o >= 0)
 741                 s = substring(s, 0, o);
 742
 743         //   remove trailing spaces
 744         while(substring(s, -1, 1) == " ")
 745                 s = substring(s, 0, -2);
 746
 747         if(t == "#include")
 748         {
 749                 if(recurse > 0)
 750                 {
 751                         fh = fopen(s, FILE_READ);
 752                         if(fh < 0)
 753                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 754                         else
 755                         {
 756                                 for(;;)
 757                                 {
 758                                         if not((s = fgets(fh)))
 759                                                 break;
 760
 761                                         // catch different sorts of comments
 762                                         if(s == "")                    // empty lines
 763                                                 continue;
 764                                         if(substring(s, 0, 1) == "#")  // UNIX style
 765                                                 continue;
 766                                         if(substring(s, 0, 2) == "//") // C++ style
 767                                                 continue;
 768                                         if(substring(s, 0, 1) == "_")  // q3map style
 769                                                 continue;
 770
 771                                         if(substring(s, 0, 4) == "set ")
 772                                                 s = substring(s, 4, -1);
 773                                         if(substring(s, 0, 5) == "seta ")
 774                                                 s = substring(s, 5, -1);
 775
 776                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 777                                 }
 778                                 fclose(fh);
 779                         }
 780                 }
 781                 else
 782                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 783         }
 784         else if(t == "")
 785                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 786         else if not(cvar_value_issafe(t))
 787                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 788         else if not (cvar_value_issafe(s))
 789                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 790         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 791                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 792         else if(matchacl(acl, t) <= 0)
 793                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 794         else
 795         {
 796                 if(type == 0) // server set
 797                 {
 798                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 799                         if(cvar("g_campaign"))
 800                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 801                         else
 802                                 cvar_settemp(t, s);
 803                 }
 804                 else
 805                 {
 806                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 807                         MapInfo_Map_clientstuff = strcat(
 808                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 809                                         );
 810                 }
 811         }
 812 }
 813
 814 float MapInfo_isRedundant(string fn, string t)
 815 {
 816         // normalize file name
 817         fn = strreplace("_", "-", fn);
 818
 819         // normalize visible title
 820         t = strreplace(": ", "-", t);
 821         t = strreplace(":", "-", t);
 822         t = strreplace(" ", "-", t);
 823         t = strreplace("_", "-", t);
 824         t = strreplace("'", "-", t);
 825
 826         if(!strcasecmp(fn, t))
 827                 return TRUE;
 828
 829         // we allow the visible title to have punctuation the file name does
 830         // not, but not vice versa
 831         t = strreplace("-", "", t);
 832
 833         if(!strcasecmp(fn, t))
 834                 return TRUE;
 835
 836         return FALSE;
 837 }
 838
 839 // load info about a map by name into the MapInfo_Map_* globals
 840 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 841 {
 842         string fn;
 843         string s, t;
 844         float fh;
 845         float r, f, n, i, p;
 846         string acl;
 847
 848         acl = MAPINFO_SETTEMP_ACL_USER;
 849
 850         if(strstrofs(pFilename, "/", 0) >= 0)
 851         {
 852                 print("Invalid character in map name, ignored\n");
 853                 return 0;
 854         }
 855
 856         if(pGametypeToSet == 0)
 857                 if(MapInfo_Cache_Retrieve(pFilename))
 858                         return 1;
 859
 860         r = 1;
 861
 862         MapInfo_Map_bspname = pFilename;
 863
 864         // default all generic fields so they have "good" values in case something fails
 865         fn = strcat("maps/", pFilename, ".mapinfo");
 866         fh = fopen(fn, FILE_READ);
 867         if(fh < 0)
 868         {
 869                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 870                 fh = fopen(fn, FILE_READ);
 871                 if(fh < 0)
 872                 {
 873                         if(!pAllowGenerate)
 874                                 return 0;
 875                         _MapInfo_Map_Reset();
 876                         r = _MapInfo_Generate(pFilename);
 877                         if(!r)
 878                                 return 0;
 879                         fh = fopen(fn, FILE_WRITE);
 880                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 881                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 882                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 883                         if(_MapInfo_Map_worldspawn_music != "")
 884                         {
 885                                 if(
 886                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 887                                         ||
 888                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 889                                 )
 890                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 891                                 else
 892                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 893                         }
 894                         else
 895                         {
 896                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 897                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 898                                 for(;;)
 899                                 {
 900                                         i = floor(random() * n);
 901                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 902                                                 break;
 903                                 }
 904                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 905                         }
 906                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 907                                 fputs(fh, "has weapons\n");
 908                         else
 909                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 910                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 911                                 fputs(fh, "has turrets\n");
 912                         else
 913                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 914                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 915                                 fputs(fh, "has weapons\n");
 916                         else
 917                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 918                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 919                                 fputs(fh, "frustrating\n");
 920
 921                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 922                                 if(MapInfo_Map_supportedGametypes & i)
 923                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 924
 925                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 926                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 927
 928                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 929                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 930                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 931                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 932                         fputs(fh, "// optional: hidden\n");
 933
 934                         fclose(fh);
 935                         r = 2;
 936                         // return r;
 937                         fh = fopen(fn, FILE_READ);
 938                         if(fh < 0)
 939                                 error("... but I just wrote it!");
 940                 }
 941
 942                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 943         }
 944
 945         _MapInfo_Map_Reset();
 946         for(;;)
 947         {
 948                 if not((s = fgets(fh)))
 949                         break;
 950
 951                 // catch different sorts of comments
 952                 if(s == "")                    // empty lines
 953                         continue;
 954                 if(substring(s, 0, 1) == "#")  // UNIX style
 955                         continue;
 956                 if(substring(s, 0, 2) == "//") // C++ style
 957                         continue;
 958                 if(substring(s, 0, 1) == "_")  // q3map style
 959                         continue;
 960
 961                 p = strstrofs(s, "//", 0);
 962                 if(p >= 0)
 963                         s = substring(s, 0, p);
 964
 965                 t = car(s); s = cdr(s);
 966                 if(t == "title")
 967                         MapInfo_Map_title = s;
 968                 else if(t == "description")
 969                         MapInfo_Map_description = s;
 970                 else if(t == "author")
 971                         MapInfo_Map_author = s;
 972                 else if(t == "has")
 973                 {
 974                         t = car(s); // s = cdr(s);
 975                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 976                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 977                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 978                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 979                         else
 980                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 981                 }
 982                 else if(t == "hidden")
 983                 {
 984                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 985                 }
 986                 else if(t == "forbidden")
 987                 {
 988                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 989                 }
 990                 else if(t == "frustrating")
 991                 {
 992                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 993                 }
 994                 else if(t == "type")
 995                 {
 996                         t = car(s); s = cdr(s);
 997                         f = MapInfo_Type_FromString(t);
 998                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
 999                         if(f)
1000                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
1001                         else
1002                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1003                 }
1004                 else if(t == "gametype")
1005                 {
1006                         t = car(s); s = cdr(s);
1007                         f = MapInfo_Type_FromString(t);
1008                         if(f)
1009                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1010                         else
1011                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1012                 }
1013                 else if(t == "size")
1014                 {
1015                         float a, b, c, d, e;
1016                         t = car(s); s = cdr(s); a = stof(t);
1017                         t = car(s); s = cdr(s); b = stof(t);
1018                         t = car(s); s = cdr(s); c = stof(t);
1019                         t = car(s); s = cdr(s); d = stof(t);
1020                         t = car(s); s = cdr(s); e = stof(t);
1021                         if(s == "")
1022                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1023                         else
1024                         {
1025                                 t = car(s); s = cdr(s); f = stof(t);
1026                                 if(s != "")
1027                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1028                                 else
1029                                 {
1030                                         if(a >= d || b >= e || c >= f)
1031                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1032                                         else
1033                                         {
1034                                                 MapInfo_Map_mins_x = a;
1035                                                 MapInfo_Map_mins_y = b;
1036                                                 MapInfo_Map_mins_z = c;
1037                                                 MapInfo_Map_maxs_x = d;
1038                                                 MapInfo_Map_maxs_y = e;
1039                                                 MapInfo_Map_maxs_z = f;
1040                                         }
1041                                 }
1042                         }
1043                 }
1044                 else if(t == "settemp_for_type")
1045                 {
1046                         t = car(s); s = cdr(s);
1047                         if((f = MapInfo_Type_FromString(t)))
1048                         {
1049                                 if(f & pGametypeToSet)
1050                                 {
1051                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1052                                 }
1053                         }
1054                         else
1055                         {
1056                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1057                         }
1058                 }
1059                 else if(t == "clientsettemp_for_type")
1060                 {
1061                         t = car(s); s = cdr(s);
1062                         if((f = MapInfo_Type_FromString(t)))
1063                         {
1064                                 if(f & pGametypeToSet)
1065                                 {
1066                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1067                                 }
1068                         }
1069                         else
1070                         {
1071                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1072                         }
1073                 }
1074                 else if(t == "fog")
1075                 {
1076                         if not(cvar_value_issafe(s))
1077                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1078                         else
1079                                 MapInfo_Map_fog = s;
1080                 }
1081                 else if(t == "cdtrack")
1082                 {
1083                         t = car(s); s = cdr(s);
1084                         if(pGametypeToSet) // FIXME is this check right here?
1085                         {
1086                                 if not(cvar_value_issafe(t))
1087                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1088                                 else
1089                                         MapInfo_Map_clientstuff = strcat(
1090                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1091                                         );
1092                         }
1093                 }
1094                 else
1095                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1096         }
1097         fclose(fh);
1098
1099         if(MapInfo_Map_title == "<TITLE>")
1100                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1101         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1102                 MapInfo_Map_titlestring = MapInfo_Map_title;
1103         else
1104                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1105
1106         MapInfo_Cache_Store();
1107         if(MapInfo_Map_supportedGametypes != 0)
1108                 return r;
1109         dprint("Map ", pFilename, " supports no game types, ignored\n");
1110         return 0;
1111 }
1112 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1113 {
1114         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1115
1116         if(cvar("g_tdm_on_dm_maps"))
1117         {
1118                 // if this is set, all DM maps support TDM too
1119                 if not(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH)
1120                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1121                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1122         }
1123
1124         if(pGametypeToSet)
1125         {
1126                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1127                 {
1128                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1129                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1130                         //return;
1131                 }
1132         }
1133
1134         return r;
1135 }
1136
1137 float MapInfo_FindName(string s)
1138 {
1139         // if there is exactly one map of prefix s, return it
1140         // if not, return the null string
1141         // note that DP sorts glob results... so I can use a binary search
1142         float l, r, m, cmp;
1143         l = 0;
1144         r = MapInfo_count;
1145         // invariants: r is behind s, l-1 is equal or before
1146         while(l != r)
1147         {
1148                 m = floor((l + r) / 2);
1149                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1150                 cmp = strcasecmp(MapInfo_FindName_match, s);
1151                 if(cmp == 0)
1152                         return m; // found and good
1153                 if(cmp < 0)
1154                         l = m + 1; // l-1 is before s
1155                 else
1156                         r = m; // behind s
1157         }
1158         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1159         MapInfo_FindName_firstResult = l;
1160         // r == l, so: l is behind s, l-1 is before
1161         // SO: if there is any, l is the one with the right prefix
1162         //     and l+1 may be one too
1163         if(l == MapInfo_count)
1164         {
1165                 MapInfo_FindName_match = string_null;
1166                 MapInfo_FindName_firstResult = -1;
1167                 return -1; // no MapInfo_FindName_match, behind last item
1168         }
1169         if(!startsWithNocase(MapInfo_FindName_match, s))
1170         {
1171                 MapInfo_FindName_match = string_null;
1172                 MapInfo_FindName_firstResult = -1;
1173                 return -1; // wrong prefix
1174         }
1175         if(l == MapInfo_count - 1)
1176                 return l; // last one, nothing can follow => unique
1177         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1178         {
1179                 MapInfo_FindName_match = string_null;
1180                 return -1; // ambigous MapInfo_FindName_match
1181         }
1182         return l;
1183 }
1184
1185 string MapInfo_FixName(string s)
1186 {
1187         MapInfo_FindName(s);
1188         return MapInfo_FindName_match;
1189 }
1190
1191 float MapInfo_CurrentFeatures()
1192 {
1193         float req;
1194         req = 0;
1195         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1196                 req |= MAPINFO_FEATURE_WEAPONS;
1197         return req;
1198 }
1199
1200 float MapInfo_CurrentGametype()
1201 {
1202         float prev;
1203         entity e;
1204         prev = cvar("gamecfg");
1205         for(e = MapInfo_Type_first; e; e = e.enemy)
1206                 if(cvar(e.netname))
1207                         if(prev != e.items)
1208                                 return e.items;
1209         if(prev)
1210                 return prev;
1211         return MAPINFO_TYPE_DEATHMATCH;
1212 }
1213
1214 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1215 {
1216         if(!MapInfo_Get_ByName(s, 1, 0))
1217                 return 0;
1218         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1219                 return 0;
1220         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1221                 return 0;
1222         return 1;
1223 }
1224
1225 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1226 {
1227         float r;
1228         r = _MapInfo_CheckMap(s);
1229         MapInfo_ClearTemps();
1230         return r;
1231 }
1232
1233 void MapInfo_SwitchGameType(float t)
1234 {
1235         entity e;
1236         for(e = MapInfo_Type_first; e; e = e.enemy)
1237                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1238 }
1239
1240 void MapInfo_LoadMap(string s, float reinit)
1241 {
1242         MapInfo_Map_supportedGametypes = 0;
1243         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1244         //if(!MapInfo_CheckMap(s))
1245         //{
1246         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1247         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1248         //}
1249
1250         cvar_settemp_restore();
1251         if(reinit)
1252                 localcmd(strcat("\nmap ", s, "\n"));
1253         else
1254                 localcmd(strcat("\nchangelevel ", s, "\n"));
1255 }
1256
1257 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1258 {
1259         string out;
1260         float i;
1261
1262         // to make absolutely sure:
1263         MapInfo_Enumerate();
1264         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1265
1266         out = "";
1267         for(i = 0; i < MapInfo_count; ++i)
1268                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1269         return substring(out, 1, strlen(out) - 1);
1270 }
1271
1272 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1273 {
1274         string out;
1275         float i;
1276
1277         // to make absolutely sure:
1278         MapInfo_Enumerate();
1279         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1280
1281         out = "";
1282         for(i = 0; i < MapInfo_count; ++i)
1283                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1284
1285         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1286
1287         return substring(out, 1, strlen(out) - 1);
1288 }
1289
1290 void MapInfo_LoadMapSettings_SaveGameType(float t)
1291 {
1292         MapInfo_SwitchGameType(t);
1293         cvar_set("gamecfg", ftos(t));
1294         MapInfo_LoadedGametype = t;
1295 }
1296
1297 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1298 {
1299         float t;
1300
1301         t = MapInfo_CurrentGametype();
1302         MapInfo_LoadMapSettings_SaveGameType(t);
1303
1304         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1305         {
1306                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1307                 {
1308                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1309                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1310                         return; // do not call Get_ByName!
1311                 }
1312
1313                 if(MapInfo_Map_supportedGametypes == 0)
1314                 {
1315                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1316                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1317                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1318                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1319                         return; // do not call Get_ByName!
1320                 }
1321
1322                 t = 1;
1323                 while(!(MapInfo_Map_supportedGametypes & 1))
1324                 {
1325                         t *= 2;
1326                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1327                 }
1328
1329                 // t is now a supported mode!
1330                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1331                 MapInfo_LoadMapSettings_SaveGameType(t);
1332         }
1333         MapInfo_Get_ByName(s, 1, t);
1334 }
1335
1336 void MapInfo_ClearTemps()
1337 {
1338         MapInfo_Map_bspname = string_null;
1339         MapInfo_Map_title = string_null;
1340         MapInfo_Map_titlestring = string_null;
1341         MapInfo_Map_description = string_null;
1342         MapInfo_Map_author = string_null;
1343         MapInfo_Map_clientstuff = string_null;
1344         MapInfo_Map_supportedGametypes = 0;
1345         MapInfo_Map_supportedFeatures = 0;
1346 }
1347
1348 void MapInfo_Shutdown()
1349 {
1350         MapInfo_ClearTemps();
1351         MapInfo_Filter_Free();
1352         MapInfo_Cache_Destroy();
1353         if(_MapInfo_globopen)
1354         {
1355                 search_end(_MapInfo_globhandle);
1356                 _MapInfo_globhandle = -1;
1357                 _MapInfo_globopen = FALSE;
1358         }
1359 }
1360
1361 float MapInfo_ForbiddenFlags()
1362 {
1363         float f;
1364         f = MAPINFO_FLAG_FORBIDDEN;
1365
1366 #ifndef MENUQC
1367         if not(cvar("g_maplist_allow_hidden"))
1368 #endif
1369                 f |= MAPINFO_FLAG_HIDDEN;
1370
1371         if not(cvar("g_maplist_allow_frustrating"))
1372                 f |= MAPINFO_FLAG_FRUSTRATING;
1373
1374         return f;
1375 }
1376
1377 float MapInfo_RequiredFlags()
1378 {
1379         float f;
1380         f = 0;
1381
1382         if(cvar("g_maplist_allow_frustrating") > 1)
1383                 f |= MAPINFO_FLAG_FRUSTRATING;
1384
1385         return f;
1386 }