qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(s != "")
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(s == "")
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         if(!_MapInfo_globopen)
  93                 return string_null;
  94         s = search_getfilename(_MapInfo_globhandle, i);
  95         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  96 }
  97
  98 void MapInfo_Enumerate()
  99 {
 100         if(_MapInfo_globopen)
 101         {
 102                 search_end(_MapInfo_globhandle);
 103                 _MapInfo_globopen = 0;
 104         }
 105         MapInfo_Cache_Invalidate();
 106         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 107         if(_MapInfo_globhandle >= 0)
 108         {
 109                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 110                 _MapInfo_globopen = 1;
 111         }
 112         else
 113                 _MapInfo_globcount = 0;
 114 }
 115
 116 // filter the info by game type mask (updates MapInfo_count)
 117 //
 118 float _MapInfo_filtered;
 119 float _MapInfo_filtered_allocated;
 120 float MapInfo_FilterList_Lookup(float i)
 121 {
 122         return stof(bufstr_get(_MapInfo_filtered, i));
 123 }
 124
 125 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 126 {
 127         string h;
 128         h = bufstr_get(_MapInfo_filtered, i);
 129         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 130         bufstr_set(_MapInfo_filtered, j, h);
 131 }
 132
 133 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 134 {
 135         string a, b;
 136         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 137         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 138         return strcasecmp(a, b);
 139 }
 140
 141 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 142 {
 143         float i, j;
 144         if not(_MapInfo_filtered_allocated)
 145         {
 146                 _MapInfo_filtered_allocated = 1;
 147                 _MapInfo_filtered = buf_create();
 148         }
 149         MapInfo_count = 0;
 150         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 151         {
 152                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 153                         if(pAbortOnGenerate)
 154                         {
 155                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 156                                 MapInfo_progress = i / _MapInfo_globcount;
 157                                 return 0;
 158                         }
 159                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 160                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 161                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 162                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 163                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 164         }
 165         MapInfo_count = j + 1;
 166         MapInfo_ClearTemps();
 167
 168         // sometimes the glob isn't sorted nicely, so fix it here...
 169         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 170
 171         return 1;
 172 }
 173
 174 void MapInfo_Filter_Free()
 175 {
 176         if(_MapInfo_filtered_allocated)
 177         {
 178                 buf_del(_MapInfo_filtered);
 179                 _MapInfo_filtered_allocated = 0;
 180         }
 181 }
 182
 183 // load info about the i-th map into the MapInfo_Map_* globals
 184 string MapInfo_BSPName_ByID(float i)
 185 {
 186         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 187 }
 188
 189 string unquote(string s)
 190 {
 191         float i, j, l;
 192         l = strlen(s);
 193         j = -1;
 194         for(i = 0; i < l; ++i)
 195         {
 196                 string ch;
 197                 ch = substring(s, i, 1);
 198                 if(ch != " ") if(ch != "\"")
 199                 {
 200                         for(j = strlen(s) - i - 1; j > 0; --j)
 201                         {
 202                                 ch = substring(s, i+j, 1);
 203                                 if(ch != " ") if(ch != "\"")
 204                                         return substring(s, i, j+1);
 205                         }
 206                         return substring(s, i, 1);
 207                 }
 208         }
 209         return "";
 210 }
 211
 212 float MapInfo_Get_ByID(float i)
 213 {
 214         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 215                 return 1;
 216         return 0;
 217 }
 218
 219 string _MapInfo_Map_worldspawn_music;
 220
 221 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 222 {
 223         string fn;
 224         float fh;
 225         string s, k, v;
 226         vector o;
 227         float i;
 228         float inWorldspawn;
 229         float r;
 230         float twoBaseModes;
 231         float diameter, spawnpoints;
 232         float spawnplaces;
 233
 234         vector mapMins, mapMaxs;
 235
 236         r = 1;
 237         fn = strcat("maps/", pFilename, ".ent");
 238         fh = fopen(fn, FILE_READ);
 239         if(fh < 0)
 240         {
 241                 r = 2;
 242                 fn = strcat("maps/", pFilename, ".bsp");
 243                 fh = fopen(fn, FILE_READ);
 244         }
 245         if(fh < 0)
 246                 return 0;
 247         print("Analyzing ", fn, " to generate initial mapinfo\n");
 248
 249         inWorldspawn = 2;
 250         MapInfo_Map_flags = 0;
 251         MapInfo_Map_supportedGametypes = 0;
 252         spawnpoints = 0;
 253         spawnplaces = 0;
 254         _MapInfo_Map_worldspawn_music = "";
 255         mapMins = '0 0 0';
 256         mapMaxs = '0 0 0';
 257
 258         for(;;)
 259         {
 260                 if not((s = fgets(fh)))
 261                         break;
 262                 if(inWorldspawn == 1)
 263                         if(startsWith(s, "}"))
 264                                 inWorldspawn = 0;
 265                 k = unquote(car(s));
 266                 v = unquote(cdr(s));
 267                 if(inWorldspawn)
 268                 {
 269                         if(k == "classname" && v == "worldspawn")
 270                                 inWorldspawn = 1;
 271                         else if(k == "author")
 272                                 MapInfo_Map_author = v;
 273                         else if(k == "_description")
 274                                 MapInfo_Map_description = v;
 275                         else if(k == "music")
 276                                 _MapInfo_Map_worldspawn_music = v;
 277                         else if(k == "noise")
 278                                 _MapInfo_Map_worldspawn_music = v;
 279                         else if(k == "message")
 280                         {
 281                                 i = strstrofs(v, " by ", 0);
 282                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 283                                 {
 284                                         MapInfo_Map_title = substring(v, 0, i);
 285                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 286                                 }
 287                                 else
 288                                         MapInfo_Map_title = v;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if(k == "origin")
 294                         {
 295                                 o = stov(strcat("'", v, "'"));
 296                                 mapMins_x = min(mapMins_x, o_x);
 297                                 mapMins_y = min(mapMins_y, o_y);
 298                                 mapMins_z = min(mapMins_z, o_z);
 299                                 mapMaxs_x = max(mapMaxs_x, o_x);
 300                                 mapMaxs_y = max(mapMaxs_y, o_y);
 301                                 mapMaxs_z = max(mapMaxs_z, o_z);
 302                         }
 303                         else if(k == "race_place")
 304                         {
 305                                 if(stof(v) > 0)
 306                                         spawnplaces = 1;
 307                         }
 308                         else if(k == "classname")
 309                         {
 310                                 if(v == "dom_controlpoint")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 312                                 else if(v == "item_flag_team2")
 313                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 314                                 else if(v == "team_CTF_blueflag")
 315                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 316                                 else if(v == "runematch_spawn_point")
 317                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 318                                 else if(v == "target_assault_roundend")
 319                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 320                                 else if(v == "onslaught_generator")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 322                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 323                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 324                                 else if(v == "info_player_team1")
 325                                         ++spawnpoints;
 326                                 else if(v == "info_player_team2")
 327                                         ++spawnpoints;
 328                                 else if(v == "info_player_start")
 329                                         ++spawnpoints;
 330                                 else if(v == "info_player_deathmatch")
 331                                         ++spawnpoints;
 332                                 else if(v == "trigger_race_checkpoint")
 333                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 334                                 else if(v == "target_startTimer")
 335                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 336                                 else if(v == "weapon_nex")
 337                                         { }
 338                                 else if(v == "weapon_railgun")
 339                                         { }
 340                                 else if(startsWith(v, "weapon_"))
 341                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 342                                 else if(startsWith(v, "turret_"))
 343                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 344                                 else if(startsWith(v, "vehicle_"))
 345                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 346                                 else if(v == "target_music" || v == "trigger_music")
 347                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 348                         }
 349                 }
 350         }
 351         if(inWorldspawn)
 352         {
 353                 print(fn, " ended still in worldspawn, BUG\n");
 354                 return 0;
 355         }
 356         diameter = vlen(mapMaxs - mapMins);
 357
 358         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 359         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 360         {
 361                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 362                 // as the map is too symmetric for them.
 363         }
 364         else
 365         {
 366                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 367                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 368                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 369                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 370
 371                 if(spawnpoints >= 8  && diameter > 4096) {
 372                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 373                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 374                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 375                 }
 376                 if(                     diameter < 4096)
 377                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 378                 if(spawnpoints >= 12 && diameter > 5120)
 379                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 380         }
 381
 382         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 383         if(!spawnplaces)
 384         {
 385                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 386                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 387         }
 388
 389         dprint("-> diameter ",    ftos(diameter));
 390         dprint(";  spawnpoints ", ftos(spawnpoints));
 391         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 392
 393         fclose(fh);
 394
 395         return r;
 396 }
 397
 398 void _MapInfo_Map_Reset()
 399 {
 400         MapInfo_Map_title = "<TITLE>";
 401         MapInfo_Map_titlestring = "<TITLE>";
 402         MapInfo_Map_description = "<DESCRIPTION>";
 403         MapInfo_Map_author = "<AUTHOR>";
 404         MapInfo_Map_supportedGametypes = 0;
 405         MapInfo_Map_supportedFeatures = 0;
 406         MapInfo_Map_flags = 0;
 407         MapInfo_Map_clientstuff = "";
 408         MapInfo_Map_fog = "";
 409         MapInfo_Map_mins = '0 0 0';
 410         MapInfo_Map_maxs = '0 0 0';
 411 }
 412
 413 string _MapInfo_GetDefault(float t)
 414 {
 415         switch(t)
 416         {
 417                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 418                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 419                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 420                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 421                 case MAPINFO_TYPE_RUNEMATCH:       return "200 20 0";
 422                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 423                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
 424                 case MAPINFO_TYPE_CA:              return "10 20 0";
 425                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 426                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 427                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 428                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 429                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 430                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 431                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 432                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 433                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 434                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 435                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 436                 default:                           return "";
 437         }
 438 }
 439
 440 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 441 {
 442         string sa;
 443         MapInfo_Map_supportedGametypes |= pThisType;
 444         if(!(pThisType & pWantedType))
 445                 return;
 446
 447         if(load_default)
 448                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 449
 450         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 451         {
 452                 cvar_set("fraglimit", "0");
 453         }
 454         else
 455         {
 456                 sa = car(s);
 457                 if(sa != "")
 458                         cvar_set("fraglimit", sa);
 459                 s = cdr(s);
 460         }
 461
 462         sa = car(s);
 463         if(sa != "")
 464                 cvar_set("timelimit", sa);
 465         s = cdr(s);
 466
 467         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 468         {
 469                 sa = car(s);
 470                 if(sa != "")
 471                         cvar_set("g_tdm_teams", sa);
 472                 s = cdr(s);
 473         }
 474
 475         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 476         {
 477                 sa = car(s);
 478                 if(sa != "")
 479                         cvar_set("g_keyhunt_teams", sa);
 480                 s = cdr(s);
 481         }
 482
 483         if(pWantedType == MAPINFO_TYPE_CTF)
 484         {
 485                 sa = car(s);
 486                 if(sa != "")
 487                         cvar_set("fraglimit", sa);
 488                 s = cdr(s);
 489         }
 490
 491         /* keepaway wuz here
 492         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 493         {
 494                 sa = car(s);
 495                 if(sa != "")
 496                         cvar_set("fraglimit", sa);
 497                 s = cdr(s);
 498         }
 499         */
 500
 501         // rc = timelimit timelimit_qualification laps laps_teamplay
 502         if(pWantedType == MAPINFO_TYPE_RACE)
 503         {
 504                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 505                 cvar_set("g_race_qualifying_timelimit", sa);
 506                 s = cdr(s);
 507
 508                 sa = car(s);
 509                 if(sa != "")
 510                         if(cvar("g_race_teams") < 2)
 511                                 cvar_set("fraglimit", sa);
 512                 s = cdr(s);
 513
 514                 sa = car(s);
 515                 if(sa != "")
 516                         if(cvar("g_race_teams") >= 2)
 517                                 cvar_set("fraglimit", sa);
 518                 s = cdr(s);
 519         }
 520
 521         if(pWantedType == MAPINFO_TYPE_CTS)
 522         {
 523                 sa = car(s);
 524
 525                 // this is the skill of the map
 526                 // not parsed by anything yet
 527                 // for map databases
 528                 //if(sa != "")
 529                 //      cvar_set("fraglimit", sa);
 530
 531                 s = cdr(s);
 532         }
 533
 534         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 535         {
 536                 cvar_set("leadlimit", "0");
 537         }
 538         else
 539         {
 540                 sa = car(s);
 541                 if(sa != "")
 542                         cvar_set("leadlimit", sa);
 543                 s = cdr(s);
 544         }
 545 }
 546
 547 string _MapInfo_GetDefaultEx(float t)
 548 {
 549         entity e;
 550         for(e = MapInfo_Type_first; e; e = e.enemy)
 551                 if(t == e.items)
 552                         return e.model2;
 553         return "";
 554 }
 555
 556 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 557 {
 558         string sa, k, v;
 559         float p;
 560         string fraglimit_normal;
 561         string fraglimit_teams;
 562
 563         MapInfo_Map_supportedGametypes |= pThisType;
 564         if(!(pThisType & pWantedType))
 565                 return;
 566
 567         // reset all the cvars to their defaults
 568
 569         cvar_set("timelimit", cvar_defstring("timelimit"));
 570         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 571         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 572         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 573         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 574         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 575         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 576
 577         fraglimit_normal = string_null;
 578         fraglimit_teams = string_null;
 579
 580         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 581         while(s != "")
 582         {
 583                 sa = car(s);
 584                 s = cdr(s);
 585
 586                 if(sa == "")
 587                         continue;
 588
 589                 p = strstrofs(sa, "=", 0);
 590                 if(p < 0)
 591                 {
 592                         k = "timelimit";
 593                         v = s;
 594                 }
 595                 else
 596                 {
 597                         k = substring(sa, 0, p);
 598                         v = substring(sa, p+1, -1);
 599                 }
 600
 601                 if(k == "timelimit")
 602                 {
 603                         cvar_set("timelimit", v);
 604                 }
 605                 else if(k == "leadlimit")
 606                 {
 607                         cvar_set("leadlimit", v);
 608                 }
 609                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 610                 {
 611                         fraglimit_normal = v;
 612                 }
 613                 else if(k == "teampointlimit" || k == "teamlaplimit")
 614                 {
 615                         fraglimit_teams = v;
 616                 }
 617                 else if(k == "teams")
 618                 {
 619                         cvar_set("g_tdm_teams", v);
 620                         cvar_set("g_keyhunt_teams", v);
 621                         cvar_set("g_domination_default_teams", v);
 622                 }
 623                 else if(k == "qualifying_timelimit")
 624                 {
 625                         cvar_set("g_race_qualifying_timelimit", v);
 626                 }
 627                 else if(k == "skill")
 628                 {
 629                         // ignore
 630                 }
 631                 else
 632                 {
 633                         print("Invalid gametype key in mapinfo: ", k, "\n");
 634                 }
 635         }
 636
 637         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 638         {
 639                 if(fraglimit_teams)
 640                         cvar_set("fraglimit", fraglimit_teams);
 641         }
 642         else
 643         {
 644                 if(fraglimit_normal)
 645                         cvar_set("fraglimit", fraglimit_normal);
 646         }
 647 }
 648
 649 float MapInfo_Type_FromString(string t)
 650 {
 651         entity e;
 652         if(t == "nexball")
 653         {
 654                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 655                 t = "nb";
 656                 print("'. Should use '", t, "'.\n");
 657         }
 658         if(t == "freezetag")
 659         {
 660                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 661                 t = "ft";
 662                 print("'. Should use '", t, "'.\n");
 663         }
 664         if(t == "keepaway")
 665         {
 666                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 667                 t = "ka";
 668                 print("'. Should use '", t, "'.\n");
 669         }
 670         if(t == "all")
 671                 return MAPINFO_TYPE_ALL;
 672         for(e = MapInfo_Type_first; e; e = e.enemy)
 673                 if(t == e.mdl)
 674                         return e.items;
 675         return 0;
 676 }
 677
 678 string MapInfo_Type_ToString(float t)
 679 {
 680         entity e;
 681         if(t == MAPINFO_TYPE_ALL)
 682                 return "all";
 683         for(e = MapInfo_Type_first; e; e = e.enemy)
 684                 if(t == e.items)
 685                         return e.mdl;
 686         return "";
 687 }
 688
 689 string MapInfo_Type_ToText(float t)
 690 {
 691         entity e;
 692         for(e = MapInfo_Type_first; e; e = e.enemy)
 693                 if(t == e.items)
 694                         return e.message;
 695         return _("@!#%'n Tuba Throwing");
 696 }
 697
 698 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 699 {
 700         string t;
 701         float fh, o;
 702         t = car(s); s = cdr(s);
 703
 704         // limited support of "" and comments
 705         //   remove trailing and leading " of t
 706         if(substring(t, 0, 1) == "\"")
 707         {
 708                 if(substring(t, -1, 1) == "\"")
 709                         t = substring(t, 1, -2);
 710         }
 711
 712         //   remove leading " of s
 713         if(substring(s, 0, 1) == "\"")
 714         {
 715                 s = substring(s, 1, -1);
 716         }
 717         //   remove trailing " of s, and all that follows (cvar description)
 718         o = strstrofs(s, "\"", 0);
 719         if(o >= 0)
 720                 s = substring(s, 0, o);
 721
 722         //   remove // comments
 723         o = strstrofs(s, "//", 0);
 724         if(o >= 0)
 725                 s = substring(s, 0, o);
 726
 727         //   remove trailing spaces
 728         while(substring(s, -1, 1) == " ")
 729                 s = substring(s, 0, -2);
 730
 731         if(t == "#include")
 732         {
 733                 if(recurse > 0)
 734                 {
 735                         fh = fopen(s, FILE_READ);
 736                         if(fh < 0)
 737                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 738                         else
 739                         {
 740                                 for(;;)
 741                                 {
 742                                         if not((s = fgets(fh)))
 743                                                 break;
 744
 745                                         // catch different sorts of comments
 746                                         if(s == "")                    // empty lines
 747                                                 continue;
 748                                         if(substring(s, 0, 1) == "#")  // UNIX style
 749                                                 continue;
 750                                         if(substring(s, 0, 2) == "//") // C++ style
 751                                                 continue;
 752                                         if(substring(s, 0, 1) == "_")  // q3map style
 753                                                 continue;
 754
 755                                         if(substring(s, 0, 4) == "set ")
 756                                                 s = substring(s, 4, -1);
 757                                         if(substring(s, 0, 5) == "seta ")
 758                                                 s = substring(s, 5, -1);
 759
 760                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 761                                 }
 762                                 fclose(fh);
 763                         }
 764                 }
 765                 else
 766                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 767         }
 768         else if(t == "")
 769                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 770         else if not(cvar_value_issafe(t))
 771                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 772         else if not (cvar_value_issafe(s))
 773                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 774         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 775                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 776         else if(matchacl(acl, t) <= 0)
 777                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 778         else
 779         {
 780                 if(type == 0) // server set
 781                 {
 782                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 783                         if(cvar("g_campaign"))
 784                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 785                         else
 786                                 cvar_settemp(t, s);
 787                 }
 788                 else
 789                 {
 790                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 791                         MapInfo_Map_clientstuff = strcat(
 792                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 793                                         );
 794                 }
 795         }
 796 }
 797
 798 float MapInfo_isRedundant(string fn, string t)
 799 {
 800         // normalize file name
 801         fn = strreplace("_", "-", fn);
 802
 803         // normalize visible title
 804         t = strreplace(": ", "-", t);
 805         t = strreplace(":", "-", t);
 806         t = strreplace(" ", "-", t);
 807         t = strreplace("_", "-", t);
 808         t = strreplace("'", "-", t);
 809
 810         if(!strcasecmp(fn, t))
 811                 return TRUE;
 812
 813         // we allow the visible title to have punctuation the file name does
 814         // not, but not vice versa
 815         t = strreplace("-", "", t);
 816
 817         if(!strcasecmp(fn, t))
 818                 return TRUE;
 819
 820         return FALSE;
 821 }
 822
 823 // load info about a map by name into the MapInfo_Map_* globals
 824 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 825 {
 826         string fn;
 827         string s, t;
 828         float fh;
 829         float r, f, n, i, p;
 830         string acl;
 831
 832         acl = MAPINFO_SETTEMP_ACL_USER;
 833
 834         if(strstrofs(pFilename, "/", 0) >= 0)
 835         {
 836                 print("Invalid character in map name, ignored\n");
 837                 return 0;
 838         }
 839
 840         if(pGametypeToSet == 0)
 841                 if(MapInfo_Cache_Retrieve(pFilename))
 842                         return 1;
 843
 844         r = 1;
 845
 846         MapInfo_Map_bspname = pFilename;
 847
 848         // default all generic fields so they have "good" values in case something fails
 849         fn = strcat("maps/", pFilename, ".mapinfo");
 850         fh = fopen(fn, FILE_READ);
 851         if(fh < 0)
 852         {
 853                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 854                 fh = fopen(fn, FILE_READ);
 855                 if(fh < 0)
 856                 {
 857                         if(!pAllowGenerate)
 858                                 return 0;
 859                         _MapInfo_Map_Reset();
 860                         r = _MapInfo_Generate(pFilename);
 861                         if(!r)
 862                                 return 0;
 863                         fh = fopen(fn, FILE_WRITE);
 864                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 865                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 866                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 867                         if(_MapInfo_Map_worldspawn_music != "")
 868                         {
 869                                 if(
 870                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 871                                         ||
 872                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 873                                 )
 874                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 875                                 else
 876                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 877                         }
 878                         else
 879                         {
 880                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 881                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 882                                 for(;;)
 883                                 {
 884                                         i = floor(random() * n);
 885                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 886                                                 break;
 887                                 }
 888                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 889                         }
 890                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 891                                 fputs(fh, "has weapons\n");
 892                         else
 893                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 894                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 895                                 fputs(fh, "has turrets\n");
 896                         else
 897                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 898                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 899                                 fputs(fh, "has weapons\n");
 900                         else
 901                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 902                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 903                                 fputs(fh, "frustrating\n");
 904
 905                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 906                                 if(MapInfo_Map_supportedGametypes & i)
 907                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 908
 909                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 910                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 911
 912                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 913                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 914                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 915                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 916                         fputs(fh, "// optional: hidden\n");
 917
 918                         fclose(fh);
 919                         r = 2;
 920                         // return r;
 921                         fh = fopen(fn, FILE_READ);
 922                         if(fh < 0)
 923                                 error("... but I just wrote it!");
 924                 }
 925
 926                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 927         }
 928
 929         _MapInfo_Map_Reset();
 930         for(;;)
 931         {
 932                 if not((s = fgets(fh)))
 933                         break;
 934
 935                 // catch different sorts of comments
 936                 if(s == "")                    // empty lines
 937                         continue;
 938                 if(substring(s, 0, 1) == "#")  // UNIX style
 939                         continue;
 940                 if(substring(s, 0, 2) == "//") // C++ style
 941                         continue;
 942                 if(substring(s, 0, 1) == "_")  // q3map style
 943                         continue;
 944
 945                 p = strstrofs(s, "//", 0);
 946                 if(p >= 0)
 947                         s = substring(s, 0, p);
 948
 949                 t = car(s); s = cdr(s);
 950                 if(t == "title")
 951                         MapInfo_Map_title = s;
 952                 else if(t == "description")
 953                         MapInfo_Map_description = s;
 954                 else if(t == "author")
 955                         MapInfo_Map_author = s;
 956                 else if(t == "has")
 957                 {
 958                         t = car(s); // s = cdr(s);
 959                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 960                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 961                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 962                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 963                         else
 964                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 965                 }
 966                 else if(t == "hidden")
 967                 {
 968                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 969                 }
 970                 else if(t == "forbidden")
 971                 {
 972                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 973                 }
 974                 else if(t == "frustrating")
 975                 {
 976                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 977                 }
 978                 else if(t == "type")
 979                 {
 980                         t = car(s); s = cdr(s);
 981                         f = MapInfo_Type_FromString(t);
 982                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
 983                         if(f)
 984                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
 985                         else
 986                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 987                 }
 988                 else if(t == "gametype")
 989                 {
 990                         t = car(s); s = cdr(s);
 991                         f = MapInfo_Type_FromString(t);
 992                         if(f)
 993                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
 994                         else
 995                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 996                 }
 997                 else if(t == "size")
 998                 {
 999                         float a, b, c, d, e;
1000                         t = car(s); s = cdr(s); a = stof(t);
1001                         t = car(s); s = cdr(s); b = stof(t);
1002                         t = car(s); s = cdr(s); c = stof(t);
1003                         t = car(s); s = cdr(s); d = stof(t);
1004                         t = car(s); s = cdr(s); e = stof(t);
1005                         if(s == "")
1006                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1007                         else
1008                         {
1009                                 t = car(s); s = cdr(s); f = stof(t);
1010                                 if(s != "")
1011                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1012                                 else
1013                                 {
1014                                         if(a >= d || b >= e || c >= f)
1015                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1016                                         else
1017                                         {
1018                                                 MapInfo_Map_mins_x = a;
1019                                                 MapInfo_Map_mins_y = b;
1020                                                 MapInfo_Map_mins_z = c;
1021                                                 MapInfo_Map_maxs_x = d;
1022                                                 MapInfo_Map_maxs_y = e;
1023                                                 MapInfo_Map_maxs_z = f;
1024                                         }
1025                                 }
1026                         }
1027                 }
1028                 else if(t == "settemp_for_type")
1029                 {
1030                         t = car(s); s = cdr(s);
1031                         if((f = MapInfo_Type_FromString(t)))
1032                         {
1033                                 if(f & pGametypeToSet)
1034                                 {
1035                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1036                                 }
1037                         }
1038                         else
1039                         {
1040                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1041                         }
1042                 }
1043                 else if(t == "clientsettemp_for_type")
1044                 {
1045                         t = car(s); s = cdr(s);
1046                         if((f = MapInfo_Type_FromString(t)))
1047                         {
1048                                 if(f & pGametypeToSet)
1049                                 {
1050                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1051                                 }
1052                         }
1053                         else
1054                         {
1055                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1056                         }
1057                 }
1058                 else if(t == "fog")
1059                 {
1060                         if not(cvar_value_issafe(t))
1061                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1062                         else
1063                                 MapInfo_Map_fog = s;
1064                 }
1065                 else if(t == "cdtrack")
1066                 {
1067                         if(pGametypeToSet)
1068                         {
1069                                 if not(cvar_value_issafe(t))
1070                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1071                                 else
1072                                         MapInfo_Map_clientstuff = strcat(
1073                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
1074                                         );
1075                         }
1076                 }
1077                 else
1078                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1079         }
1080         fclose(fh);
1081
1082         if(MapInfo_Map_title == "<TITLE>")
1083                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1084         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1085                 MapInfo_Map_titlestring = MapInfo_Map_title;
1086         else
1087                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1088
1089         MapInfo_Cache_Store();
1090         if(MapInfo_Map_supportedGametypes != 0)
1091                 return r;
1092         dprint("Map ", pFilename, " supports no game types, ignored\n");
1093         return 0;
1094 }
1095 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1096 {
1097         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1098
1099         if(cvar("g_tdm_on_dm_maps"))
1100         {
1101                 // if this is set, all DM maps support TDM too
1102                 if not(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH)
1103                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1104                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1105         }
1106
1107         if(pGametypeToSet)
1108         {
1109                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1110                 {
1111                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1112                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1113                         //return;
1114                 }
1115         }
1116
1117         return r;
1118 }
1119
1120 float MapInfo_FindName(string s)
1121 {
1122         // if there is exactly one map of prefix s, return it
1123         // if not, return the null string
1124         // note that DP sorts glob results... so I can use a binary search
1125         float l, r, m, cmp;
1126         l = 0;
1127         r = MapInfo_count;
1128         // invariants: r is behind s, l-1 is equal or before
1129         while(l != r)
1130         {
1131                 m = floor((l + r) / 2);
1132                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1133                 cmp = strcasecmp(MapInfo_FindName_match, s);
1134                 if(cmp == 0)
1135                         return m; // found and good
1136                 if(cmp < 0)
1137                         l = m + 1; // l-1 is before s
1138                 else
1139                         r = m; // behind s
1140         }
1141         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1142         MapInfo_FindName_firstResult = l;
1143         // r == l, so: l is behind s, l-1 is before
1144         // SO: if there is any, l is the one with the right prefix
1145         //     and l+1 may be one too
1146         if(l == MapInfo_count)
1147         {
1148                 MapInfo_FindName_match = string_null;
1149                 MapInfo_FindName_firstResult = -1;
1150                 return -1; // no MapInfo_FindName_match, behind last item
1151         }
1152         if(!startsWithNocase(MapInfo_FindName_match, s))
1153         {
1154                 MapInfo_FindName_match = string_null;
1155                 MapInfo_FindName_firstResult = -1;
1156                 return -1; // wrong prefix
1157         }
1158         if(l == MapInfo_count - 1)
1159                 return l; // last one, nothing can follow => unique
1160         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1161         {
1162                 MapInfo_FindName_match = string_null;
1163                 return -1; // ambigous MapInfo_FindName_match
1164         }
1165         return l;
1166 }
1167
1168 string MapInfo_FixName(string s)
1169 {
1170         MapInfo_FindName(s);
1171         return MapInfo_FindName_match;
1172 }
1173
1174 float MapInfo_CurrentFeatures()
1175 {
1176         float req;
1177         req = 0;
1178         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1179                 req |= MAPINFO_FEATURE_WEAPONS;
1180         return req;
1181 }
1182
1183 float MapInfo_CurrentGametype()
1184 {
1185         float prev;
1186         entity e;
1187         prev = cvar("gamecfg");
1188         for(e = MapInfo_Type_first; e; e = e.enemy)
1189                 if(cvar(e.netname))
1190                         if(prev != e.items)
1191                                 return e.items;
1192         if(prev)
1193                 return prev;
1194         return MAPINFO_TYPE_DEATHMATCH;
1195 }
1196
1197 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1198 {
1199         if(!MapInfo_Get_ByName(s, 1, 0))
1200                 return 0;
1201         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1202                 return 0;
1203         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1204                 return 0;
1205         return 1;
1206 }
1207
1208 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1209 {
1210         float r;
1211         r = _MapInfo_CheckMap(s);
1212         MapInfo_ClearTemps();
1213         return r;
1214 }
1215
1216 void MapInfo_SwitchGameType(float t)
1217 {
1218         entity e;
1219         for(e = MapInfo_Type_first; e; e = e.enemy)
1220                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1221 }
1222
1223 void MapInfo_LoadMap(string s, float reinit)
1224 {
1225         MapInfo_Map_supportedGametypes = 0;
1226         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1227         //if(!MapInfo_CheckMap(s))
1228         //{
1229         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1230         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1231         //}
1232
1233         cvar_settemp_restore();
1234         if(reinit)
1235                 localcmd(strcat("\nmap ", s, "\n"));
1236         else
1237                 localcmd(strcat("\nchangelevel ", s, "\n"));
1238 }
1239
1240 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1241 {
1242         string out;
1243         float i;
1244
1245         // to make absolutely sure:
1246         MapInfo_Enumerate();
1247         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1248
1249         out = "";
1250         for(i = 0; i < MapInfo_count; ++i)
1251                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1252         return substring(out, 1, strlen(out) - 1);
1253 }
1254
1255 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1256 {
1257         string out;
1258         float i;
1259
1260         // to make absolutely sure:
1261         MapInfo_Enumerate();
1262         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1263
1264         out = "";
1265         for(i = 0; i < MapInfo_count; ++i)
1266                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1267
1268         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1269
1270         return substring(out, 1, strlen(out) - 1);
1271 }
1272
1273 void MapInfo_LoadMapSettings_SaveGameType(float t)
1274 {
1275         MapInfo_SwitchGameType(t);
1276         cvar_set("gamecfg", ftos(t));
1277         MapInfo_LoadedGametype = t;
1278 }
1279
1280 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1281 {
1282         float t;
1283
1284         t = MapInfo_CurrentGametype();
1285         MapInfo_LoadMapSettings_SaveGameType(t);
1286
1287         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1288         {
1289                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1290                 {
1291                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1292                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1293                         return; // do not call Get_ByName!
1294                 }
1295
1296                 if(MapInfo_Map_supportedGametypes == 0)
1297                 {
1298                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1299                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1300                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1301                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1302                         return; // do not call Get_ByName!
1303                 }
1304
1305                 t = 1;
1306                 while(!(MapInfo_Map_supportedGametypes & 1))
1307                 {
1308                         t *= 2;
1309                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1310                 }
1311
1312                 // t is now a supported mode!
1313                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1314                 MapInfo_LoadMapSettings_SaveGameType(t);
1315         }
1316         MapInfo_Get_ByName(s, 1, t);
1317 }
1318
1319 void MapInfo_ClearTemps()
1320 {
1321         MapInfo_Map_bspname = string_null;
1322         MapInfo_Map_title = string_null;
1323         MapInfo_Map_titlestring = string_null;
1324         MapInfo_Map_description = string_null;
1325         MapInfo_Map_author = string_null;
1326         MapInfo_Map_clientstuff = string_null;
1327         MapInfo_Map_supportedGametypes = 0;
1328         MapInfo_Map_supportedFeatures = 0;
1329 }
1330
1331 void MapInfo_Shutdown()
1332 {
1333         MapInfo_ClearTemps();
1334         MapInfo_Filter_Free();
1335         MapInfo_Cache_Destroy();
1336         if(_MapInfo_globopen)
1337         {
1338                 search_end(_MapInfo_globhandle);
1339                 _MapInfo_globhandle = -1;
1340                 _MapInfo_globopen = FALSE;
1341         }
1342 }
1343
1344 float MapInfo_ForbiddenFlags()
1345 {
1346         float f;
1347         f = MAPINFO_FLAG_FORBIDDEN;
1348
1349 #ifndef MENUQC
1350         if not(cvar("g_maplist_allow_hidden"))
1351 #endif
1352                 f |= MAPINFO_FLAG_HIDDEN;
1353
1354         if not(cvar("g_maplist_allow_frustrating"))
1355                 f |= MAPINFO_FLAG_FRUSTRATING;
1356
1357         return f;
1358 }
1359
1360 float MapInfo_RequiredFlags()
1361 {
1362         float f;
1363         f = 0;
1364
1365         if(cvar("g_maplist_allow_frustrating") > 1)
1366                 f |= MAPINFO_FLAG_FRUSTRATING;
1367
1368         return f;
1369 }