qcsrc/common/monsters/monster/mage.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ MAGE,
   4 /* function   */ m_mage,
   5 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-36 -36 -24', '36 36 50',
   7 /* model      */ "mage.dpm",
   8 /* netname    */ "mage",
   9 /* fullname   */ _("Mage")
  10 );
  11
  12 #define MAGE_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_spike_damage) \
  15         MON_ADD_CVAR(monster, attack_spike_radius) \
  16         MON_ADD_CVAR(monster, attack_spike_delay) \
  17         MON_ADD_CVAR(monster, attack_spike_accel) \
  18         MON_ADD_CVAR(monster, attack_spike_decel) \
  19         MON_ADD_CVAR(monster, attack_spike_turnrate) \
  20         MON_ADD_CVAR(monster, attack_spike_speed_max) \
  21         MON_ADD_CVAR(monster, attack_spike_smart) \
  22         MON_ADD_CVAR(monster, attack_spike_smart_trace_min) \
  23         MON_ADD_CVAR(monster, attack_spike_smart_trace_max) \
  24         MON_ADD_CVAR(monster, attack_spike_smart_mindist) \
  25         MON_ADD_CVAR(monster, heal_self) \
  26         MON_ADD_CVAR(monster, heal_allies) \
  27         MON_ADD_CVAR(monster, heal_minhealth) \
  28         MON_ADD_CVAR(monster, heal_range) \
  29         MON_ADD_CVAR(monster, heal_delay) \
  30         MON_ADD_CVAR(monster, shield_time) \
  31         MON_ADD_CVAR(monster, shield_delay) \
  32         MON_ADD_CVAR(monster, shield_blockpercent) \
  33         MON_ADD_CVAR(monster, speed_stop) \
  34         MON_ADD_CVAR(monster, speed_run) \
  35         MON_ADD_CVAR(monster, speed_walk)
  36
  37 #ifdef SVQC
  38 MAGE_SETTINGS(mage)
  39 #endif // SVQC
  40 #else
  41 #ifdef SVQC
  42 const float mage_anim_idle              = 0;
  43 const float mage_anim_walk              = 1;
  44 const float mage_anim_attack    = 2;
  45 const float mage_anim_pain              = 3;
  46 const float mage_anim_death     = 4;
  47 const float mage_anim_run               = 5;
  48
  49 void() mage_heal;
  50 void() mage_shield;
  51
  52 .entity mage_spike;
  53
  54 float friend_needshelp(entity e)
  55 {
  56         if(e == world)
  57                 return FALSE;
  58         if(e.health <= 0)
  59                 return FALSE;
  60         if(DIFF_TEAM(e, self) && e != self.monster_owner)
  61                 return FALSE;
  62         if(e.frozen)
  63                 return FALSE;
  64         if(!IS_PLAYER(e))
  65                 return (e.flags & FL_MONSTER && e.health < e.max_health);
  66         if(e.items & IT_INVINCIBLE)
  67                 return FALSE;
  68
  69         switch(self.skin)
  70         {
  71                 case 0: return (e.health < autocvar_g_balance_health_regenstable);
  72                 case 1: return ((e.ammo_cells && e.ammo_cells < g_pickup_cells_max) || (e.ammo_rockets && e.ammo_rockets < g_pickup_rockets_max) || (e.ammo_nails && e.ammo_nails < g_pickup_nails_max) || (e.ammo_shells && e.ammo_shells < g_pickup_shells_max));
  73                 case 2: return (e.armorvalue < autocvar_g_balance_armor_regenstable);
  74                 case 3: return (e.health > 0);
  75         }
  76
  77         return FALSE;
  78 }
  79
  80 void mage_spike_explode()
  81 {
  82         self.event_damage = func_null;
  83
  84         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTEN_NORM);
  85
  86         self.realowner.mage_spike = world;
  87
  88         pointparticles(particleeffectnum("explosion_small"), self.origin, '0 0 0', 1);
  89         RadiusDamage (self, self.realowner, MON_CVAR(mage, attack_spike_damage), MON_CVAR(mage, attack_spike_damage) * 0.5, MON_CVAR(mage, attack_spike_radius), world, 0, DEATH_MONSTER_MAGE, other);
  90
  91         remove (self);
  92 }
  93
  94 void mage_spike_touch()
  95 {
  96         PROJECTILE_TOUCH;
  97
  98         mage_spike_explode();
  99 }
 100
 101 // copied from W_Seeker_Think
 102 void mage_spike_think()
 103 {
 104         entity e;
 105         vector desireddir, olddir, newdir, eorg;
 106         float turnrate;
 107         float dist;
 108         float spd;
 109
 110         if (time > self.ltime || self.enemy.health <= 0 || self.owner.health <= 0)
 111         {
 112                 self.projectiledeathtype |= HITTYPE_SPLASH;
 113                 mage_spike_explode();
 114         }
 115
 116         spd = vlen(self.velocity);
 117         spd = bound(
 118                 spd - MON_CVAR(mage, attack_spike_decel) * frametime,
 119                 MON_CVAR(mage, attack_spike_speed_max),
 120                 spd + MON_CVAR(mage, attack_spike_accel) * frametime
 121         );
 122
 123         if (self.enemy != world)
 124                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 125                         self.enemy = world;
 126
 127         if (self.enemy != world)
 128         {
 129                 e               = self.enemy;
 130                 eorg            = 0.5 * (e.absmin + e.absmax);
 131                 turnrate        = MON_CVAR(mage, attack_spike_turnrate); // how fast to turn
 132                 desireddir      = normalize(eorg - self.origin);
 133                 olddir          = normalize(self.velocity); // get my current direction
 134                 dist            = vlen(eorg - self.origin);
 135
 136                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 137                 if (MON_CVAR(mage, attack_spike_smart) && (dist > MON_CVAR(mage, attack_spike_smart_mindist)))
 138                 {
 139                         // Is it a better idea (shorter distance) to trace to the target itself?
 140                         if ( vlen(self.origin + olddir * self.wait) < dist)
 141                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 142                         else
 143                                 traceline(self.origin, eorg, FALSE, self);
 144
 145                         // Setup adaptive tracelength
 146                         self.wait = bound(MON_CVAR(mage, attack_spike_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = MON_CVAR(mage, attack_spike_smart_trace_max));
 147
 148                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 149                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 150                 }
 151
 152                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 153                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 154         }
 155         else
 156                 dist = 0;
 157
 158         ///////////////
 159
 160         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 161         self.nextthink = time;// + 0.05; // csqc projectiles
 162         UpdateCSQCProjectile(self);
 163 }
 164
 165 void mage_attack_spike()
 166 {
 167         entity missile;
 168         vector dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
 169
 170         makevectors(self.angles);
 171
 172         missile = spawn ();
 173         missile.owner = missile.realowner = self;
 174         missile.think = mage_spike_think;
 175         missile.ltime = time + 7;
 176         missile.nextthink = time;
 177         missile.solid = SOLID_BBOX;
 178         missile.movetype = MOVETYPE_FLYMISSILE;
 179         missile.flags = FL_PROJECTILE;
 180         setorigin(missile, self.origin + v_forward * 14 + '0 0 30' + v_right * -14);
 181         setsize (missile, '0 0 0', '0 0 0');
 182         missile.velocity = dir * 400;
 183         missile.avelocity = '300 300 300';
 184         missile.enemy = self.enemy;
 185         missile.touch = mage_spike_touch;
 186
 187         self.mage_spike = missile;
 188
 189         CSQCProjectile(missile, TRUE, PROJECTILE_MAGE_SPIKE, TRUE);
 190 }
 191
 192 void mage_attack_beam()
 193 {
 194         if(self.health <= 0 || self.enemy.health <= 0)
 195                 return;
 196
 197         traceline(self.origin + self.view_ofs, self.enemy.origin, FALSE, self);
 198
 199         if(vlen(self.origin - trace_endpos) > 500)
 200         {
 201                 self.attack_finished_single = time;
 202                 return;
 203         }
 204
 205         if(trace_ent)
 206                 Damage(trace_ent, self, self, 10, DEATH_MONSTER_MAGE, trace_ent.origin, '0 0 0');
 207
 208         trailparticles(self, particleeffectnum("TE_TEI_G3RED_HIT"), self.origin + self.view_ofs, trace_ent.origin);
 209
 210         if(time < self.attack_finished_single)
 211                 defer(0.1, mage_attack_beam);
 212 }
 213
 214 void mage_heal()
 215 {
 216         entity head;
 217         float washealed = FALSE;
 218
 219         for(head = findradius(self.origin, MON_CVAR(mage, heal_range)); head; head = head.chain) if(friend_needshelp(head))
 220         {
 221                 washealed = TRUE;
 222                 string fx = "";
 223                 if(IS_PLAYER(head))
 224                 {
 225                         switch(self.skin)
 226                         {
 227                                 case 0:
 228                                         if(head.health < autocvar_g_balance_health_regenstable) head.health = bound(0, head.health + MON_CVAR(mage, heal_allies), autocvar_g_balance_health_regenstable);
 229                                         fx = "healing_fx";
 230                                         break;
 231                                 case 1:
 232                                         if(head.ammo_cells) head.ammo_cells = bound(head.ammo_cells, head.ammo_cells + 1, g_pickup_cells_max);
 233                                         if(head.ammo_rockets) head.ammo_rockets = bound(head.ammo_rockets, head.ammo_rockets + 1, g_pickup_rockets_max);
 234                                         if(head.ammo_shells) head.ammo_shells = bound(head.ammo_shells, head.ammo_shells + 2, g_pickup_shells_max);
 235                                         if(head.ammo_nails) head.ammo_nails = bound(head.ammo_nails, head.ammo_nails + 5, g_pickup_nails_max);
 236                                         fx = "ammoregen_fx";
 237                                         break;
 238                                 case 2:
 239                                         if(head.armorvalue < autocvar_g_balance_armor_regenstable)
 240                                         {
 241                                                 head.armorvalue = bound(0, head.armorvalue + MON_CVAR(mage, heal_allies), autocvar_g_balance_armor_regenstable);
 242                                                 fx = "armorrepair_fx";
 243                                         }
 244                                         break;
 245                                 case 3:
 246                                         head.health = bound(0, head.health - ((head == self)  ? MON_CVAR(mage, heal_self) : MON_CVAR(mage, heal_allies)), autocvar_g_balance_health_regenstable);
 247                                         fx = "rage";
 248                                         break;
 249                         }
 250
 251                         pointparticles(particleeffectnum(fx), head.origin, '0 0 0', 1);
 252                 }
 253                 else
 254                 {
 255                         pointparticles(particleeffectnum("healing_fx"), head.origin, '0 0 0', 1);
 256                         head.health = bound(0, head.health + MON_CVAR(mage, heal_allies), head.max_health);
 257                         WaypointSprite_UpdateHealth(head.sprite, head.health);
 258                 }
 259         }
 260
 261         if(washealed)
 262         {
 263                 self.frame = mage_anim_attack;
 264                 self.attack_finished_single = time + MON_CVAR(mage, heal_delay);
 265         }
 266 }
 267
 268 void mage_shield_think()
 269 {
 270         self.nextthink = time;
 271
 272         if(time >= self.ltime || self.owner.health <= 0)
 273         {
 274                 self.owner.armorvalue = 0;
 275                 self.owner.m_armor_blockpercent = autocvar_g_monsters_armor_blockpercent;
 276                 remove(self);
 277                 return;
 278         }
 279 }
 280
 281 void mage_shield()
 282 {
 283         if(self.weaponentity)
 284                 return; // already have a shield
 285
 286         entity shield = spawn();
 287
 288         shield.owner = self;
 289         shield.team = self.team;
 290         shield.ltime = time + MON_CVAR(mage, shield_time);
 291         shield.classname = "shield";
 292         shield.effects = EF_ADDITIVE;
 293         shield.movetype = MOVETYPE_NOCLIP;
 294         shield.solid = SOLID_TRIGGER;
 295         shield.avelocity = '7 0 11';
 296         shield.scale = self.scale * 0.6;
 297         shield.think = mage_shield_think;
 298         shield.nextthink = time;
 299
 300         setattachment(shield, self, "");
 301         setmodel(shield, "models/ctf/shield.md3");
 302         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 303
 304         self.lastshielded = time + MON_CVAR(mage, shield_delay);
 305
 306         self.frame = mage_anim_attack;
 307         self.attack_finished_single = time + 1;
 308
 309         self.m_armor_blockpercent = MON_CVAR(mage, shield_blockpercent);
 310         self.armorvalue = self.health;
 311 }
 312
 313 float mage_attack(float attack_type)
 314 {
 315         switch(attack_type)
 316         {
 317                 case MONSTER_ATTACK_MELEE:
 318                 case MONSTER_ATTACK_RANGED:
 319                 {
 320                         if not(self.mage_spike)
 321                         {
 322                                 if(random() <= 0.5)
 323                                 {
 324                                         self.frame = mage_anim_attack;
 325                                         self.attack_finished_single = time + 1.5; // 0.3 seconds of beam
 326                                         defer(1.2, mage_attack_beam);
 327
 328                                         return TRUE;
 329                                 }
 330                                 else
 331                                 {
 332                                         self.frame = mage_anim_attack;
 333                                         self.attack_finished_single = time + MON_CVAR(mage, attack_spike_delay);
 334                                         defer(0.2, mage_attack_spike);
 335
 336                                         return TRUE;
 337                                 }
 338                         }
 339
 340                         if(self.mage_spike)
 341                                 return TRUE;
 342                         else
 343                                 return FALSE;
 344                 }
 345         }
 346
 347         return FALSE;
 348 }
 349
 350 void spawnfunc_monster_mage()
 351 {
 352         self.classname = "monster_mage";
 353
 354         self.monster_spawnfunc = spawnfunc_monster_mage;
 355
 356         if(Monster_CheckAppearFlags(self))
 357                 return;
 358
 359         if not(monster_initialize(MON_MAGE, FALSE)) { remove(self); return; }
 360 }
 361
 362 // compatibility with old spawns
 363 void spawnfunc_monster_shalrath() { spawnfunc_monster_mage(); }
 364
 365 float m_mage(float req)
 366 {
 367         switch(req)
 368         {
 369                 case MR_THINK:
 370                 {
 371                         entity head;
 372                         float need_help = FALSE;
 373
 374                         for(head = findradius(self.origin, MON_CVAR(mage, heal_range)); head; head = head.chain)
 375                         if(head != self)
 376                         if(friend_needshelp(head))
 377                         {
 378                                 need_help = TRUE;
 379                                 break;
 380                         }
 381
 382                         if(self.health < MON_CVAR(mage, heal_minhealth) || need_help)
 383                         if(time >= self.attack_finished_single)
 384                         if(random() < 0.5)
 385                                 mage_heal();
 386
 387                         if(self.enemy)
 388                         if(self.health < self.max_health)
 389                         if(time >= self.lastshielded)
 390                         if(random() < 0.5)
 391                                 mage_shield();
 392
 393                         monster_move(MON_CVAR(mage, speed_run), MON_CVAR(mage, speed_walk), MON_CVAR(mage, speed_stop), mage_anim_walk, mage_anim_run, mage_anim_idle);
 394                         return TRUE;
 395                 }
 396                 case MR_DEATH:
 397                 {
 398                         self.frame = mage_anim_death;
 399                         return TRUE;
 400                 }
 401                 case MR_SETUP:
 402                 {
 403                         if not(self.health) self.health = MON_CVAR(mage, health);
 404
 405                         self.monster_loot = spawnfunc_item_health_large;
 406                         self.monster_attackfunc = mage_attack;
 407                         self.frame = mage_anim_walk;
 408
 409                         return TRUE;
 410                 }
 411                 case MR_PRECACHE:
 412                 {
 413                         precache_model ("models/monsters/mage.dpm");
 414                         precache_model ("models/ctf/shield.md3");
 415                         precache_sound ("weapons/grenade_impact.wav");
 416                         return TRUE;
 417                 }
 418                 case MR_CONFIG:
 419                 {
 420                         MON_CONFIG_SETTINGS(MAGE_SETTINGS(mage))
 421                         return TRUE;
 422                 }
 423         }
 424
 425         return TRUE;
 426 }
 427
 428 #endif // SVQC
 429 #ifdef CSQC
 430 float m_mage(float req)
 431 {
 432         switch(req)
 433         {
 434                 case MR_PRECACHE:
 435                 {
 436                         precache_model ("models/monsters/mage.dpm");
 437                         return TRUE;
 438                 }
 439         }
 440
 441         return TRUE;
 442 }
 443
 444 #endif // CSQC
 445 #endif // REGISTER_MONSTER