qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(!s) // empty string is NOT valid here!
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  57 }
  58
  59 float MapInfo_Cache_Retrieve(string map)
  60 {
  61         float i;
  62         string s;
  63         if(!_MapInfo_Cache_Active)
  64                 return 0;
  65
  66         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  67         if(!s)
  68                 return 0;
  69         i = stof(s);
  70
  71         // now retrieve all the stuff
  72         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  73         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  74         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  77         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  78         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         return 1;
  80 }
  81
  82 // GLOB HANDLING (for all BSP files)
  83 float _MapInfo_globopen;
  84 float _MapInfo_globcount;
  85 float _MapInfo_globhandle;
  86 string _MapInfo_GlobItem(float i)
  87 {
  88         string s;
  89         s = search_getfilename(_MapInfo_globhandle, i);
  90         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  91 }
  92
  93 void MapInfo_Enumerate()
  94 {
  95         if(_MapInfo_globopen)
  96                 search_end(_MapInfo_globhandle);
  97         MapInfo_Cache_Invalidate();
  98         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
  99         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 100         _MapInfo_globopen = 1;
 101 }
 102
 103 // filter the info by game type mask (updates MapInfo_count)
 104 //
 105 float _MapInfo_filtered;
 106 float _MapInfo_filtered_allocated;
 107 float MapInfo_FilterList_Lookup(float i)
 108 {
 109         return stof(bufstr_get(_MapInfo_filtered, i));
 110 }
 111
 112 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 113 {
 114         string h;
 115         h = bufstr_get(_MapInfo_filtered, i);
 116         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 117         bufstr_set(_MapInfo_filtered, j, h);
 118 }
 119
 120 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 121 {
 122         string a, b;
 123         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 124         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 125         return strcasecmp(a, b);
 126 }
 127
 128 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 129 {
 130         float i, j;
 131         if not(_MapInfo_filtered_allocated)
 132         {
 133                 _MapInfo_filtered_allocated = 1;
 134                 _MapInfo_filtered = buf_create();
 135         }
 136         MapInfo_count = 0;
 137         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 138         {
 139                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 140                         if(pAbortOnGenerate)
 141                         {
 142                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 143                                 MapInfo_progress = i / _MapInfo_globcount;
 144                                 return 0;
 145                         }
 146                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 147                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 148                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 149                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 150                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 151         }
 152         MapInfo_count = j + 1;
 153         MapInfo_ClearTemps();
 154
 155         // sometimes the glob isn't sorted nicely, so fix it here...
 156         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 157
 158         return 1;
 159 }
 160
 161 void MapInfo_Filter_Free()
 162 {
 163         if(_MapInfo_filtered_allocated)
 164         {
 165                 buf_del(_MapInfo_filtered);
 166                 _MapInfo_filtered_allocated = 0;
 167         }
 168 }
 169
 170 // load info about the i-th map into the MapInfo_Map_* globals
 171 string MapInfo_BSPName_ByID(float i)
 172 {
 173         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 174 }
 175
 176 string unquote(string s)
 177 {
 178         float i, j, l;
 179         l = strlen(s);
 180         j = -1;
 181         for(i = 0; i < l; ++i)
 182         {
 183                 string ch;
 184                 ch = substring(s, i, 1);
 185                 if(ch != " ") if(ch != "\"")
 186                 {
 187                         for(j = strlen(s) - i - 1; j > 0; --j)
 188                         {
 189                                 ch = substring(s, i+j, 1);
 190                                 if(ch != " ") if(ch != "\"")
 191                                         return substring(s, i, j+1);
 192                         }
 193                         return substring(s, i, 1);
 194                 }
 195         }
 196         return "";
 197 }
 198
 199 float MapInfo_Get_ByID(float i)
 200 {
 201         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 202                 return 1;
 203         return 0;
 204 }
 205
 206 string _MapInfo_Map_worldspawn_music;
 207
 208 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 209 {
 210         string fn;
 211         float fh;
 212         string s, k, v;
 213         vector o;
 214         float i;
 215         float inWorldspawn;
 216         float r;
 217         float twoBaseModes;
 218         float diameter, spawnpoints;
 219         float spawnplaces;
 220
 221         vector mapMins, mapMaxs;
 222
 223         r = 1;
 224         fn = strcat("maps/", pFilename, ".ent");
 225         fh = fopen(fn, FILE_READ);
 226         if(fh < 0)
 227         {
 228                 r = 2;
 229                 fn = strcat("maps/", pFilename, ".bsp");
 230                 fh = fopen(fn, FILE_READ);
 231         }
 232         if(fh < 0)
 233                 return 0;
 234         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 235
 236         inWorldspawn = 2;
 237         MapInfo_Map_flags = 0;
 238         MapInfo_Map_supportedGametypes = 0;
 239         spawnpoints = 0;
 240         spawnplaces = 0;
 241         _MapInfo_Map_worldspawn_music = "";
 242
 243         for(;;)
 244         {
 245                 if not((s = fgets(fh)))
 246                         break;
 247                 if(inWorldspawn == 1)
 248                         if(startsWith(s, "}"))
 249                                 inWorldspawn = 0;
 250                 k = unquote(car(s));
 251                 v = unquote(cdr(s));
 252                 if(inWorldspawn)
 253                 {
 254                         if(k == "classname" && v == "worldspawn")
 255                                 inWorldspawn = 1;
 256                         else if(k == "author")
 257                                 MapInfo_Map_author = v;
 258                         else if(k == "_description")
 259                                 MapInfo_Map_description = v;
 260                         else if(k == "music")
 261                                 _MapInfo_Map_worldspawn_music = v;
 262                         else if(k == "noise")
 263                                 _MapInfo_Map_worldspawn_music = v;
 264                         else if(k == "message")
 265                         {
 266                                 i = strstrofs(v, " by ", 0);
 267                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 268                                 {
 269                                         MapInfo_Map_title = substring(v, 0, i);
 270                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 271                                 }
 272                                 else
 273                                         MapInfo_Map_title = v;
 274                         }
 275                 }
 276                 else
 277                 {
 278                         if(k == "origin")
 279                         {
 280                                 o = stov(strcat("'", v, "'"));
 281                                 mapMins_x = min(mapMins_x, o_x);
 282                                 mapMins_y = min(mapMins_y, o_y);
 283                                 mapMins_z = min(mapMins_z, o_z);
 284                                 mapMaxs_x = max(mapMaxs_x, o_x);
 285                                 mapMaxs_y = max(mapMaxs_y, o_y);
 286                                 mapMaxs_z = max(mapMaxs_z, o_z);
 287                         }
 288                         else if(k == "race_place")
 289                         {
 290                                 if(stof(v) > 0)
 291                                         spawnplaces = 1;
 292                         }
 293                         else if(k == "classname")
 294                         {
 295                                 if(v == "dom_controlpoint")
 296                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 297                                 else if(v == "item_flag_team2")
 298                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 299                                 else if(v == "team_CTF_blueflag")
 300                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 301                                 else if(v == "runematch_spawn_point")
 302                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 303                                 else if(v == "target_assault_roundend")
 304                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 305                                 else if(v == "onslaught_generator")
 306                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 307                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 308                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 309                                 else if(v == "info_player_team1")
 310                                         ++spawnpoints;
 311                                 else if(v == "info_player_team2")
 312                                         ++spawnpoints;
 313                                 else if(v == "info_player_start")
 314                                         ++spawnpoints;
 315                                 else if(v == "info_player_deathmatch")
 316                                         ++spawnpoints;
 317                                 else if(v == "trigger_race_checkpoint")
 318                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 319                                 else if(v == "target_startTimer")
 320                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 321                                 else if(v == "weapon_nex")
 322                                         { }
 323                                 else if(v == "weapon_railgun")
 324                                         { }
 325                                 else if(startsWith(v, "weapon_"))
 326                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 327                                 else if(v == "target_music" || v == "trigger_music")
 328                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 329                         }
 330                 }
 331         }
 332         if(inWorldspawn)
 333         {
 334                 print(fn, " ended still in worldspawn, BUG\n");
 335                 return 0;
 336         }
 337         diameter = vlen(mapMaxs - mapMins);
 338
 339         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 340         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 341         {
 342                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 343                 // as the map is too symmetric for them.
 344         }
 345         else
 346         {
 347                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 348                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 349                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 350
 351                 if(spawnpoints >= 8  && diameter > 4096) {
 352                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 353                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 354                 }
 355                 if(                     diameter < 4096)
 356                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 357                 if(spawnpoints >= 12 && diameter > 5120)
 358                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 359         }
 360
 361         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 362         if(!spawnplaces)
 363         {
 364                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 365                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 366         }
 367
 368         dprint("-> diameter ",    ftos(diameter));
 369         dprint(";  spawnpoints ", ftos(spawnpoints));
 370         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 371
 372         fclose(fh);
 373
 374         return r;
 375 }
 376
 377 void _MapInfo_Map_Reset()
 378 {
 379         MapInfo_Map_title = "<TITLE>";
 380         MapInfo_Map_description = "<DESCRIPTION>";
 381         MapInfo_Map_author = "<AUTHOR>";
 382         MapInfo_Map_supportedGametypes = 0;
 383         MapInfo_Map_supportedFeatures = 0;
 384         MapInfo_Map_flags = 0;
 385         MapInfo_Map_clientstuff = "";
 386         MapInfo_Map_fog = "";
 387         MapInfo_Map_mins = '0 0 0';
 388         MapInfo_Map_maxs = '0 0 0';
 389 }
 390
 391 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 392 {
 393         string sa;
 394         MapInfo_Map_supportedGametypes |= pThisType;
 395         if(!(pThisType & pWantedType))
 396                 return;
 397
 398         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 399         {
 400                 cvar_set("fraglimit", "0");
 401         }
 402         else
 403         {
 404                 cvar_set("fraglimit", car(s));
 405                 s = cdr(s);
 406         }
 407
 408         cvar_set("timelimit", car(s));
 409         s = cdr(s);
 410
 411         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 412         {
 413                 sa = car(s); if(sa == "") sa = "2";
 414                 cvar_set("g_tdm_teams", sa);
 415                 s = cdr(s);
 416         }
 417
 418         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 419         {
 420                 sa = car(s); if(sa == "") sa = "3";
 421                 cvar_set("g_keyhunt_teams", sa);
 422                 s = cdr(s);
 423         }
 424
 425         if(pWantedType == MAPINFO_TYPE_CTF)
 426         {
 427                 sa = car(s); if(sa == "") sa = "10";
 428                 if(cvar("g_ctf_win_mode") < 2)
 429                         cvar_set("fraglimit", sa);
 430                 s = cdr(s);
 431         }
 432
 433         // rc = timelimit timelimit_qualification laps laps_teamplay
 434         if(pWantedType == MAPINFO_TYPE_RACE)
 435         {
 436                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 437                 cvar_set("g_race_qualifying_timelimit", sa);
 438                 s = cdr(s);
 439
 440                 sa = car(s); if(sa == "") sa = "10";
 441                 if(cvar("g_race_teams") < 2)
 442                         cvar_set("fraglimit", sa);
 443                 s = cdr(s);
 444
 445                 sa = car(s); if(sa == "") sa = "20";
 446                 if(cvar("g_race_teams") >= 2)
 447                         cvar_set("fraglimit", sa);
 448                 s = cdr(s);
 449         }
 450
 451         if(pWantedType == MAPINFO_TYPE_CTS)
 452         {
 453                 sa = car(s); if(sa == "") sa = cvar_string("fraglimit");
 454                 if(cvar("g_race_teams"))
 455                         cvar_set("fraglimit", sa);
 456                 s = cdr(s);
 457         }
 458
 459         sa = car(s); if(sa == "") sa = "0";
 460         cvar_set("leadlimit", sa);
 461         s = cdr(s);
 462 }
 463
 464 float MapInfo_Type_FromString(string t)
 465 {
 466         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
 467         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
 468         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
 469         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
 470         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
 471         else if(t == "lms")     return MAPINFO_TYPE_LMS;
 472         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
 473         else if(t == "ca")      return MAPINFO_TYPE_CA;
 474         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
 475         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
 476         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
 477         else if(t == "rc")      return MAPINFO_TYPE_RACE;
 478         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
 479         else if(t == "cts")     return MAPINFO_TYPE_CTS;
 480         else if(t == "all")     return MAPINFO_TYPE_ALL;
 481         else                    return 0;
 482 }
 483
 484 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 485 {
 486         string t;
 487         float fh, o;
 488         t = car(s); s = cdr(s);
 489
 490         // limited support of "" and comments
 491         //   remove trailing and leading " of t
 492         if(substring(t, 0, 1) == "\"")
 493         {
 494                 if(substring(t, -1, 1) == "\"")
 495                         t = substring(t, 1, -2);
 496         }
 497
 498         //   remove leading " of s
 499         if(substring(s, 0, 1) == "\"")
 500         {
 501                 s = substring(s, 1, -1);
 502         }
 503         //   remove trailing " of s, and all that follows (cvar description)
 504         o = strstrofs(s, "\"", 0);
 505         if(o >= 0)
 506                 s = substring(s, 0, o);
 507
 508         //   remove // comments
 509         o = strstrofs(s, "//", 0);
 510         if(o >= 0)
 511                 s = substring(s, 0, o);
 512
 513         //   remove trailing spaces
 514         while(substring(s, -1, 1) == " ")
 515                 s = substring(s, 0, -2);
 516
 517         if(t == "#include")
 518         {
 519                 if(recurse > 0)
 520                 {
 521                         fh = fopen(s, FILE_READ);
 522                         if(fh < 0)
 523                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 524                         else
 525                         {
 526                                 for(;;)
 527                                 {
 528                                         if not((s = fgets(fh)))
 529                                                 break;
 530
 531                                         // catch different sorts of comments
 532                                         if(s == "")                    // empty lines
 533                                                 continue;
 534                                         if(substring(s, 0, 1) == "#")  // UNIX style
 535                                                 continue;
 536                                         if(substring(s, 0, 2) == "//") // C++ style
 537                                                 continue;
 538                                         if(substring(s, 0, 1) == "_")  // q3map style
 539                                                 continue;
 540
 541                                         if(substring(s, 0, 4) == "set ")
 542                                                 s = substring(s, 4, -1);
 543                                         if(substring(s, 0, 5) == "seta ")
 544                                                 s = substring(s, 5, -1);
 545
 546                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 547                                 }
 548                                 fclose(fh);
 549                         }
 550                 }
 551                 else
 552                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 553         }
 554         else if(t == "")
 555                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 556         else if not(cvar_value_issafe(t))
 557                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 558         else if not (cvar_value_issafe(s))
 559                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 560         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 561                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 562         else if(matchacl(acl, t) <= 0)
 563                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 564         else
 565         {
 566                 if(type == 0) // server set
 567                 {
 568                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 569                         if(cvar("g_campaign"))
 570                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 571                         else
 572                                 cvar_settemp(t, s);
 573                 }
 574                 else
 575                 {
 576                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 577                         MapInfo_Map_clientstuff = strcat(
 578                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 579                                         );
 580                 }
 581         }
 582 }
 583
 584 // load info about a map by name into the MapInfo_Map_* globals
 585 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 586 {
 587         string fn;
 588         string s, t;
 589         float fh, fh2;
 590         float r, f, n, i;
 591         string acl;
 592
 593         acl = MAPINFO_SETTEMP_ACL_USER;
 594
 595         if(strstrofs(pFilename, "/", 0) >= 0)
 596         {
 597                 print("Invalid character in map name, ignored\n");
 598                 return 0;
 599         }
 600
 601         if(pGametypeToSet == 0)
 602                 if(MapInfo_Cache_Retrieve(pFilename))
 603                         return 1;
 604
 605         r = 1;
 606
 607         MapInfo_Map_bspname = pFilename;
 608
 609         // default all generic fields so they have "good" values in case something fails
 610         fn = strcat("maps/", pFilename, ".mapinfo");
 611         fh = fopen(fn, FILE_READ);
 612         if(fh < 0)
 613         {
 614                 if(!pAllowGenerate)
 615                         return 0;
 616                 _MapInfo_Map_Reset();
 617                 r = _MapInfo_Generate(pFilename);
 618                 if(!r)
 619                         return 0;
 620                 fh = fopen(fn, FILE_WRITE);
 621                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 622                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 623                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 624                 if(_MapInfo_Map_worldspawn_music != "")
 625                 {
 626                         if(
 627                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 628                                 ||
 629                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 630                         )
 631                                 fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 632                         else
 633                                 fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 634                 }
 635                 else if(_MapInfo_Map_worldspawn_music)
 636                 {
 637                         n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 638                         s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 639                         for(;;)
 640                         {
 641                                 i = floor(random() * n);
 642                                 if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 643                                         break;
 644                         }
 645                         fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 646                 }
 647                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 648                         fputs(fh, "has weapons\n");
 649                 else
 650                         fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 651                 if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 652                         fputs(fh, "frustrating\n");
 653                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 654                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 655                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 656                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 657                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 658                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 659                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 660                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CA)              fputs(fh, "type ca 10 20\n");
 661                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 662                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 663                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)            fputs(fh, "type rc 20 5 7 15\n");
 664                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 665                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_NEXBALL)         fputs(fh, "type nexball 5 20\n");
 666                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTS)             fputs(fh, "type cts 20 -1\n");
 667
 668                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 669                 if(fh2 >= 0)
 670                 {
 671                         fclose(fh2);
 672                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 673                 }
 674
 675                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 676                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 677                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 678                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 679                 fputs(fh, "// optional: hidden\n");
 680
 681                 fclose(fh);
 682                 r = 2;
 683                 // return r;
 684                 fh = fopen(fn, FILE_READ);
 685                 if(fh < 0)
 686                         error("... but I just wrote it!");
 687         }
 688
 689         _MapInfo_Map_Reset();
 690         for(;;)
 691         {
 692                 if not((s = fgets(fh)))
 693                         break;
 694
 695                 // catch different sorts of comments
 696                 if(s == "")                    // empty lines
 697                         continue;
 698                 if(substring(s, 0, 1) == "#")  // UNIX style
 699                         continue;
 700                 if(substring(s, 0, 2) == "//") // C++ style
 701                         continue;
 702                 if(substring(s, 0, 1) == "_")  // q3map style
 703                         continue;
 704
 705                 t = car(s); s = cdr(s);
 706                 if(t == "title")
 707                         MapInfo_Map_title = s;
 708                 else if(t == "description")
 709                         MapInfo_Map_description = s;
 710                 else if(t == "author")
 711                         MapInfo_Map_author = s;
 712                 else if(t == "has")
 713                 {
 714                         t = car(s); s = cdr(s);
 715                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 716                         else
 717                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 718                 }
 719                 else if(t == "hidden")
 720                 {
 721                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 722                 }
 723                 else if(t == "forbidden")
 724                 {
 725                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 726                 }
 727                 else if(t == "frustrating")
 728                 {
 729                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 730                 }
 731                 else if(t == "type")
 732                 {
 733                         t = car(s); s = cdr(s);
 734                         f = MapInfo_Type_FromString(t);
 735                         if(f)
 736                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 737                         else
 738                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 739                 }
 740                 else if(t == "size")
 741                 {
 742                         float a, b, c, d, e;
 743                         t = car(s); s = cdr(s); a = stof(t);
 744                         t = car(s); s = cdr(s); b = stof(t);
 745                         t = car(s); s = cdr(s); c = stof(t);
 746                         t = car(s); s = cdr(s); d = stof(t);
 747                         t = car(s); s = cdr(s); e = stof(t);
 748                         if(s == "")
 749                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 750                         else
 751                         {
 752                                 t = car(s); s = cdr(s); f = stof(t);
 753                                 if(s != "")
 754                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 755                                 else
 756                                 {
 757                                         if(a >= d || b >= e || c >= f)
 758                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 759                                         else
 760                                         {
 761                                                 MapInfo_Map_mins_x = a;
 762                                                 MapInfo_Map_mins_y = b;
 763                                                 MapInfo_Map_mins_z = c;
 764                                                 MapInfo_Map_maxs_x = d;
 765                                                 MapInfo_Map_maxs_y = e;
 766                                                 MapInfo_Map_maxs_z = f;
 767                                         }
 768                                 }
 769                         }
 770                 }
 771                 else if(t == "settemp_for_type")
 772                 {
 773                         t = car(s); s = cdr(s);
 774                         if((f = MapInfo_Type_FromString(t)))
 775                         {
 776                                 if(f & pGametypeToSet)
 777                                 {
 778                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
 779                                 }
 780                         }
 781                         else
 782                         {
 783                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 784                         }
 785                 }
 786                 else if(t == "clientsettemp_for_type")
 787                 {
 788                         t = car(s); s = cdr(s);
 789                         if((f = MapInfo_Type_FromString(t)))
 790                         {
 791                                 if(f & pGametypeToSet)
 792                                 {
 793                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
 794                                 }
 795                         }
 796                         else
 797                         {
 798                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
 799                         }
 800                 }
 801                 else if(t == "fog")
 802                 {
 803                         if not(cvar_value_issafe(t))
 804                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
 805                         else
 806                                 MapInfo_Map_fog = s;
 807                 }
 808                 else if(t == "cdtrack")
 809                 {
 810                         if(pGametypeToSet)
 811                         {
 812                                 if not(cvar_value_issafe(t))
 813                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
 814                                 else
 815                                         MapInfo_Map_clientstuff = strcat(
 816                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
 817                                         );
 818                         }
 819                 }
 820                 else
 821                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 822         }
 823         fclose(fh);
 824
 825         if(pGametypeToSet)
 826         {
 827                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 828                 {
 829                         print("Can't select the requested game type. Trying anyway with stupid settings.\n");
 830                         _MapInfo_Map_ApplyGametype("0 0 0", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
 831                 }
 832         }
 833
 834         MapInfo_Cache_Store();
 835         if(MapInfo_Map_supportedGametypes != 0)
 836                 return r;
 837         dprint("Map ", pFilename, " supports no game types, ignored\n");
 838         return 0;
 839 }
 840
 841 float MapInfo_FindName(string s)
 842 {
 843         // if there is exactly one map of prefix s, return it
 844         // if not, return the null string
 845         // note that DP sorts glob results... so I can use a binary search
 846         float l, r, m, cmp;
 847         l = 0;
 848         r = MapInfo_count;
 849         // invariants: r is behind s, l-1 is equal or before
 850         while(l != r)
 851         {
 852                 m = floor((l + r) / 2);
 853                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 854                 cmp = strcasecmp(MapInfo_FindName_match, s);
 855                 if(cmp == 0)
 856                         return m; // found and good
 857                 if(cmp < 0)
 858                         l = m + 1; // l-1 is before s
 859                 else
 860                         r = m; // behind s
 861         }
 862         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 863         MapInfo_FindName_firstResult = l;
 864         // r == l, so: l is behind s, l-1 is before
 865         // SO: if there is any, l is the one with the right prefix
 866         //     and l+1 may be one too
 867         if(l == MapInfo_count)
 868         {
 869                 MapInfo_FindName_match = string_null;
 870                 MapInfo_FindName_firstResult = -1;
 871                 return -1; // no MapInfo_FindName_match, behind last item
 872         }
 873         if(!startsWithNocase(MapInfo_FindName_match, s))
 874         {
 875                 MapInfo_FindName_match = string_null;
 876                 MapInfo_FindName_firstResult = -1;
 877                 return -1; // wrong prefix
 878         }
 879         if(l == MapInfo_count - 1)
 880                 return l; // last one, nothing can follow => unique
 881         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 882         {
 883                 MapInfo_FindName_match = string_null;
 884                 return -1; // ambigous MapInfo_FindName_match
 885         }
 886         return l;
 887 }
 888
 889 string MapInfo_FixName(string s)
 890 {
 891         MapInfo_FindName(s);
 892         return MapInfo_FindName_match;
 893 }
 894
 895 float MapInfo_CurrentFeatures()
 896 {
 897         float req;
 898         req = 0;
 899         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
 900                 req |= MAPINFO_FEATURE_WEAPONS;
 901         return req;
 902 }
 903
 904 float MapInfo_CurrentGametype()
 905 {
 906         if(cvar("g_domination"))
 907                 return MAPINFO_TYPE_DOMINATION;
 908         else if(cvar("g_ctf"))
 909                 return MAPINFO_TYPE_CTF;
 910         else if(cvar("g_runematch"))
 911                 return MAPINFO_TYPE_RUNEMATCH;
 912         else if(cvar("g_tdm"))
 913                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 914         else if(cvar("g_assault"))
 915                 return MAPINFO_TYPE_ASSAULT;
 916         else if(cvar("g_lms"))
 917                 return MAPINFO_TYPE_LMS;
 918         else if(cvar("g_arena"))
 919                 return MAPINFO_TYPE_ARENA;
 920         else if(cvar("g_ca"))
 921                 return MAPINFO_TYPE_CA;
 922         else if(cvar("g_keyhunt"))
 923                 return MAPINFO_TYPE_KEYHUNT;
 924         else if(cvar("g_onslaught"))
 925                 return MAPINFO_TYPE_ONSLAUGHT;
 926         else if(cvar("g_race"))
 927                 return MAPINFO_TYPE_RACE;
 928         else if(cvar("g_nexball"))
 929                 return MAPINFO_TYPE_NEXBALL;
 930         else if(cvar("g_cts"))
 931                 return MAPINFO_TYPE_CTS;
 932         else
 933                 return MAPINFO_TYPE_DEATHMATCH;
 934 }
 935
 936 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 937 {
 938         if(!MapInfo_Get_ByName(s, 1, 0))
 939                 return 0;
 940         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 941                 return 0;
 942         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 943                 return 0;
 944         return 1;
 945 }
 946
 947 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 948 {
 949         float r;
 950         r = _MapInfo_CheckMap(s);
 951         MapInfo_ClearTemps();
 952         return r;
 953 }
 954
 955 string MapInfo_GetGameTypeCvar(float t)
 956 {
 957         switch(t)
 958         {
 959                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
 960                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
 961                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
 962                 case MAPINFO_TYPE_CTF: return "g_ctf";
 963                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
 964                 case MAPINFO_TYPE_LMS: return "g_lms";
 965                 case MAPINFO_TYPE_ARENA: return "g_arena";
 966                 case MAPINFO_TYPE_CA: return "g_ca";
 967                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
 968                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
 969                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
 970                 case MAPINFO_TYPE_RACE: return "g_race";
 971                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
 972                 case MAPINFO_TYPE_CTS: return "g_cts";
 973                 default: return "";
 974         }
 975 }
 976
 977 void MapInfo_SwitchGameType(float t)
 978 {
 979         cvar_set("gamecfg",      "0");
 980         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 981         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 982         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 983         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 984         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 985         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 986         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 987         cvar_set("g_ca",         (t == MAPINFO_TYPE_CA)              ? "1" : "0");
 988         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 989         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 990         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 991         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
 992         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
 993         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
 994 }
 995
 996 void MapInfo_LoadMap(string s)
 997 {
 998         MapInfo_Map_supportedGametypes = 0;
 999         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1000         //if(!MapInfo_CheckMap(s))
1001         //{
1002         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1003         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1004         //}
1005         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1006 }
1007
1008 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1009 {
1010         string out;
1011         float i;
1012
1013         // to make absolutely sure:
1014         MapInfo_Enumerate();
1015         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1016
1017         out = "";
1018         for(i = 0; i < MapInfo_count; ++i)
1019                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1020         return substring(out, 1, strlen(out) - 1);
1021 }
1022
1023 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1024 {
1025         float t, t0;
1026         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1027         {
1028                 if(MapInfo_Map_supportedGametypes == 0)
1029                 {
1030                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1031                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1032                 }
1033
1034                 t = 1;
1035                 while(!(MapInfo_Map_supportedGametypes & 1))
1036                 {
1037                         t *= 2;
1038                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1039                 }
1040                 // t is now a supported mode!
1041                 t0 = MapInfo_CurrentGametype();
1042                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1043                 {
1044                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1045                         cvar_set("timelimit", "0");
1046                         cvar_set("fraglimit", "0");
1047                         cvar_set("g_tdm_teams", "2");
1048                         cvar_set("g_keyhunt_teams", "3");
1049                         cvar_set("g_race_qualifying_timelimit", "0");
1050                         cvar_set("leadlimit", "0");
1051                 }
1052                 else
1053                 {
1054                         print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1055                         MapInfo_SwitchGameType(t);
1056                 }
1057         }
1058         cvar_settemp_restore();
1059         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1060 }
1061
1062 void MapInfo_ClearTemps()
1063 {
1064         MapInfo_Map_bspname = string_null;
1065         MapInfo_Map_title = string_null;
1066         MapInfo_Map_description = string_null;
1067         MapInfo_Map_author = string_null;
1068         MapInfo_Map_clientstuff = string_null;
1069         MapInfo_Map_supportedGametypes = 0;
1070         MapInfo_Map_supportedFeatures = 0;
1071 }
1072
1073 void MapInfo_Shutdown()
1074 {
1075         MapInfo_ClearTemps();
1076         MapInfo_Filter_Free();
1077         MapInfo_Cache_Destroy();
1078         if(_MapInfo_globopen)
1079         {
1080                 search_end(_MapInfo_globhandle);
1081                 _MapInfo_globhandle = -1;
1082                 _MapInfo_globopen = FALSE;
1083         }
1084 }
1085
1086 float MapInfo_ForbiddenFlags()
1087 {
1088         float f;
1089         f = MAPINFO_FLAG_FORBIDDEN;
1090
1091 #ifndef MENUQC
1092         if not(cvar("g_maplist_allow_hidden"))
1093 #endif
1094                 f |= MAPINFO_FLAG_HIDDEN;
1095
1096         if not(cvar("g_maplist_allow_frustrating"))
1097                 f |= MAPINFO_FLAG_FRUSTRATING;
1098
1099         return f;
1100 }
1101
1102 float MapInfo_RequiredFlags()
1103 {
1104         float f;
1105         f = 0;
1106
1107         if(cvar("g_maplist_allow_frustrating") > 1)
1108                 f |= MAPINFO_FLAG_FRUSTRATING;
1109
1110         return f;
1111 }