qcsrc/common/monsters/monster/mage.qc

   1 #ifndef MENUQC
   2 bool m_mage(int);
   3 #endif
   4 REGISTER_MONSTER_SIMPLE(
   5 /* MON_##id   */ MAGE,
   6 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_RANGED,
   7 /* mins,maxs  */ '-36 -36 -24', '36 36 50',
   8 /* model      */ "mage.dpm",
   9 /* netname    */ "mage",
  10 /* fullname   */ _("Mage")
  11 ) {
  12 #ifndef MENUQC
  13     this.monster_func = m_mage;
  14 #endif
  15 }
  16
  17 #ifdef SVQC
  18 float autocvar_g_monster_mage_health;
  19 float autocvar_g_monster_mage_attack_spike_damage;
  20 float autocvar_g_monster_mage_attack_spike_radius;
  21 float autocvar_g_monster_mage_attack_spike_delay;
  22 float autocvar_g_monster_mage_attack_spike_accel;
  23 float autocvar_g_monster_mage_attack_spike_decel;
  24 float autocvar_g_monster_mage_attack_spike_turnrate;
  25 float autocvar_g_monster_mage_attack_spike_speed_max;
  26 float autocvar_g_monster_mage_attack_spike_smart;
  27 float autocvar_g_monster_mage_attack_spike_smart_trace_min;
  28 float autocvar_g_monster_mage_attack_spike_smart_trace_max;
  29 float autocvar_g_monster_mage_attack_spike_smart_mindist;
  30 float autocvar_g_monster_mage_attack_push_damage;
  31 float autocvar_g_monster_mage_attack_push_radius;
  32 float autocvar_g_monster_mage_attack_push_delay;
  33 float autocvar_g_monster_mage_attack_push_force;
  34 float autocvar_g_monster_mage_heal_self;
  35 float autocvar_g_monster_mage_heal_allies;
  36 float autocvar_g_monster_mage_heal_minhealth;
  37 float autocvar_g_monster_mage_heal_range;
  38 float autocvar_g_monster_mage_heal_delay;
  39 float autocvar_g_monster_mage_shield_time;
  40 float autocvar_g_monster_mage_shield_delay;
  41 float autocvar_g_monster_mage_shield_blockpercent;
  42 float autocvar_g_monster_mage_speed_stop;
  43 float autocvar_g_monster_mage_speed_run;
  44 float autocvar_g_monster_mage_speed_walk;
  45
  46 const float mage_anim_idle              = 0;
  47 const float mage_anim_walk              = 1;
  48 const float mage_anim_attack    = 2;
  49 const float mage_anim_pain              = 3;
  50 const float mage_anim_death             = 4;
  51 const float mage_anim_run               = 5;
  52
  53 void() mage_heal;
  54 void() mage_shield;
  55
  56 .entity mage_spike;
  57 .float shield_ltime;
  58
  59 float friend_needshelp(entity e)
  60 {
  61         if(e == world)
  62                 return false;
  63         if(e.health <= 0)
  64                 return false;
  65         if(DIFF_TEAM(e, self) && e != self.monster_owner)
  66                 return false;
  67         if(e.frozen)
  68                 return false;
  69         if(!IS_PLAYER(e))
  70                 return (IS_MONSTER(e) && e.health < e.max_health);
  71         if(e.items & ITEM_Shield.m_itemid)
  72                 return false;
  73
  74         switch(self.skin)
  75         {
  76                 case 0: return (e.health < autocvar_g_balance_health_regenstable);
  77                 case 1: return ((e.ammo_cells && e.ammo_cells < g_pickup_cells_max) || (e.ammo_plasma && e.ammo_plasma < g_pickup_plasma_max) || (e.ammo_rockets && e.ammo_rockets < g_pickup_rockets_max) || (e.ammo_nails && e.ammo_nails < g_pickup_nails_max) || (e.ammo_shells && e.ammo_shells < g_pickup_shells_max));
  78                 case 2: return (e.armorvalue < autocvar_g_balance_armor_regenstable);
  79                 case 3: return (e.health > 0);
  80         }
  81
  82         return false;
  83 }
  84
  85 void mage_spike_explode()
  86 {
  87         self.event_damage = func_null;
  88
  89         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTEN_NORM);
  90
  91         self.realowner.mage_spike = world;
  92
  93         Send_Effect("explosion_small", self.origin, '0 0 0', 1);
  94         RadiusDamage (self, self.realowner, (autocvar_g_monster_mage_attack_spike_damage), (autocvar_g_monster_mage_attack_spike_damage) * 0.5, (autocvar_g_monster_mage_attack_spike_radius), world, world, 0, DEATH_MONSTER_MAGE, other);
  95
  96         remove (self);
  97 }
  98
  99 void mage_spike_touch()
 100 {
 101         PROJECTILE_TOUCH;
 102
 103         mage_spike_explode();
 104 }
 105
 106 // copied from W_Seeker_Think
 107 void mage_spike_think()
 108 {
 109         entity e;
 110         vector desireddir, olddir, newdir, eorg;
 111         float turnrate;
 112         float dist;
 113         float spd;
 114
 115         if (time > self.ltime || self.enemy.health <= 0 || self.owner.health <= 0)
 116         {
 117                 self.projectiledeathtype |= HITTYPE_SPLASH;
 118                 mage_spike_explode();
 119         }
 120
 121         spd = vlen(self.velocity);
 122         spd = bound(
 123                 spd - (autocvar_g_monster_mage_attack_spike_decel) * frametime,
 124                 (autocvar_g_monster_mage_attack_spike_speed_max),
 125                 spd + (autocvar_g_monster_mage_attack_spike_accel) * frametime
 126         );
 127
 128         if (self.enemy != world)
 129                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 130                         self.enemy = world;
 131
 132         if (self.enemy != world)
 133         {
 134                 e                               = self.enemy;
 135                 eorg                    = 0.5 * (e.absmin + e.absmax);
 136                 turnrate                = (autocvar_g_monster_mage_attack_spike_turnrate); // how fast to turn
 137                 desireddir              = normalize(eorg - self.origin);
 138                 olddir                  = normalize(self.velocity); // get my current direction
 139                 dist                    = vlen(eorg - self.origin);
 140
 141                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 142                 if ((autocvar_g_monster_mage_attack_spike_smart) && (dist > (autocvar_g_monster_mage_attack_spike_smart_mindist)))
 143                 {
 144                         // Is it a better idea (shorter distance) to trace to the target itself?
 145                         if ( vlen(self.origin + olddir * self.wait) < dist)
 146                                 traceline(self.origin, self.origin + olddir * self.wait, false, self);
 147                         else
 148                                 traceline(self.origin, eorg, false, self);
 149
 150                         // Setup adaptive tracelength
 151                         self.wait = bound((autocvar_g_monster_mage_attack_spike_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = (autocvar_g_monster_mage_attack_spike_smart_trace_max));
 152
 153                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 154                         desireddir = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 155                 }
 156
 157                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 158                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 159         }
 160         else
 161                 dist = 0;
 162
 163         ///////////////
 164
 165         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 166         self.nextthink = time;// + 0.05; // csqc projectiles
 167         UpdateCSQCProjectile(self);
 168 }
 169
 170 void mage_attack_spike()
 171 {
 172         entity missile;
 173         vector dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
 174
 175         makevectors(self.angles);
 176
 177         missile = spawn ();
 178         missile.owner = missile.realowner = self;
 179         missile.think = mage_spike_think;
 180         missile.ltime = time + 7;
 181         missile.nextthink = time;
 182         missile.solid = SOLID_BBOX;
 183         missile.movetype = MOVETYPE_FLYMISSILE;
 184         missile.flags = FL_PROJECTILE;
 185         setorigin(missile, self.origin + v_forward * 14 + '0 0 30' + v_right * -14);
 186         setsize (missile, '0 0 0', '0 0 0');
 187         missile.velocity = dir * 400;
 188         missile.avelocity = '300 300 300';
 189         missile.enemy = self.enemy;
 190         missile.touch = mage_spike_touch;
 191
 192         self.mage_spike = missile;
 193
 194         CSQCProjectile(missile, true, PROJECTILE_MAGE_SPIKE, true);
 195 }
 196
 197 void mage_heal()
 198 {
 199         entity head;
 200         float washealed = false;
 201
 202         for(head = findradius(self.origin, (autocvar_g_monster_mage_heal_range)); head; head = head.chain) if(friend_needshelp(head))
 203         {
 204                 washealed = true;
 205                 string fx = "";
 206                 if(IS_PLAYER(head))
 207                 {
 208                         switch(self.skin)
 209                         {
 210                                 case 0:
 211                                         if(head.health < autocvar_g_balance_health_regenstable) head.health = bound(0, head.health + (autocvar_g_monster_mage_heal_allies), autocvar_g_balance_health_regenstable);
 212                                         fx = "healing_fx";
 213                                         break;
 214                                 case 1:
 215                                         if(head.ammo_cells) head.ammo_cells = bound(head.ammo_cells, head.ammo_cells + 1, g_pickup_cells_max);
 216                                         if(head.ammo_plasma) head.ammo_plasma = bound(head.ammo_plasma, head.ammo_plasma + 1, g_pickup_plasma_max);
 217                                         if(head.ammo_rockets) head.ammo_rockets = bound(head.ammo_rockets, head.ammo_rockets + 1, g_pickup_rockets_max);
 218                                         if(head.ammo_shells) head.ammo_shells = bound(head.ammo_shells, head.ammo_shells + 2, g_pickup_shells_max);
 219                                         if(head.ammo_nails) head.ammo_nails = bound(head.ammo_nails, head.ammo_nails + 5, g_pickup_nails_max);
 220                                         fx = "ammoregen_fx";
 221                                         break;
 222                                 case 2:
 223                                         if(head.armorvalue < autocvar_g_balance_armor_regenstable)
 224                                         {
 225                                                 head.armorvalue = bound(0, head.armorvalue + (autocvar_g_monster_mage_heal_allies), autocvar_g_balance_armor_regenstable);
 226                                                 fx = "armorrepair_fx";
 227                                         }
 228                                         break;
 229                                 case 3:
 230                                         head.health = bound(0, head.health - ((head == self)  ? (autocvar_g_monster_mage_heal_self) : (autocvar_g_monster_mage_heal_allies)), autocvar_g_balance_health_regenstable);
 231                                         fx = "rage";
 232                                         break;
 233                         }
 234
 235                         Send_Effect(fx, head.origin, '0 0 0', 1);
 236                 }
 237                 else
 238                 {
 239                         Send_Effect("healing_fx", head.origin, '0 0 0', 1);
 240                         head.health = bound(0, head.health + (autocvar_g_monster_mage_heal_allies), head.max_health);
 241                         if(!(head.spawnflags & MONSTERFLAG_INVINCIBLE))
 242                                 WaypointSprite_UpdateHealth(head.sprite, head.health);
 243                 }
 244         }
 245
 246         if(washealed)
 247         {
 248                 self.frame = mage_anim_attack;
 249                 self.attack_finished_single = time + (autocvar_g_monster_mage_heal_delay);
 250         }
 251 }
 252
 253 void mage_push()
 254 {
 255         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 256         RadiusDamage (self, self, (autocvar_g_monster_mage_attack_push_damage), (autocvar_g_monster_mage_attack_push_damage), (autocvar_g_monster_mage_attack_push_radius), world, world, (autocvar_g_monster_mage_attack_push_force), DEATH_MONSTER_MAGE, self.enemy);
 257         Send_Effect("TE_EXPLOSION", self.origin, '0 0 0', 1);
 258
 259         self.frame = mage_anim_attack;
 260         self.attack_finished_single = time + (autocvar_g_monster_mage_attack_push_delay);
 261 }
 262
 263 void mage_teleport()
 264 {
 265         if(vlen(self.enemy.origin - self.origin) >= 500)
 266                 return;
 267
 268         makevectors(self.enemy.angles);
 269         tracebox(self.enemy.origin + ((v_forward * -1) * 200), self.mins, self.maxs, self.origin, MOVE_NOMONSTERS, self);
 270
 271         if(trace_fraction < 1)
 272                 return;
 273
 274         Send_Effect("spawn_event_neutral", self.origin, '0 0 0', 1);
 275         setorigin(self, self.enemy.origin + ((v_forward * -1) * 200));
 276
 277         self.attack_finished_single = time + 0.2;
 278 }
 279
 280 void mage_shield_remove()
 281 {
 282         self.effects &= ~(EF_ADDITIVE | EF_BLUE);
 283         self.armorvalue = 0;
 284         self.m_armor_blockpercent = autocvar_g_monsters_armor_blockpercent;
 285 }
 286
 287 void mage_shield()
 288 {
 289         self.effects |= (EF_ADDITIVE | EF_BLUE);
 290         self.lastshielded = time + (autocvar_g_monster_mage_shield_delay);
 291         self.m_armor_blockpercent = (autocvar_g_monster_mage_shield_blockpercent);
 292         self.armorvalue = self.health;
 293         self.shield_ltime = time + (autocvar_g_monster_mage_shield_time);
 294         self.frame = mage_anim_attack;
 295         self.attack_finished_single = time + 1;
 296 }
 297
 298 float mage_attack(float attack_type)
 299 {
 300         switch(attack_type)
 301         {
 302                 case MONSTER_ATTACK_MELEE:
 303                 {
 304                         if(random() <= 0.7)
 305                         {
 306                                 mage_push();
 307                                 return true;
 308                         }
 309
 310                         return false;
 311                 }
 312                 case MONSTER_ATTACK_RANGED:
 313                 {
 314                         if(!self.mage_spike)
 315                         {
 316                                 if(random() <= 0.4)
 317                                 {
 318                                         mage_teleport();
 319                                         return true;
 320                                 }
 321                                 else
 322                                 {
 323                                         self.frame = mage_anim_attack;
 324                                         self.attack_finished_single = time + (autocvar_g_monster_mage_attack_spike_delay);
 325                                         defer(0.2, mage_attack_spike);
 326                                         return true;
 327                                 }
 328                         }
 329
 330                         if(self.mage_spike)
 331                                 return true;
 332                         else
 333                                 return false;
 334                 }
 335         }
 336
 337         return false;
 338 }
 339
 340 void spawnfunc_monster_mage()
 341 {
 342         self.classname = "monster_mage";
 343
 344         if(!monster_initialize(MON_MAGE.monsterid)) { remove(self); return; }
 345 }
 346
 347 // compatibility with old spawns
 348 void spawnfunc_monster_shalrath() { spawnfunc_monster_mage(); }
 349
 350 float m_mage(float req)
 351 {
 352         switch(req)
 353         {
 354                 case MR_THINK:
 355                 {
 356                         entity head;
 357                         float need_help = false;
 358
 359                         for(head = findradius(self.origin, (autocvar_g_monster_mage_heal_range)); head; head = head.chain)
 360                         if(head != self)
 361                         if(friend_needshelp(head))
 362                         {
 363                                 need_help = true;
 364                                 break;
 365                         }
 366
 367                         if(self.health < (autocvar_g_monster_mage_heal_minhealth) || need_help)
 368                         if(time >= self.attack_finished_single)
 369                         if(random() < 0.5)
 370                                 mage_heal();
 371
 372                         if(time >= self.shield_ltime && self.armorvalue)
 373                                 mage_shield_remove();
 374
 375                         if(self.enemy)
 376                         if(self.health < self.max_health)
 377                         if(time >= self.lastshielded)
 378                         if(random() < 0.5)
 379                                 mage_shield();
 380
 381                         monster_move((autocvar_g_monster_mage_speed_run), (autocvar_g_monster_mage_speed_walk), (autocvar_g_monster_mage_speed_stop), mage_anim_walk, mage_anim_run, mage_anim_idle);
 382                         return true;
 383                 }
 384                 case MR_DEATH:
 385                 {
 386                         self.frame = mage_anim_death;
 387                         return true;
 388                 }
 389                 case MR_SETUP:
 390                 {
 391                         if(!self.health) self.health = (autocvar_g_monster_mage_health);
 392
 393                         self.monster_loot = spawnfunc_item_health_large;
 394                         self.monster_attackfunc = mage_attack;
 395                         self.frame = mage_anim_walk;
 396
 397                         return true;
 398                 }
 399                 case MR_PRECACHE:
 400                 {
 401                         precache_model("models/monsters/mage.dpm");
 402                         precache_sound ("weapons/grenade_impact.wav");
 403                         precache_sound ("weapons/tagexp1.wav");
 404                         return true;
 405                 }
 406         }
 407
 408         return true;
 409 }
 410
 411 #endif // SVQC
 412 #ifdef CSQC
 413 float m_mage(float req)
 414 {
 415         switch(req)
 416         {
 417                 case MR_PRECACHE:
 418                 {
 419                         return true;
 420                 }
 421         }
 422
 423         return true;
 424 }
 425
 426 #endif // CSQC