qcsrc/common/mapinfo.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qh"
   3     #include "../client/defs.qh"
   4     #include "util.qh"
   5     #include "buffs.qh"
   6     #include "weapons/weapons.qh"
   7     #include "mapinfo.qh"
   8 #elif defined(MENUQC)
   9 #elif defined(SVQC)
  10         #include "../dpdefs/progsdefs.qh"
  11     #include "../dpdefs/dpextensions.qh"
  12     #include "util.qh"
  13     #include "buffs.qh"
  14     #include "monsters/monsters.qh"
  15     #include "mapinfo.qh"
  16 #endif
  17
  18 // generic string stuff
  19
  20 int _MapInfo_Cache_Active;
  21 int _MapInfo_Cache_DB_NameToIndex;
  22 int _MapInfo_Cache_Buf_IndexToMapData;
  23
  24 void MapInfo_Cache_Destroy()
  25 {
  26         if(!_MapInfo_Cache_Active)
  27                 return;
  28
  29         db_close(_MapInfo_Cache_DB_NameToIndex);
  30         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  31         _MapInfo_Cache_Active = 0;
  32 }
  33
  34 void MapInfo_Cache_Create()
  35 {
  36         MapInfo_Cache_Destroy();
  37         _MapInfo_Cache_DB_NameToIndex = db_create();
  38         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  39         _MapInfo_Cache_Active = 1;
  40 }
  41
  42 void MapInfo_Cache_Invalidate()
  43 {
  44         if(!_MapInfo_Cache_Active)
  45                 return;
  46
  47         MapInfo_Cache_Create();
  48 }
  49
  50 void MapInfo_Cache_Store()
  51 {
  52         float i;
  53         string s;
  54         if(!_MapInfo_Cache_Active)
  55                 return;
  56
  57         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  58         if(s == "")
  59         {
  60                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  61                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  62         }
  63         else
  64                 i = stof(s);
  65
  66         // now store all the stuff
  67         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  75 }
  76
  77 float MapInfo_Cache_Retrieve(string map)
  78 {
  79         float i;
  80         string s;
  81         if(!_MapInfo_Cache_Active)
  82                 return 0;
  83
  84         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  85         if(s == "")
  86                 return 0;
  87         i = stof(s);
  88
  89         // now retrieve all the stuff
  90         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  91         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  92         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  93         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  94         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  95         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  96         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  97         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  98
  99         return 1;
 100 }
 101
 102 // GLOB HANDLING (for all BSP files)
 103 float _MapInfo_globopen;
 104 float _MapInfo_globcount;
 105 float _MapInfo_globhandle;
 106 string _MapInfo_GlobItem(float i)
 107 {
 108         string s;
 109         if(!_MapInfo_globopen)
 110                 return string_null;
 111         s = search_getfilename(_MapInfo_globhandle, i);
 112         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 113 }
 114
 115 void MapInfo_Enumerate()
 116 {
 117         if(_MapInfo_globopen)
 118         {
 119                 search_end(_MapInfo_globhandle);
 120                 _MapInfo_globopen = 0;
 121         }
 122         MapInfo_Cache_Invalidate();
 123         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 124         if(_MapInfo_globhandle >= 0)
 125         {
 126                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 127                 _MapInfo_globopen = 1;
 128         }
 129         else
 130                 _MapInfo_globcount = 0;
 131 }
 132
 133 // filter the info by game type mask (updates MapInfo_count)
 134 //
 135 float _MapInfo_filtered;
 136 float _MapInfo_filtered_allocated;
 137 float MapInfo_FilterList_Lookup(float i)
 138 {
 139         return stof(bufstr_get(_MapInfo_filtered, i));
 140 }
 141
 142 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 143 {
 144         string h;
 145         h = bufstr_get(_MapInfo_filtered, i);
 146         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 147         bufstr_set(_MapInfo_filtered, j, h);
 148 }
 149
 150 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 151 {
 152         string a, b;
 153         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 154         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 155         return strcasecmp(a, b);
 156 }
 157
 158 float MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 159 {
 160         float i, j;
 161         if (!_MapInfo_filtered_allocated)
 162         {
 163                 _MapInfo_filtered_allocated = 1;
 164                 _MapInfo_filtered = buf_create();
 165         }
 166         MapInfo_count = 0;
 167         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 168         {
 169                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 170                         if(pAbortOnGenerate)
 171                         {
 172                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 173                                 MapInfo_progress = i / _MapInfo_globcount;
 174                                 return 0;
 175                         }
 176                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 177                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 178                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 179                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 180                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 181         }
 182         MapInfo_count = j + 1;
 183         MapInfo_ClearTemps();
 184
 185         // sometimes the glob isn't sorted nicely, so fix it here...
 186         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 187
 188         return 1;
 189 }
 190 void MapInfo_FilterString(string sf)
 191 {
 192         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 193         float i, j;
 194         string title;
 195
 196         for(i = 0, j = -1; i < MapInfo_count; ++i)
 197         {
 198                 if (MapInfo_Get_ByID(i))
 199                 {
 200                         // prepare for keyword filter
 201                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 202                                 title = MapInfo_Map_title;
 203                         else
 204                                 title = MapInfo_Map_bspname;
 205                         // keyword filter
 206                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 207                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 208                 }
 209         }
 210         MapInfo_count = j + 1;
 211         MapInfo_ClearTemps();
 212
 213         // sometimes the glob isn't sorted nicely, so fix it here...
 214         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 215 }
 216
 217 void MapInfo_Filter_Free()
 218 {
 219         if(_MapInfo_filtered_allocated)
 220         {
 221                 buf_del(_MapInfo_filtered);
 222                 _MapInfo_filtered_allocated = 0;
 223         }
 224 }
 225
 226 // load info about the i-th map into the MapInfo_Map_* globals
 227 string MapInfo_BSPName_ByID(float i)
 228 {
 229         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 230 }
 231
 232 string unquote(string s)
 233 {
 234         float i, j, l;
 235         l = strlen(s);
 236         j = -1;
 237         for(i = 0; i < l; ++i)
 238         {
 239                 string ch;
 240                 ch = substring(s, i, 1);
 241                 if(ch != " ") if(ch != "\"")
 242                 {
 243                         for(j = strlen(s) - i - 1; j > 0; --j)
 244                         {
 245                                 ch = substring(s, i+j, 1);
 246                                 if(ch != " ") if(ch != "\"")
 247                                         return substring(s, i, j+1);
 248                         }
 249                         return substring(s, i, 1);
 250                 }
 251         }
 252         return "";
 253 }
 254
 255 float MapInfo_Get_ByID(float i)
 256 {
 257         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 258                 return 1;
 259         return 0;
 260 }
 261
 262 string _MapInfo_Map_worldspawn_music;
 263
 264 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 265 {
 266         string fn;
 267         float fh;
 268         string s, k, v;
 269         vector o;
 270         float i;
 271         float inWorldspawn;
 272         float r;
 273         float twoBaseModes;
 274         float diameter, spawnpoints;
 275         float spawnplaces;
 276
 277         vector mapMins, mapMaxs;
 278
 279         r = 1;
 280         fn = strcat("maps/", pFilename, ".ent");
 281         fh = fopen(fn, FILE_READ);
 282         if(fh < 0)
 283         {
 284                 r = 2;
 285                 fn = strcat("maps/", pFilename, ".bsp");
 286                 fh = fopen(fn, FILE_READ);
 287         }
 288         if(fh < 0)
 289                 return 0;
 290         print("Analyzing ", fn, " to generate initial mapinfo\n");
 291
 292         inWorldspawn = 2;
 293         MapInfo_Map_flags = 0;
 294         MapInfo_Map_supportedGametypes = 0;
 295         spawnpoints = 0;
 296         spawnplaces = 0;
 297         _MapInfo_Map_worldspawn_music = "";
 298         mapMins = '0 0 0';
 299         mapMaxs = '0 0 0';
 300
 301         for (;;)
 302         {
 303                 if (!((s = fgets(fh))))
 304                         break;
 305                 if(inWorldspawn == 1)
 306                         if(startsWith(s, "}"))
 307                                 inWorldspawn = 0;
 308                 k = unquote(car(s));
 309                 v = unquote(cdr(s));
 310                 if(inWorldspawn)
 311                 {
 312                         if(k == "classname" && v == "worldspawn")
 313                                 inWorldspawn = 1;
 314                         else if(k == "author")
 315                                 MapInfo_Map_author = v;
 316                         else if(k == "_description")
 317                                 MapInfo_Map_description = v;
 318                         else if(k == "music")
 319                                 _MapInfo_Map_worldspawn_music = v;
 320                         else if(k == "noise")
 321                                 _MapInfo_Map_worldspawn_music = v;
 322                         else if(k == "message")
 323                         {
 324                                 i = strstrofs(v, " by ", 0);
 325                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 326                                 {
 327                                         MapInfo_Map_title = substring(v, 0, i);
 328                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 329                                 }
 330                                 else
 331                                         MapInfo_Map_title = v;
 332                         }
 333                 }
 334                 else
 335                 {
 336                         if(k == "origin")
 337                         {
 338                                 o = stov(strcat("'", v, "'"));
 339                                 mapMins.x = min(mapMins.x, o.x);
 340                                 mapMins.y = min(mapMins.y, o.y);
 341                                 mapMins.z = min(mapMins.z, o.z);
 342                                 mapMaxs.x = max(mapMaxs.x, o.x);
 343                                 mapMaxs.y = max(mapMaxs.y, o.y);
 344                                 mapMaxs.z = max(mapMaxs.z, o.z);
 345                         }
 346                         else if(k == "race_place")
 347                         {
 348                                 if(stof(v) > 0)
 349                                         spawnplaces = 1;
 350                         }
 351                         else if(k == "classname")
 352                         {
 353                                 if(v == "dom_controlpoint")
 354                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 355                                 else if(v == "item_flag_team2")
 356                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 357                                 else if(v == "team_CTF_blueflag")
 358                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 359                                 else if(v == "invasion_spawnpoint")
 360                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_INVASION;
 361                                 else if(v == "target_assault_roundend")
 362                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 363                                 else if(v == "onslaught_generator")
 364                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 365                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 366                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 367                                 else if(v == "info_player_team1")
 368                                         ++spawnpoints;
 369                                 else if(v == "info_player_team2")
 370                                         ++spawnpoints;
 371                                 else if(v == "info_player_start")
 372                                         ++spawnpoints;
 373                                 else if(v == "info_player_deathmatch")
 374                                         ++spawnpoints;
 375                                 else if(v == "trigger_race_checkpoint")
 376                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 377                                 else if(v == "target_startTimer")
 378                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 379                                 else if(v == "weapon_nex")
 380                                         { }
 381                                 else if(v == "weapon_railgun")
 382                                         { }
 383                                 else if(startsWith(v, "weapon_"))
 384                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 385                                 else if(startsWith(v, "turret_"))
 386                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 387                                 else if(startsWith(v, "vehicle_"))
 388                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 389                                 else if(startsWith(v, "monster_"))
 390                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 391                                 else if(v == "target_music" || v == "trigger_music")
 392                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 393                         }
 394                 }
 395         }
 396         if(inWorldspawn)
 397         {
 398                 print(fn, " ended still in worldspawn, BUG\n");
 399                 return 0;
 400         }
 401         diameter = vlen(mapMaxs - mapMins);
 402
 403         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 404         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 405         {
 406                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 407                 // as the map is too symmetric for them.
 408         }
 409         else
 410         {
 411                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 412                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 413                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 414
 415                 if(spawnpoints >= 8  && diameter > 4096) {
 416                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 417                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 418                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 419                 }
 420                 if(spawnpoints >= 12 && diameter > 5120)
 421                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 422         }
 423
 424         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 425         if(!spawnplaces)
 426         {
 427                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 428                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 429         }
 430
 431         dprint("-> diameter ",    ftos(diameter));
 432         dprint(";  spawnpoints ", ftos(spawnpoints));
 433         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 434
 435         fclose(fh);
 436
 437         return r;
 438 }
 439
 440 void _MapInfo_Map_Reset()
 441 {
 442         MapInfo_Map_title = "<TITLE>";
 443         MapInfo_Map_titlestring = "<TITLE>";
 444         MapInfo_Map_description = "<DESCRIPTION>";
 445         MapInfo_Map_author = "<AUTHOR>";
 446         MapInfo_Map_supportedGametypes = 0;
 447         MapInfo_Map_supportedFeatures = 0;
 448         MapInfo_Map_flags = 0;
 449         MapInfo_Map_clientstuff = "";
 450         MapInfo_Map_fog = "";
 451         MapInfo_Map_mins = '0 0 0';
 452         MapInfo_Map_maxs = '0 0 0';
 453 }
 454
 455 string _MapInfo_GetDefault(float t)
 456 {
 457         switch(t)
 458         {
 459                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 460                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 461                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 462                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 463                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 464                 case MAPINFO_TYPE_CA:              return "10 20 0";
 465                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 466                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 467                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 468                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 469                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 470                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 471                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 472                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 473                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 474                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 475                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 476                 default:                           return "";
 477         }
 478 }
 479
 480 void _MapInfo_Map_ApplyGametype(string s, int pWantedType, int pThisType, int load_default)
 481 {
 482         string sa;
 483         MapInfo_Map_supportedGametypes |= pThisType;
 484         if(!(pThisType & pWantedType))
 485                 return;
 486
 487         if(load_default)
 488                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 489
 490         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 491         {
 492                 cvar_set("fraglimit", "0");
 493         }
 494         else
 495         {
 496                 sa = car(s);
 497                 if(sa != "")
 498                         cvar_set("fraglimit", sa);
 499                 s = cdr(s);
 500         }
 501
 502         sa = car(s);
 503         if(sa != "")
 504                 cvar_set("timelimit", sa);
 505         s = cdr(s);
 506
 507         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 508         {
 509                 sa = car(s);
 510                 if(sa != "")
 511                         cvar_set("g_tdm_teams", sa);
 512                 s = cdr(s);
 513         }
 514
 515         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 516         {
 517                 sa = car(s);
 518                 if(sa != "")
 519                         cvar_set("g_keyhunt_teams", sa);
 520                 s = cdr(s);
 521         }
 522
 523         if(pWantedType == MAPINFO_TYPE_CA)
 524         {
 525                 sa = car(s);
 526                 if(sa != "")
 527                         cvar_set("g_ca_teams", sa);
 528                 s = cdr(s);
 529         }
 530
 531         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 532         {
 533                 sa = car(s);
 534                 if(sa != "")
 535                         cvar_set("g_freezetag_teams", sa);
 536                 s = cdr(s);
 537         }
 538
 539         if(pWantedType == MAPINFO_TYPE_CTF)
 540         {
 541                 sa = car(s);
 542                 if(sa != "")
 543                         cvar_set("fraglimit", sa);
 544                 s = cdr(s);
 545         }
 546
 547         /* keepaway wuz here
 548         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 549         {
 550                 sa = car(s);
 551                 if(sa != "")
 552                         cvar_set("fraglimit", sa);
 553                 s = cdr(s);
 554         }
 555         */
 556
 557         // rc = timelimit timelimit_qualification laps laps_teamplay
 558         if(pWantedType == MAPINFO_TYPE_RACE)
 559         {
 560                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 561                 cvar_set("g_race_qualifying_timelimit", sa);
 562                 s = cdr(s);
 563
 564                 sa = car(s);
 565                 if(sa != "")
 566                         if(cvar("g_race_teams") < 2)
 567                                 cvar_set("fraglimit", sa);
 568                 s = cdr(s);
 569
 570                 sa = car(s);
 571                 if(sa != "")
 572                         if(cvar("g_race_teams") >= 2)
 573                                 cvar_set("fraglimit", sa);
 574                 s = cdr(s);
 575         }
 576
 577         if(pWantedType == MAPINFO_TYPE_CTS)
 578         {
 579                 sa = car(s);
 580
 581                 // this is the skill of the map
 582                 // not parsed by anything yet
 583                 // for map databases
 584                 //if(sa != "")
 585                 //      cvar_set("fraglimit", sa);
 586
 587                 s = cdr(s);
 588         }
 589
 590         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 591         {
 592                 cvar_set("leadlimit", "0");
 593         }
 594         else
 595         {
 596                 sa = car(s);
 597                 if(sa != "")
 598                         cvar_set("leadlimit", sa);
 599                 s = cdr(s);
 600         }
 601 }
 602
 603 string _MapInfo_GetDefaultEx(float t)
 604 {
 605         entity e;
 606         for(e = MapInfo_Type_first; e; e = e.enemy)
 607                 if(t == e.items)
 608                         return e.model2;
 609         return "";
 610 }
 611
 612 float _MapInfo_GetTeamPlayBool(float t)
 613 {
 614         entity e;
 615         for(e = MapInfo_Type_first; e; e = e.enemy)
 616                 if(t == e.items)
 617                         return e.team;
 618         return false;
 619 }
 620
 621 void _MapInfo_Map_ApplyGametypeEx(string s, int pWantedType, int pThisType)
 622 {
 623         string sa, k, v;
 624         float p;
 625         string fraglimit_normal;
 626         string fraglimit_teams;
 627
 628         MapInfo_Map_supportedGametypes |= pThisType;
 629         if(!(pThisType & pWantedType))
 630                 return;
 631
 632         // reset all the cvars to their defaults
 633
 634         cvar_set("timelimit", cvar_defstring("timelimit"));
 635         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 636         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 637         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 638         cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 639         cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 640         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 641         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 642         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 643
 644         fraglimit_normal = string_null;
 645         fraglimit_teams = string_null;
 646
 647         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 648         while(s != "")
 649         {
 650                 sa = car(s);
 651                 s = cdr(s);
 652
 653                 if(sa == "")
 654                         continue;
 655
 656                 p = strstrofs(sa, "=", 0);
 657                 if(p < 0)
 658                 {
 659                         print("Invalid gametype setting in mapinfo for gametype ", MapInfo_Type_ToString(pWantedType), ": ", sa, "\n");
 660                         continue;
 661                 }
 662                 k = substring(sa, 0, p);
 663                 v = substring(sa, p+1, -1);
 664
 665                 if(k == "timelimit")
 666                 {
 667                         cvar_set("timelimit", v);
 668                 }
 669                 else if(k == "leadlimit")
 670                 {
 671                         cvar_set("leadlimit", v);
 672                 }
 673                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 674                 {
 675                         fraglimit_normal = v;
 676                 }
 677                 else if(k == "teampointlimit" || k == "teamlaplimit")
 678                 {
 679                         fraglimit_teams = v;
 680                 }
 681                 else if(k == "teams")
 682                 {
 683                         cvar_set("g_tdm_teams", v);
 684                         cvar_set("g_ca_teams", v);
 685                         cvar_set("g_freezetag_teams", v);
 686                         cvar_set("g_keyhunt_teams", v);
 687                         cvar_set("g_domination_default_teams", v);
 688                         cvar_set("g_invasion_teams", v);
 689                 }
 690                 else if(k == "qualifying_timelimit")
 691                 {
 692                         cvar_set("g_race_qualifying_timelimit", v);
 693                 }
 694                 else if(k == "skill")
 695                 {
 696                         // ignore
 697                 }
 698                 else
 699                 {
 700                         print("Invalid gametype setting in mapinfo for gametype ", MapInfo_Type_ToString(pWantedType), ": ", sa, "\n");
 701                 }
 702         }
 703
 704         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 705         {
 706                 if(fraglimit_teams)
 707                         cvar_set("fraglimit", fraglimit_teams);
 708         }
 709         else
 710         {
 711                 if(fraglimit_normal)
 712                         cvar_set("fraglimit", fraglimit_normal);
 713         }
 714 }
 715
 716 float MapInfo_Type_FromString(string t)
 717 {
 718         entity e;
 719         if(t == "nexball")
 720         {
 721                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 722                 t = "nb";
 723                 print("'. Should use '", t, "'.\n");
 724         }
 725         if(t == "freezetag")
 726         {
 727                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 728                 t = "ft";
 729                 print("'. Should use '", t, "'.\n");
 730         }
 731         if(t == "keepaway")
 732         {
 733                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 734                 t = "ka";
 735                 print("'. Should use '", t, "'.\n");
 736         }
 737         if(t == "invasion")
 738         {
 739                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 740                 t = "inv";
 741                 print("'. Should use '", t, "'.\n");
 742         }
 743         if(t == "assault")
 744         {
 745                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 746                 t = "as";
 747                 print("'. Should use '", t, "'.\n");
 748         }
 749         if(t == "race")
 750         {
 751                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 752                 t = "rc";
 753                 print("'. Should use '", t, "'.\n");
 754         }
 755         if(t == "all")
 756                 return MAPINFO_TYPE_ALL;
 757         for(e = MapInfo_Type_first; e; e = e.enemy)
 758                 if(t == e.mdl)
 759                         return e.items;
 760         return 0;
 761 }
 762
 763 string MapInfo_Type_Description(float t)
 764 {
 765         entity e;
 766         for(e = MapInfo_Type_first; e; e = e.enemy)
 767                 if(t == e.items)
 768                         return e.gametype_description;
 769         return "";
 770 }
 771
 772 string MapInfo_Type_ToString(float t)
 773 {
 774         entity e;
 775         if(t == MAPINFO_TYPE_ALL)
 776                 return "all";
 777         for(e = MapInfo_Type_first; e; e = e.enemy)
 778                 if(t == e.items)
 779                         return e.mdl;
 780         return "";
 781 }
 782
 783 string MapInfo_Type_ToText(float t)
 784 {
 785         entity e;
 786         for(e = MapInfo_Type_first; e; e = e.enemy)
 787                 if(t == e.items)
 788                         return e.message;
 789         /* xgettext:no-c-format */
 790         return _("@!#%'n Tuba Throwing");
 791 }
 792
 793 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 794 {
 795         string t;
 796         float fh, o;
 797         t = car(s); s = cdr(s);
 798
 799         // limited support of "" and comments
 800         //   remove trailing and leading " of t
 801         if(substring(t, 0, 1) == "\"")
 802         {
 803                 if(substring(t, -1, 1) == "\"")
 804                         t = substring(t, 1, -2);
 805         }
 806
 807         //   remove leading " of s
 808         if(substring(s, 0, 1) == "\"")
 809         {
 810                 s = substring(s, 1, -1);
 811         }
 812         //   remove trailing " of s, and all that follows (cvar description)
 813         o = strstrofs(s, "\"", 0);
 814         if(o >= 0)
 815                 s = substring(s, 0, o);
 816
 817         //   remove // comments
 818         o = strstrofs(s, "//", 0);
 819         if(o >= 0)
 820                 s = substring(s, 0, o);
 821
 822         //   remove trailing spaces
 823         while(substring(s, -1, 1) == " ")
 824                 s = substring(s, 0, -2);
 825
 826         if(t == "#include")
 827         {
 828                 if(recurse > 0)
 829                 {
 830                         fh = fopen(s, FILE_READ);
 831                         if(fh < 0)
 832                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 833                         else
 834                         {
 835                                 for (;;)
 836                                 {
 837                                         if (!((s = fgets(fh))))
 838                                                 break;
 839
 840                                         // catch different sorts of comments
 841                                         if(s == "")                    // empty lines
 842                                                 continue;
 843                                         if(substring(s, 0, 1) == "#")  // UNIX style
 844                                                 continue;
 845                                         if(substring(s, 0, 2) == "//") // C++ style
 846                                                 continue;
 847                                         if(substring(s, 0, 1) == "_")  // q3map style
 848                                                 continue;
 849
 850                                         if(substring(s, 0, 4) == "set ")
 851                                                 s = substring(s, 4, -1);
 852                                         if(substring(s, 0, 5) == "seta ")
 853                                                 s = substring(s, 5, -1);
 854
 855                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 856                                 }
 857                                 fclose(fh);
 858                         }
 859                 }
 860                 else
 861                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 862         }
 863         else if(t == "")
 864                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 865         else if (!cvar_value_issafe(t))
 866                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 867         else if (!cvar_value_issafe(s))
 868                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 869         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 870                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 871         else if(matchacl(acl, t) <= 0)
 872                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 873         else
 874         {
 875                 if(type == 0) // server set
 876                 {
 877                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 878                         if(cvar("g_campaign"))
 879                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 880                         else
 881                                 cvar_settemp(t, s);
 882                 }
 883                 else
 884                 {
 885                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 886                         MapInfo_Map_clientstuff = strcat(
 887                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 888                                         );
 889                 }
 890         }
 891 }
 892
 893 float MapInfo_isRedundant(string fn, string t)
 894 {
 895         // normalize file name
 896         fn = strreplace("_", "-", fn);
 897
 898         // normalize visible title
 899         t = strreplace(": ", "-", t);
 900         t = strreplace(":", "-", t);
 901         t = strreplace(" ", "-", t);
 902         t = strreplace("_", "-", t);
 903         t = strreplace("'", "-", t);
 904
 905         if(!strcasecmp(fn, t))
 906                 return true;
 907
 908         // we allow the visible title to have punctuation the file name does
 909         // not, but not vice versa
 910         t = strreplace("-", "", t);
 911
 912         if(!strcasecmp(fn, t))
 913                 return true;
 914
 915         return false;
 916 }
 917
 918 // load info about a map by name into the MapInfo_Map_* globals
 919 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, int pGametypeToSet)
 920 {
 921         string fn;
 922         string s, t;
 923         float fh;
 924         int f, i;
 925         float r, n, p;
 926         string acl;
 927
 928         acl = MAPINFO_SETTEMP_ACL_USER;
 929
 930         if(strstrofs(pFilename, "/", 0) >= 0)
 931         {
 932                 print("Invalid character in map name, ignored\n");
 933                 return 0;
 934         }
 935
 936         if(pGametypeToSet == 0)
 937                 if(MapInfo_Cache_Retrieve(pFilename))
 938                         return 1;
 939
 940         r = 1;
 941
 942         MapInfo_Map_bspname = pFilename;
 943
 944         // default all generic fields so they have "good" values in case something fails
 945         fn = strcat("maps/", pFilename, ".mapinfo");
 946         fh = fopen(fn, FILE_READ);
 947         if(fh < 0)
 948         {
 949                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 950                 fh = fopen(fn, FILE_READ);
 951                 if(fh < 0)
 952                 {
 953                         if(!pAllowGenerate)
 954                                 return 0;
 955                         _MapInfo_Map_Reset();
 956                         r = _MapInfo_Generate(pFilename);
 957                         if(!r)
 958                                 return 0;
 959                         fh = fopen(fn, FILE_WRITE);
 960                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 961                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 962                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 963                         if(_MapInfo_Map_worldspawn_music != "")
 964                         {
 965                                 if(
 966                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 967                                         ||
 968                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 969                                 )
 970                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 971                                 else
 972                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 973                         }
 974                         else
 975                         {
 976                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 977                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 978                                 for (;;)
 979                                 {
 980                                         i = floor(random() * n);
 981                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 982                                                 break;
 983                                 }
 984                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 985                         }
 986                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 987                                 fputs(fh, "has weapons\n");
 988                         else
 989                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 990                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 991                                 fputs(fh, "has turrets\n");
 992                         else
 993                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 994                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 995                                 fputs(fh, "has vehicles\n");
 996                         else
 997                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 998                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 999                                 fputs(fh, "frustrating\n");
1000
1001                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
1002                                 if(MapInfo_Map_supportedGametypes & i)
1003                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
1004
1005                         if(fexists(strcat("scripts/", pFilename, ".arena")))
1006                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
1007
1008                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
1009                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
1010                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
1011                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1012                         fputs(fh, "// optional: hidden\n");
1013
1014                         fclose(fh);
1015                         r = 2;
1016                         // return r;
1017                         fh = fopen(fn, FILE_READ);
1018                         if(fh < 0)
1019                                 error("... but I just wrote it!");
1020                 }
1021
1022                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
1023         }
1024
1025         _MapInfo_Map_Reset();
1026         for (;;)
1027         {
1028                 if (!((s = fgets(fh))))
1029                         break;
1030
1031                 // catch different sorts of comments
1032                 if(s == "")                    // empty lines
1033                         continue;
1034                 if(substring(s, 0, 1) == "#")  // UNIX style
1035                         continue;
1036                 if(substring(s, 0, 2) == "//") // C++ style
1037                         continue;
1038                 if(substring(s, 0, 1) == "_")  // q3map style
1039                         continue;
1040
1041                 p = strstrofs(s, "//", 0);
1042                 if(p >= 0)
1043                         s = substring(s, 0, p);
1044
1045                 t = car(s); s = cdr(s);
1046                 if(t == "title")
1047                         MapInfo_Map_title = s;
1048                 else if(t == "description")
1049                         MapInfo_Map_description = s;
1050                 else if(t == "author")
1051                         MapInfo_Map_author = s;
1052                 else if(t == "has")
1053                 {
1054                         t = car(s); // s = cdr(s);
1055                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1056                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1057                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1058                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1059                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1060                         else
1061                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
1062                 }
1063                 else if(t == "hidden")
1064                 {
1065                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1066                 }
1067                 else if(t == "forbidden")
1068                 {
1069                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1070                 }
1071                 else if(t == "frustrating")
1072                 {
1073                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1074                 }
1075                 else if(t == "noautomaplist")
1076                 {
1077                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1078                 }
1079                 else if(t == "type")
1080                 {
1081                         t = car(s); s = cdr(s);
1082                         f = MapInfo_Type_FromString(t);
1083                         dprint("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1084                         if(f)
1085                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1086                         else
1087                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1088                 }
1089                 else if(t == "gametype")
1090                 {
1091                         t = car(s); s = cdr(s);
1092                         f = MapInfo_Type_FromString(t);
1093                         if(f)
1094                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1095                         else
1096                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1097                 }
1098                 else if(t == "size")
1099                 {
1100                         float a, b, c, d, e;
1101                         t = car(s); s = cdr(s); a = stof(t);
1102                         t = car(s); s = cdr(s); b = stof(t);
1103                         t = car(s); s = cdr(s); c = stof(t);
1104                         t = car(s); s = cdr(s); d = stof(t);
1105                         t = car(s); s = cdr(s); e = stof(t);
1106                         if(s == "")
1107                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1108                         else
1109                         {
1110                                 t = car(s); s = cdr(s); f = stof(t);
1111                                 if(s != "")
1112                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1113                                 else
1114                                 {
1115                                         if(a >= d || b >= e || c >= f)
1116                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1117                                         else
1118                                         {
1119                                                 MapInfo_Map_mins.x = a;
1120                                                 MapInfo_Map_mins.y = b;
1121                                                 MapInfo_Map_mins.z = c;
1122                                                 MapInfo_Map_maxs.x = d;
1123                                                 MapInfo_Map_maxs.y = e;
1124                                                 MapInfo_Map_maxs.z = f;
1125                                         }
1126                                 }
1127                         }
1128                 }
1129                 else if(t == "settemp_for_type")
1130                 {
1131                         t = car(s); s = cdr(s);
1132                         if((f = MapInfo_Type_FromString(t)))
1133                         {
1134                                 if(f & pGametypeToSet)
1135                                 {
1136                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1137                                 }
1138                         }
1139                         else
1140                         {
1141                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1142                         }
1143                 }
1144                 else if(t == "clientsettemp_for_type")
1145                 {
1146                         t = car(s); s = cdr(s);
1147                         if((f = MapInfo_Type_FromString(t)))
1148                         {
1149                                 if(f & pGametypeToSet)
1150                                 {
1151                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1152                                 }
1153                         }
1154                         else
1155                         {
1156                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1157                         }
1158                 }
1159                 else if(t == "fog")
1160                 {
1161                         if (!cvar_value_issafe(s))
1162                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1163                         else
1164                                 MapInfo_Map_fog = s;
1165                 }
1166                 else if(t == "cdtrack")
1167                 {
1168                         t = car(s); s = cdr(s);
1169                         if(pGametypeToSet) // FIXME is this check right here?
1170                         {
1171                                 if (!cvar_value_issafe(t))
1172                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1173                                 else
1174                                         MapInfo_Map_clientstuff = strcat(
1175                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1176                                         );
1177                         }
1178                 }
1179                 else
1180                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1181         }
1182         fclose(fh);
1183
1184         if(MapInfo_Map_title == "<TITLE>")
1185                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1186         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1187                 MapInfo_Map_titlestring = MapInfo_Map_title;
1188         else
1189                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1190
1191         MapInfo_Cache_Store();
1192         if(MapInfo_Map_supportedGametypes != 0)
1193                 return r;
1194         dprint("Map ", pFilename, " supports no game types, ignored\n");
1195         return 0;
1196 }
1197 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, int pGametypeToSet)
1198 {
1199         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1200
1201         if(cvar("g_tdm_on_dm_maps"))
1202         {
1203                 // if this is set, all DM maps support TDM too
1204                 if (!(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH))
1205                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1206                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1207         }
1208
1209         if(pGametypeToSet)
1210         {
1211                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1212                 {
1213                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1214                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1215                         //return;
1216                 }
1217         }
1218
1219         return r;
1220 }
1221
1222 float MapInfo_FindName(string s)
1223 {
1224         // if there is exactly one map of prefix s, return it
1225         // if not, return the null string
1226         // note that DP sorts glob results... so I can use a binary search
1227         float l, r, m, cmp;
1228         l = 0;
1229         r = MapInfo_count;
1230         // invariants: r is behind s, l-1 is equal or before
1231         while(l != r)
1232         {
1233                 m = floor((l + r) / 2);
1234                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1235                 cmp = strcasecmp(MapInfo_FindName_match, s);
1236                 if(cmp == 0)
1237                         return m; // found and good
1238                 if(cmp < 0)
1239                         l = m + 1; // l-1 is before s
1240                 else
1241                         r = m; // behind s
1242         }
1243         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1244         MapInfo_FindName_firstResult = l;
1245         // r == l, so: l is behind s, l-1 is before
1246         // SO: if there is any, l is the one with the right prefix
1247         //     and l+1 may be one too
1248         if(l == MapInfo_count)
1249         {
1250                 MapInfo_FindName_match = string_null;
1251                 MapInfo_FindName_firstResult = -1;
1252                 return -1; // no MapInfo_FindName_match, behind last item
1253         }
1254         if(!startsWithNocase(MapInfo_FindName_match, s))
1255         {
1256                 MapInfo_FindName_match = string_null;
1257                 MapInfo_FindName_firstResult = -1;
1258                 return -1; // wrong prefix
1259         }
1260         if(l == MapInfo_count - 1)
1261                 return l; // last one, nothing can follow => unique
1262         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1263         {
1264                 MapInfo_FindName_match = string_null;
1265                 return -1; // ambigous MapInfo_FindName_match
1266         }
1267         return l;
1268 }
1269
1270 string MapInfo_FixName(string s)
1271 {
1272         MapInfo_FindName(s);
1273         return MapInfo_FindName_match;
1274 }
1275
1276 int MapInfo_CurrentFeatures()
1277 {
1278         int req = 0;
1279         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1280                 req |= MAPINFO_FEATURE_WEAPONS;
1281         return req;
1282 }
1283
1284 int MapInfo_CurrentGametype()
1285 {
1286         entity e;
1287         int prev = cvar("gamecfg");
1288         for(e = MapInfo_Type_first; e; e = e.enemy)
1289                 if(cvar(e.netname))
1290                         if(prev != e.items)
1291                                 return e.items;
1292         if(prev)
1293                 return prev;
1294         return MAPINFO_TYPE_DEATHMATCH;
1295 }
1296
1297 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1298 {
1299         if(!MapInfo_Get_ByName(s, 1, 0))
1300                 return 0;
1301         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1302                 return 0;
1303         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1304                 return 0;
1305         return 1;
1306 }
1307
1308 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1309 {
1310         float r;
1311         r = _MapInfo_CheckMap(s);
1312         MapInfo_ClearTemps();
1313         return r;
1314 }
1315
1316 void MapInfo_SwitchGameType(int t)
1317 {
1318         for (entity e = MapInfo_Type_first; e; e = e.enemy) {
1319                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1320         }
1321 }
1322
1323 void MapInfo_LoadMap(string s, float reinit)
1324 {
1325         MapInfo_Map_supportedGametypes = 0;
1326         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1327         //if(!MapInfo_CheckMap(s))
1328         //{
1329         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1330         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1331         //}
1332
1333         cvar_settemp_restore();
1334         if(reinit)
1335                 localcmd(strcat("\nmap ", s, "\n"));
1336         else
1337                 localcmd(strcat("\nchangelevel ", s, "\n"));
1338 }
1339
1340 string MapInfo_ListAllowedMaps(float type, float pRequiredFlags, float pForbiddenFlags)
1341 {
1342         string out;
1343         float i;
1344
1345         // to make absolutely sure:
1346         MapInfo_Enumerate();
1347         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1348
1349         out = "";
1350         for(i = 0; i < MapInfo_count; ++i)
1351                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1352         return substring(out, 1, strlen(out) - 1);
1353 }
1354
1355 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1356 {
1357         string out;
1358         float i;
1359
1360         // to make absolutely sure:
1361         MapInfo_Enumerate();
1362         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1363
1364         out = "";
1365         for(i = 0; i < MapInfo_count; ++i)
1366                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1367
1368         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1369
1370         return substring(out, 1, strlen(out) - 1);
1371 }
1372
1373 void MapInfo_LoadMapSettings_SaveGameType(float t)
1374 {
1375         MapInfo_SwitchGameType(t);
1376         cvar_set("gamecfg", ftos(t));
1377         MapInfo_LoadedGametype = t;
1378 }
1379
1380 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1381 {
1382         float t;
1383
1384         t = MapInfo_CurrentGametype();
1385         MapInfo_LoadMapSettings_SaveGameType(t);
1386
1387         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1388         {
1389                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1390                 {
1391                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1392                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1393                         return; // do not call Get_ByName!
1394                 }
1395
1396                 if(MapInfo_Map_supportedGametypes == 0)
1397                 {
1398                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1399                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1400                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1401                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1402                         return; // do not call Get_ByName!
1403                 }
1404
1405                 t = 1;
1406                 while(!(MapInfo_Map_supportedGametypes & 1))
1407                 {
1408                         t *= 2;
1409                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1410                 }
1411
1412                 // t is now a supported mode!
1413                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1414                 MapInfo_LoadMapSettings_SaveGameType(t);
1415         }
1416         MapInfo_Get_ByName(s, 1, t);
1417 }
1418
1419 void MapInfo_ClearTemps()
1420 {
1421         MapInfo_Map_bspname = string_null;
1422         MapInfo_Map_title = string_null;
1423         MapInfo_Map_titlestring = string_null;
1424         MapInfo_Map_description = string_null;
1425         MapInfo_Map_author = string_null;
1426         MapInfo_Map_clientstuff = string_null;
1427         MapInfo_Map_supportedGametypes = 0;
1428         MapInfo_Map_supportedFeatures = 0;
1429 }
1430
1431 void MapInfo_Shutdown()
1432 {
1433         MapInfo_ClearTemps();
1434         MapInfo_Filter_Free();
1435         MapInfo_Cache_Destroy();
1436         if(_MapInfo_globopen)
1437         {
1438                 search_end(_MapInfo_globhandle);
1439                 _MapInfo_globhandle = -1;
1440                 _MapInfo_globopen = false;
1441         }
1442 }
1443
1444 int MapInfo_ForbiddenFlags()
1445 {
1446         int f = MAPINFO_FLAG_FORBIDDEN;
1447
1448 #ifndef MENUQC
1449         if (!cvar("g_maplist_allow_hidden"))
1450 #endif
1451                 f |= MAPINFO_FLAG_HIDDEN;
1452
1453         if (!cvar("g_maplist_allow_frustrating"))
1454                 f |= MAPINFO_FLAG_FRUSTRATING;
1455
1456         return f;
1457 }
1458
1459 int MapInfo_RequiredFlags()
1460 {
1461         int f = 0;
1462
1463         if(cvar("g_maplist_allow_frustrating") > 1)
1464                 f |= MAPINFO_FLAG_FRUSTRATING;
1465
1466         return f;
1467 }