Merge remote-tracking branch 'origin/terencehill/bot_waypoints'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mapobjects / teleporters.qc
1 #include "teleporters.qh"
2
3 #if defined(CSQC)
4 #elif defined(MENUQC)
5 #elif defined(SVQC)
6     #include <lib/warpzone/common.qh>
7     #include <lib/warpzone/util_server.qh>
8     #include <lib/warpzone/server.qh>
9     #include "../constants.qh"
10         #include "../mapobjects/subs.qh"
11     #include "../util.qh"
12     #include <server/weapons/csqcprojectile.qh>
13     #include <server/autocvars.qh>
14     #include <server/constants.qh>
15     #include <server/defs.qh>
16     #include "../deathtypes/all.qh"
17     #include "../turrets/sv_turrets.qh"
18     #include "../vehicles/all.qh"
19     #include "../mapinfo.qh"
20     #include <server/anticheat.qh>
21 #endif
22
23 #ifdef SVQC
24 float check_tdeath(entity player, vector org, vector telefragmin, vector telefragmax)
25 {
26         if (IS_PLAYER(player) && !IS_DEAD(player))
27         {
28                 TDEATHLOOP(org)
29                 {
30                 #ifdef SVQC
31                         if (!(teamplay && autocvar_g_telefrags_teamplay && head.team == player.team))
32                 #endif
33                                 if(IS_PLAYER(head))
34                                         if(!IS_DEAD(head))
35                                                 return 1;
36                 }
37         }
38         return 0;
39 }
40
41 void trigger_teleport_link(entity this);
42
43 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
44 {
45         TDEATHLOOP(player.origin)
46         {
47                 if (IS_PLAYER(player) && GetResourceAmount(player, RESOURCE_HEALTH) >= 1)
48                 {
49                         if (!(teamplay && autocvar_g_telefrags_teamplay && head.team == player.team))
50                         {
51                                 if(IS_PLAYER(head))
52                                         if(GetResourceAmount(head, RESOURCE_HEALTH) >= 1)
53                                                 ++tdeath_hit;
54                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG.m_id, DMG_NOWEP, head.origin, '0 0 0');
55                         }
56                 }
57                 else // dead bodies and monsters gib themselves instead of telefragging
58                         Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG.m_id, DMG_NOWEP, telefragger.origin, '0 0 0');
59         }
60 }
61
62 void spawn_tdeath(vector v0, entity e, vector v)
63 {
64         tdeath(e, e, e, '0 0 0', '0 0 0');
65 }
66 #endif
67
68 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax, float tflags)
69 {
70         entity telefragger;
71         vector from;
72
73         if(teleporter.owner)
74                 telefragger = teleporter.owner;
75         else
76                 telefragger = player;
77
78         makevectors (to_angles);
79
80 #ifdef SVQC
81         if(player.teleportable == TELEPORT_NORMAL) // don't play sounds or show particles for anything that isn't a player, maybe change later to block only observers
82         {
83                 if(teleporter.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
84                 {
85                         if(tflags & TELEPORT_FLAG_SOUND)
86                         {
87                                 string thesound = SND(TELEPORT);
88                                 if(teleporter.noise != "")
89                                 {
90                                         RandomSelection_Init();
91                                         FOREACH_WORD(teleporter.noise, true,
92                                         {
93                                                 RandomSelection_AddString(it, 1, 1);
94                                         });
95                                         thesound = RandomSelection_chosen_string;
96                                 }
97                                 _sound (player, CH_TRIGGER, thesound, VOL_BASE, ATTEN_NORM);
98                         }
99                         if(tflags & TELEPORT_FLAG_PARTICLES)
100                         {
101                                 Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
102                                 Send_Effect(EFFECT_TELEPORT, to + v_forward * 32, '0 0 0', 1);
103                         }
104                         teleporter.pushltime = time + 0.2;
105                 }
106         }
107 #endif
108
109         // Relocate the player
110         // assuming to allows PL_MIN to PL_MAX box and some more
111 #ifdef SVQC
112         from = player.origin;
113         setorigin(player, to);
114         player.oldorigin = to; // don't undo the teleport by unsticking
115         player.angles = to_angles;
116         if (IS_BOT_CLIENT(player))
117         {
118                 player.v_angle = player.angles;
119                 bot_aim_reset(player);
120         }
121         player.fixangle = true;
122         player.velocity = to_velocity;
123         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
124
125         makevectors(player.angles);
126         Reset_ArcBeam(player, v_forward);
127         UpdateCSQCProjectileAfterTeleport(player);
128         UpdateItemAfterTeleport(player);
129 #elif defined(CSQC)
130         from = player.origin;
131         setorigin(player, to);
132         player.angles = to_angles;
133         player.velocity = to_velocity;
134         UNSET_ONGROUND(player);
135         player.iflags |= IFLAG_TELEPORTED | IFLAG_V_ANGLE | IFLAG_ANGLES;
136         player.csqcmodel_teleported = 1;
137         player.v_angle = to_angles;
138
139         if(player == csqcplayer) // not for anything but the main player
140         {
141                 setproperty(VF_ANGLES, player.angles);
142                 setproperty(VF_CL_VIEWANGLES, player.angles);
143         }
144 #endif
145
146 #ifdef SVQC
147         if(IS_PLAYER(player))
148         {
149                 if(tflags & TELEPORT_FLAG_TDEATH)
150                         if(player.takedamage && !IS_DEAD(player) && !g_race && !g_cts && (autocvar_g_telefrags || (tflags & TELEPORT_FLAG_FORCE_TDEATH)))
151                                 tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
152
153                 // player no longer is on ground
154                 UNSET_ONGROUND(player);
155
156                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
157                 player.oldvelocity = player.velocity;
158
159                 // reset tracking of who pushed you into a hazard (for kill credit)
160                 if(teleporter.owner)
161                 {
162                         player.pusher = teleporter.owner;
163                         player.pushltime = time + autocvar_g_maxpushtime;
164                         player.istypefrag = PHYS_INPUT_BUTTON_CHAT(player);
165                 }
166                 else
167                 {
168                         player.pushltime = 0;
169                         player.istypefrag = 0;
170                 }
171
172                 player.lastteleporttime = time;
173                 player.lastteleport_origin = from;
174         }
175 #endif
176 }
177
178 entity Simple_TeleportPlayer(entity teleporter, entity player)
179 {
180         vector locout;
181         entity e = NULL;
182
183         // Find the output teleporter
184         if(teleporter.enemy)
185         {
186                 e = teleporter.enemy;
187         }
188         else
189         {
190                 // sorry CSQC, random stuff ain't gonna happen
191 #ifdef SVQC
192                 RandomSelection_Init();
193                 FOREACH_ENTITY_STRING(targetname, teleporter.target,
194                 {
195                         bool p = true;
196                         if(STAT(TELEPORT_TELEFRAG_AVOID, player))
197                         {
198                         #ifdef SVQC
199                                 locout = it.origin + '0 0 1' * (1 - player.mins.z - 24);
200                         #elif defined(CSQC)
201                                 locout = it.origin + '0 0 1' * (1 - player.mins.z - 24);
202                         #endif
203                                 if(check_tdeath(player, locout, '0 0 0', '0 0 0'))
204                                         p = false;
205                         }
206                         RandomSelection_AddEnt(it, (it.cnt ? it.cnt : 1), p);
207                 });
208                 e = RandomSelection_chosen_ent;
209 #endif
210         }
211
212 #ifdef SVQC
213         if(!e) { sprint(player, "Teleport destination vanished. Sorry... please complain to the mapper.\n"); }
214 #elif defined(CSQC)
215         if(!e) { LOG_INFO("Teleport destination could not be found from CSQC."); }
216 #endif
217
218         makevectors(e.mangle);
219
220         if(e.speed)
221                 if(vdist(player.velocity, >, e.speed))
222                         player.velocity = normalize(player.velocity) * max(0, e.speed);
223
224         if(STAT(TELEPORT_MAXSPEED, player))
225                 if(vdist(player.velocity, >, STAT(TELEPORT_MAXSPEED, player)))
226                         player.velocity = normalize(player.velocity) * max(0, STAT(TELEPORT_MAXSPEED, player));
227
228         locout = e.origin + '0 0 1' * (1 - player.mins.z - 24);
229
230         TeleportPlayer(teleporter, player, locout, e.mangle, v_forward * vlen(player.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
231
232         return e;
233 }
234
235 void teleport_findtarget(entity this)
236 {
237         bool istrigger = (this.solid == SOLID_TRIGGER);
238
239         int n = 0;
240         for(entity e = NULL; (e = find(e, targetname, this.target)); )
241         {
242                 ++n;
243 #ifdef SVQC
244                 if(e.move_movetype == MOVETYPE_NONE)
245                 {
246                         entity tracetest_ent = spawn();
247                         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
248                         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
249                         waypoint_spawnforteleporter(this, e.origin, 0, tracetest_ent);
250                         delete(tracetest_ent);
251                 }
252                 if(e.classname != "info_teleport_destination")
253                         LOG_INFO("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.");
254 #endif
255         }
256
257         if(n == 0)
258         {
259                 // no dest!
260                 objerror (this, "Teleporter with nonexistant target");
261                 return;
262         }
263         else if(n == 1)
264         {
265                 // exactly one dest - bots love that
266                 this.enemy = find(NULL, targetname, this.target);
267         }
268         else
269         {
270                 // have to use random selection every single time
271                 this.enemy = NULL;
272         }
273
274         // now enable touch
275         if(istrigger)
276                 settouch(this, Teleport_Touch);
277 #ifdef SVQC
278         if(istrigger)
279                 trigger_teleport_link(this);
280 #endif
281 }
282
283 entity Teleport_Find(vector mi, vector ma)
284 {
285         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
286         {
287                 return it;
288         });
289         return NULL;
290 }
291
292 void WarpZone_PostTeleportPlayer_Callback(entity pl)
293 {
294 #ifdef SVQC
295         makevectors(pl.angles);
296         Reset_ArcBeam(pl, v_forward);
297         UpdateCSQCProjectileAfterTeleport(pl);
298         UpdateItemAfterTeleport(pl);
299     if (IS_PLAYER(pl)) anticheat_fixangle(pl);
300 #endif
301         // "disown" projectiles after teleport
302         if(pl.owner)
303         if(pl.owner == pl.realowner)
304         {
305         #ifdef SVQC
306                 if(!(pl.flags & FL_PROJECTILE))
307         #elif defined(CSQC)
308                 if(!(pl.flags & BIT(15))) // FL_PROJECTILE
309         #endif
310                         LOG_INFO("A non-projectile got through a warpzone and its owner cleared. It's a ", pl.classname, ".");
311                 pl.owner = NULL;
312         }
313         if(IS_PLAYER(pl))
314         {
315                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
316         #ifdef SVQC
317                 pl.oldvelocity = pl.velocity;
318         #endif
319         }
320 }