qcsrc/common/mapobjects/func/breakable.qc

   1 #include "breakable.qh"
   2 #ifdef SVQC
   3
   4 #include <server/g_damage.qh>
   5 #include <server/bot/api.qh>
   6 #include <common/csqcmodel_settings.qh>
   7 #include <lib/csqcmodel/sv_model.qh>
   8 #include <server/weapons/common.qh>
   9
  10 .entity sprite;
  11
  12 .float dmg;
  13 .float dmg_edge;
  14 .float dmg_radius;
  15 .float dmg_force;
  16 .float debrismovetype;
  17 .float debrissolid;
  18 .vector debrisvelocity;
  19 .vector debrisvelocityjitter;
  20 .vector debrisavelocityjitter;
  21 .float debristime;
  22 .float debristimejitter;
  23 .float debrisfadetime;
  24 .float debrisdamageforcescale;
  25 .float debrisskin;
  26
  27 .string mdl_dead; // or "" to hide when broken
  28 .string debris; // space separated list of debris models
  29 // other fields:
  30 //   mdl = particle effect name
  31 //   count = particle effect multiplier
  32 //   targetname = target to trigger to unbreak the model
  33 //   target = targets to trigger when broken
  34 //   health = amount of damage it can take
  35 //   spawnflags:
  36 //     START_DISABLED: needs to be triggered to activate
  37 //     BREAKABLE_INDICATE_DAMAGE: indicate damage
  38 //     BREAKABLE_NODAMAGE: don't take direct damage (needs to be triggered to 'explode', then triggered again to restore)
  39 //     NOSPLASH: don't take splash damage
  40 // notes:
  41 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  42 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  43 //   want that!
  44
  45 void func_breakable_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force);
  46
  47 //
  48 // func_breakable
  49 // - basically func_assault_destructible for general gameplay use
  50 //
  51 void LaunchDebris (entity this, string debrisname, vector force)
  52 {
  53         entity dbr = spawn();
  54         vector org = this.absmin
  55                    + '1 0 0' * random() * (this.absmax.x - this.absmin.x)
  56                    + '0 1 0' * random() * (this.absmax.y - this.absmin.y)
  57                    + '0 0 1' * random() * (this.absmax.z - this.absmin.z);
  58         setorigin(dbr, org);
  59         _setmodel (dbr, debrisname );
  60         dbr.skin = this.debrisskin;
  61         dbr.colormap = this.colormap; // inherit team colors
  62         dbr.owner = this; // do not be affected by our own explosion
  63         set_movetype(dbr, this.debrismovetype);
  64         dbr.solid = this.debrissolid;
  65         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  66                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  67         dbr.velocity_x = this.debrisvelocity.x + this.debrisvelocityjitter.x * crandom();
  68         dbr.velocity_y = this.debrisvelocity.y + this.debrisvelocityjitter.y * crandom();
  69         dbr.velocity_z = this.debrisvelocity.z + this.debrisvelocityjitter.z * crandom();
  70         dbr.velocity = dbr.velocity + force * this.debrisdamageforcescale;
  71         dbr.angles = this.angles;
  72         dbr.avelocity_x = random()*this.debrisavelocityjitter.x;
  73         dbr.avelocity_y = random()*this.debrisavelocityjitter.y;
  74         dbr.avelocity_z = random()*this.debrisavelocityjitter.z;
  75         dbr.damageforcescale = this.debrisdamageforcescale;
  76         if(dbr.damageforcescale)
  77                 dbr.takedamage = DAMAGE_YES;
  78         SUB_SetFade(dbr, time + this.debristime + crandom() * this.debristimejitter, this.debrisfadetime);
  79 }
  80
  81 void func_breakable_colormod(entity this)
  82 {
  83         float h;
  84         if (!(this.spawnflags & BREAKABLE_INDICATE_DAMAGE))
  85                 return;
  86         h = GetResource(this, RES_HEALTH) / this.max_health;
  87         if(h < 0.25)
  88                 this.colormod = '1 0 0';
  89         else if(h <= 0.75)
  90                 this.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  91         else
  92                 this.colormod = '1 1 1';
  93 }
  94
  95 void func_breakable_look_destroyed(entity this)
  96 {
  97         float floorZ;
  98
  99         if(this.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
 100                 this.dropped_origin = this.origin;
 101
 102         if(this.mdl_dead == "")
 103                 this.effects |= EF_NODRAW;
 104         else {
 105                 if (this.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
 106                         floorZ = this.absmin.z;
 107                         setorigin(this, ((this.absmax + this.absmin) * 0.5));
 108                         this.origin_z = floorZ;
 109                 }
 110                 _setmodel(this, this.mdl_dead);
 111                 ApplyMinMaxScaleAngles(this);
 112                 this.effects &= ~EF_NODRAW;
 113         }
 114
 115         this.solid = SOLID_NOT;
 116 }
 117
 118 void func_breakable_look_restore(entity this)
 119 {
 120         _setmodel(this, this.mdl);
 121         ApplyMinMaxScaleAngles(this);
 122         this.effects &= ~EF_NODRAW;
 123
 124         if(this.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 125                 setorigin(this, this.dropped_origin);
 126
 127         this.solid = SOLID_BSP;
 128 }
 129
 130 void func_breakable_behave_destroyed(entity this)
 131 {
 132         SetResourceExplicit(this, RES_HEALTH, this.max_health);
 133         this.takedamage = DAMAGE_NO;
 134         if(this.bot_attack)
 135                 IL_REMOVE(g_bot_targets, this);
 136         this.bot_attack = false;
 137         this.event_damage = func_null;
 138         this.state = STATE_BROKEN;
 139         if(this.spawnflags & BREAKABLE_NODAMAGE)
 140                 this.use = func_null;
 141         func_breakable_colormod(this);
 142         if (this.noise1)
 143                 stopsound (this, CH_TRIGGER_SINGLE);
 144
 145         IL_EACH(g_projectiles, it.classname == "grapplinghook" && it.aiment == this,
 146         {
 147                 RemoveHook(it);
 148         });
 149 }
 150
 151 void func_breakable_think(entity this)
 152 {
 153         this.nextthink = time;
 154         CSQCMODEL_AUTOUPDATE(this);
 155 }
 156
 157 void func_breakable_destroy(entity this, entity actor, entity trigger);
 158 void func_breakable_behave_restore(entity this)
 159 {
 160         SetResourceExplicit(this, RES_HEALTH, this.max_health);
 161         if(this.sprite)
 162         {
 163                 WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
 164                 WaypointSprite_UpdateHealth(this.sprite, GetResource(this, RES_HEALTH));
 165         }
 166         if(!(this.spawnflags & BREAKABLE_NODAMAGE))
 167         {
 168                 this.takedamage = DAMAGE_AIM;
 169                 if(!this.bot_attack)
 170                         IL_PUSH(g_bot_targets, this);
 171                 this.bot_attack = true;
 172                 this.event_damage = func_breakable_damage;
 173         }
 174         if(this.spawnflags & BREAKABLE_NODAMAGE)
 175                 this.use = func_breakable_destroy; // don't need to set it usually, as .use isn't reset
 176         this.state = STATE_ALIVE;
 177         //this.nextthink = 0; // cancel auto respawn
 178         setthink(this, func_breakable_think);
 179         this.nextthink = time + 0.1;
 180         func_breakable_colormod(this);
 181         if (this.noise1)
 182                 _sound (this, CH_TRIGGER_SINGLE, this.noise1, VOL_BASE, ATTEN_NORM);
 183 }
 184
 185 void func_breakable_init_for_player(entity this, entity player)
 186 {
 187         if (this.noise1 && this.state == STATE_ALIVE && IS_REAL_CLIENT(player))
 188         {
 189                 msg_entity = player;
 190                 soundto (MSG_ONE, this, CH_TRIGGER_SINGLE, this.noise1, VOL_BASE, ATTEN_NORM);
 191         }
 192 }
 193
 194 void func_breakable_destroyed(entity this)
 195 {
 196         func_breakable_look_destroyed(this);
 197         func_breakable_behave_destroyed(this);
 198 }
 199
 200 void func_breakable_restore(entity this, entity actor, entity trigger)
 201 {
 202         func_breakable_look_restore(this);
 203         func_breakable_behave_restore(this);
 204 }
 205
 206 void func_breakable_restore_self(entity this)
 207 {
 208         // TODO: use a clipgroup for all func_breakables so they don't collide with eachother
 209         float oldhit = this.dphitcontentsmask;
 210         this.dphitcontentsmask = DPCONTENTS_BODY; // we really only care about when players are standing inside, obey the mapper in other cases!
 211         tracebox(this.origin, this.mins, this.maxs, this.origin, MOVE_NORMAL, this);
 212         this.dphitcontentsmask = oldhit;
 213         if(trace_startsolid || trace_fraction < 1)
 214         {
 215                 this.nextthink = time + 5; // retry every 5 seconds until the area becomes clear
 216                 return;
 217         }
 218         func_breakable_restore(this, NULL, NULL);
 219 }
 220
 221 vector debrisforce; // global, set before calling this
 222 void func_breakable_destroy(entity this, entity actor, entity trigger)
 223 {
 224         float n, i;
 225         string oldmsg;
 226
 227         entity act = this.owner;
 228         this.owner = NULL; // set by W_PrepareExplosionByDamage
 229
 230         // now throw around the debris
 231         n = tokenize_console(this.debris);
 232         for(i = 0; i < n; ++i)
 233                 LaunchDebris(this, argv(i), debrisforce);
 234
 235         func_breakable_destroyed(this);
 236
 237         if(this.noise)
 238                 _sound (this, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 239
 240         if(this.dmg)
 241                 RadiusDamage(this, act, this.dmg, this.dmg_edge, this.dmg_radius, this, NULL, this.dmg_force, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, NULL);
 242
 243         if(this.cnt) // TODO
 244                 __pointparticles(this.cnt, this.absmin * 0.5 + this.absmax * 0.5, '0 0 0', this.count);
 245
 246         if(this.respawntime)
 247         {
 248                 CSQCMODEL_AUTOUPDATE(this);
 249                 setthink(this, func_breakable_restore_self);
 250                 this.nextthink = time + this.respawntime + crandom() * this.respawntimejitter;
 251         }
 252
 253         oldmsg = this.message;
 254         this.message = "";
 255         SUB_UseTargets(this, act, trigger);
 256         this.message = oldmsg;
 257 }
 258
 259 void func_breakable_destroy_self(entity this)
 260 {
 261         func_breakable_destroy(this, NULL, NULL);
 262 }
 263
 264 void func_breakable_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 265 {
 266         if(this.state == STATE_BROKEN)
 267                 return;
 268         if(this.spawnflags & NOSPLASH)
 269                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 270                         return;
 271         if(this.team)
 272                 if(attacker.team == this.team)
 273                         return;
 274         this.pain_finished = time;
 275         TakeResource(this, RES_HEALTH, damage);
 276         if(this.sprite)
 277         {
 278                 WaypointSprite_Ping(this.sprite);
 279                 WaypointSprite_UpdateHealth(this.sprite, GetResource(this, RES_HEALTH));
 280         }
 281         func_breakable_colormod(this);
 282
 283         if(GetResource(this, RES_HEALTH) <= 0)
 284         {
 285                 debrisforce = force;
 286
 287                 this.takedamage = DAMAGE_NO;
 288                 this.event_damage = func_null;
 289
 290                 if(IS_CLIENT(attacker)) //&& this.classname == "func_assault_destructible")
 291                 {
 292                         this.owner = attacker;
 293                         this.realowner = attacker;
 294                 }
 295
 296                 // do not explode NOW but in the NEXT FRAME!
 297                 // because recursive calls to RadiusDamage are not allowed
 298                 this.nextthink = time;
 299                 CSQCMODEL_AUTOUPDATE(this);
 300                 setthink(this, func_breakable_destroy_self);
 301         }
 302 }
 303
 304 void func_breakable_reset(entity this)
 305 {
 306         this.team = this.team_saved;
 307         func_breakable_look_restore(this);
 308         if(this.spawnflags & START_DISABLED)
 309                 func_breakable_behave_destroyed(this);
 310         else
 311                 func_breakable_behave_restore(this);
 312 }
 313
 314 // destructible walls that can be used to trigger target_objective_decrease
 315 spawnfunc(func_breakable)
 316 {
 317         float n, i;
 318         if(!GetResource(this, RES_HEALTH))
 319                 SetResourceExplicit(this, RES_HEALTH, 100);
 320         this.max_health = GetResource(this, RES_HEALTH);
 321
 322         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 323         if(!this.debrismovetype) this.debrismovetype = MOVETYPE_BOUNCE;
 324         if(!this.debrissolid) this.debrissolid = SOLID_NOT;
 325         if(this.debrisvelocity == '0 0 0') this.debrisvelocity = '0 0 140';
 326         if(this.debrisvelocityjitter == '0 0 0') this.debrisvelocityjitter = '70 70 70';
 327         if(this.debrisavelocityjitter == '0 0 0') this.debrisavelocityjitter = '600 600 600';
 328         if(!this.debristime) this.debristime = 3.5;
 329         if(!this.debristimejitter) this.debristime = 2.5;
 330
 331         if(this.mdl != "")
 332                 this.cnt = _particleeffectnum(this.mdl);
 333         if(this.count == 0)
 334                 this.count = 1;
 335
 336         if(this.message == "")
 337                 this.message = "got too close to an explosion";
 338         if(this.message2 == "")
 339                 this.message2 = "was pushed into an explosion by";
 340         if(!this.dmg_radius)
 341                 this.dmg_radius = 150;
 342         if(!this.dmg_force)
 343                 this.dmg_force = 200;
 344
 345         this.mdl = this.model;
 346         SetBrushEntityModel(this, true);
 347
 348         if(this.spawnflags & BREAKABLE_NODAMAGE)
 349                 this.use = func_breakable_destroy;
 350         else
 351                 this.use = func_breakable_restore;
 352
 353         if(this.spawnflags & BREAKABLE_NODAMAGE)
 354         {
 355                 this.takedamage = DAMAGE_NO;
 356                 this.event_damage = func_null;
 357                 this.bot_attack = false;
 358         }
 359
 360         // precache all the models
 361         if (this.mdl_dead)
 362                 precache_model(this.mdl_dead);
 363         n = tokenize_console(this.debris);
 364         for(i = 0; i < n; ++i)
 365                 precache_model(argv(i));
 366         if(this.noise)
 367                 precache_sound(this.noise);
 368         if(this.noise1)
 369                 precache_sound(this.noise1);
 370
 371         this.team_saved = this.team;
 372         IL_PUSH(g_saved_team, this);
 373         this.dropped_origin = this.origin;
 374
 375         this.reset = func_breakable_reset;
 376         this.reset(this);
 377
 378         IL_PUSH(g_initforplayer, this);
 379         this.init_for_player = func_breakable_init_for_player;
 380
 381         CSQCMODEL_AUTOINIT(this);
 382 }
 383
 384 // for use in maps with a "model" key set
 385 spawnfunc(misc_breakablemodel) {
 386         spawnfunc_func_breakable(this);
 387 }
 388 #endif