qcsrc/common/monsters/monster/shambler.qc

   1 #ifndef MENUQC
   2 bool m_shambler(int);
   3 #endif
   4 REGISTER_MONSTER_SIMPLE(
   5 /* MON_##id   */ SHAMBLER,
   6 /* spawnflags */ MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER | MON_FLAG_MELEE | MON_FLAG_RANGED,
   7 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   8 /* model      */ "shambler.mdl",
   9 /* netname    */ "shambler",
  10 /* fullname   */ _("Shambler")
  11 ) {
  12 #ifndef MENUQC
  13         this.monster_func = m_shambler;
  14 #endif
  15 }
  16
  17 #ifdef SVQC
  18 float autocvar_g_monster_shambler_health;
  19 float autocvar_g_monster_shambler_attack_smash_damage;
  20 float autocvar_g_monster_shambler_attack_claw_damage;
  21 float autocvar_g_monster_shambler_attack_lightning_damage;
  22 float autocvar_g_monster_shambler_attack_lightning_force;
  23 float autocvar_g_monster_shambler_attack_lightning_radius;
  24 float autocvar_g_monster_shambler_attack_lightning_radius_zap;
  25 float autocvar_g_monster_shambler_attack_lightning_speed;
  26 float autocvar_g_monster_shambler_attack_lightning_speed_up;
  27 float autocvar_g_monster_shambler_speed_stop;
  28 float autocvar_g_monster_shambler_speed_run;
  29 float autocvar_g_monster_shambler_speed_walk;
  30
  31 const float shambler_anim_stand         = 0;
  32 const float shambler_anim_walk          = 1;
  33 const float shambler_anim_run           = 2;
  34 const float shambler_anim_smash         = 3;
  35 const float shambler_anim_swingr        = 4;
  36 const float shambler_anim_swingl        = 5;
  37 const float shambler_anim_magic         = 6;
  38 const float shambler_anim_pain          = 7;
  39 const float shambler_anim_death         = 8;
  40
  41 .float shambler_lastattack; // delay attacks separately
  42
  43 void shambler_smash()
  44 {
  45         makevectors(self.angles);
  46         Send_Effect("explosion_medium", (self.origin + (v_forward * 150)) - ('0 0 1' * self.maxs.z), '0 0 0', 1);
  47         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
  48
  49         tracebox(self.origin + v_forward * 50, self.mins * 0.5, self.maxs * 0.5, self.origin + v_forward * 500, MOVE_NORMAL, self);
  50
  51         if(trace_ent.takedamage)
  52                 Damage(trace_ent, self, self, (autocvar_g_monster_shambler_attack_smash_damage) * Monster_SkillModifier(), DEATH_MONSTER_SHAMBLER_SMASH, trace_ent.origin, normalize(trace_ent.origin - self.origin));
  53 }
  54
  55 void shambler_swing()
  56 {
  57         float r = (random() < 0.5);
  58         monster_melee(self.enemy, (autocvar_g_monster_shambler_attack_claw_damage), ((r) ? shambler_anim_swingr : shambler_anim_swingl), self.attack_range, 0.8, DEATH_MONSTER_SHAMBLER_CLAW, true);
  59         if(r)
  60         {
  61                 defer(0.5, shambler_swing);
  62                 self.attack_finished_single += 0.5;
  63         }
  64 }
  65
  66 void shambler_lightning_explode()
  67 {
  68         entity head;
  69
  70         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
  71         Send_Effect("electro_impact", '0 0 0', '0 0 0', 1);
  72
  73         self.event_damage = func_null;
  74         self.takedamage = DAMAGE_NO;
  75         self.movetype = MOVETYPE_NONE;
  76         self.velocity = '0 0 0';
  77
  78         if(self.movetype == MOVETYPE_NONE)
  79                 self.velocity = self.oldvelocity;
  80
  81         RadiusDamage (self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_radius), world, world, (autocvar_g_monster_shambler_attack_lightning_force), self.projectiledeathtype, other);
  82
  83         for(head = findradius(self.origin, (autocvar_g_monster_shambler_attack_lightning_radius_zap)); head; head = head.chain) if(head != self.realowner) if(head.takedamage)
  84         {
  85                 te_csqc_lightningarc(self.origin, head.origin);
  86                 Damage(head, self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage) * Monster_SkillModifier(), DEATH_MONSTER_SHAMBLER_ZAP, head.origin, '0 0 0');
  87         }
  88
  89         self.think = SUB_Remove;
  90         self.nextthink = time + 0.2;
  91 }
  92
  93 void shambler_lightning_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
  94 {
  95         if (self.health <= 0)
  96                 return;
  97
  98         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  99                 return; // g_projectiles_damage says to halt
 100
 101         self.health = self.health - damage;
 102
 103         if (self.health <= 0)
 104                 W_PrepareExplosionByDamage(attacker, self.use);
 105 }
 106
 107 void shambler_lightning_touch()
 108 {
 109         PROJECTILE_TOUCH;
 110
 111         self.use ();
 112 }
 113
 114 void shambler_lightning_think()
 115 {
 116         self.nextthink = time;
 117         if (time > self.cnt)
 118         {
 119                 other = world;
 120                 shambler_lightning_explode();
 121                 return;
 122         }
 123 }
 124
 125 void shambler_lightning()
 126 {
 127         entity gren;
 128
 129         monster_makevectors(self.enemy);
 130
 131         gren = spawn ();
 132         gren.owner = gren.realowner = self;
 133         gren.classname = "grenade";
 134         gren.bot_dodge = true;
 135         gren.bot_dodgerating = (autocvar_g_monster_shambler_attack_lightning_damage);
 136         gren.movetype = MOVETYPE_BOUNCE;
 137         PROJECTILE_MAKETRIGGER(gren);
 138         gren.projectiledeathtype = DEATH_MONSTER_SHAMBLER_ZAP;
 139         setorigin(gren, CENTER_OR_VIEWOFS(self));
 140         setsize(gren, '-8 -8 -8', '8 8 8');
 141         gren.scale = 2.5;
 142
 143         gren.cnt = time + 5;
 144         gren.nextthink = time;
 145         gren.think = shambler_lightning_think;
 146         gren.use = shambler_lightning_explode;
 147         gren.touch = shambler_lightning_touch;
 148
 149         gren.takedamage = DAMAGE_YES;
 150         gren.health = 50;
 151         gren.damageforcescale = 0;
 152         gren.event_damage = shambler_lightning_damage;
 153         gren.damagedbycontents = true;
 154         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 155         W_SetupProjVelocity_Explicit(gren, v_forward, v_up, (autocvar_g_monster_shambler_attack_lightning_speed), (autocvar_g_monster_shambler_attack_lightning_speed_up), 0, 0, false);
 156
 157         gren.angles = vectoangles (gren.velocity);
 158         gren.flags = FL_PROJECTILE;
 159
 160         CSQCProjectile(gren, true, PROJECTILE_SHAMBLER_LIGHTNING, true);
 161 }
 162
 163 float shambler_attack(float attack_type)
 164 {
 165         switch(attack_type)
 166         {
 167                 case MONSTER_ATTACK_MELEE:
 168                 {
 169                         shambler_swing();
 170                         return true;
 171                 }
 172                 case MONSTER_ATTACK_RANGED:
 173                 {
 174                         if(time >= self.shambler_lastattack) // shambler doesn't attack much
 175                         if(self.flags & FL_ONGROUND)
 176                         if(random() <= 0.5 && vlen(self.enemy.origin - self.origin) <= 500)
 177                         {
 178                                 self.frame = shambler_anim_smash;
 179                                 defer(0.7, shambler_smash);
 180                                 self.attack_finished_single = time + 1.1;
 181                                 self.shambler_lastattack = time + 3;
 182                                 return true;
 183                         }
 184                         else if(random() <= 0.1) // small chance, don't want this spammed
 185                         {
 186                                 self.frame = shambler_anim_magic;
 187                                 self.attack_finished_single = time + 1.1;
 188                                 self.shambler_lastattack = time + 3;
 189                                 defer(0.6, shambler_lightning);
 190                                 return true;
 191                         }
 192
 193                         return false;
 194                 }
 195         }
 196
 197         return false;
 198 }
 199
 200 void spawnfunc_monster_shambler()
 201 {
 202         self.classname = "monster_shambler";
 203
 204         if(!monster_initialize(MON_SHAMBLER.monsterid)) { remove(self); return; }
 205 }
 206
 207 float m_shambler(float req)
 208 {
 209         switch(req)
 210         {
 211                 case MR_THINK:
 212                 {
 213                         monster_move((autocvar_g_monster_shambler_speed_run), (autocvar_g_monster_shambler_speed_walk), (autocvar_g_monster_shambler_speed_stop), shambler_anim_run, shambler_anim_walk, shambler_anim_stand);
 214                         return true;
 215                 }
 216                 case MR_DEATH:
 217                 {
 218                         self.frame = shambler_anim_death;
 219                         return true;
 220                 }
 221                 case MR_SETUP:
 222                 {
 223                         if(!self.health) self.health = (autocvar_g_monster_shambler_health);
 224                         if(!self.attack_range) self.attack_range = 150;
 225
 226                         self.monster_loot = spawnfunc_item_health_mega;
 227                         self.monster_attackfunc = shambler_attack;
 228                         self.frame = shambler_anim_stand;
 229                         self.weapon = WEP_VORTEX.m_id;
 230
 231                         return true;
 232                 }
 233                 case MR_PRECACHE:
 234                 {
 235                         precache_model("models/monsters/shambler.mdl");
 236                         return true;
 237                 }
 238         }
 239
 240         return true;
 241 }
 242
 243 #endif // SVQC
 244 #ifdef CSQC
 245 float m_shambler(float req)
 246 {
 247         switch(req)
 248         {
 249                 case MR_PRECACHE:
 250                 {
 251                         return true;
 252                 }
 253         }
 254
 255         return true;
 256 }
 257
 258 #endif // CSQC