qcsrc/common/monsters/monster/shambler.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SHAMBLER,
   4 /* function   */ m_shambler,
   5 /* spawnflags */ MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER | MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   7 /* model      */ "shambler.mdl",
   8 /* netname    */ "shambler",
   9 /* fullname   */ _("Shambler")
  10 );
  11
  12 #define SHAMBLER_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_smash_damage) \
  15         MON_ADD_CVAR(monster, attack_claw_damage) \
  16         MON_ADD_CVAR(monster, attack_lightning_damage) \
  17         MON_ADD_CVAR(monster, attack_lightning_force) \
  18         MON_ADD_CVAR(monster, attack_lightning_radius) \
  19         MON_ADD_CVAR(monster, attack_lightning_radius_zap) \
  20         MON_ADD_CVAR(monster, attack_lightning_speed) \
  21         MON_ADD_CVAR(monster, attack_lightning_speed_up) \
  22         MON_ADD_CVAR(monster, speed_stop) \
  23         MON_ADD_CVAR(monster, speed_run) \
  24         MON_ADD_CVAR(monster, speed_walk)
  25
  26 #ifdef SVQC
  27 SHAMBLER_SETTINGS(shambler)
  28 #endif // SVQC
  29 #else
  30 #ifdef SVQC
  31 const float shambler_anim_stand         = 0;
  32 const float shambler_anim_walk          = 1;
  33 const float shambler_anim_run           = 2;
  34 const float shambler_anim_smash         = 3;
  35 const float shambler_anim_swingr        = 4;
  36 const float shambler_anim_swingl        = 5;
  37 const float shambler_anim_magic         = 6;
  38 const float shambler_anim_pain          = 7;
  39 const float shambler_anim_death         = 8;
  40
  41 void shambler_smash()
  42 {
  43         makevectors(self.angles);
  44         pointparticles(particleeffectnum("explosion_medium"), (self.origin + (v_forward * 150)) - ('0 0 1' * self.maxs_z), '0 0 0', 1);
  45         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
  46
  47         tracebox(self.origin + v_forward * 50, self.mins * 0.5, self.maxs * 0.5, self.origin + v_forward * 500, MOVE_NORMAL, self);
  48
  49         if(trace_ent.takedamage)
  50                 Damage(trace_ent, self, self, MON_CVAR(shambler, attack_smash_damage) * Monster_SkillModifier(), DEATH_MONSTER_SHAMBLER_SMASH, trace_ent.origin, normalize(trace_ent.origin - self.origin));
  51 }
  52
  53 void shambler_swing()
  54 {
  55         float r = (random() < 0.5);
  56         monster_melee(self.enemy, MON_CVAR(shambler, attack_claw_damage), ((r) ? shambler_anim_swingr : shambler_anim_swingl), self.attack_range, 0.8, DEATH_MONSTER_SHAMBLER_CLAW, TRUE);
  57         if(r)
  58         {
  59                 defer(0.5, shambler_swing);
  60                 self.attack_finished_single += 0.5;
  61         }
  62 }
  63
  64 void shambler_lightning_explode()
  65 {
  66         entity head;
  67
  68         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
  69         pointparticles(particleeffectnum("electro_impact"), '0 0 0', '0 0 0', 1);
  70
  71         self.event_damage = func_null;
  72         self.takedamage = DAMAGE_NO;
  73         self.movetype = MOVETYPE_NONE;
  74         self.velocity = '0 0 0';
  75         UpdateCSQCProjectile(self);
  76
  77         if(self.movetype == MOVETYPE_NONE)
  78                 self.velocity = self.oldvelocity;
  79
  80         RadiusDamage (self, self.realowner, MON_CVAR(shambler, attack_lightning_damage), MON_CVAR(shambler, attack_lightning_damage), MON_CVAR(shambler, attack_lightning_radius), world, MON_CVAR(shambler, attack_lightning_force), self.projectiledeathtype, other);
  81
  82         for(head = findradius(self.origin, MON_CVAR(shambler, attack_lightning_radius_zap)); head; head = head.chain) if(head != self.realowner)
  83         {
  84                 te_csqc_lightningarc(self.origin, head.origin);
  85                 Damage(head, self, self.realowner, MON_CVAR(shambler, attack_lightning_damage) * Monster_SkillModifier(), DEATH_MONSTER_SHAMBLER_ZAP, head.origin, '0 0 0');
  86         }
  87
  88         self.think = SUB_Remove;
  89         self.nextthink = time + 0.2;
  90 }
  91
  92 void shambler_lightning_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  93 {
  94         if (self.health <= 0)
  95                 return;
  96
  97         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  98                 return; // g_projectiles_damage says to halt
  99
 100         self.health = self.health - damage;
 101
 102         if (self.health <= 0)
 103                 W_PrepareExplosionByDamage(attacker, self.use);
 104 }
 105
 106 void shambler_lightning_touch()
 107 {
 108         PROJECTILE_TOUCH;
 109
 110         self.use ();
 111 }
 112
 113 void shambler_lightning_think()
 114 {
 115         self.nextthink = time;
 116         if (time > self.cnt)
 117         {
 118                 other = world;
 119                 shambler_lightning_explode();
 120                 return;
 121         }
 122 }
 123
 124 void shambler_lightning()
 125 {
 126         entity gren;
 127
 128         monster_makevectors(self.enemy);
 129
 130         gren = spawn ();
 131         gren.owner = gren.realowner = self;
 132         gren.classname = "grenade";
 133         gren.bot_dodge = TRUE;
 134         gren.bot_dodgerating = MON_CVAR(shambler, attack_lightning_damage);
 135         gren.movetype = MOVETYPE_BOUNCE;
 136         PROJECTILE_MAKETRIGGER(gren);
 137         gren.projectiledeathtype = DEATH_MONSTER_SHAMBLER_ZAP;
 138         setorigin(gren, CENTER_OR_VIEWOFS(self));
 139         setsize(gren, '-8 -8 -8', '8 8 8');
 140         gren.scale = 2.5;
 141
 142         gren.cnt = time + 5;
 143         gren.nextthink = time;
 144         gren.think = shambler_lightning_think;
 145         gren.use = shambler_lightning_explode;
 146         gren.touch = shambler_lightning_touch;
 147
 148         gren.takedamage = DAMAGE_YES;
 149         gren.health = 50;
 150         gren.damageforcescale = 0;
 151         gren.event_damage = shambler_lightning_damage;
 152         gren.damagedbycontents = TRUE;
 153         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 154         W_SetupProjectileVelocityEx(gren, v_forward, v_up, MON_CVAR(shambler, attack_lightning_speed), MON_CVAR(shambler, attack_lightning_speed_up), 0, 0, FALSE);
 155
 156         gren.angles = vectoangles (gren.velocity);
 157         gren.flags = FL_PROJECTILE;
 158
 159         CSQCProjectile(gren, TRUE, PROJECTILE_SHAMBLER_LIGHTNING, TRUE);
 160 }
 161
 162 float shambler_attack(float attack_type)
 163 {
 164         switch(attack_type)
 165         {
 166                 case MONSTER_ATTACK_MELEE:
 167                 {
 168                         shambler_swing();
 169                         return TRUE;
 170                 }
 171                 case MONSTER_ATTACK_RANGED:
 172                 {
 173                         if(random() <= 0.5 && vlen(self.enemy.origin - self.origin) <= 500)
 174                         {
 175                                 self.frame = shambler_anim_smash;
 176                                 defer(0.7, shambler_smash);
 177                                 self.attack_finished_single = time + 1.1;
 178                         }
 179                         else
 180                         {
 181                                 self.frame = shambler_anim_magic;
 182                                 self.attack_finished_single = time + 1.1;
 183                                 defer(0.6, shambler_lightning);
 184                         }
 185
 186                         return TRUE;
 187                 }
 188         }
 189
 190         return FALSE;
 191 }
 192
 193 void spawnfunc_monster_shambler()
 194 {
 195         self.classname = "monster_shambler";
 196
 197         self.monster_spawnfunc = spawnfunc_monster_shambler;
 198
 199         if(Monster_CheckAppearFlags(self))
 200                 return;
 201
 202         if not(monster_initialize(MON_SHAMBLER, FALSE)) { remove(self); return; }
 203 }
 204
 205 float m_shambler(float req)
 206 {
 207         switch(req)
 208         {
 209                 case MR_THINK:
 210                 {
 211                         monster_move(MON_CVAR(shambler, speed_run), MON_CVAR(shambler, speed_walk), MON_CVAR(shambler, speed_stop), shambler_anim_run, shambler_anim_walk, shambler_anim_stand);
 212                         return TRUE;
 213                 }
 214                 case MR_DEATH:
 215                 {
 216                         self.frame = shambler_anim_death;
 217                         return TRUE;
 218                 }
 219                 case MR_SETUP:
 220                 {
 221                         if not(self.health) self.health = MON_CVAR(shambler, health);
 222                         if not(self.attack_range) self.attack_range = 150;
 223
 224                         self.monster_loot = spawnfunc_item_health_mega;
 225                         self.monster_attackfunc = shambler_attack;
 226                         self.frame = shambler_anim_stand;
 227                         self.weapon = WEP_NEX;
 228
 229                         return TRUE;
 230                 }
 231                 case MR_PRECACHE:
 232                 {
 233                         precache_model ("models/monsters/shambler.mdl");
 234                         return TRUE;
 235                 }
 236                 case MR_CONFIG:
 237                 {
 238                         MON_CONFIG_SETTINGS(SHAMBLER_SETTINGS(shambler))
 239                         return TRUE;
 240                 }
 241         }
 242
 243         return TRUE;
 244 }
 245
 246 #endif // SVQC
 247 #ifdef CSQC
 248 float m_shambler(float req)
 249 {
 250         switch(req)
 251         {
 252                 case MR_PRECACHE:
 253                 {
 254                         precache_model ("models/monsters/shambler.mdl");
 255                         return TRUE;
 256                 }
 257         }
 258
 259         return TRUE;
 260 }
 261
 262 #endif // CSQC
 263 #endif // REGISTER_MONSTER