qcsrc/common/monsters/monster/brute.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ BRUTE,
   4 /* function   */ m_brute,
   5 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_RANGED | MON_FLAG_MUTATORBLOCKED,
   6 /* mins,maxs  */ '-36 -36 -20', '36 36 50',
   7 /* model      */ "ogre.dpm",
   8 /* netname    */ "brute",
   9 /* fullname   */ _("Brute")
  10 );
  11
  12 #define BRUTE_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_chainsaw_damage) \
  15         MON_ADD_CVAR(monster, attack_uzi_bullets) \
  16         MON_ADD_CVAR(monster, attack_uzi_damage) \
  17         MON_ADD_CVAR(monster, attack_uzi_force) \
  18         MON_ADD_CVAR(monster, attack_uzi_chance) \
  19         MON_ADD_CVAR(monster, attack_grenade_damage) \
  20         MON_ADD_CVAR(monster, attack_grenade_edgedamage) \
  21         MON_ADD_CVAR(monster, attack_grenade_force) \
  22         MON_ADD_CVAR(monster, attack_grenade_radius) \
  23         MON_ADD_CVAR(monster, attack_grenade_speed) \
  24         MON_ADD_CVAR(monster, attack_grenade_speed_up) \
  25         MON_ADD_CVAR(monster, speed_stop) \
  26         MON_ADD_CVAR(monster, speed_run) \
  27         MON_ADD_CVAR(monster, speed_walk)
  28
  29 #ifdef SVQC
  30 BRUTE_SETTINGS(brute)
  31 #endif // SVQC
  32 #else
  33 #ifdef SVQC
  34 const float brute_anim_idle             = 0;
  35 const float brute_anim_walk             = 1;
  36 const float brute_anim_run                      = 2;
  37 const float brute_anim_pain             = 3;
  38 const float brute_anim_swing            = 4;
  39 const float brute_anim_die                      = 5;
  40
  41 .float brute_cycles;
  42
  43 void brute_blade()
  44 {
  45         self.brute_cycles += 1;
  46         self.angles_y = self.angles_y + random()* 25;
  47
  48         monster_melee(self.enemy, MON_CVAR(brute, attack_chainsaw_damage), brute_anim_swing, self.attack_range, 0, DEATH_MONSTER_BRUTE_BLADE, TRUE);
  49
  50         if(self.brute_cycles <= 4)
  51                 defer(0.2, brute_blade);
  52 }
  53
  54 void brute_uzi()
  55 {
  56         self.brute_cycles += 1;
  57
  58         monster_makevectors(self.enemy);
  59
  60         sound(self, CH_WEAPON_A, "weapons/uzi_fire.wav", VOL_BASE, ATTEN_NORM);
  61         fireBallisticBullet(CENTER_OR_VIEWOFS(self), v_forward, 0.02, 18000, 5, MON_CVAR(brute, attack_uzi_damage), MON_CVAR(brute, attack_uzi_force), DEATH_MONSTER_BRUTE_UZI, 0, 1, 115);
  62         endFireBallisticBullet();
  63
  64         if(self.brute_cycles <= MON_CVAR(brute, attack_uzi_bullets))
  65                 defer(0.1, brute_uzi);
  66 }
  67
  68 void brute_grenade_explode()
  69 {
  70         pointparticles(particleeffectnum("grenade_explode"), self.origin, '0 0 0', 1);
  71         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTEN_NORM);
  72
  73         self.event_damage = func_null;
  74         self.takedamage = DAMAGE_NO;
  75
  76         if(self.movetype == MOVETYPE_NONE)
  77                 self.velocity = self.oldvelocity;
  78
  79         RadiusDamage (self, self.realowner, MON_CVAR(brute, attack_grenade_damage), MON_CVAR(brute, attack_grenade_edgedamage), MON_CVAR(brute, attack_grenade_radius), world, MON_CVAR(brute, attack_grenade_force), self.projectiledeathtype, other);
  80
  81         remove (self);
  82 }
  83
  84 void brute_grenade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  85 {
  86         if (self.health <= 0)
  87                 return;
  88
  89         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  90                 return; // g_projectiles_damage says to halt
  91
  92         self.health = self.health - damage;
  93
  94         if (self.health <= 0)
  95                 W_PrepareExplosionByDamage(attacker, self.use);
  96 }
  97
  98 void brute_grenade_touch()
  99 {
 100         PROJECTILE_TOUCH;
 101
 102         self.use ();
 103 }
 104
 105 void brute_grenade_think()
 106 {
 107         self.nextthink = time;
 108         if (time > self.cnt)
 109         {
 110                 other = world;
 111                 brute_grenade_explode();
 112                 return;
 113         }
 114 }
 115
 116 void brute_grenade()
 117 {
 118         entity gren;
 119
 120         monster_makevectors(self.enemy);
 121
 122         sound(self, CH_WEAPON_A, "weapons/grenade_fire.wav", VOL_BASE, ATTEN_NORM);
 123
 124         gren = spawn ();
 125         gren.owner = gren.realowner = self;
 126         gren.classname = "grenade";
 127         gren.bot_dodge = TRUE;
 128         gren.bot_dodgerating = MON_CVAR(brute, attack_grenade_damage);
 129         gren.movetype = MOVETYPE_BOUNCE;
 130         PROJECTILE_MAKETRIGGER(gren);
 131         gren.projectiledeathtype = DEATH_MONSTER_BRUTE_GRENADE;
 132         setorigin(gren, CENTER_OR_VIEWOFS(self));
 133         setsize(gren, '-3 -3 -3', '3 3 3');
 134
 135         gren.cnt = time + 5;
 136         gren.nextthink = time;
 137         gren.think = brute_grenade_think;
 138         gren.use = brute_grenade_explode;
 139         gren.touch = brute_grenade_touch;
 140
 141         gren.takedamage = DAMAGE_YES;
 142         gren.health = 50;
 143         gren.damageforcescale = 0;
 144         gren.event_damage = brute_grenade_damage;
 145         gren.damagedbycontents = TRUE;
 146         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 147         W_SetupProjectileVelocityEx(gren, v_forward, v_up, MON_CVAR(brute, attack_grenade_speed), MON_CVAR(brute, attack_grenade_speed_up), 0, 0, FALSE);
 148
 149         gren.angles = vectoangles (gren.velocity);
 150         gren.flags = FL_PROJECTILE;
 151
 152         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 153 }
 154
 155 float brute_attack(float attack_type)
 156 {
 157         switch(attack_type)
 158         {
 159                 case MONSTER_ATTACK_MELEE:
 160                 {
 161                         self.brute_cycles = 0;
 162                         self.attack_finished_single = time + 1.3;
 163                         brute_blade();
 164
 165                         return TRUE;
 166                 }
 167                 case MONSTER_ATTACK_RANGED:
 168                 {
 169                         self.brute_cycles = 0;
 170                         if(random() <= MON_CVAR(brute, attack_uzi_chance))
 171                         {
 172                                 self.frame = brute_anim_pain;
 173                                 self.attack_finished_single = time + 0.8;
 174                                 defer(0.1, brute_uzi);
 175                         }
 176                         else
 177                         {
 178                                 monster_makevectors(self.enemy);
 179                                 brute_grenade();
 180                                 self.frame = brute_anim_pain;
 181                                 self.attack_finished_single = time + 1.2;
 182                         }
 183
 184                         return TRUE;
 185                 }
 186         }
 187
 188         return FALSE;
 189 }
 190
 191 void spawnfunc_monster_brute()
 192 {
 193         self.classname = "monster_brute";
 194
 195         self.monster_spawnfunc = spawnfunc_monster_brute;
 196
 197         if(Monster_CheckAppearFlags(self))
 198                 return;
 199
 200         if not(monster_initialize(MON_BRUTE, FALSE)) { remove(self); return; }
 201 }
 202
 203 // compatibility with old spawns
 204 void spawnfunc_monster_ogre() { spawnfunc_monster_brute(); }
 205
 206 float m_brute(float req)
 207 {
 208         switch(req)
 209         {
 210                 case MR_THINK:
 211                 {
 212                         monster_move(MON_CVAR(brute, speed_run), MON_CVAR(brute, speed_walk), MON_CVAR(brute, speed_stop), brute_anim_run, brute_anim_walk, brute_anim_idle);
 213                         return TRUE;
 214                 }
 215                 case MR_DEATH:
 216                 {
 217                         self.frame = brute_anim_die;
 218                         return TRUE;
 219                 }
 220                 case MR_SETUP:
 221                 {
 222                         if not(self.health) self.health = MON_CVAR(brute, health);
 223
 224                         self.monster_loot = spawnfunc_item_bullets;
 225                         self.monster_attackfunc = brute_attack;
 226                         self.frame = brute_anim_idle;
 227                         self.weapon = WEP_GRENADE_LAUNCHER;
 228
 229                         return TRUE;
 230                 }
 231                 case MR_PRECACHE:
 232                 {
 233                         precache_model ("models/monsters/ogre.dpm");
 234                         precache_sound ("weapons/uzi_fire.wav");
 235                         precache_sound ("weapons/grenade_impact.wav");
 236                         precache_sound ("weapons/grenade_fire.wav");
 237                         return TRUE;
 238                 }
 239                 case MR_CONFIG:
 240                 {
 241                         MON_CONFIG_SETTINGS(BRUTE_SETTINGS(brute))
 242                         return TRUE;
 243                 }
 244         }
 245
 246         return TRUE;
 247 }
 248
 249 #endif // SVQC
 250 #ifdef CSQC
 251 float m_brute(float req)
 252 {
 253         switch(req)
 254         {
 255                 case MR_PRECACHE:
 256                 {
 257                         precache_model ("models/monsters/ogre.dpm");
 258                         return TRUE;
 259                 }
 260         }
 261
 262         return TRUE;
 263 }
 264
 265 #endif // CSQC
 266 #endif // REGISTER_MONSTER