qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(!s) // empty string is NOT valid here!
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  57 }
  58
  59 float MapInfo_Cache_Retrieve(string map)
  60 {
  61         float i;
  62         string s;
  63         if(!_MapInfo_Cache_Active)
  64                 return 0;
  65
  66         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  67         if(!s)
  68                 return 0;
  69         i = stof(s);
  70
  71         // now retrieve all the stuff
  72         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  73         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  74         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  77         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  78         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         return 1;
  80 }
  81
  82 // GLOB HANDLING (for all BSP files)
  83 float _MapInfo_globopen;
  84 float _MapInfo_globcount;
  85 float _MapInfo_globhandle;
  86 string _MapInfo_GlobItem(float i)
  87 {
  88         string s;
  89         s = search_getfilename(_MapInfo_globhandle, i);
  90         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  91 }
  92
  93 void MapInfo_Enumerate()
  94 {
  95         if(_MapInfo_globopen)
  96                 search_end(_MapInfo_globhandle);
  97         MapInfo_Cache_Invalidate();
  98         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
  99         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 100         _MapInfo_globopen = 1;
 101 }
 102
 103 // filter the info by game type mask (updates MapInfo_count)
 104 //
 105 float _MapInfo_filtered;
 106 float _MapInfo_filtered_allocated;
 107 float MapInfo_FilterList_Lookup(float i)
 108 {
 109         return stof(bufstr_get(_MapInfo_filtered, i));
 110 }
 111
 112 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 113 {
 114         string h;
 115         h = bufstr_get(_MapInfo_filtered, i);
 116         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 117         bufstr_set(_MapInfo_filtered, j, h);
 118 }
 119
 120 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 121 {
 122         string a, b;
 123         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 124         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 125         return strcasecmp(a, b);
 126 }
 127
 128 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 129 {
 130         float i, j;
 131         if not(_MapInfo_filtered_allocated)
 132         {
 133                 _MapInfo_filtered_allocated = 1;
 134                 _MapInfo_filtered = buf_create();
 135         }
 136         MapInfo_count = 0;
 137         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 138         {
 139                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 140                         if(pAbortOnGenerate)
 141                         {
 142                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 143                                 MapInfo_progress = i / _MapInfo_globcount;
 144                                 return 0;
 145                         }
 146                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 147                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 148                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 149                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 150                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 151         }
 152         MapInfo_count = j + 1;
 153         MapInfo_ClearTemps();
 154
 155         // sometimes the glob isn't sorted nicely, so fix it here...
 156         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 157
 158         return 1;
 159 }
 160
 161 void MapInfo_Filter_Free()
 162 {
 163         if(_MapInfo_filtered_allocated)
 164         {
 165                 buf_del(_MapInfo_filtered);
 166                 _MapInfo_filtered_allocated = 0;
 167         }
 168 }
 169
 170 // load info about the i-th map into the MapInfo_Map_* globals
 171 string MapInfo_BSPName_ByID(float i)
 172 {
 173         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 174 }
 175
 176 string unquote(string s)
 177 {
 178         float i, j, l;
 179         l = strlen(s);
 180         j = -1;
 181         for(i = 0; i < l; ++i)
 182         {
 183                 string ch;
 184                 ch = substring(s, i, 1);
 185                 if(ch != " ") if(ch != "\"")
 186                 {
 187                         for(j = strlen(s) - i - 1; j > 0; --j)
 188                         {
 189                                 ch = substring(s, i+j, 1);
 190                                 if(ch != " ") if(ch != "\"")
 191                                         return substring(s, i, j+1);
 192                         }
 193                         return substring(s, i, 1);
 194                 }
 195         }
 196         return "";
 197 }
 198
 199 float MapInfo_Get_ByID(float i)
 200 {
 201         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 202                 return 1;
 203         return 0;
 204 }
 205
 206 string _MapInfo_Map_worldspawn_music;
 207
 208 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 209 {
 210         string fn;
 211         float fh;
 212         string s, k, v;
 213         vector o;
 214         float i;
 215         float inWorldspawn;
 216         float r;
 217         float twoBaseModes;
 218         float diameter, spawnpoints;
 219         float spawnplaces;
 220
 221         vector mapMins, mapMaxs;
 222
 223         r = 1;
 224         fn = strcat("maps/", pFilename, ".ent");
 225         fh = fopen(fn, FILE_READ);
 226         if(fh < 0)
 227         {
 228                 r = 2;
 229                 fn = strcat("maps/", pFilename, ".bsp");
 230                 fh = fopen(fn, FILE_READ);
 231         }
 232         if(fh < 0)
 233                 return 0;
 234         print("Analyzing ", fn, " to generate initial mapinfo\n");
 235
 236         inWorldspawn = 2;
 237         MapInfo_Map_flags = 0;
 238         MapInfo_Map_supportedGametypes = 0;
 239         spawnpoints = 0;
 240         spawnplaces = 0;
 241         _MapInfo_Map_worldspawn_music = "";
 242
 243         for(;;)
 244         {
 245                 if not((s = fgets(fh)))
 246                         break;
 247                 if(inWorldspawn == 1)
 248                         if(startsWith(s, "}"))
 249                                 inWorldspawn = 0;
 250                 k = unquote(car(s));
 251                 v = unquote(cdr(s));
 252                 if(inWorldspawn)
 253                 {
 254                         if(k == "classname" && v == "worldspawn")
 255                                 inWorldspawn = 1;
 256                         else if(k == "author")
 257                                 MapInfo_Map_author = v;
 258                         else if(k == "_description")
 259                                 MapInfo_Map_description = v;
 260                         else if(k == "music")
 261                                 _MapInfo_Map_worldspawn_music = v;
 262                         else if(k == "noise")
 263                                 _MapInfo_Map_worldspawn_music = v;
 264                         else if(k == "message")
 265                         {
 266                                 i = strstrofs(v, " by ", 0);
 267                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 268                                 {
 269                                         MapInfo_Map_title = substring(v, 0, i);
 270                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 271                                 }
 272                                 else
 273                                         MapInfo_Map_title = v;
 274                         }
 275                 }
 276                 else
 277                 {
 278                         if(k == "origin")
 279                         {
 280                                 o = stov(strcat("'", v, "'"));
 281                                 mapMins_x = min(mapMins_x, o_x);
 282                                 mapMins_y = min(mapMins_y, o_y);
 283                                 mapMins_z = min(mapMins_z, o_z);
 284                                 mapMaxs_x = max(mapMaxs_x, o_x);
 285                                 mapMaxs_y = max(mapMaxs_y, o_y);
 286                                 mapMaxs_z = max(mapMaxs_z, o_z);
 287                         }
 288                         else if(k == "race_place")
 289                         {
 290                                 if(stof(v) > 0)
 291                                         spawnplaces = 1;
 292                         }
 293                         else if(k == "classname")
 294                         {
 295                                 if(v == "dom_controlpoint")
 296                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 297                                 else if(v == "item_flag_team2")
 298                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 299                                 else if(v == "team_CTF_blueflag")
 300                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 301                                 else if(v == "runematch_spawn_point")
 302                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 303                                 else if(v == "target_assault_roundend")
 304                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 305                                 else if(v == "onslaught_generator")
 306                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 307                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 308                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 309                                 else if(v == "info_player_team1")
 310                                         ++spawnpoints;
 311                                 else if(v == "info_player_team2")
 312                                         ++spawnpoints;
 313                                 else if(v == "info_player_start")
 314                                         ++spawnpoints;
 315                                 else if(v == "info_player_deathmatch")
 316                                         ++spawnpoints;
 317                                 else if(v == "trigger_race_checkpoint")
 318                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 319                                 else if(v == "target_startTimer")
 320                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 321                                 else if(v == "weapon_nex")
 322                                         { }
 323                                 else if(v == "weapon_railgun")
 324                                         { }
 325                                 else if(startsWith(v, "weapon_"))
 326                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 327                                 else if(v == "target_music" || v == "trigger_music")
 328                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 329                         }
 330                 }
 331         }
 332         if(inWorldspawn)
 333         {
 334                 print(fn, " ended still in worldspawn, BUG\n");
 335                 return 0;
 336         }
 337         diameter = vlen(mapMaxs - mapMins);
 338
 339         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 340         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 341         {
 342                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 343                 // as the map is too symmetric for them.
 344         }
 345         else
 346         {
 347                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 348                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 349                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 350                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 351
 352                 if(spawnpoints >= 8  && diameter > 4096) {
 353                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 354                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 355                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 356                 }
 357                 if(                     diameter < 4096)
 358                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 359                 if(spawnpoints >= 12 && diameter > 5120)
 360                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 361         }
 362
 363         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 364         if(!spawnplaces)
 365         {
 366                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 367                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 368         }
 369
 370         dprint("-> diameter ",    ftos(diameter));
 371         dprint(";  spawnpoints ", ftos(spawnpoints));
 372         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 373
 374         fclose(fh);
 375
 376         return r;
 377 }
 378
 379 void _MapInfo_Map_Reset()
 380 {
 381         MapInfo_Map_title = "<TITLE>";
 382         MapInfo_Map_description = "<DESCRIPTION>";
 383         MapInfo_Map_author = "<AUTHOR>";
 384         MapInfo_Map_supportedGametypes = 0;
 385         MapInfo_Map_supportedFeatures = 0;
 386         MapInfo_Map_flags = 0;
 387         MapInfo_Map_clientstuff = "";
 388         MapInfo_Map_fog = "";
 389         MapInfo_Map_mins = '0 0 0';
 390         MapInfo_Map_maxs = '0 0 0';
 391 }
 392
 393 string _MapInfo_GetDefault(float t)
 394 {
 395         switch(t)
 396         {
 397                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 398                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 399                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 400                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 401                 case MAPINFO_TYPE_RUNEMATCH:       return "200 20 0";
 402                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 403                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
 404                 case MAPINFO_TYPE_CA:              return "10 20 0";
 405                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 406                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 407                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 408                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 409                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 410                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 411                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 412                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 413                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 414                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 415                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 416                 default:                           return "";
 417         }
 418 }
 419
 420 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 421 {
 422         string sa;
 423         MapInfo_Map_supportedGametypes |= pThisType;
 424         if(!(pThisType & pWantedType))
 425                 return;
 426
 427         if(load_default)
 428                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 429
 430         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 431         {
 432                 cvar_set("fraglimit", "0");
 433         }
 434         else
 435         {
 436                 sa = car(s);
 437                 if(sa != "")
 438                         cvar_set("fraglimit", sa);
 439                 s = cdr(s);
 440         }
 441
 442         sa = car(s);
 443         if(sa != "")
 444                 cvar_set("timelimit", sa);
 445         s = cdr(s);
 446
 447         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 448         {
 449                 sa = car(s);
 450                 if(sa != "")
 451                         cvar_set("g_tdm_teams", sa);
 452                 s = cdr(s);
 453         }
 454
 455         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 456         {
 457                 sa = car(s);
 458                 if(sa != "")
 459                         cvar_set("g_keyhunt_teams", sa);
 460                 s = cdr(s);
 461         }
 462
 463         if(pWantedType == MAPINFO_TYPE_CTF)
 464         {
 465                 sa = car(s);
 466                 if(sa != "")
 467                         if(cvar("g_ctf_win_mode") < 2)
 468                                 cvar_set("fraglimit", sa);
 469                 s = cdr(s);
 470         }
 471
 472         /* keepaway wuz here
 473         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 474         {
 475                 sa = car(s);
 476                 if(sa != "")
 477                         cvar_set("fraglimit", sa);
 478                 s = cdr(s);
 479         }
 480         */
 481
 482         // rc = timelimit timelimit_qualification laps laps_teamplay
 483         if(pWantedType == MAPINFO_TYPE_RACE)
 484         {
 485                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 486                 cvar_set("g_race_qualifying_timelimit", sa);
 487                 s = cdr(s);
 488
 489                 sa = car(s);
 490                 if(sa != "")
 491                         if(cvar("g_race_teams") < 2)
 492                                 cvar_set("fraglimit", sa);
 493                 s = cdr(s);
 494
 495                 sa = car(s);
 496                 if(sa != "")
 497                         if(cvar("g_race_teams") >= 2)
 498                                 cvar_set("fraglimit", sa);
 499                 s = cdr(s);
 500         }
 501
 502         if(pWantedType == MAPINFO_TYPE_CTS)
 503         {
 504                 sa = car(s);
 505
 506                 // this is the skill of the map
 507                 // not parsed by anything yet
 508                 // for map databases
 509                 //if(sa != "")
 510                 //      cvar_set("fraglimit", sa);
 511
 512                 s = cdr(s);
 513         }
 514
 515         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 516         {
 517                 cvar_set("leadlimit", "0");
 518         }
 519         else
 520         {
 521                 sa = car(s);
 522                 if(sa != "")
 523                         cvar_set("leadlimit", sa);
 524                 s = cdr(s);
 525         }
 526 }
 527
 528 string _MapInfo_GetDefaultEx(float t)
 529 {
 530         switch(t)
 531         {
 532                 case MAPINFO_TYPE_DEATHMATCH:      return "timelimit=20 pointlimit=30 leadlimit=0";
 533                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "timelimit=20 pointlimit=50 teams=2 leadlimit=0";
 534                 case MAPINFO_TYPE_DOMINATION:      return "timelimit=20 pointlimit=200 teams=2 leadlimit=0";
 535                 case MAPINFO_TYPE_CTF:             return "timelimit=20 pointlimit=300 caplimit=10 leadlimit=0";
 536                 case MAPINFO_TYPE_RUNEMATCH:       return "timelimit=20 pointlimit=200 leadlimit=0";
 537                 case MAPINFO_TYPE_LMS:             return "timelimit=20 lives=9 leadlimit=0";
 538                 case MAPINFO_TYPE_ARENA:           return "timelimit=20 pointlimit=10 leadlimit=0";
 539                 case MAPINFO_TYPE_CA:              return "timelimit=20 pointlimit=10 leadlimit=0";
 540                 case MAPINFO_TYPE_KEYHUNT:         return "timelimit=20 pointlimit=1000 teams=3 leadlimit=0";
 541                 case MAPINFO_TYPE_ASSAULT:         return "timelimit=20";
 542                 case MAPINFO_TYPE_RACE:            return "timelimit=20 qualifying_timelimit=5 laplimit=7 teamlaplimit=15 leadlimit=0";
 543                 case MAPINFO_TYPE_ONSLAUGHT:       return "timelimit=20";
 544                 case MAPINFO_TYPE_NEXBALL:         return "timelimit=20 pointlimit=5 leadlimit=0";
 545                 case MAPINFO_TYPE_CTS:             return "timelimit=20 skill=-1";
 546                 case MAPINFO_TYPE_FREEZETAG:       return "timelimit=20 pointlimit=10 teams=2 leadlimit=0";
 547                 case MAPINFO_TYPE_KEEPAWAY:        return "timelimit=20 pointlimit=30";
 548                 default:                           return "";
 549         }
 550 }
 551
 552 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 553 {
 554         string sa, k, v;
 555         float p;
 556         string fraglimit_normal;
 557         string fraglimit_caps;
 558         string fraglimit_teams;
 559
 560         MapInfo_Map_supportedGametypes |= pThisType;
 561         if(!(pThisType & pWantedType))
 562                 return;
 563
 564         // reset all the cvars to their defaults
 565
 566         cvar_set("timelimit", cvar_defstring("timelimit"));
 567         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 568         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 569         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 570         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 571         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 572         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 573
 574         fraglimit_normal = string_null;
 575         fraglimit_caps = string_null;
 576         fraglimit_teams = string_null;
 577
 578         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 579         while(s != "")
 580         {
 581                 sa = car(s);
 582                 s = cdr(s);
 583
 584                 if(sa == "")
 585                         continue;
 586
 587                 p = strstrofs(sa, "=", 0);
 588                 if(p < 0)
 589                 {
 590                         k = "timelimit";
 591                         v = s;
 592                 }
 593                 else
 594                 {
 595                         k = substring(sa, 0, p);
 596                         v = substring(sa, p+1, -1);
 597                 }
 598
 599                 if(k == "timelimit")
 600                 {
 601                         cvar_set("timelimit", v);
 602                 }
 603                 else if(k == "leadlimit")
 604                 {
 605                         cvar_set("leadlimit", v);
 606                 }
 607                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit")
 608                 {
 609                         fraglimit_normal = v;
 610                 }
 611                 else if(k == "caplimit")
 612                 {
 613                         fraglimit_caps = v;
 614                 }
 615                 else if(k == "teampointlimit" || k == "teamlaplimit")
 616                 {
 617                         fraglimit_teams = v;
 618                 }
 619                 else if(k == "teams")
 620                 {
 621                         cvar_set("g_tdm_teams", v);
 622                         cvar_set("g_keyhunt_teams", v);
 623                         cvar_set("g_domination_default_teams", v);
 624                 }
 625                 else if(k == "qualifying_timelimit")
 626                 {
 627                         cvar_set("g_race_qualifying_timelimit", v);
 628                 }
 629                 else if(k == "skill")
 630                 {
 631                         // ignore
 632                 }
 633                 else
 634                 {
 635                         print("Invalid gametype key in mapinfo: ", k, "\n");
 636                 }
 637         }
 638
 639         if(pWantedType == MAPINFO_TYPE_CTF && cvar("g_ctf_win_mode") < 2)
 640         {
 641                 if(fraglimit_caps)
 642                         cvar_set("fraglimit", fraglimit_caps);
 643         }
 644         else if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 645         {
 646                 if(fraglimit_teams)
 647                         cvar_set("fraglimit", fraglimit_teams);
 648         }
 649         else
 650         {
 651                 if(fraglimit_normal)
 652                         cvar_set("fraglimit", fraglimit_normal);
 653         }
 654 }
 655
 656 float MapInfo_Type_FromString(string t)
 657 {
 658         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
 659         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
 660         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
 661         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
 662         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
 663         else if(t == "lms")     return MAPINFO_TYPE_LMS;
 664         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
 665         else if(t == "ca")      return MAPINFO_TYPE_CA;
 666         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
 667         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
 668         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
 669         else if(t == "rc")      return MAPINFO_TYPE_RACE;
 670         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
 671         else if(t == "cts")     return MAPINFO_TYPE_CTS;
 672         else if(t == "freezetag")       return MAPINFO_TYPE_FREEZETAG;
 673         else if(t == "keepaway") return MAPINFO_TYPE_KEEPAWAY;
 674         else if(t == "all")     return MAPINFO_TYPE_ALL;
 675         else                    return 0;
 676 }
 677
 678 string MapInfo_Type_ToString(float t)
 679 {
 680         if     (t == MAPINFO_TYPE_DEATHMATCH)      return "dm";
 681         else if(t == MAPINFO_TYPE_TEAM_DEATHMATCH) return "tdm";
 682         else if(t == MAPINFO_TYPE_DOMINATION)      return "dom";
 683         else if(t == MAPINFO_TYPE_CTF)             return "ctf";
 684         else if(t == MAPINFO_TYPE_RUNEMATCH)       return "rune";
 685         else if(t == MAPINFO_TYPE_LMS)             return "lms";
 686         else if(t == MAPINFO_TYPE_ARENA)           return "arena";
 687         else if(t == MAPINFO_TYPE_CA)              return "ca";
 688         else if(t == MAPINFO_TYPE_KEYHUNT)         return "kh";
 689         else if(t == MAPINFO_TYPE_ASSAULT)         return "as";
 690         else if(t == MAPINFO_TYPE_ONSLAUGHT)       return "ons";
 691         else if(t == MAPINFO_TYPE_RACE)            return "rc";
 692         else if(t == MAPINFO_TYPE_NEXBALL)         return "nexball";
 693         else if(t == MAPINFO_TYPE_CTS)             return "cts";
 694         else if(t == MAPINFO_TYPE_FREEZETAG)       return "freezetag";
 695         else if(t == MAPINFO_TYPE_KEEPAWAY)        return "keepaway";
 696         else if(t == MAPINFO_TYPE_ALL)             return "all";
 697         else                                       return "";
 698 }
 699
 700 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 701 {
 702         string t;
 703         float fh, o;
 704         t = car(s); s = cdr(s);
 705
 706         // limited support of "" and comments
 707         //   remove trailing and leading " of t
 708         if(substring(t, 0, 1) == "\"")
 709         {
 710                 if(substring(t, -1, 1) == "\"")
 711                         t = substring(t, 1, -2);
 712         }
 713
 714         //   remove leading " of s
 715         if(substring(s, 0, 1) == "\"")
 716         {
 717                 s = substring(s, 1, -1);
 718         }
 719         //   remove trailing " of s, and all that follows (cvar description)
 720         o = strstrofs(s, "\"", 0);
 721         if(o >= 0)
 722                 s = substring(s, 0, o);
 723
 724         //   remove // comments
 725         o = strstrofs(s, "//", 0);
 726         if(o >= 0)
 727                 s = substring(s, 0, o);
 728
 729         //   remove trailing spaces
 730         while(substring(s, -1, 1) == " ")
 731                 s = substring(s, 0, -2);
 732
 733         if(t == "#include")
 734         {
 735                 if(recurse > 0)
 736                 {
 737                         fh = fopen(s, FILE_READ);
 738                         if(fh < 0)
 739                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 740                         else
 741                         {
 742                                 for(;;)
 743                                 {
 744                                         if not((s = fgets(fh)))
 745                                                 break;
 746
 747                                         // catch different sorts of comments
 748                                         if(s == "")                    // empty lines
 749                                                 continue;
 750                                         if(substring(s, 0, 1) == "#")  // UNIX style
 751                                                 continue;
 752                                         if(substring(s, 0, 2) == "//") // C++ style
 753                                                 continue;
 754                                         if(substring(s, 0, 1) == "_")  // q3map style
 755                                                 continue;
 756
 757                                         if(substring(s, 0, 4) == "set ")
 758                                                 s = substring(s, 4, -1);
 759                                         if(substring(s, 0, 5) == "seta ")
 760                                                 s = substring(s, 5, -1);
 761
 762                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 763                                 }
 764                                 fclose(fh);
 765                         }
 766                 }
 767                 else
 768                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 769         }
 770         else if(t == "")
 771                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 772         else if not(cvar_value_issafe(t))
 773                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 774         else if not (cvar_value_issafe(s))
 775                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 776         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 777                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 778         else if(matchacl(acl, t) <= 0)
 779                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 780         else
 781         {
 782                 if(type == 0) // server set
 783                 {
 784                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 785                         if(cvar("g_campaign"))
 786                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 787                         else
 788                                 cvar_settemp(t, s);
 789                 }
 790                 else
 791                 {
 792                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 793                         MapInfo_Map_clientstuff = strcat(
 794                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 795                                         );
 796                 }
 797         }
 798 }
 799
 800 // load info about a map by name into the MapInfo_Map_* globals
 801 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 802 {
 803         string fn;
 804         string s, t;
 805         float fh, fh2;
 806         float r, f, n, i, p;
 807         string acl;
 808
 809         acl = MAPINFO_SETTEMP_ACL_USER;
 810
 811         if(strstrofs(pFilename, "/", 0) >= 0)
 812         {
 813                 print("Invalid character in map name, ignored\n");
 814                 return 0;
 815         }
 816
 817         if(pGametypeToSet == 0)
 818                 if(MapInfo_Cache_Retrieve(pFilename))
 819                         return 1;
 820
 821         r = 1;
 822
 823         MapInfo_Map_bspname = pFilename;
 824
 825         // default all generic fields so they have "good" values in case something fails
 826         fn = strcat("maps/", pFilename, ".mapinfo");
 827         fh = fopen(fn, FILE_READ);
 828         if(fh < 0)
 829         {
 830                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 831                 fh = fopen(fn, FILE_READ);
 832                 if(fh < 0)
 833                 {
 834                         if(!pAllowGenerate)
 835                                 return 0;
 836                         _MapInfo_Map_Reset();
 837                         r = _MapInfo_Generate(pFilename);
 838                         if(!r)
 839                                 return 0;
 840                         fh = fopen(fn, FILE_WRITE);
 841                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 842                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 843                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 844                         if(_MapInfo_Map_worldspawn_music != "")
 845                         {
 846                                 if(
 847                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 848                                         ||
 849                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 850                                 )
 851                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 852                                 else
 853                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 854                         }
 855                         else
 856                         {
 857                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 858                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 859                                 for(;;)
 860                                 {
 861                                         i = floor(random() * n);
 862                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 863                                                 break;
 864                                 }
 865                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 866                         }
 867                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 868                                 fputs(fh, "has weapons\n");
 869                         else
 870                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 871                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 872                                 fputs(fh, "frustrating\n");
 873
 874                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 875                                 if(MapInfo_Map_supportedGametypes & i)
 876                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 877
 878                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 879                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 880
 881                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 882                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 883                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 884                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 885                         fputs(fh, "// optional: hidden\n");
 886
 887                         fclose(fh);
 888                         r = 2;
 889                         // return r;
 890                         fh = fopen(fn, FILE_READ);
 891                         if(fh < 0)
 892                                 error("... but I just wrote it!");
 893                 }
 894
 895                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 896         }
 897
 898         _MapInfo_Map_Reset();
 899         for(;;)
 900         {
 901                 if not((s = fgets(fh)))
 902                         break;
 903
 904                 // catch different sorts of comments
 905                 if(s == "")                    // empty lines
 906                         continue;
 907                 if(substring(s, 0, 1) == "#")  // UNIX style
 908                         continue;
 909                 if(substring(s, 0, 2) == "//") // C++ style
 910                         continue;
 911                 if(substring(s, 0, 1) == "_")  // q3map style
 912                         continue;
 913
 914                 p = strstrofs(s, "//", 0);
 915                 if(p >= 0)
 916                         s = substring(s, 0, p);
 917
 918                 t = car(s); s = cdr(s);
 919                 if(t == "title")
 920                         MapInfo_Map_title = s;
 921                 else if(t == "description")
 922                         MapInfo_Map_description = s;
 923                 else if(t == "author")
 924                         MapInfo_Map_author = s;
 925                 else if(t == "has")
 926                 {
 927                         t = car(s); s = cdr(s);
 928                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 929                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 930                         else
 931                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 932                 }
 933                 else if(t == "hidden")
 934                 {
 935                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 936                 }
 937                 else if(t == "forbidden")
 938                 {
 939                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 940                 }
 941                 else if(t == "frustrating")
 942                 {
 943                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 944                 }
 945                 else if(t == "type")
 946                 {
 947                         t = car(s); s = cdr(s);
 948                         f = MapInfo_Type_FromString(t);
 949                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
 950                         if(f)
 951                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
 952                         else
 953                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 954                 }
 955                 else if(t == "gametype")
 956                 {
 957                         t = car(s); s = cdr(s);
 958                         f = MapInfo_Type_FromString(t);
 959                         if(f)
 960                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
 961                         else
 962                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 963                 }
 964                 else if(t == "size")
 965                 {
 966                         float a, b, c, d, e;
 967                         t = car(s); s = cdr(s); a = stof(t);
 968                         t = car(s); s = cdr(s); b = stof(t);
 969                         t = car(s); s = cdr(s); c = stof(t);
 970                         t = car(s); s = cdr(s); d = stof(t);
 971                         t = car(s); s = cdr(s); e = stof(t);
 972                         if(s == "")
 973                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 974                         else
 975                         {
 976                                 t = car(s); s = cdr(s); f = stof(t);
 977                                 if(s != "")
 978                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 979                                 else
 980                                 {
 981                                         if(a >= d || b >= e || c >= f)
 982                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 983                                         else
 984                                         {
 985                                                 MapInfo_Map_mins_x = a;
 986                                                 MapInfo_Map_mins_y = b;
 987                                                 MapInfo_Map_mins_z = c;
 988                                                 MapInfo_Map_maxs_x = d;
 989                                                 MapInfo_Map_maxs_y = e;
 990                                                 MapInfo_Map_maxs_z = f;
 991                                         }
 992                                 }
 993                         }
 994                 }
 995                 else if(t == "settemp_for_type")
 996                 {
 997                         t = car(s); s = cdr(s);
 998                         if((f = MapInfo_Type_FromString(t)))
 999                         {
1000                                 if(f & pGametypeToSet)
1001                                 {
1002                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1003                                 }
1004                         }
1005                         else
1006                         {
1007                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1008                         }
1009                 }
1010                 else if(t == "clientsettemp_for_type")
1011                 {
1012                         t = car(s); s = cdr(s);
1013                         if((f = MapInfo_Type_FromString(t)))
1014                         {
1015                                 if(f & pGametypeToSet)
1016                                 {
1017                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1018                                 }
1019                         }
1020                         else
1021                         {
1022                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1023                         }
1024                 }
1025                 else if(t == "fog")
1026                 {
1027                         if not(cvar_value_issafe(t))
1028                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1029                         else
1030                                 MapInfo_Map_fog = s;
1031                 }
1032                 else if(t == "cdtrack")
1033                 {
1034                         if(pGametypeToSet)
1035                         {
1036                                 if not(cvar_value_issafe(t))
1037                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1038                                 else
1039                                         MapInfo_Map_clientstuff = strcat(
1040                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
1041                                         );
1042                         }
1043                 }
1044                 else
1045                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1046         }
1047         fclose(fh);
1048
1049         if(pGametypeToSet)
1050         {
1051                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1052                 {
1053                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1054                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1055                         //return;
1056                 }
1057         }
1058
1059         MapInfo_Cache_Store();
1060         if(MapInfo_Map_supportedGametypes != 0)
1061                 return r;
1062         dprint("Map ", pFilename, " supports no game types, ignored\n");
1063         return 0;
1064 }
1065
1066 float MapInfo_FindName(string s)
1067 {
1068         // if there is exactly one map of prefix s, return it
1069         // if not, return the null string
1070         // note that DP sorts glob results... so I can use a binary search
1071         float l, r, m, cmp;
1072         l = 0;
1073         r = MapInfo_count;
1074         // invariants: r is behind s, l-1 is equal or before
1075         while(l != r)
1076         {
1077                 m = floor((l + r) / 2);
1078                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1079                 cmp = strcasecmp(MapInfo_FindName_match, s);
1080                 if(cmp == 0)
1081                         return m; // found and good
1082                 if(cmp < 0)
1083                         l = m + 1; // l-1 is before s
1084                 else
1085                         r = m; // behind s
1086         }
1087         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1088         MapInfo_FindName_firstResult = l;
1089         // r == l, so: l is behind s, l-1 is before
1090         // SO: if there is any, l is the one with the right prefix
1091         //     and l+1 may be one too
1092         if(l == MapInfo_count)
1093         {
1094                 MapInfo_FindName_match = string_null;
1095                 MapInfo_FindName_firstResult = -1;
1096                 return -1; // no MapInfo_FindName_match, behind last item
1097         }
1098         if(!startsWithNocase(MapInfo_FindName_match, s))
1099         {
1100                 MapInfo_FindName_match = string_null;
1101                 MapInfo_FindName_firstResult = -1;
1102                 return -1; // wrong prefix
1103         }
1104         if(l == MapInfo_count - 1)
1105                 return l; // last one, nothing can follow => unique
1106         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1107         {
1108                 MapInfo_FindName_match = string_null;
1109                 return -1; // ambigous MapInfo_FindName_match
1110         }
1111         return l;
1112 }
1113
1114 string MapInfo_FixName(string s)
1115 {
1116         MapInfo_FindName(s);
1117         return MapInfo_FindName_match;
1118 }
1119
1120 float MapInfo_CurrentFeatures()
1121 {
1122         float req;
1123         req = 0;
1124         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1125                 req |= MAPINFO_FEATURE_WEAPONS;
1126         return req;
1127 }
1128
1129 float MapInfo_CurrentGametype()
1130 {
1131         if(cvar("g_domination"))
1132                 return MAPINFO_TYPE_DOMINATION;
1133         else if(cvar("g_ctf"))
1134                 return MAPINFO_TYPE_CTF;
1135         else if(cvar("g_runematch"))
1136                 return MAPINFO_TYPE_RUNEMATCH;
1137         else if(cvar("g_tdm"))
1138                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
1139         else if(cvar("g_assault"))
1140                 return MAPINFO_TYPE_ASSAULT;
1141         else if(cvar("g_lms"))
1142                 return MAPINFO_TYPE_LMS;
1143         else if(cvar("g_arena"))
1144                 return MAPINFO_TYPE_ARENA;
1145         else if(cvar("g_ca"))
1146                 return MAPINFO_TYPE_CA;
1147         else if(cvar("g_keyhunt"))
1148                 return MAPINFO_TYPE_KEYHUNT;
1149         else if(cvar("g_onslaught"))
1150                 return MAPINFO_TYPE_ONSLAUGHT;
1151         else if(cvar("g_race"))
1152                 return MAPINFO_TYPE_RACE;
1153         else if(cvar("g_nexball"))
1154                 return MAPINFO_TYPE_NEXBALL;
1155         else if(cvar("g_cts"))
1156                 return MAPINFO_TYPE_CTS;
1157         else if(cvar("g_freezetag"))
1158                 return MAPINFO_TYPE_FREEZETAG;
1159         else if(cvar("g_keepaway"))
1160                 return MAPINFO_TYPE_KEEPAWAY;
1161         else
1162                 return MAPINFO_TYPE_DEATHMATCH;
1163 }
1164
1165 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1166 {
1167         if(!MapInfo_Get_ByName(s, 1, 0))
1168                 return 0;
1169         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1170                 return 0;
1171         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1172                 return 0;
1173         return 1;
1174 }
1175
1176 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1177 {
1178         float r;
1179         r = _MapInfo_CheckMap(s);
1180         MapInfo_ClearTemps();
1181         return r;
1182 }
1183
1184 string MapInfo_GetGameTypeCvar(float t)
1185 {
1186         switch(t)
1187         {
1188                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
1189                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
1190                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
1191                 case MAPINFO_TYPE_CTF: return "g_ctf";
1192                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
1193                 case MAPINFO_TYPE_LMS: return "g_lms";
1194                 case MAPINFO_TYPE_ARENA: return "g_arena";
1195                 case MAPINFO_TYPE_CA: return "g_ca";
1196                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
1197                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
1198                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
1199                 case MAPINFO_TYPE_RACE: return "g_race";
1200                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
1201                 case MAPINFO_TYPE_FREEZETAG: return "g_freezetag";
1202                 case MAPINFO_TYPE_CTS: return "g_cts";
1203                 case MAPINFO_TYPE_KEEPAWAY:             return "g_keepaway";
1204                 default: return "";
1205         }
1206 }
1207
1208 void MapInfo_SwitchGameType(float t)
1209 {
1210         cvar_set("gamecfg",      "0");
1211         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
1212         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
1213         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
1214         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
1215         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
1216         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
1217         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
1218         cvar_set("g_ca",         (t == MAPINFO_TYPE_CA)              ? "1" : "0");
1219         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
1220         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
1221         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
1222         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
1223         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
1224         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
1225         cvar_set("g_freezetag",  (t == MAPINFO_TYPE_FREEZETAG)       ? "1" : "0");
1226         cvar_set("g_keepaway",   (t == MAPINFO_TYPE_KEEPAWAY)        ? "1" : "0");
1227 }
1228
1229 void MapInfo_LoadMap(string s)
1230 {
1231         MapInfo_Map_supportedGametypes = 0;
1232         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1233         //if(!MapInfo_CheckMap(s))
1234         //{
1235         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1236         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1237         //}
1238         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1239 }
1240
1241 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1242 {
1243         string out;
1244         float i;
1245
1246         // to make absolutely sure:
1247         MapInfo_Enumerate();
1248         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1249
1250         out = "";
1251         for(i = 0; i < MapInfo_count; ++i)
1252                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1253         return substring(out, 1, strlen(out) - 1);
1254 }
1255
1256 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1257 {
1258         float t, t0;
1259         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1260         {
1261                 if(MapInfo_Map_supportedGametypes == 0)
1262                 {
1263                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1264                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1265                         _MapInfo_Map_ApplyGametypeEx("", t0, t0);
1266                         return; // do not call Get_ByName!
1267                 }
1268
1269                 t = 1;
1270                 while(!(MapInfo_Map_supportedGametypes & 1))
1271                 {
1272                         t *= 2;
1273                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1274                 }
1275                 // t is now a supported mode!
1276                 t0 = MapInfo_CurrentGametype();
1277                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1278                 {
1279                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1280                         cvar_settemp_restore();
1281                         _MapInfo_Map_ApplyGametypeEx("", t0, t0);
1282                         return; // do not call Get_ByName!
1283                 }
1284                 else
1285                 {
1286                         print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1287                         MapInfo_SwitchGameType(t);
1288                 }
1289         }
1290         cvar_settemp_restore();
1291         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1292 }
1293
1294 void MapInfo_ClearTemps()
1295 {
1296         MapInfo_Map_bspname = string_null;
1297         MapInfo_Map_title = string_null;
1298         MapInfo_Map_description = string_null;
1299         MapInfo_Map_author = string_null;
1300         MapInfo_Map_clientstuff = string_null;
1301         MapInfo_Map_supportedGametypes = 0;
1302         MapInfo_Map_supportedFeatures = 0;
1303 }
1304
1305 void MapInfo_Shutdown()
1306 {
1307         MapInfo_ClearTemps();
1308         MapInfo_Filter_Free();
1309         MapInfo_Cache_Destroy();
1310         if(_MapInfo_globopen)
1311         {
1312                 search_end(_MapInfo_globhandle);
1313                 _MapInfo_globhandle = -1;
1314                 _MapInfo_globopen = FALSE;
1315         }
1316 }
1317
1318 float MapInfo_ForbiddenFlags()
1319 {
1320         float f;
1321         f = MAPINFO_FLAG_FORBIDDEN;
1322
1323 #ifndef MENUQC
1324         if not(cvar("g_maplist_allow_hidden"))
1325 #endif
1326                 f |= MAPINFO_FLAG_HIDDEN;
1327
1328         if not(cvar("g_maplist_allow_frustrating"))
1329                 f |= MAPINFO_FLAG_FRUSTRATING;
1330
1331         return f;
1332 }
1333
1334 float MapInfo_RequiredFlags()
1335 {
1336         float f;
1337         f = 0;
1338
1339         if(cvar("g_maplist_allow_frustrating") > 1)
1340                 f |= MAPINFO_FLAG_FRUSTRATING;
1341
1342         return f;
1343 }