qcsrc/common/mapinfo.qc

   1 #if defined(CSQC)
   2     #include "../client/defs.qh"
   3     #include "util.qh"
   4     #include "weapons/all.qh"
   5     #include "mapinfo.qh"
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "util.qh"
   9     #include "monsters/all.qh"
  10     #include "mapinfo.qh"
  11 #endif
  12
  13 bool autocvar_developer_mapper;
  14
  15 #define LOG_MAPWARN(...) MACRO_BEGIN { if (autocvar_developer_mapper) LOG_WARNING(__VA_ARGS__); } MACRO_END
  16 #define LOG_MAPWARNF(...) MACRO_BEGIN { if (autocvar_developer_mapper) LOG_WARNINGF(__VA_ARGS__); } MACRO_END
  17
  18 // generic string stuff
  19
  20 int _MapInfo_Cache_Active;
  21 int _MapInfo_Cache_DB_NameToIndex;
  22 int _MapInfo_Cache_Buf_IndexToMapData;
  23
  24 void MapInfo_Cache_Destroy()
  25 {
  26         if(!_MapInfo_Cache_Active)
  27                 return;
  28
  29         db_close(_MapInfo_Cache_DB_NameToIndex);
  30         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  31         _MapInfo_Cache_Active = 0;
  32 }
  33
  34 void MapInfo_Cache_Create()
  35 {
  36         MapInfo_Cache_Destroy();
  37         _MapInfo_Cache_DB_NameToIndex = db_create();
  38         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  39         _MapInfo_Cache_Active = 1;
  40 }
  41
  42 void MapInfo_Cache_Invalidate()
  43 {
  44         if(!_MapInfo_Cache_Active)
  45                 return;
  46
  47         MapInfo_Cache_Create();
  48 }
  49
  50 void MapInfo_Cache_Store()
  51 {
  52         float i;
  53         string s;
  54         if(!_MapInfo_Cache_Active)
  55                 return;
  56
  57         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  58         if(s == "")
  59         {
  60                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  61                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  62         }
  63         else
  64                 i = stof(s);
  65
  66         // now store all the stuff
  67         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  75 }
  76
  77 float MapInfo_Cache_Retrieve(string map)
  78 {
  79         float i;
  80         string s;
  81         if(!_MapInfo_Cache_Active)
  82                 return 0;
  83
  84         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  85         if(s == "")
  86                 return 0;
  87         i = stof(s);
  88
  89         // now retrieve all the stuff
  90         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  91         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  92         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  93         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  94         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  95         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  96         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  97         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  98
  99         return 1;
 100 }
 101
 102 // GLOB HANDLING (for all BSP files)
 103 float _MapInfo_globopen;
 104 float _MapInfo_globcount;
 105 float _MapInfo_globhandle;
 106 string _MapInfo_GlobItem(float i)
 107 {
 108         string s;
 109         if(!_MapInfo_globopen)
 110                 return string_null;
 111         s = search_getfilename(_MapInfo_globhandle, i);
 112         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 113 }
 114
 115 void MapInfo_Enumerate()
 116 {
 117         if(_MapInfo_globopen)
 118         {
 119                 search_end(_MapInfo_globhandle);
 120                 _MapInfo_globopen = 0;
 121         }
 122         MapInfo_Cache_Invalidate();
 123         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 124         if(_MapInfo_globhandle >= 0)
 125         {
 126                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 127                 _MapInfo_globopen = 1;
 128         }
 129         else
 130                 _MapInfo_globcount = 0;
 131 }
 132
 133 // filter the info by game type mask (updates MapInfo_count)
 134 //
 135 float _MapInfo_filtered;
 136 float _MapInfo_filtered_allocated;
 137 float MapInfo_FilterList_Lookup(float i)
 138 {
 139         return stof(bufstr_get(_MapInfo_filtered, i));
 140 }
 141
 142 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 143 {
 144         string h;
 145         h = bufstr_get(_MapInfo_filtered, i);
 146         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 147         bufstr_set(_MapInfo_filtered, j, h);
 148 }
 149
 150 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 151 {
 152         string a, b;
 153         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 154         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 155         return strcasecmp(a, b);
 156 }
 157
 158 float MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 159 {
 160         float i, j;
 161         if (!_MapInfo_filtered_allocated)
 162         {
 163                 _MapInfo_filtered_allocated = 1;
 164                 _MapInfo_filtered = buf_create();
 165         }
 166         MapInfo_count = 0;
 167         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 168         {
 169                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 170                         if(pAbortOnGenerate)
 171                         {
 172                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.\n");
 173                                 MapInfo_progress = i / _MapInfo_globcount;
 174                                 return 0;
 175                         }
 176                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 177                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 178                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 179                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 180                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 181         }
 182         MapInfo_count = j + 1;
 183         MapInfo_ClearTemps();
 184
 185         // sometimes the glob isn't sorted nicely, so fix it here...
 186         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 187
 188         return 1;
 189 }
 190 void MapInfo_FilterString(string sf)
 191 {
 192         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 193         float i, j;
 194         string title;
 195
 196         for(i = 0, j = -1; i < MapInfo_count; ++i)
 197         {
 198                 if (MapInfo_Get_ByID(i))
 199                 {
 200                         // prepare for keyword filter
 201                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 202                                 title = MapInfo_Map_title;
 203                         else
 204                                 title = MapInfo_Map_bspname;
 205                         // keyword filter
 206                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 207                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 208                 }
 209         }
 210         MapInfo_count = j + 1;
 211         MapInfo_ClearTemps();
 212
 213         // sometimes the glob isn't sorted nicely, so fix it here...
 214         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 215 }
 216
 217 void MapInfo_Filter_Free()
 218 {
 219         if(_MapInfo_filtered_allocated)
 220         {
 221                 buf_del(_MapInfo_filtered);
 222                 _MapInfo_filtered_allocated = 0;
 223         }
 224 }
 225
 226 // load info about the i-th map into the MapInfo_Map_* globals
 227 string MapInfo_BSPName_ByID(float i)
 228 {
 229         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 230 }
 231
 232 string unquote(string s)
 233 {
 234         float i, j, l;
 235         l = strlen(s);
 236         j = -1;
 237         for(i = 0; i < l; ++i)
 238         {
 239                 string ch;
 240                 ch = substring(s, i, 1);
 241                 if(ch != " ") if(ch != "\"")
 242                 {
 243                         for(j = strlen(s) - i - 1; j > 0; --j)
 244                         {
 245                                 ch = substring(s, i+j, 1);
 246                                 if(ch != " ") if(ch != "\"")
 247                                         return substring(s, i, j+1);
 248                         }
 249                         return substring(s, i, 1);
 250                 }
 251         }
 252         return "";
 253 }
 254
 255 float MapInfo_Get_ByID(float i)
 256 {
 257         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 258                 return 1;
 259         return 0;
 260 }
 261
 262 string _MapInfo_Map_worldspawn_music;
 263
 264 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 265 {
 266         string fn;
 267         float fh;
 268         string s, k, v;
 269         vector o;
 270         float i;
 271         float inWorldspawn;
 272         float r;
 273         float twoBaseModes;
 274         float diameter, spawnpoints;
 275         float spawnplaces;
 276
 277         vector mapMins, mapMaxs;
 278
 279         r = 1;
 280         fn = strcat("maps/", pFilename, ".ent");
 281         fh = fopen(fn, FILE_READ);
 282         if(fh < 0)
 283         {
 284                 r = 2;
 285                 fn = strcat("maps/", pFilename, ".bsp");
 286                 fh = fopen(fn, FILE_READ);
 287         }
 288         if(fh < 0)
 289                 return 0;
 290         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo\n");
 291
 292         inWorldspawn = 2;
 293         MapInfo_Map_flags = 0;
 294         MapInfo_Map_supportedGametypes = 0;
 295         spawnpoints = 0;
 296         spawnplaces = 0;
 297         _MapInfo_Map_worldspawn_music = "";
 298         mapMins = '0 0 0';
 299         mapMaxs = '0 0 0';
 300
 301         for (;;)
 302         {
 303                 if (!((s = fgets(fh))))
 304                         break;
 305                 if(inWorldspawn == 1)
 306                         if(startsWith(s, "}"))
 307                                 inWorldspawn = 0;
 308                 k = unquote(car(s));
 309                 v = unquote(cdr(s));
 310                 if(inWorldspawn)
 311                 {
 312                         if(k == "classname" && v == "worldspawn")
 313                                 inWorldspawn = 1;
 314                         else if(k == "author")
 315                                 MapInfo_Map_author = v;
 316                         else if(k == "_description")
 317                                 MapInfo_Map_description = v;
 318                         else if(k == "music")
 319                                 _MapInfo_Map_worldspawn_music = v;
 320                         else if(k == "noise")
 321                                 _MapInfo_Map_worldspawn_music = v;
 322                         else if(k == "message")
 323                         {
 324                                 i = strstrofs(v, " by ", 0);
 325                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 326                                 {
 327                                         MapInfo_Map_title = substring(v, 0, i);
 328                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 329                                 }
 330                                 else
 331                                         MapInfo_Map_title = v;
 332                         }
 333                 }
 334                 else
 335                 {
 336                         if(k == "origin")
 337                         {
 338                                 o = stov(strcat("'", v, "'"));
 339                                 mapMins.x = min(mapMins.x, o.x);
 340                                 mapMins.y = min(mapMins.y, o.y);
 341                                 mapMins.z = min(mapMins.z, o.z);
 342                                 mapMaxs.x = max(mapMaxs.x, o.x);
 343                                 mapMaxs.y = max(mapMaxs.y, o.y);
 344                                 mapMaxs.z = max(mapMaxs.z, o.z);
 345                         }
 346                         else if(k == "race_place")
 347                         {
 348                                 if(stof(v) > 0)
 349                                         spawnplaces = 1;
 350                         }
 351                         else if(k == "classname")
 352                         {
 353                                 if(v == "dom_controlpoint")
 354                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 355                                 else if(v == "item_flag_team2")
 356                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 357                                 else if(v == "team_CTF_blueflag")
 358                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 359                                 else if(v == "invasion_spawnpoint")
 360                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_INVASION;
 361                                 else if(v == "target_assault_roundend")
 362                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 363                                 else if(v == "onslaught_generator")
 364                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 365                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 366                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 367                                 else if(v == "info_player_team1")
 368                                         ++spawnpoints;
 369                                 else if(v == "info_player_team2")
 370                                         ++spawnpoints;
 371                                 else if(v == "info_player_start")
 372                                         ++spawnpoints;
 373                                 else if(v == "info_player_deathmatch")
 374                                         ++spawnpoints;
 375                                 else if(v == "trigger_race_checkpoint")
 376                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 377                                 else if(v == "target_startTimer")
 378                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 379                                 else if(v == "weapon_nex")
 380                                         { }
 381                                 else if(v == "weapon_railgun")
 382                                         { }
 383                                 else if(startsWith(v, "weapon_"))
 384                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 385                                 else if(startsWith(v, "turret_"))
 386                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 387                                 else if(startsWith(v, "vehicle_"))
 388                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 389                                 else if(startsWith(v, "monster_"))
 390                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 391                                 else if(v == "target_music" || v == "trigger_music")
 392                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 393                         }
 394                 }
 395         }
 396         if(inWorldspawn)
 397         {
 398                 LOG_MAPWARN(fn, " ended still in worldspawn, BUG\n");
 399                 return 0;
 400         }
 401         diameter = vlen(mapMaxs - mapMins);
 402
 403         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 404         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 405         {
 406                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 407                 // as the map is too symmetric for them.
 408         }
 409         else
 410         {
 411                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 412                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 413                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 414
 415                 if(spawnpoints >= 8  && diameter > 4096) {
 416                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 417                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 418                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 419                 }
 420                 if(spawnpoints >= 12 && diameter > 5120)
 421                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 422         }
 423
 424         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 425         if(!spawnplaces)
 426         {
 427                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 428                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 429         }
 430
 431         LOG_TRACE("-> diameter ",    ftos(diameter));
 432         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 433         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 434
 435         fclose(fh);
 436
 437         return r;
 438 }
 439
 440 void _MapInfo_Map_Reset()
 441 {
 442         MapInfo_Map_title = "<TITLE>";
 443         MapInfo_Map_titlestring = "<TITLE>";
 444         MapInfo_Map_description = "<DESCRIPTION>";
 445         MapInfo_Map_author = "<AUTHOR>";
 446         MapInfo_Map_supportedGametypes = 0;
 447         MapInfo_Map_supportedFeatures = 0;
 448         MapInfo_Map_flags = 0;
 449         MapInfo_Map_clientstuff = "";
 450         MapInfo_Map_fog = "";
 451         MapInfo_Map_mins = '0 0 0';
 452         MapInfo_Map_maxs = '0 0 0';
 453 }
 454
 455 string _MapInfo_GetDefault(float t)
 456 {
 457         switch(t)
 458         {
 459                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 460                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 461                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 462                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 463                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 464                 case MAPINFO_TYPE_CA:              return "10 20 0";
 465                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 466                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 467                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 468                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 469                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 470                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 471                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 472                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 473                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 474                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 475                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 476                 default:                           return "";
 477         }
 478 }
 479
 480 void _MapInfo_Map_ApplyGametype(string s, int pWantedType, int pThisType, int load_default)
 481 {
 482         string sa;
 483         MapInfo_Map_supportedGametypes |= pThisType;
 484         if(!(pThisType & pWantedType))
 485                 return;
 486
 487         if(load_default)
 488                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 489
 490         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 491         {
 492                 cvar_set("fraglimit", "0");
 493         }
 494         else
 495         {
 496                 sa = car(s);
 497                 if(sa != "")
 498                         cvar_set("fraglimit", sa);
 499                 s = cdr(s);
 500         }
 501
 502         sa = car(s);
 503         if(sa != "")
 504                 cvar_set("timelimit", sa);
 505         s = cdr(s);
 506
 507         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 508         {
 509                 sa = car(s);
 510                 if(sa != "")
 511                         cvar_set("g_tdm_teams", sa);
 512                 s = cdr(s);
 513         }
 514
 515         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 516         {
 517                 sa = car(s);
 518                 if(sa != "")
 519                         cvar_set("g_keyhunt_teams", sa);
 520                 s = cdr(s);
 521         }
 522
 523         if(pWantedType == MAPINFO_TYPE_CA)
 524         {
 525                 sa = car(s);
 526                 if(sa != "")
 527                         cvar_set("g_ca_teams", sa);
 528                 s = cdr(s);
 529         }
 530
 531         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 532         {
 533                 sa = car(s);
 534                 if(sa != "")
 535                         cvar_set("g_freezetag_teams", sa);
 536                 s = cdr(s);
 537         }
 538
 539         if(pWantedType == MAPINFO_TYPE_CTF)
 540         {
 541                 sa = car(s);
 542                 if(sa != "")
 543                         cvar_set("fraglimit", sa);
 544                 s = cdr(s);
 545         }
 546
 547         /* keepaway wuz here
 548         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 549         {
 550                 sa = car(s);
 551                 if(sa != "")
 552                         cvar_set("fraglimit", sa);
 553                 s = cdr(s);
 554         }
 555         */
 556
 557         // rc = timelimit timelimit_qualification laps laps_teamplay
 558         if(pWantedType == MAPINFO_TYPE_RACE)
 559         {
 560                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 561                 cvar_set("g_race_qualifying_timelimit", sa);
 562                 s = cdr(s);
 563
 564                 sa = car(s);
 565                 if(sa != "")
 566                         if(cvar("g_race_teams") < 2)
 567                                 cvar_set("fraglimit", sa);
 568                 s = cdr(s);
 569
 570                 sa = car(s);
 571                 if(sa != "")
 572                         if(cvar("g_race_teams") >= 2)
 573                                 cvar_set("fraglimit", sa);
 574                 s = cdr(s);
 575         }
 576
 577         if(pWantedType == MAPINFO_TYPE_CTS)
 578         {
 579                 sa = car(s);
 580
 581                 // this is the skill of the map
 582                 // not parsed by anything yet
 583                 // for map databases
 584                 //if(sa != "")
 585                 //      cvar_set("fraglimit", sa);
 586
 587                 s = cdr(s);
 588         }
 589
 590         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 591         {
 592                 cvar_set("leadlimit", "0");
 593         }
 594         else
 595         {
 596                 sa = car(s);
 597                 if(sa != "")
 598                         cvar_set("leadlimit", sa);
 599                 s = cdr(s);
 600         }
 601 }
 602
 603 string _MapInfo_GetDefaultEx(float t)
 604 {
 605         FOREACH(Gametypes, it.items == t, LAMBDA(return it.model2));
 606         return "";
 607 }
 608
 609 float _MapInfo_GetTeamPlayBool(float t)
 610 {
 611         FOREACH(Gametypes, it.items == t, LAMBDA(return it.team));
 612         return false;
 613 }
 614
 615 void _MapInfo_Map_ApplyGametypeEx(string s, int pWantedType, int pThisType)
 616 {
 617         MapInfo_Map_supportedGametypes |= pThisType;
 618         if (!(pThisType & pWantedType))
 619                 return;
 620
 621         // reset all the cvars to their defaults
 622
 623         cvar_set("timelimit", cvar_defstring("timelimit"));
 624         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 625         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 626         FOREACH(Gametypes, true, LAMBDA(it.m_parse_mapinfo(string_null, string_null)));
 627
 628         string fraglimit_normal = string_null;
 629         string fraglimit_teams = string_null;
 630
 631         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 632                 string sa = car(s);
 633                 if (sa == "") continue;
 634                 int p = strstrofs(sa, "=", 0);
 635                 if (p < 0) {
 636                         LOG_MAPWARNF("Invalid gametype setting in mapinfo for gametype %s: %s\n", MapInfo_Type_ToString(pWantedType), sa);
 637                         continue;
 638                 }
 639                 string k = substring(sa, 0, p);
 640                 string v = substring(sa, p + 1, -1);
 641                 bool handled = true;
 642                 switch (k) {
 643                         case "timelimit":
 644                         {
 645                                 cvar_set("timelimit", v);
 646                                 break;
 647                         }
 648                         case "leadlimit":
 649                         {
 650                                 cvar_set("leadlimit", v);
 651                                 break;
 652                         }
 653                         case "pointlimit":
 654                         case "fraglimit":
 655                         case "lives":
 656                         case "laplimit":
 657                         case "caplimit":
 658                         {
 659                                 fraglimit_normal = v;
 660                                 break;
 661                         }
 662                         case "teampointlimit":
 663                         case "teamlaplimit":
 664                         {
 665                                 fraglimit_teams = v;
 666                                 break;
 667                         }
 668                         default:
 669                         {
 670                             handled = false;
 671                             break;
 672                         }
 673                 }
 674                 FOREACH(Gametypes, true, LAMBDA(handled |= it.m_parse_mapinfo(k, v)));
 675                 if (!handled)
 676             LOG_MAPWARNF("Invalid gametype setting in mapinfo for gametype %s: %s\n", MapInfo_Type_ToString(pWantedType), sa);
 677         }
 678
 679         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 680         {
 681                 if(fraglimit_teams)
 682                         cvar_set("fraglimit", fraglimit_teams);
 683         }
 684         else
 685         {
 686                 if(fraglimit_normal)
 687                         cvar_set("fraglimit", fraglimit_normal);
 688         }
 689 }
 690
 691 Gametype MapInfo_Type(int t)
 692 {
 693         FOREACH(Gametypes, it.items == t, LAMBDA(return it));
 694         return NULL;
 695 }
 696
 697 int MapInfo_Type_FromString(string t)
 698 {
 699 #define deprecate(from, to) MACRO_BEGIN { \
 700         if (t == #from) { \
 701                 string replacement = #to; \
 702                 LOG_MAPWARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.\n", MapInfo_Map_bspname, t, replacement); \
 703                 t = replacement; \
 704         } \
 705 } MACRO_END
 706         deprecate(nexball, nb);
 707         deprecate(freezetag, ft);
 708         deprecate(keepaway, ka);
 709         deprecate(invasion, inv);
 710         deprecate(assault, as);
 711         deprecate(race, rc);
 712         if (t == "all") return MAPINFO_TYPE_ALL;
 713         FOREACH(Gametypes, it.mdl == t, LAMBDA(return it.items));
 714         return 0;
 715 #undef deprecate
 716 }
 717
 718 string MapInfo_Type_Description(float t)
 719 {
 720         FOREACH(Gametypes, it.items == t, LAMBDA(return it.gametype_description));
 721         return "";
 722 }
 723
 724 string MapInfo_Type_ToString(float t)
 725 {
 726         if(t == MAPINFO_TYPE_ALL)
 727                 return "all";
 728         FOREACH(Gametypes, it.items == t, LAMBDA(return it.mdl));
 729         return "";
 730 }
 731
 732 string MapInfo_Type_ToText(float t)
 733 {
 734         FOREACH(Gametypes, it.items == t, LAMBDA(return it.message));
 735         /* xgettext:no-c-format */
 736         return _("@!#%'n Tuba Throwing");
 737 }
 738
 739 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 740 {
 741         string t;
 742         float fh, o;
 743         t = car(s); s = cdr(s);
 744
 745         // limited support of "" and comments
 746         //   remove trailing and leading " of t
 747         if(substring(t, 0, 1) == "\"")
 748         {
 749                 if(substring(t, -1, 1) == "\"")
 750                         t = substring(t, 1, -2);
 751         }
 752
 753         //   remove leading " of s
 754         if(substring(s, 0, 1) == "\"")
 755         {
 756                 s = substring(s, 1, -1);
 757         }
 758         //   remove trailing " of s, and all that follows (cvar description)
 759         o = strstrofs(s, "\"", 0);
 760         if(o >= 0)
 761                 s = substring(s, 0, o);
 762
 763         //   remove // comments
 764         o = strstrofs(s, "//", 0);
 765         if(o >= 0)
 766                 s = substring(s, 0, o);
 767
 768         //   remove trailing spaces
 769         while(substring(s, -1, 1) == " ")
 770                 s = substring(s, 0, -2);
 771
 772         if(t == "#include")
 773         {
 774                 if(recurse > 0)
 775                 {
 776                         fh = fopen(s, FILE_READ);
 777                         if(fh < 0)
 778                                 LOG_MAPWARN("Map ", pFilename, " references not existing config file ", s, "\n");
 779                         else
 780                         {
 781                                 for (;;)
 782                                 {
 783                                         if (!((s = fgets(fh))))
 784                                                 break;
 785
 786                                         // catch different sorts of comments
 787                                         if(s == "")                    // empty lines
 788                                                 continue;
 789                                         if(substring(s, 0, 1) == "#")  // UNIX style
 790                                                 continue;
 791                                         if(substring(s, 0, 2) == "//") // C++ style
 792                                                 continue;
 793                                         if(substring(s, 0, 1) == "_")  // q3map style
 794                                                 continue;
 795
 796                                         if(substring(s, 0, 4) == "set ")
 797                                                 s = substring(s, 4, -1);
 798                                         if(substring(s, 0, 5) == "seta ")
 799                                                 s = substring(s, 5, -1);
 800
 801                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 802                                 }
 803                                 fclose(fh);
 804                         }
 805                 }
 806                 else
 807                         LOG_MAPWARN("Map ", pFilename, " uses too many levels of inclusion\n");
 808         }
 809         else if(t == "")
 810                 LOG_MAPWARN("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 811         else if (!cvar_value_issafe(t))
 812                 LOG_MAPWARN("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 813         else if (!cvar_value_issafe(s))
 814                 LOG_MAPWARN("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 815         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 816                 LOG_MAPWARN("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 817         else if(matchacl(acl, t) <= 0)
 818                 LOG_MAPWARN("Map ", pFilename, " contains a denied setting, ignored\n");
 819         else
 820         {
 821                 if(type == 0) // server set
 822                 {
 823                         LOG_TRACE("Applying temporary setting ", t, " := ", s, "\n");
 824                         if(cvar("g_campaign"))
 825                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 826                         else
 827                                 cvar_settemp(t, s);
 828                 }
 829                 else
 830                 {
 831                         LOG_TRACE("Applying temporary client setting ", t, " := ", s, "\n");
 832                         MapInfo_Map_clientstuff = strcat(
 833                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 834                                         );
 835                 }
 836         }
 837 }
 838
 839 float MapInfo_isRedundant(string fn, string t)
 840 {
 841         // normalize file name
 842         fn = strreplace("_", "-", fn);
 843
 844         // normalize visible title
 845         t = strreplace(": ", "-", t);
 846         t = strreplace(":", "-", t);
 847         t = strreplace(" ", "-", t);
 848         t = strreplace("_", "-", t);
 849         t = strreplace("'", "-", t);
 850
 851         if(!strcasecmp(fn, t))
 852                 return true;
 853
 854         // we allow the visible title to have punctuation the file name does
 855         // not, but not vice versa
 856         t = strreplace("-", "", t);
 857
 858         if(!strcasecmp(fn, t))
 859                 return true;
 860
 861         return false;
 862 }
 863
 864 // load info about a map by name into the MapInfo_Map_* globals
 865 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, int pGametypeToSet)
 866 {
 867         string fn;
 868         string s, t;
 869         float fh;
 870         int f, i;
 871         float r, n, p;
 872         string acl;
 873
 874         acl = MAPINFO_SETTEMP_ACL_USER;
 875
 876         if(strstrofs(pFilename, "/", 0) >= 0)
 877         {
 878                 LOG_MAPWARN("Invalid character in map name, ignored\n");
 879                 return 0;
 880         }
 881
 882         if(pGametypeToSet == 0)
 883                 if(MapInfo_Cache_Retrieve(pFilename))
 884                         return 1;
 885
 886         r = 1;
 887
 888         MapInfo_Map_bspname = pFilename;
 889
 890         // default all generic fields so they have "good" values in case something fails
 891         fn = strcat("maps/", pFilename, ".mapinfo");
 892         fh = fopen(fn, FILE_READ);
 893         if(fh < 0)
 894         {
 895                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 896                 fh = fopen(fn, FILE_READ);
 897                 if(fh < 0)
 898                 {
 899                         if(!pAllowGenerate)
 900                                 return 0;
 901                         _MapInfo_Map_Reset();
 902                         r = _MapInfo_Generate(pFilename);
 903                         if(!r)
 904                                 return 0;
 905                         fh = fopen(fn, FILE_WRITE);
 906                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 907                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 908                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 909                         if(_MapInfo_Map_worldspawn_music != "")
 910                         {
 911                                 if(
 912                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 913                                         ||
 914                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 915                                 )
 916                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 917                                 else
 918                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 919                         }
 920                         else
 921                         {
 922                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 923                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 924                                 for (;;)
 925                                 {
 926                                         i = floor(random() * n);
 927                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 928                                                 break;
 929                                 }
 930                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 931                         }
 932                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 933                                 fputs(fh, "has weapons\n");
 934                         else
 935                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 936                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 937                                 fputs(fh, "has turrets\n");
 938                         else
 939                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 940                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 941                                 fputs(fh, "has vehicles\n");
 942                         else
 943                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 944                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 945                                 fputs(fh, "frustrating\n");
 946
 947                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 948                                 if(MapInfo_Map_supportedGametypes & i)
 949                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 950
 951                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 952                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 953
 954                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 955                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 956                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 957                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 958                         fputs(fh, "// optional: hidden\n");
 959
 960                         fclose(fh);
 961                         r = 2;
 962                         // return r;
 963                         fh = fopen(fn, FILE_READ);
 964                         if(fh < 0)
 965                                 error("... but I just wrote it!");
 966                 }
 967
 968                 LOG_MAPWARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 969         }
 970
 971         _MapInfo_Map_Reset();
 972         for (;;)
 973         {
 974                 if (!((s = fgets(fh))))
 975                         break;
 976
 977                 // catch different sorts of comments
 978                 if(s == "")                    // empty lines
 979                         continue;
 980                 if(substring(s, 0, 1) == "#")  // UNIX style
 981                         continue;
 982                 if(substring(s, 0, 2) == "//") // C++ style
 983                         continue;
 984                 if(substring(s, 0, 1) == "_")  // q3map style
 985                         continue;
 986
 987                 p = strstrofs(s, "//", 0);
 988                 if(p >= 0)
 989                         s = substring(s, 0, p);
 990
 991                 t = car(s); s = cdr(s);
 992                 if(t == "title")
 993                         MapInfo_Map_title = s;
 994                 else if(t == "description")
 995                         MapInfo_Map_description = s;
 996                 else if(t == "author")
 997                         MapInfo_Map_author = s;
 998                 else if(t == "has")
 999                 {
1000                         t = car(s); // s = cdr(s);
1001                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1002                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1003                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1004                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1005                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1006                         else
1007                                 LOG_MAPWARN("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
1008                 }
1009                 else if(t == "hidden")
1010                 {
1011                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1012                 }
1013                 else if(t == "forbidden")
1014                 {
1015                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1016                 }
1017                 else if(t == "frustrating")
1018                 {
1019                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1020                 }
1021                 else if(t == "noautomaplist")
1022                 {
1023                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1024                 }
1025                 else if(t == "gameversion_min")
1026                 {
1027                         if (cvar("gameversion") < stof(s))
1028                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1029                 }
1030                 else if(t == "type")
1031                 {
1032                         t = car(s); s = cdr(s);
1033                         f = MapInfo_Type_FromString(t);
1034                         LOG_MAPWARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1035                         if(f)
1036                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1037                         else
1038                                 LOG_MAPWARN("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1039                 }
1040                 else if(t == "gametype")
1041                 {
1042                         t = car(s); s = cdr(s);
1043                         f = MapInfo_Type_FromString(t);
1044                         if(f)
1045                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1046                         else
1047                                 LOG_MAPWARN("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1048                 }
1049                 else if(t == "size")
1050                 {
1051                         float a, b, c, d, e;
1052                         t = car(s); s = cdr(s); a = stof(t);
1053                         t = car(s); s = cdr(s); b = stof(t);
1054                         t = car(s); s = cdr(s); c = stof(t);
1055                         t = car(s); s = cdr(s); d = stof(t);
1056                         t = car(s); s = cdr(s); e = stof(t);
1057                         if(s == "")
1058                                 LOG_MAPWARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1059                         else
1060                         {
1061                                 t = car(s); s = cdr(s); f = stof(t);
1062                                 if(s != "")
1063                                         LOG_MAPWARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1064                                 else
1065                                 {
1066                                         if(a >= d || b >= e || c >= f)
1067                                                 LOG_MAPWARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1068                                         else
1069                                         {
1070                                                 MapInfo_Map_mins.x = a;
1071                                                 MapInfo_Map_mins.y = b;
1072                                                 MapInfo_Map_mins.z = c;
1073                                                 MapInfo_Map_maxs.x = d;
1074                                                 MapInfo_Map_maxs.y = e;
1075                                                 MapInfo_Map_maxs.z = f;
1076                                         }
1077                                 }
1078                         }
1079                 }
1080                 else if(t == "settemp_for_type")
1081                 {
1082                         t = car(s); s = cdr(s);
1083                         if((f = MapInfo_Type_FromString(t)))
1084                         {
1085                                 if(f & pGametypeToSet)
1086                                 {
1087                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1088                                 }
1089                         }
1090                         else
1091                         {
1092                                 LOG_MAPWARN("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1093                         }
1094                 }
1095                 else if(t == "clientsettemp_for_type")
1096                 {
1097                         t = car(s); s = cdr(s);
1098                         if((f = MapInfo_Type_FromString(t)))
1099                         {
1100                                 if(f & pGametypeToSet)
1101                                 {
1102                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1103                                 }
1104                         }
1105                         else
1106                         {
1107                                 LOG_MAPWARN("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1108                         }
1109                 }
1110                 else if(t == "fog")
1111                 {
1112                         if (!cvar_value_issafe(s))
1113                                 LOG_MAPWARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1114                         else
1115                                 MapInfo_Map_fog = s;
1116                 }
1117                 else if(t == "cdtrack")
1118                 {
1119                         t = car(s); s = cdr(s);
1120                         // We do this only if pGametypeToSet even though this
1121                         // content is theoretically game type independent,
1122                         // because MapInfo_Map_clientstuff contains otherwise
1123                         // game type dependent stuff. That way this value stays
1124                         // empty when not setting a game type to not set any
1125                         // false expectations.
1126                         if(pGametypeToSet)
1127                         {
1128                                 if (!cvar_value_issafe(t))
1129                                         LOG_MAPWARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1130                                 else
1131                                         MapInfo_Map_clientstuff = strcat(
1132                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1133                                         );
1134                         }
1135                 }
1136                 else
1137                         LOG_MAPWARN("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1138         }
1139         fclose(fh);
1140
1141         if(MapInfo_Map_title == "<TITLE>")
1142                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1143         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1144                 MapInfo_Map_titlestring = MapInfo_Map_title;
1145         else
1146                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1147
1148         MapInfo_Cache_Store();
1149         if(MapInfo_Map_supportedGametypes != 0)
1150                 return r;
1151         LOG_MAPWARN("Map ", pFilename, " supports no game types, ignored\n");
1152         return 0;
1153 }
1154 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, int pGametypeToSet)
1155 {
1156         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1157
1158         if(cvar("g_tdm_on_dm_maps"))
1159         {
1160                 // if this is set, all DM maps support TDM too
1161                 if (!(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH))
1162                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1163                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1164         }
1165
1166         if(pGametypeToSet)
1167         {
1168                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1169                 {
1170                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1171                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1172                         //return;
1173                 }
1174         }
1175
1176         return r;
1177 }
1178
1179 float MapInfo_FindName(string s)
1180 {
1181         // if there is exactly one map of prefix s, return it
1182         // if not, return the null string
1183         // note that DP sorts glob results... so I can use a binary search
1184         float l, r, m, cmp;
1185         l = 0;
1186         r = MapInfo_count;
1187         // invariants: r is behind s, l-1 is equal or before
1188         while(l != r)
1189         {
1190                 m = floor((l + r) / 2);
1191                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1192                 cmp = strcasecmp(MapInfo_FindName_match, s);
1193                 if(cmp == 0)
1194                         return m; // found and good
1195                 if(cmp < 0)
1196                         l = m + 1; // l-1 is before s
1197                 else
1198                         r = m; // behind s
1199         }
1200         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1201         MapInfo_FindName_firstResult = l;
1202         // r == l, so: l is behind s, l-1 is before
1203         // SO: if there is any, l is the one with the right prefix
1204         //     and l+1 may be one too
1205         if(l == MapInfo_count)
1206         {
1207                 MapInfo_FindName_match = string_null;
1208                 MapInfo_FindName_firstResult = -1;
1209                 return -1; // no MapInfo_FindName_match, behind last item
1210         }
1211         if(!startsWithNocase(MapInfo_FindName_match, s))
1212         {
1213                 MapInfo_FindName_match = string_null;
1214                 MapInfo_FindName_firstResult = -1;
1215                 return -1; // wrong prefix
1216         }
1217         if(l == MapInfo_count - 1)
1218                 return l; // last one, nothing can follow => unique
1219         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1220         {
1221                 MapInfo_FindName_match = string_null;
1222                 return -1; // ambigous MapInfo_FindName_match
1223         }
1224         return l;
1225 }
1226
1227 string MapInfo_FixName(string s)
1228 {
1229         MapInfo_FindName(s);
1230         return MapInfo_FindName_match;
1231 }
1232
1233 int MapInfo_CurrentFeatures()
1234 {
1235         int req = 0;
1236         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1237                 req |= MAPINFO_FEATURE_WEAPONS;
1238         return req;
1239 }
1240
1241 int MapInfo_CurrentGametype()
1242 {
1243         int prev = cvar("gamecfg");
1244         FOREACH(Gametypes, cvar(it.netname) && it.items != prev, LAMBDA(return it.items));
1245         if (prev) return prev;
1246         return MAPINFO_TYPE_DEATHMATCH;
1247 }
1248
1249 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1250 {
1251         if(!MapInfo_Get_ByName(s, 1, 0))
1252                 return 0;
1253         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1254                 return 0;
1255         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1256                 return 0;
1257         return 1;
1258 }
1259
1260 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1261 {
1262         float r;
1263         r = _MapInfo_CheckMap(s);
1264         MapInfo_ClearTemps();
1265         return r;
1266 }
1267
1268 void MapInfo_SwitchGameType(int t)
1269 {
1270         FOREACH(Gametypes, true, LAMBDA(
1271                 cvar_set(it.netname, (it.items == t) ? "1" : "0")
1272         ));
1273 }
1274
1275 void MapInfo_LoadMap(string s, float reinit)
1276 {
1277         MapInfo_Map_supportedGametypes = 0;
1278         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1279         //if(!MapInfo_CheckMap(s))
1280         //{
1281         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1282         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1283         //}
1284
1285         cvar_settemp_restore();
1286         if(reinit)
1287                 localcmd(strcat("\nmap ", s, "\n"));
1288         else
1289                 localcmd(strcat("\nchangelevel ", s, "\n"));
1290 }
1291
1292 string MapInfo_ListAllowedMaps(float type, float pRequiredFlags, float pForbiddenFlags)
1293 {
1294         string out;
1295         float i;
1296
1297         // to make absolutely sure:
1298         MapInfo_Enumerate();
1299         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1300
1301         out = "";
1302         for(i = 0; i < MapInfo_count; ++i)
1303                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1304         return substring(out, 1, strlen(out) - 1);
1305 }
1306
1307 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1308 {
1309         string out;
1310         float i;
1311
1312         // to make absolutely sure:
1313         MapInfo_Enumerate();
1314         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1315
1316         out = "";
1317         for(i = 0; i < MapInfo_count; ++i)
1318                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1319
1320         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1321
1322         return substring(out, 1, strlen(out) - 1);
1323 }
1324
1325 void MapInfo_LoadMapSettings_SaveGameType(float t)
1326 {
1327         MapInfo_SwitchGameType(t);
1328         cvar_set("gamecfg", ftos(t));
1329         MapInfo_LoadedGametype = t;
1330 }
1331
1332 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1333 {
1334         float t;
1335
1336         t = MapInfo_CurrentGametype();
1337         MapInfo_LoadMapSettings_SaveGameType(t);
1338
1339         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1340         {
1341                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1342                 {
1343                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.\n");
1344                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1345                         return; // do not call Get_ByName!
1346                 }
1347
1348                 if(MapInfo_Map_supportedGametypes == 0)
1349                 {
1350                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1351                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1352                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1353                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1354                         return; // do not call Get_ByName!
1355                 }
1356
1357                 t = 1;
1358                 while(!(MapInfo_Map_supportedGametypes & 1))
1359                 {
1360                         t *= 2;
1361                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1362                 }
1363
1364                 // t is now a supported mode!
1365                 LOG_WARNING("can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1366                 MapInfo_LoadMapSettings_SaveGameType(t);
1367         }
1368         MapInfo_Get_ByName(s, 1, t);
1369 }
1370
1371 void MapInfo_ClearTemps()
1372 {
1373         MapInfo_Map_bspname = string_null;
1374         MapInfo_Map_title = string_null;
1375         MapInfo_Map_titlestring = string_null;
1376         MapInfo_Map_description = string_null;
1377         MapInfo_Map_author = string_null;
1378         MapInfo_Map_clientstuff = string_null;
1379         MapInfo_Map_supportedGametypes = 0;
1380         MapInfo_Map_supportedFeatures = 0;
1381 }
1382
1383 void MapInfo_Shutdown()
1384 {
1385         MapInfo_ClearTemps();
1386         MapInfo_Filter_Free();
1387         MapInfo_Cache_Destroy();
1388         if(_MapInfo_globopen)
1389         {
1390                 search_end(_MapInfo_globhandle);
1391                 _MapInfo_globhandle = -1;
1392                 _MapInfo_globopen = false;
1393         }
1394 }
1395
1396 int MapInfo_ForbiddenFlags()
1397 {
1398         int f = MAPINFO_FLAG_FORBIDDEN;
1399
1400 #ifndef MENUQC
1401         if (!cvar("g_maplist_allow_hidden"))
1402 #endif
1403                 f |= MAPINFO_FLAG_HIDDEN;
1404
1405         if (!cvar("g_maplist_allow_frustrating"))
1406                 f |= MAPINFO_FLAG_FRUSTRATING;
1407
1408         return f;
1409 }
1410
1411 int MapInfo_RequiredFlags()
1412 {
1413         int f = 0;
1414
1415         if(cvar("g_maplist_allow_frustrating") > 1)
1416                 f |= MAPINFO_FLAG_FRUSTRATING;
1417
1418         return f;
1419 }