qcsrc/common/mapinfo.qh

   1 #pragma once
   2
   3 bool autocvar_developer_mapper;
   4
   5 #define LOG_MAPWARN(...) MACRO_BEGIN { if (autocvar_developer_mapper) LOG_WARN(__VA_ARGS__); } MACRO_END
   6 #define LOG_MAPWARNF(...) MACRO_BEGIN { if (autocvar_developer_mapper) LOG_WARNF(__VA_ARGS__); } MACRO_END
   7
   8 #include "util.qh"
   9
  10 // info about a map that MapInfo loads
  11 string MapInfo_Map_bspname;
  12 string MapInfo_Map_title;
  13 string MapInfo_Map_titlestring; // either bspname: title or just title, depending on whether bspname is redundant
  14 string MapInfo_Map_description;
  15 string MapInfo_Map_author;
  16 string MapInfo_Map_clientstuff; // not in cache, only for map load
  17 string MapInfo_Map_fog; // not in cache, only for map load
  18 int MapInfo_Map_supportedGametypes;
  19 int MapInfo_Map_supportedFeatures;
  20 int MapInfo_Map_flags;
  21 vector MapInfo_Map_mins; // these are '0 0 0' if not supported!
  22 vector MapInfo_Map_maxs; // these are '0 0 0' if not specified!
  23
  24 int MAPINFO_TYPE_ALL;
  25 .int m_flags;
  26
  27 CLASS(Gametype, Object)
  28     ATTRIB(Gametype, m_id, int, 0);
  29     /** game type ID */
  30     ATTRIB(Gametype, items, int, 0);
  31     /** game type name as in cvar (with g_ prefix) */
  32     ATTRIB(Gametype, netname, string);
  33     /** game type short name */
  34     ATTRIB(Gametype, mdl, string);
  35     /** human readable name */
  36     ATTRIB(Gametype, message, string);
  37     /** does this gametype support teamplay? */
  38     ATTRIB(Gametype, team, bool, false);
  39     /** game type defaults */
  40     ATTRIB(Gametype, model2, string);
  41     /** game type description */
  42     ATTRIB(Gametype, gametype_description, string);
  43 #ifdef CSQC
  44     ATTRIB(Gametype, m_modicons, void(vector pos, vector mySize));
  45     ATTRIB(Gametype, m_modicons_reset, void());
  46 #endif
  47
  48     ATTRIB(Gametype, m_mutators, string);
  49     METHOD(Gametype, m_parse_mapinfo, bool(string k, string v))
  50     {
  51         return false;
  52     }
  53     METHOD(Gametype, m_generate_mapinfo, void(Gametype this, string v))
  54     {
  55         TC(Gametype, this);
  56     }
  57     METHOD(Gametype, m_isTwoBaseMode, bool())
  58     {
  59         return false;
  60     }
  61     METHOD(Gametype, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
  62     {
  63         return false;
  64     }
  65
  66     METHOD(Gametype, describe, string(Gametype this))
  67     {
  68         TC(Gametype, this);
  69         return this.gametype_description;
  70     }
  71
  72     METHOD(Gametype, display, void(Gametype this, void(string name, string icon) returns))
  73     {
  74         TC(Gametype, this);
  75         returns(this.message, strcat("gametype_", this.mdl));
  76     }
  77
  78     METHOD(Gametype, gametype_init, void(Gametype this, string hname, string sname, string g_name, bool gteamplay, string mutators, string defaults, string gdescription))
  79     {
  80         this.netname = g_name;
  81         this.mdl = sname;
  82         this.message = hname;
  83         this.team = gteamplay;
  84         this.m_mutators = cons(sname, mutators);
  85         this.model2 = defaults;
  86         this.gametype_description = gdescription;
  87
  88         // same as `1 << m_id`
  89         MAPINFO_TYPE_ALL |= this.items = this.m_flags = (MAPINFO_TYPE_ALL + 1);
  90     }
  91 ENDCLASS(Gametype)
  92
  93 REGISTRY(Gametypes, 24)
  94 #define Gametypes_from(i) _Gametypes_from(i, NULL)
  95 REGISTER_REGISTRY(Gametypes)
  96 REGISTRY_CHECK(Gametypes)
  97 #define REGISTER_GAMETYPE(NAME, inst) REGISTER(Gametypes, MAPINFO_TYPE, NAME, m_id, inst)
  98
  99 #define IS_GAMETYPE(NAME) (MapInfo_LoadedGametype == MAPINFO_TYPE_##NAME)
 100
 101 CLASS(Deathmatch, Gametype)
 102     INIT(Deathmatch)
 103     {
 104         this.gametype_init(this, _("Deathmatch"),"dm","g_dm",false,"","timelimit=20 pointlimit=30 leadlimit=0",_("Score as many frags as you can"));
 105     }
 106     METHOD(Deathmatch, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 107     {
 108         return true;
 109     }
 110 ENDCLASS(Deathmatch)
 111 REGISTER_GAMETYPE(DEATHMATCH, NEW(Deathmatch));
 112
 113 CLASS(LastManStanding, Gametype)
 114     INIT(LastManStanding)
 115     {
 116         this.gametype_init(this, _("Last Man Standing"),"lms","g_lms",false,"","timelimit=20 lives=9 leadlimit=0",_("Survive and kill until the enemies have no lives left"));
 117     }
 118     METHOD(LastManStanding, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 119     {
 120         return true;
 121     }
 122 ENDCLASS(LastManStanding)
 123 REGISTER_GAMETYPE(LMS, NEW(LastManStanding));
 124
 125 #ifdef CSQC
 126 void HUD_Mod_Race(vector pos, vector mySize);
 127 #endif
 128 CLASS(Race, Gametype)
 129     INIT(Race)
 130     {
 131         this.gametype_init(this, _("Race"),"rc","g_race",false,"","timelimit=20 qualifying_timelimit=5 laplimit=7 teamlaplimit=15 leadlimit=0",_("Race against other players to the finish line"));
 132     }
 133     METHOD(Race, m_parse_mapinfo, bool(string k, string v))
 134     {
 135         if (!k) {
 136             cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 137             return true;
 138         }
 139         switch (k) {
 140             case "qualifying_timelimit":
 141                 cvar_set("g_race_qualifying_timelimit", v);
 142                 return true;
 143         }
 144         return false;
 145     }
 146     METHOD(Race, m_generate_mapinfo, void(Gametype this, string v))
 147     {
 148         if(v == "trigger_race_checkpoint")
 149             MapInfo_Map_supportedGametypes |= this.m_flags;
 150     }
 151     METHOD(Race, m_isTwoBaseMode, bool())
 152     {
 153         return true;
 154     }
 155 #ifdef CSQC
 156     ATTRIB(Race, m_modicons, void(vector pos, vector mySize), HUD_Mod_Race);
 157 #endif
 158 ENDCLASS(Race)
 159 REGISTER_GAMETYPE(RACE, NEW(Race));
 160 #define g_race IS_GAMETYPE(RACE)
 161
 162 CLASS(RaceCTS, Gametype)
 163     INIT(RaceCTS)
 164     {
 165         this.gametype_init(this, _("Race CTS"),"cts","g_cts",false,"cloaked","timelimit=20",_("Race for fastest time."));
 166     }
 167     METHOD(RaceCTS, m_generate_mapinfo, void(Gametype this, string v))
 168     {
 169         if(v == "target_startTimer")
 170             MapInfo_Map_supportedGametypes |= this.m_flags;
 171     }
 172 #ifdef CSQC
 173     ATTRIB(RaceCTS, m_modicons, void(vector pos, vector mySize), HUD_Mod_Race);
 174 #endif
 175 ENDCLASS(RaceCTS)
 176 REGISTER_GAMETYPE(CTS, NEW(RaceCTS));
 177 #define g_cts IS_GAMETYPE(CTS)
 178
 179 CLASS(TeamDeathmatch, Gametype)
 180     INIT(TeamDeathmatch)
 181     {
 182         this.gametype_init(this, _("Team Deathmatch"),"tdm","g_tdm",true,"","timelimit=20 pointlimit=50 teams=2 leadlimit=0",_("Help your team score the most frags against the enemy team"));
 183     }
 184     METHOD(TeamDeathmatch, m_parse_mapinfo, bool(string k, string v))
 185     {
 186         if (!k) {
 187             cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 188             return true;
 189         }
 190         switch (k) {
 191             case "teams":
 192                 cvar_set("g_tdm_teams", v);
 193                 return true;
 194         }
 195         return false;
 196     }
 197     METHOD(TeamDeathmatch, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 198     {
 199         if(spawnpoints >= 8 && diameter > 4096)
 200             return true;
 201         return false;
 202     }
 203 ENDCLASS(TeamDeathmatch)
 204 REGISTER_GAMETYPE(TEAM_DEATHMATCH, NEW(TeamDeathmatch));
 205 #define g_tdm IS_GAMETYPE(TEAM_DEATHMATCH)
 206
 207 #ifdef CSQC
 208 void HUD_Mod_CTF(vector pos, vector mySize);
 209 void HUD_Mod_CTF_Reset();
 210 #endif
 211 CLASS(CaptureTheFlag, Gametype)
 212     INIT(CaptureTheFlag)
 213     {
 214         this.gametype_init(this, _("Capture the Flag"),"ctf","g_ctf",true,"","timelimit=20 caplimit=10 leadlimit=6",_("Find and bring the enemy flag to your base to capture it, defend your base from the other team"));
 215     }
 216     METHOD(CaptureTheFlag, m_generate_mapinfo, void(Gametype this, string v))
 217     {
 218         if(v == "item_flag_team2" || v == "team_CTF_blueflag")
 219             MapInfo_Map_supportedGametypes |= this.m_flags;
 220     }
 221     METHOD(CaptureTheFlag, m_isTwoBaseMode, bool())
 222     {
 223         return true;
 224     }
 225 #ifdef CSQC
 226     ATTRIB(CaptureTheFlag, m_modicons, void(vector pos, vector mySize), HUD_Mod_CTF);
 227     ATTRIB(CaptureTheFlag, m_modicons_reset, void(), HUD_Mod_CTF_Reset);
 228 #endif
 229 ENDCLASS(CaptureTheFlag)
 230 REGISTER_GAMETYPE(CTF, NEW(CaptureTheFlag));
 231 #define g_ctf IS_GAMETYPE(CTF)
 232
 233 #ifdef CSQC
 234 void HUD_Mod_CA(vector pos, vector mySize);
 235 #endif
 236 CLASS(ClanArena, Gametype)
 237     INIT(ClanArena)
 238     {
 239         this.gametype_init(this, _("Clan Arena"),"ca","g_ca",true,"","timelimit=20 pointlimit=10 teams=2 leadlimit=0",_("Kill all enemy teammates to win the round"));
 240     }
 241     METHOD(ClanArena, m_parse_mapinfo, bool(string k, string v))
 242     {
 243         if (!k) {
 244             cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 245             return true;
 246         }
 247         switch (k) {
 248             case "teams":
 249                 cvar_set("g_ca_teams", v);
 250                 return true;
 251         }
 252         return false;
 253     }
 254     METHOD(ClanArena, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 255     {
 256         if(spawnpoints >= 8 && diameter > 4096)
 257             return true;
 258         return false;
 259     }
 260 #ifdef CSQC
 261     ATTRIB(ClanArena, m_modicons, void(vector pos, vector mySize), HUD_Mod_CA);
 262 #endif
 263 ENDCLASS(ClanArena)
 264 REGISTER_GAMETYPE(CA, NEW(ClanArena));
 265 #define g_ca IS_GAMETYPE(CA)
 266
 267 #ifdef CSQC
 268 void HUD_Mod_Dom(vector pos, vector mySize);
 269 #endif
 270 CLASS(Domination, Gametype)
 271     INIT(Domination)
 272     {
 273         this.gametype_init(this, _("Domination"),"dom","g_domination",true,"","timelimit=20 pointlimit=200 teams=2 leadlimit=0",_("Capture and defend all the control points to win"));
 274     }
 275     METHOD(Domination, m_parse_mapinfo, bool(string k, string v))
 276     {
 277         if (!k) {
 278             cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 279             return true;
 280         }
 281         switch (k) {
 282             case "teams":
 283                 cvar_set("g_domination_default_teams", v);
 284                 return true;
 285         }
 286         return false;
 287     }
 288     METHOD(Domination, m_generate_mapinfo, void(Gametype this, string v))
 289     {
 290         if(v == "dom_controlpoint")
 291             MapInfo_Map_supportedGametypes |= this.m_flags;
 292     }
 293 #ifdef CSQC
 294     ATTRIB(Domination, m_modicons, void(vector pos, vector mySize), HUD_Mod_Dom);
 295 #endif
 296 ENDCLASS(Domination)
 297 REGISTER_GAMETYPE(DOMINATION, NEW(Domination));
 298
 299 #ifdef CSQC
 300 void HUD_Mod_KH(vector pos, vector mySize);
 301 #endif
 302 CLASS(KeyHunt, Gametype)
 303     INIT(KeyHunt)
 304     {
 305         this.gametype_init(this, _("Key Hunt"),"kh","g_keyhunt",true,"","timelimit=20 pointlimit=1000 teams=3 leadlimit=0",_("Gather all the keys to win the round"));
 306     }
 307     METHOD(KeyHunt, m_parse_mapinfo, bool(string k, string v))
 308     {
 309         if (!k) {
 310             cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 311             return true;
 312         }
 313         switch (k) {
 314             case "teams":
 315                 cvar_set("g_keyhunt_teams", v);
 316                 return true;
 317         }
 318         return false;
 319     }
 320     METHOD(KeyHunt, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 321     {
 322         if(spawnpoints >= 12 && diameter > 5120)
 323             return true;
 324         return false;
 325     }
 326 #ifdef CSQC
 327     ATTRIB(KeyHunt, m_modicons, void(vector pos, vector mySize), HUD_Mod_KH);
 328 #endif
 329 ENDCLASS(KeyHunt)
 330 REGISTER_GAMETYPE(KEYHUNT, NEW(KeyHunt));
 331
 332 CLASS(Assault, Gametype)
 333     INIT(Assault)
 334     {
 335         this.gametype_init(this, _("Assault"),"as","g_assault",true,"","timelimit=20",_("Destroy obstacles to find and destroy the enemy power core before time runs out"));
 336     }
 337     METHOD(Assault, m_generate_mapinfo, void(Gametype this, string v))
 338     {
 339         if(v == "target_assault_roundend")
 340             MapInfo_Map_supportedGametypes |= this.m_flags;
 341     }
 342     METHOD(Assault, m_isTwoBaseMode, bool())
 343     {
 344         return true;
 345     }
 346 ENDCLASS(Assault)
 347 REGISTER_GAMETYPE(ASSAULT, NEW(Assault));
 348 #define g_assault IS_GAMETYPE(ASSAULT)
 349
 350 CLASS(Onslaught, Gametype)
 351     INIT(Onslaught)
 352     {
 353         this.gametype_init(this, _("Onslaught"),"ons","g_onslaught",true,"","pointlimit=1 timelimit=20",_("Capture control points to reach and destroy the enemy generator"));
 354     }
 355     METHOD(Onslaught, m_generate_mapinfo, void(Gametype this, string v))
 356     {
 357         if(v == "onslaught_generator")
 358             MapInfo_Map_supportedGametypes |= this.m_flags;
 359     }
 360 ENDCLASS(Onslaught)
 361 REGISTER_GAMETYPE(ONSLAUGHT, NEW(Onslaught));
 362
 363 #ifdef CSQC
 364 void HUD_Mod_NexBall(vector pos, vector mySize);
 365 #endif
 366 CLASS(NexBall, Gametype)
 367     INIT(NexBall)
 368     {
 369         this.gametype_init(this, _("Nexball"),"nb","g_nexball",true,"","timelimit=20 pointlimit=5 leadlimit=0",_("Shoot and kick the ball into the enemies goal, keep your goal clean"));
 370     }
 371     METHOD(NexBall, m_generate_mapinfo, void(Gametype this, string v))
 372     {
 373         if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 374             MapInfo_Map_supportedGametypes |= this.m_flags;
 375     }
 376     METHOD(NexBall, m_isTwoBaseMode, bool())
 377     {
 378         return true;
 379     }
 380 #ifdef CSQC
 381     ATTRIB(NexBall, m_modicons, void(vector pos, vector mySize), HUD_Mod_NexBall);
 382 #endif
 383 ENDCLASS(NexBall)
 384 REGISTER_GAMETYPE(NEXBALL, NEW(NexBall));
 385 #define g_nexball IS_GAMETYPE(NEXBALL)
 386
 387 CLASS(FreezeTag, Gametype)
 388     INIT(FreezeTag)
 389     {
 390         this.gametype_init(this, _("Freeze Tag"),"ft","g_freezetag",true,"","timelimit=20 pointlimit=10 teams=2 leadlimit=0",_("Kill enemies to freeze them, stand next to teammates to revive them, freeze the most enemies to win"));
 391     }
 392     METHOD(FreezeTag, m_parse_mapinfo, bool(string k, string v))
 393     {
 394         if (!k) {
 395             cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 396             return true;
 397         }
 398         switch (k) {
 399             case "teams":
 400                 cvar_set("g_freezetag_teams", v);
 401                 return true;
 402         }
 403         return false;
 404     }
 405     METHOD(FreezeTag, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 406     {
 407         if(spawnpoints >= 8 && diameter > 4096)
 408             return true;
 409         return false;
 410     }
 411 #ifdef CSQC
 412     ATTRIB(FreezeTag, m_modicons, void(vector pos, vector mySize), HUD_Mod_CA);
 413 #endif
 414 ENDCLASS(FreezeTag)
 415 REGISTER_GAMETYPE(FREEZETAG, NEW(FreezeTag));
 416 #define g_freezetag IS_GAMETYPE(FREEZETAG)
 417
 418 #ifdef CSQC
 419 void HUD_Mod_Keepaway(vector pos, vector mySize);
 420 #endif
 421 CLASS(Keepaway, Gametype)
 422     INIT(Keepaway)
 423     {
 424         this.gametype_init(this, _("Keepaway"),"ka","g_keepaway",true,"","timelimit=20 pointlimit=30",_("Hold the ball to get points for kills"));
 425     }
 426     METHOD(Keepaway, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 427     {
 428         return true;
 429     }
 430 #ifdef CSQC
 431     ATTRIB(Keepaway, m_modicons, void(vector pos, vector mySize), HUD_Mod_Keepaway);
 432 #endif
 433 ENDCLASS(Keepaway)
 434 REGISTER_GAMETYPE(KEEPAWAY, NEW(Keepaway));
 435
 436 CLASS(Invasion, Gametype)
 437     INIT(Invasion)
 438     {
 439         this.gametype_init(this, _("Invasion"),"inv","g_invasion",false,"","pointlimit=50 teams=0",_("Survive against waves of monsters"));
 440     }
 441     METHOD(Invasion, m_parse_mapinfo, bool(string k, string v))
 442     {
 443         switch (k) {
 444             case "teams":
 445                 cvar_set("g_invasion_teams", v);
 446                 return true;
 447         }
 448         return false;
 449     }
 450     METHOD(Invasion, m_generate_mapinfo, void(Gametype this, string v))
 451     {
 452         if(v == "invasion_spawnpoint")
 453             MapInfo_Map_supportedGametypes |= this.m_flags;
 454     }
 455 ENDCLASS(Invasion)
 456 REGISTER_GAMETYPE(INVASION, NEW(Invasion));
 457
 458 const int MAPINFO_FEATURE_WEAPONS       = 1; // not defined for instagib-only maps
 459 const int MAPINFO_FEATURE_VEHICLES      = 2;
 460 const int MAPINFO_FEATURE_TURRETS       = 4;
 461 const int MAPINFO_FEATURE_MONSTERS      = 8;
 462
 463 const int MAPINFO_FLAG_HIDDEN           = 1; // not in lsmaps/menu/vcall/etc., can just be changed to manually
 464 const int MAPINFO_FLAG_FORBIDDEN        = 2; // don't even allow the map by a cvar setting that allows hidden maps
 465 const int MAPINFO_FLAG_FRUSTRATING      = 4; // this map is near impossible to play, enable at your own risk
 466 const int MAPINFO_FLAG_NOAUTOMAPLIST    = 8; // do not include when automatically building maplist (counts as hidden for maplist building purposes)
 467
 468 float MapInfo_count;
 469
 470 // load MapInfo_count; generate mapinfo for maps that miss them, and clear the
 471 // cache; you need to call MapInfo_FilterGametype afterwards!
 472 void MapInfo_Enumerate();
 473
 474 // filter the info by game type mask (updates MapInfo_count)
 475 float MapInfo_progress;
 476 float MapInfo_FilterGametype(Gametype gametypeFlags, float features, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate); // 1 on success, 0 on temporary failure (call it again next frame then; use MapInfo_progress as progress indicator)
 477 float _MapInfo_FilterGametype(int gametypeFlags, float features, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate); // 1 on success, 0 on temporary failure (call it again next frame then; use MapInfo_progress as progress indicator)
 478 void MapInfo_FilterString(string sf); // filter _MapInfo_filtered (created by MapInfo_FilterGametype) with keyword
 479 int MapInfo_CurrentFeatures(); // retrieves currently required features from cvars
 480 Gametype MapInfo_CurrentGametype(); // retrieves current gametype from cvars
 481 int MapInfo_ForbiddenFlags(); // retrieves current flags from cvars
 482 int MapInfo_RequiredFlags(); // retrieves current flags from cvars
 483
 484 // load info about the i-th map into the MapInfo_Map_* globals
 485 float MapInfo_Get_ByID(float i); // 1 on success, 0 on failure
 486 string MapInfo_BSPName_ByID(float i);
 487
 488 // load info about a map by name into the MapInfo_Map_* globals
 489 int MapInfo_Get_ByName(string s, float allowGenerate, Gametype gametypeToSet); // 1 on success, 0 on failure, 2 if it autogenerated a mapinfo file
 490
 491 // look for a map by a prefix, returns the actual map name on success, string_null on failure or ambigous match
 492 string MapInfo_FindName_match; // the name of the map that was found
 493 float MapInfo_FindName_firstResult; // -1 if none were found, index of first one if not unique but found (FindName then returns -1)
 494 float MapInfo_FindName(string s);
 495 string MapInfo_FixName(string s);
 496
 497 // play a map
 498 float MapInfo_CheckMap(string s); // returns 0 if the map can't be played with the current settings
 499 void MapInfo_LoadMap(string s, float reinit);
 500
 501 // list all maps for the current game type
 502 string MapInfo_ListAllowedMaps(Gametype type, float pFlagsRequired, float pFlagsForbidden);
 503 // list all allowed maps (for any game type)
 504 string MapInfo_ListAllAllowedMaps(float pFlagsRequired, float pFlagsForbidden);
 505
 506 // gets a gametype from a string
 507 string _MapInfo_GetDefaultEx(Gametype t);
 508 float _MapInfo_GetTeamPlayBool(Gametype t);
 509 Gametype MapInfo_Type_FromString(string t);
 510 string MapInfo_Type_Description(Gametype t);
 511 string MapInfo_Type_ToString(Gametype t);
 512 string MapInfo_Type_ToText(Gametype t);
 513 void MapInfo_SwitchGameType(Gametype t);
 514
 515 // to be called from worldspawn to set up cvars
 516 void MapInfo_LoadMapSettings(string s);
 517 Gametype MapInfo_LoadedGametype; // game type that was active during map load
 518
 519 void MapInfo_Cache_Destroy(); // disable caching
 520 void MapInfo_Cache_Create(); // enable caching
 521 void MapInfo_Cache_Invalidate(); // delete cache if any, but keep enabled
 522
 523 void MapInfo_ClearTemps(); // call this when done with mapinfo for this frame
 524
 525 void MapInfo_Shutdown(); // call this in the shutdown handler
 526
 527 #define MAPINFO_SETTEMP_ACL_USER cvar_string("g_mapinfo_settemp_acl")
 528 #define MAPINFO_SETTEMP_ACL_SYSTEM "-g_mapinfo_* -rcon_* -_* -g_ban* +*"