qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(!s) // empty string is NOT valid here!
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  57 }
  58
  59 float MapInfo_Cache_Retrieve(string map)
  60 {
  61         float i;
  62         string s;
  63         if(!_MapInfo_Cache_Active)
  64                 return 0;
  65
  66         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  67         if(!s)
  68                 return 0;
  69         i = stof(s);
  70
  71         // now retrieve all the stuff
  72         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  73         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  74         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  77         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  78         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         return 1;
  80 }
  81
  82 // GLOB HANDLING (for all BSP files)
  83 float _MapInfo_globopen;
  84 float _MapInfo_globcount;
  85 float _MapInfo_globhandle;
  86 string _MapInfo_GlobItem(float i)
  87 {
  88         string s;
  89         s = search_getfilename(_MapInfo_globhandle, i);
  90         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  91 }
  92
  93 void MapInfo_Enumerate()
  94 {
  95         if(_MapInfo_globopen)
  96                 search_end(_MapInfo_globhandle);
  97         MapInfo_Cache_Invalidate();
  98         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
  99         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 100         _MapInfo_globopen = 1;
 101 }
 102
 103 // filter the info by game type mask (updates MapInfo_count)
 104 //
 105 float _MapInfo_filtered;
 106 float _MapInfo_filtered_allocated;
 107 float MapInfo_FilterList_Lookup(float i)
 108 {
 109         return stof(bufstr_get(_MapInfo_filtered, i));
 110 }
 111
 112 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 113 {
 114         string h;
 115         h = bufstr_get(_MapInfo_filtered, i);
 116         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 117         bufstr_set(_MapInfo_filtered, j, h);
 118 }
 119
 120 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 121 {
 122         string a, b;
 123         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 124         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 125         return strcasecmp(a, b);
 126 }
 127
 128 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 129 {
 130         float i, j;
 131         if not(_MapInfo_filtered_allocated)
 132         {
 133                 _MapInfo_filtered_allocated = 1;
 134                 _MapInfo_filtered = buf_create();
 135         }
 136         MapInfo_count = 0;
 137         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 138         {
 139                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 140                         if(pAbortOnGenerate)
 141                         {
 142                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 143                                 MapInfo_progress = i / _MapInfo_globcount;
 144                                 return 0;
 145                         }
 146                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 147                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 148                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 149                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 150                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 151         }
 152         MapInfo_count = j + 1;
 153         MapInfo_ClearTemps();
 154
 155         // sometimes the glob isn't sorted nicely, so fix it here...
 156         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 157
 158         return 1;
 159 }
 160
 161 void MapInfo_Filter_Free()
 162 {
 163         if(_MapInfo_filtered_allocated)
 164         {
 165                 buf_del(_MapInfo_filtered);
 166                 _MapInfo_filtered_allocated = 0;
 167         }
 168 }
 169
 170 // load info about the i-th map into the MapInfo_Map_* globals
 171 string MapInfo_BSPName_ByID(float i)
 172 {
 173         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 174 }
 175
 176 string unquote(string s)
 177 {
 178         float i, j, l;
 179         l = strlen(s);
 180         j = -1;
 181         for(i = 0; i < l; ++i)
 182         {
 183                 string ch;
 184                 ch = substring(s, i, 1);
 185                 if(ch != " ") if(ch != "\"")
 186                 {
 187                         for(j = strlen(s) - i - 1; j > 0; --j)
 188                         {
 189                                 ch = substring(s, i+j, 1);
 190                                 if(ch != " ") if(ch != "\"")
 191                                         return substring(s, i, j+1);
 192                         }
 193                         return substring(s, i, 1);
 194                 }
 195         }
 196         return "";
 197 }
 198
 199 float MapInfo_Get_ByID(float i)
 200 {
 201         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 202                 return 1;
 203         return 0;
 204 }
 205
 206 string _MapInfo_Map_worldspawn_music;
 207
 208 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 209 {
 210         string fn;
 211         float fh;
 212         string s, k, v;
 213         vector o;
 214         float i;
 215         float inWorldspawn;
 216         float r;
 217         float twoBaseModes;
 218         float diameter, spawnpoints;
 219         float spawnplaces;
 220
 221         vector mapMins, mapMaxs;
 222
 223         r = 1;
 224         fn = strcat("maps/", pFilename, ".ent");
 225         fh = fopen(fn, FILE_READ);
 226         if(fh < 0)
 227         {
 228                 r = 2;
 229                 fn = strcat("maps/", pFilename, ".bsp");
 230                 fh = fopen(fn, FILE_READ);
 231         }
 232         if(fh < 0)
 233                 return 0;
 234         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 235
 236         inWorldspawn = 2;
 237         MapInfo_Map_flags = 0;
 238         MapInfo_Map_supportedGametypes = 0;
 239         spawnpoints = 0;
 240         spawnplaces = 0;
 241         _MapInfo_Map_worldspawn_music = "";
 242
 243         for(;;)
 244         {
 245                 if not((s = fgets(fh)))
 246                         break;
 247                 if(inWorldspawn == 1)
 248                         if(startsWith(s, "}"))
 249                                 inWorldspawn = 0;
 250                 k = unquote(car(s));
 251                 v = unquote(cdr(s));
 252                 if(inWorldspawn)
 253                 {
 254                         if(k == "classname" && v == "worldspawn")
 255                                 inWorldspawn = 1;
 256                         else if(k == "author")
 257                                 MapInfo_Map_author = v;
 258                         else if(k == "_description")
 259                                 MapInfo_Map_description = v;
 260                         else if(k == "music")
 261                                 _MapInfo_Map_worldspawn_music = v;
 262                         else if(k == "noise")
 263                                 _MapInfo_Map_worldspawn_music = v;
 264                         else if(k == "message")
 265                         {
 266                                 i = strstrofs(v, " by ", 0);
 267                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 268                                 {
 269                                         MapInfo_Map_title = substring(v, 0, i);
 270                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 271                                 }
 272                                 else
 273                                         MapInfo_Map_title = v;
 274                         }
 275                 }
 276                 else
 277                 {
 278                         if(k == "origin")
 279                         {
 280                                 o = stov(strcat("'", v, "'"));
 281                                 mapMins_x = min(mapMins_x, o_x);
 282                                 mapMins_y = min(mapMins_y, o_y);
 283                                 mapMins_z = min(mapMins_z, o_z);
 284                                 mapMaxs_x = max(mapMaxs_x, o_x);
 285                                 mapMaxs_y = max(mapMaxs_y, o_y);
 286                                 mapMaxs_z = max(mapMaxs_z, o_z);
 287                         }
 288                         else if(k == "race_place")
 289                         {
 290                                 if(stof(v) > 0)
 291                                         spawnplaces = 1;
 292                         }
 293                         else if(k == "classname")
 294                         {
 295                                 if(v == "dom_controlpoint")
 296                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 297                                 else if(v == "item_flag_team2")
 298                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 299                                 else if(v == "team_CTF_blueflag")
 300                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 301                                 else if(v == "runematch_spawn_point")
 302                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 303                                 else if(v == "target_assault_roundend")
 304                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 305                                 else if(v == "onslaught_generator")
 306                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 307                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 308                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 309                                 else if(v == "info_player_team1")
 310                                         ++spawnpoints;
 311                                 else if(v == "info_player_team2")
 312                                         ++spawnpoints;
 313                                 else if(v == "info_player_start")
 314                                         ++spawnpoints;
 315                                 else if(v == "info_player_deathmatch")
 316                                         ++spawnpoints;
 317                                 else if(v == "trigger_race_checkpoint")
 318                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 319                                 else if(v == "target_startTimer")
 320                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 321                                 else if(v == "weapon_nex")
 322                                         { }
 323                                 else if(v == "weapon_railgun")
 324                                         { }
 325                                 else if(startsWith(v, "weapon_"))
 326                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 327                                 else if(v == "target_music" || v == "trigger_music")
 328                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 329                         }
 330                 }
 331         }
 332         if(inWorldspawn)
 333         {
 334                 print(fn, " ended still in worldspawn, BUG\n");
 335                 return 0;
 336         }
 337         diameter = vlen(mapMaxs - mapMins);
 338
 339         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 340         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 341         {
 342                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 343                 // as the map is too symmetric for them.
 344         }
 345         else
 346         {
 347                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 348                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 349                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 350
 351                 if(spawnpoints >= 8  && diameter > 4096) {
 352                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 353                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 354                 }
 355                 if(                     diameter < 4096)
 356                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 357                 if(spawnpoints >= 12 && diameter > 5120)
 358                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 359         }
 360
 361         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 362         if(!spawnplaces)
 363         {
 364                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
 365                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 366         }
 367
 368         dprint("-> diameter ",    ftos(diameter));
 369         dprint(";  spawnpoints ", ftos(spawnpoints));
 370         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 371
 372         fclose(fh);
 373
 374         return r;
 375 }
 376
 377 void _MapInfo_Map_Reset()
 378 {
 379         MapInfo_Map_title = "<TITLE>";
 380         MapInfo_Map_description = "<DESCRIPTION>";
 381         MapInfo_Map_author = "<AUTHOR>";
 382         MapInfo_Map_supportedGametypes = 0;
 383         MapInfo_Map_supportedFeatures = 0;
 384         MapInfo_Map_flags = 0;
 385         MapInfo_Map_clientstuff = "";
 386         MapInfo_Map_fog = "";
 387         MapInfo_Map_mins = '0 0 0';
 388         MapInfo_Map_maxs = '0 0 0';
 389 }
 390
 391 string MapInfo_GetDefault(float t)
 392 {
 393         switch(t)
 394         {
 395                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 396                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 397                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 398                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 399                 case MAPINFO_TYPE_RUNEMATCH:       return "200 20 0";
 400                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 401                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
 402                 case MAPINFO_TYPE_CA:              return "10 20 0";
 403                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 404                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 405                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 406                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 407                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 408                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 409                 default:                           return "";
 410         }
 411 }
 412
 413 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 414 {
 415         string sa;
 416         MapInfo_Map_supportedGametypes |= pThisType;
 417         if(!(pThisType & pWantedType))
 418                 return;
 419
 420         if(load_default)
 421                 _MapInfo_Map_ApplyGametype(MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 422
 423         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 424         {
 425                 cvar_set("fraglimit", "0");
 426         }
 427         else
 428         {
 429                 sa = car(s);
 430                 if(sa != "")
 431                         cvar_set("fraglimit", sa);
 432                 s = cdr(s);
 433         }
 434
 435         sa = car(s);
 436         if(sa != "")
 437                 cvar_set("timelimit", sa);
 438         s = cdr(s);
 439
 440         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 441         {
 442                 sa = car(s);
 443                 if(sa != "")
 444                         cvar_set("g_tdm_teams", sa);
 445                 s = cdr(s);
 446         }
 447
 448         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 449         {
 450                 sa = car(s);
 451                 if(sa != "")
 452                         cvar_set("g_keyhunt_teams", sa);
 453                 s = cdr(s);
 454         }
 455
 456         if(pWantedType == MAPINFO_TYPE_CTF)
 457         {
 458                 sa = car(s);
 459                 if(sa != "")
 460                         if(cvar("g_ctf_win_mode") < 2)
 461                                 cvar_set("fraglimit", sa);
 462                 s = cdr(s);
 463         }
 464
 465         // rc = timelimit timelimit_qualification laps laps_teamplay
 466         if(pWantedType == MAPINFO_TYPE_RACE)
 467         {
 468                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 469                 cvar_set("g_race_qualifying_timelimit", sa);
 470                 s = cdr(s);
 471
 472                 sa = car(s);
 473                 if(sa != "")
 474                         if(cvar("g_race_teams") < 2)
 475                                 cvar_set("fraglimit", sa);
 476                 s = cdr(s);
 477
 478                 sa = car(s);
 479                 if(sa != "")
 480                         if(cvar("g_race_teams") >= 2)
 481                                 cvar_set("fraglimit", sa);
 482                 s = cdr(s);
 483         }
 484
 485         if(pWantedType == MAPINFO_TYPE_CTS)
 486         {
 487                 sa = car(s);
 488
 489                 // this is the skill of the map
 490                 // not parsed by anything yet
 491                 // for map databases
 492                 //if(sa != "")
 493                 //      cvar_set("fraglimit", sa);
 494
 495                 s = cdr(s);
 496         }
 497
 498         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 499         {
 500                 cvar_set("leadlimit", "0");
 501         }
 502         else
 503         {
 504                 sa = car(s);
 505                 if(sa != "")
 506                         cvar_set("leadlimit", sa);
 507                 s = cdr(s);
 508         }
 509 }
 510
 511 float MapInfo_Type_FromString(string t)
 512 {
 513         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
 514         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
 515         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
 516         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
 517         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
 518         else if(t == "lms")     return MAPINFO_TYPE_LMS;
 519         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
 520         else if(t == "ca")      return MAPINFO_TYPE_CA;
 521         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
 522         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
 523         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
 524         else if(t == "rc")      return MAPINFO_TYPE_RACE;
 525         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
 526         else if(t == "cts")     return MAPINFO_TYPE_CTS;
 527         else if(t == "all")     return MAPINFO_TYPE_ALL;
 528         else                    return 0;
 529 }
 530
 531 string MapInfo_Type_ToString(float t)
 532 {
 533         if     (t == MAPINFO_TYPE_DEATHMATCH)      return "dm";
 534         else if(t == MAPINFO_TYPE_TEAM_DEATHMATCH) return "tdm";
 535         else if(t == MAPINFO_TYPE_DOMINATION)      return "dom";
 536         else if(t == MAPINFO_TYPE_CTF)             return "ctf";
 537         else if(t == MAPINFO_TYPE_RUNEMATCH)       return "rune";
 538         else if(t == MAPINFO_TYPE_LMS)             return "lms";
 539         else if(t == MAPINFO_TYPE_ARENA)           return "arena";
 540         else if(t == MAPINFO_TYPE_CA)              return "ca";
 541         else if(t == MAPINFO_TYPE_KEYHUNT)         return "kh";
 542         else if(t == MAPINFO_TYPE_ASSAULT)         return "as";
 543         else if(t == MAPINFO_TYPE_ONSLAUGHT)       return "ons";
 544         else if(t == MAPINFO_TYPE_RACE)            return "rc";
 545         else if(t == MAPINFO_TYPE_NEXBALL)         return "nexball";
 546         else if(t == MAPINFO_TYPE_CTS)             return "cts";
 547         else if(t == MAPINFO_TYPE_ALL)             return "all";
 548         else                                       return "";
 549 }
 550
 551 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 552 {
 553         string t;
 554         float fh, o;
 555         t = car(s); s = cdr(s);
 556
 557         // limited support of "" and comments
 558         //   remove trailing and leading " of t
 559         if(substring(t, 0, 1) == "\"")
 560         {
 561                 if(substring(t, -1, 1) == "\"")
 562                         t = substring(t, 1, -2);
 563         }
 564
 565         //   remove leading " of s
 566         if(substring(s, 0, 1) == "\"")
 567         {
 568                 s = substring(s, 1, -1);
 569         }
 570         //   remove trailing " of s, and all that follows (cvar description)
 571         o = strstrofs(s, "\"", 0);
 572         if(o >= 0)
 573                 s = substring(s, 0, o);
 574
 575         //   remove // comments
 576         o = strstrofs(s, "//", 0);
 577         if(o >= 0)
 578                 s = substring(s, 0, o);
 579
 580         //   remove trailing spaces
 581         while(substring(s, -1, 1) == " ")
 582                 s = substring(s, 0, -2);
 583
 584         if(t == "#include")
 585         {
 586                 if(recurse > 0)
 587                 {
 588                         fh = fopen(s, FILE_READ);
 589                         if(fh < 0)
 590                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 591                         else
 592                         {
 593                                 for(;;)
 594                                 {
 595                                         if not((s = fgets(fh)))
 596                                                 break;
 597
 598                                         // catch different sorts of comments
 599                                         if(s == "")                    // empty lines
 600                                                 continue;
 601                                         if(substring(s, 0, 1) == "#")  // UNIX style
 602                                                 continue;
 603                                         if(substring(s, 0, 2) == "//") // C++ style
 604                                                 continue;
 605                                         if(substring(s, 0, 1) == "_")  // q3map style
 606                                                 continue;
 607
 608                                         if(substring(s, 0, 4) == "set ")
 609                                                 s = substring(s, 4, -1);
 610                                         if(substring(s, 0, 5) == "seta ")
 611                                                 s = substring(s, 5, -1);
 612
 613                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 614                                 }
 615                                 fclose(fh);
 616                         }
 617                 }
 618                 else
 619                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 620         }
 621         else if(t == "")
 622                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 623         else if not(cvar_value_issafe(t))
 624                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 625         else if not (cvar_value_issafe(s))
 626                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 627         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 628                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 629         else if(matchacl(acl, t) <= 0)
 630                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 631         else
 632         {
 633                 if(type == 0) // server set
 634                 {
 635                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 636                         if(cvar("g_campaign"))
 637                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 638                         else
 639                                 cvar_settemp(t, s);
 640                 }
 641                 else
 642                 {
 643                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 644                         MapInfo_Map_clientstuff = strcat(
 645                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 646                                         );
 647                 }
 648         }
 649 }
 650
 651 // load info about a map by name into the MapInfo_Map_* globals
 652 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 653 {
 654         string fn;
 655         string s, t;
 656         float fh, fh2;
 657         float r, f, n, i;
 658         string acl;
 659
 660         acl = MAPINFO_SETTEMP_ACL_USER;
 661
 662         if(strstrofs(pFilename, "/", 0) >= 0)
 663         {
 664                 print("Invalid character in map name, ignored\n");
 665                 return 0;
 666         }
 667
 668         if(pGametypeToSet == 0)
 669                 if(MapInfo_Cache_Retrieve(pFilename))
 670                         return 1;
 671
 672         r = 1;
 673
 674         MapInfo_Map_bspname = pFilename;
 675
 676         // default all generic fields so they have "good" values in case something fails
 677         fn = strcat("maps/", pFilename, ".mapinfo");
 678         fh = fopen(fn, FILE_READ);
 679         if(fh < 0)
 680         {
 681                 if(!pAllowGenerate)
 682                         return 0;
 683                 _MapInfo_Map_Reset();
 684                 r = _MapInfo_Generate(pFilename);
 685                 if(!r)
 686                         return 0;
 687                 fh = fopen(fn, FILE_WRITE);
 688                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 689                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 690                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 691                 if(_MapInfo_Map_worldspawn_music != "")
 692                 {
 693                         if(
 694                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 695                                 ||
 696                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 697                         )
 698                                 fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 699                         else
 700                                 fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 701                 }
 702                 else if(_MapInfo_Map_worldspawn_music)
 703                 {
 704                         n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 705                         s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 706                         for(;;)
 707                         {
 708                                 i = floor(random() * n);
 709                                 if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 710                                         break;
 711                         }
 712                         fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 713                 }
 714                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 715                         fputs(fh, "has weapons\n");
 716                 else
 717                         fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 718                 if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 719                         fputs(fh, "frustrating\n");
 720
 721                 for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 722                         if(MapInfo_Map_supportedGametypes & i)
 723                                 fputs(fh, sprintf("type %s %s\n", i, MapInfo_GetDefault(i)));
 724
 725                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 726                 if(fh2 >= 0)
 727                 {
 728                         fclose(fh2);
 729                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 730                 }
 731
 732                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 733                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 734                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 735                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 736                 fputs(fh, "// optional: hidden\n");
 737
 738                 fclose(fh);
 739                 r = 2;
 740                 // return r;
 741                 fh = fopen(fn, FILE_READ);
 742                 if(fh < 0)
 743                         error("... but I just wrote it!");
 744         }
 745
 746         _MapInfo_Map_Reset();
 747         for(;;)
 748         {
 749                 if not((s = fgets(fh)))
 750                         break;
 751
 752                 // catch different sorts of comments
 753                 if(s == "")                    // empty lines
 754                         continue;
 755                 if(substring(s, 0, 1) == "#")  // UNIX style
 756                         continue;
 757                 if(substring(s, 0, 2) == "//") // C++ style
 758                         continue;
 759                 if(substring(s, 0, 1) == "_")  // q3map style
 760                         continue;
 761
 762                 t = car(s); s = cdr(s);
 763                 if(t == "title")
 764                         MapInfo_Map_title = s;
 765                 else if(t == "description")
 766                         MapInfo_Map_description = s;
 767                 else if(t == "author")
 768                         MapInfo_Map_author = s;
 769                 else if(t == "has")
 770                 {
 771                         t = car(s); s = cdr(s);
 772                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 773                         else
 774                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 775                 }
 776                 else if(t == "hidden")
 777                 {
 778                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 779                 }
 780                 else if(t == "forbidden")
 781                 {
 782                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 783                 }
 784                 else if(t == "frustrating")
 785                 {
 786                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 787                 }
 788                 else if(t == "type")
 789                 {
 790                         t = car(s); s = cdr(s);
 791                         f = MapInfo_Type_FromString(t);
 792                         if(f)
 793                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
 794                         else
 795                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 796                 }
 797                 else if(t == "size")
 798                 {
 799                         float a, b, c, d, e;
 800                         t = car(s); s = cdr(s); a = stof(t);
 801                         t = car(s); s = cdr(s); b = stof(t);
 802                         t = car(s); s = cdr(s); c = stof(t);
 803                         t = car(s); s = cdr(s); d = stof(t);
 804                         t = car(s); s = cdr(s); e = stof(t);
 805                         if(s == "")
 806                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 807                         else
 808                         {
 809                                 t = car(s); s = cdr(s); f = stof(t);
 810                                 if(s != "")
 811                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 812                                 else
 813                                 {
 814                                         if(a >= d || b >= e || c >= f)
 815                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 816                                         else
 817                                         {
 818                                                 MapInfo_Map_mins_x = a;
 819                                                 MapInfo_Map_mins_y = b;
 820                                                 MapInfo_Map_mins_z = c;
 821                                                 MapInfo_Map_maxs_x = d;
 822                                                 MapInfo_Map_maxs_y = e;
 823                                                 MapInfo_Map_maxs_z = f;
 824                                         }
 825                                 }
 826                         }
 827                 }
 828                 else if(t == "settemp_for_type")
 829                 {
 830                         t = car(s); s = cdr(s);
 831                         if((f = MapInfo_Type_FromString(t)))
 832                         {
 833                                 if(f & pGametypeToSet)
 834                                 {
 835                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
 836                                 }
 837                         }
 838                         else
 839                         {
 840                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 841                         }
 842                 }
 843                 else if(t == "clientsettemp_for_type")
 844                 {
 845                         t = car(s); s = cdr(s);
 846                         if((f = MapInfo_Type_FromString(t)))
 847                         {
 848                                 if(f & pGametypeToSet)
 849                                 {
 850                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
 851                                 }
 852                         }
 853                         else
 854                         {
 855                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
 856                         }
 857                 }
 858                 else if(t == "fog")
 859                 {
 860                         if not(cvar_value_issafe(t))
 861                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
 862                         else
 863                                 MapInfo_Map_fog = s;
 864                 }
 865                 else if(t == "cdtrack")
 866                 {
 867                         if(pGametypeToSet)
 868                         {
 869                                 if not(cvar_value_issafe(t))
 870                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
 871                                 else
 872                                         MapInfo_Map_clientstuff = strcat(
 873                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
 874                                         );
 875                         }
 876                 }
 877                 else
 878                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 879         }
 880         fclose(fh);
 881
 882         if(pGametypeToSet)
 883         {
 884                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 885                 {
 886                         print("Can't select the requested game type. Trying anyway with stupid settings.\n");
 887                         _MapInfo_Map_ApplyGametype(MapInfo_GetDefault(MAPINFO_TYPE_DEATHMATCH), pGametypeToSet, MAPINFO_TYPE_DEATHMATCH, FALSE);
 888                 }
 889         }
 890
 891         MapInfo_Cache_Store();
 892         if(MapInfo_Map_supportedGametypes != 0)
 893                 return r;
 894         dprint("Map ", pFilename, " supports no game types, ignored\n");
 895         return 0;
 896 }
 897
 898 float MapInfo_FindName(string s)
 899 {
 900         // if there is exactly one map of prefix s, return it
 901         // if not, return the null string
 902         // note that DP sorts glob results... so I can use a binary search
 903         float l, r, m, cmp;
 904         l = 0;
 905         r = MapInfo_count;
 906         // invariants: r is behind s, l-1 is equal or before
 907         while(l != r)
 908         {
 909                 m = floor((l + r) / 2);
 910                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 911                 cmp = strcasecmp(MapInfo_FindName_match, s);
 912                 if(cmp == 0)
 913                         return m; // found and good
 914                 if(cmp < 0)
 915                         l = m + 1; // l-1 is before s
 916                 else
 917                         r = m; // behind s
 918         }
 919         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 920         MapInfo_FindName_firstResult = l;
 921         // r == l, so: l is behind s, l-1 is before
 922         // SO: if there is any, l is the one with the right prefix
 923         //     and l+1 may be one too
 924         if(l == MapInfo_count)
 925         {
 926                 MapInfo_FindName_match = string_null;
 927                 MapInfo_FindName_firstResult = -1;
 928                 return -1; // no MapInfo_FindName_match, behind last item
 929         }
 930         if(!startsWithNocase(MapInfo_FindName_match, s))
 931         {
 932                 MapInfo_FindName_match = string_null;
 933                 MapInfo_FindName_firstResult = -1;
 934                 return -1; // wrong prefix
 935         }
 936         if(l == MapInfo_count - 1)
 937                 return l; // last one, nothing can follow => unique
 938         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 939         {
 940                 MapInfo_FindName_match = string_null;
 941                 return -1; // ambigous MapInfo_FindName_match
 942         }
 943         return l;
 944 }
 945
 946 string MapInfo_FixName(string s)
 947 {
 948         MapInfo_FindName(s);
 949         return MapInfo_FindName_match;
 950 }
 951
 952 float MapInfo_CurrentFeatures()
 953 {
 954         float req;
 955         req = 0;
 956         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
 957                 req |= MAPINFO_FEATURE_WEAPONS;
 958         return req;
 959 }
 960
 961 float MapInfo_CurrentGametype()
 962 {
 963         if(cvar("g_domination"))
 964                 return MAPINFO_TYPE_DOMINATION;
 965         else if(cvar("g_ctf"))
 966                 return MAPINFO_TYPE_CTF;
 967         else if(cvar("g_runematch"))
 968                 return MAPINFO_TYPE_RUNEMATCH;
 969         else if(cvar("g_tdm"))
 970                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 971         else if(cvar("g_assault"))
 972                 return MAPINFO_TYPE_ASSAULT;
 973         else if(cvar("g_lms"))
 974                 return MAPINFO_TYPE_LMS;
 975         else if(cvar("g_arena"))
 976                 return MAPINFO_TYPE_ARENA;
 977         else if(cvar("g_ca"))
 978                 return MAPINFO_TYPE_CA;
 979         else if(cvar("g_keyhunt"))
 980                 return MAPINFO_TYPE_KEYHUNT;
 981         else if(cvar("g_onslaught"))
 982                 return MAPINFO_TYPE_ONSLAUGHT;
 983         else if(cvar("g_race"))
 984                 return MAPINFO_TYPE_RACE;
 985         else if(cvar("g_nexball"))
 986                 return MAPINFO_TYPE_NEXBALL;
 987         else if(cvar("g_cts"))
 988                 return MAPINFO_TYPE_CTS;
 989         else
 990                 return MAPINFO_TYPE_DEATHMATCH;
 991 }
 992
 993 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 994 {
 995         if(!MapInfo_Get_ByName(s, 1, 0))
 996                 return 0;
 997         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 998                 return 0;
 999         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1000                 return 0;
1001         return 1;
1002 }
1003
1004 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1005 {
1006         float r;
1007         r = _MapInfo_CheckMap(s);
1008         MapInfo_ClearTemps();
1009         return r;
1010 }
1011
1012 string MapInfo_GetGameTypeCvar(float t)
1013 {
1014         switch(t)
1015         {
1016                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
1017                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
1018                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
1019                 case MAPINFO_TYPE_CTF: return "g_ctf";
1020                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
1021                 case MAPINFO_TYPE_LMS: return "g_lms";
1022                 case MAPINFO_TYPE_ARENA: return "g_arena";
1023                 case MAPINFO_TYPE_CA: return "g_ca";
1024                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
1025                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
1026                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
1027                 case MAPINFO_TYPE_RACE: return "g_race";
1028                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
1029                 case MAPINFO_TYPE_CTS: return "g_cts";
1030                 default: return "";
1031         }
1032 }
1033
1034 void MapInfo_SwitchGameType(float t)
1035 {
1036         cvar_set("gamecfg",      "0");
1037         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
1038         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
1039         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
1040         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
1041         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
1042         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
1043         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
1044         cvar_set("g_ca",         (t == MAPINFO_TYPE_CA)              ? "1" : "0");
1045         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
1046         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
1047         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
1048         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
1049         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
1050         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
1051 }
1052
1053 void MapInfo_LoadMap(string s)
1054 {
1055         MapInfo_Map_supportedGametypes = 0;
1056         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1057         //if(!MapInfo_CheckMap(s))
1058         //{
1059         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1060         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1061         //}
1062         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1063 }
1064
1065 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1066 {
1067         string out;
1068         float i;
1069
1070         // to make absolutely sure:
1071         MapInfo_Enumerate();
1072         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1073
1074         out = "";
1075         for(i = 0; i < MapInfo_count; ++i)
1076                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1077         return substring(out, 1, strlen(out) - 1);
1078 }
1079
1080 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1081 {
1082         float t, t0;
1083         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1084         {
1085                 if(MapInfo_Map_supportedGametypes == 0)
1086                 {
1087                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1088                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1089                 }
1090
1091                 t = 1;
1092                 while(!(MapInfo_Map_supportedGametypes & 1))
1093                 {
1094                         t *= 2;
1095                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1096                 }
1097                 // t is now a supported mode!
1098                 t0 = MapInfo_CurrentGametype();
1099                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1100                 {
1101                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1102                         cvar_set("timelimit", "0");
1103                         cvar_set("fraglimit", "0");
1104                         cvar_set("g_tdm_teams", "2");
1105                         cvar_set("g_keyhunt_teams", "3");
1106                         cvar_set("g_race_qualifying_timelimit", "0");
1107                         cvar_set("leadlimit", "0");
1108                 }
1109                 else
1110                 {
1111                         print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1112                         MapInfo_SwitchGameType(t);
1113                 }
1114         }
1115         cvar_settemp_restore();
1116         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1117 }
1118
1119 void MapInfo_ClearTemps()
1120 {
1121         MapInfo_Map_bspname = string_null;
1122         MapInfo_Map_title = string_null;
1123         MapInfo_Map_description = string_null;
1124         MapInfo_Map_author = string_null;
1125         MapInfo_Map_clientstuff = string_null;
1126         MapInfo_Map_supportedGametypes = 0;
1127         MapInfo_Map_supportedFeatures = 0;
1128 }
1129
1130 void MapInfo_Shutdown()
1131 {
1132         MapInfo_ClearTemps();
1133         MapInfo_Filter_Free();
1134         MapInfo_Cache_Destroy();
1135         if(_MapInfo_globopen)
1136         {
1137                 search_end(_MapInfo_globhandle);
1138                 _MapInfo_globhandle = -1;
1139                 _MapInfo_globopen = FALSE;
1140         }
1141 }
1142
1143 float MapInfo_ForbiddenFlags()
1144 {
1145         float f;
1146         f = MAPINFO_FLAG_FORBIDDEN;
1147
1148 #ifndef MENUQC
1149         if not(cvar("g_maplist_allow_hidden"))
1150 #endif
1151                 f |= MAPINFO_FLAG_HIDDEN;
1152
1153         if not(cvar("g_maplist_allow_frustrating"))
1154                 f |= MAPINFO_FLAG_FRUSTRATING;
1155
1156         return f;
1157 }
1158
1159 float MapInfo_RequiredFlags()
1160 {
1161         float f;
1162         f = 0;
1163
1164         if(cvar("g_maplist_allow_frustrating") > 1)
1165                 f |= MAPINFO_FLAG_FRUSTRATING;
1166
1167         return f;
1168 }