qcsrc/common/monsters/monster/spider.qc

   1 #ifndef SPIDER_H
   2 #define SPIDER_H
   3
   4 #ifndef MENUQC
   5 MODEL(MON_SPIDER, "models/monsters/spider.dpm");
   6 #endif
   7
   8 CLASS(Spider, Monster)
   9     ATTRIB(Spider, spawnflags, int, MON_FLAG_MELEE | MON_FLAG_RANGED | MON_FLAG_RIDE);
  10     ATTRIB(Spider, mins, vector, '-18 -18 -25');
  11     ATTRIB(Spider, maxs, vector, '18 18 30');
  12 #ifndef MENUQC
  13     ATTRIB(Spider, m_model, Model, MDL_MON_SPIDER);
  14 #endif
  15     ATTRIB(Spider, netname, string, "spider");
  16     ATTRIB(Spider, monster_name, string, _("Spider"));
  17 ENDCLASS(Spider)
  18
  19 REGISTER_MONSTER(SPIDER, NEW(Spider)) {
  20 #ifndef MENUQC
  21     MON_ACTION(this, MR_PRECACHE);
  22 #endif
  23 }
  24
  25 #include "../../weapons/all.qh"
  26
  27 CLASS(SpiderAttack, PortoLaunch)
  28 /* flags     */ ATTRIB(SpiderAttack, spawnflags, int, WEP_TYPE_OTHER | WEP_FLAG_HIDDEN);
  29 /* impulse   */ ATTRIB(SpiderAttack, impulse, int, 9);
  30 /* refname   */ ATTRIB(SpiderAttack, netname, string, "spider");
  31 /* wepname   */ ATTRIB(SpiderAttack, message, string, _("Spider attack"));
  32 ENDCLASS(SpiderAttack)
  33 REGISTER_WEAPON(SPIDER_ATTACK, NEW(SpiderAttack));
  34
  35 #endif
  36
  37 #ifdef IMPLEMENTATION
  38
  39 #ifdef SVQC
  40
  41 .float spider_web_delay;
  42
  43 float autocvar_g_monster_spider_attack_web_damagetime;
  44 float autocvar_g_monster_spider_attack_web_speed;
  45 float autocvar_g_monster_spider_attack_web_speed_up;
  46 float autocvar_g_monster_spider_attack_web_delay;
  47
  48 float autocvar_g_monster_spider_attack_bite_damage;
  49 float autocvar_g_monster_spider_attack_bite_delay;
  50
  51 void M_Spider_Attack_Web();
  52
  53 METHOD(SpiderAttack, wr_think, void(SpiderAttack thiswep, entity actor, bool fire1, bool fire2)) {
  54     bool isPlayer = IS_PLAYER(actor);
  55     if (fire1)
  56     if ((!isPlayer && time >= actor.spider_web_delay) || weapon_prepareattack(actor, false, autocvar_g_monster_spider_attack_web_delay)) {
  57                 if (!isPlayer) {
  58                         actor.spider_web_delay = time + 3;
  59                         setanim(actor, actor.anim_shoot, true, true, true);
  60                         actor.attack_finished_single = time + (autocvar_g_monster_spider_attack_web_delay);
  61                         actor.anim_finished = time + 1;
  62                 }
  63         if (isPlayer) actor.enemy = Monster_FindTarget(actor);
  64         W_SetupShot_Dir(actor, v_forward, false, 0, W_Sound("electro_fire"), CH_WEAPON_B, 0);
  65         if (!isPlayer) w_shotdir = normalize((actor.enemy.origin + '0 0 10') - actor.origin);
  66                 M_Spider_Attack_Web();
  67         weapon_thinkf(actor, WFRAME_FIRE1, 0, w_ready);
  68         return;
  69     }
  70     if (fire2)
  71     if (!isPlayer || weapon_prepareattack(actor, true, 0.5)) {
  72         if (isPlayer) {
  73                 actor.enemy = Monster_FindTarget(actor);
  74                 actor.attack_range = 60;
  75         }
  76         Monster_Attack_Melee(actor.enemy, (autocvar_g_monster_spider_attack_bite_damage), ((random() > 0.5) ? self.anim_melee : self.anim_shoot), self.attack_range, (autocvar_g_monster_spider_attack_bite_delay), DEATH_MONSTER_SPIDER, true);
  77         weapon_thinkf(actor, WFRAME_FIRE2, 0, w_ready);
  78     }
  79 }
  80
  81 float autocvar_g_monster_spider_health;
  82 float autocvar_g_monster_spider_damageforcescale = 0.6;
  83 float autocvar_g_monster_spider_speed_stop;
  84 float autocvar_g_monster_spider_speed_run;
  85 float autocvar_g_monster_spider_speed_walk;
  86
  87 /*
  88 const float spider_anim_idle            = 0;
  89 const float spider_anim_walk            = 1;
  90 const float spider_anim_attack          = 2;
  91 const float spider_anim_attack2         = 3;
  92 */
  93
  94 void M_Spider_Attack_Web_Explode()
  95 {SELFPARAM();
  96         entity e;
  97         if(self)
  98         {
  99                 Send_Effect(EFFECT_ELECTRO_IMPACT, self.origin, '0 0 0', 1);
 100                 RadiusDamage(self, self.realowner, 0, 0, 25, world, world, 25, self.projectiledeathtype, world);
 101
 102                 for(e = findradius(self.origin, 25); e; e = e.chain) if(e != self) if(e.takedamage && e.deadflag == DEAD_NO) if(e.health > 0) if(e.monsterid != MON_SPIDER.monsterid)
 103                         e.spider_slowness = time + (autocvar_g_monster_spider_attack_web_damagetime);
 104
 105                 remove(self);
 106         }
 107 }
 108
 109 void M_Spider_Attack_Web_Touch()
 110 {
 111         PROJECTILE_TOUCH;
 112
 113         M_Spider_Attack_Web_Explode();
 114 }
 115
 116 void M_Spider_Attack_Web()
 117 {SELFPARAM();
 118         monster_makevectors(self.enemy);
 119
 120         sound(self, CH_SHOTS, SND_ELECTRO_FIRE2, VOL_BASE, ATTEN_NORM);
 121
 122         entity proj = spawn ();
 123         proj.classname = "plasma";
 124         proj.owner = proj.realowner = self;
 125         proj.use = M_Spider_Attack_Web_Explode;
 126         proj.think = adaptor_think2use_hittype_splash;
 127         proj.bot_dodge = true;
 128         proj.bot_dodgerating = 0;
 129         proj.nextthink = time + 5;
 130         PROJECTILE_MAKETRIGGER(proj);
 131         proj.projectiledeathtype = DEATH_MONSTER_SPIDER;
 132         setorigin(proj, CENTER_OR_VIEWOFS(self));
 133
 134         //proj.glow_size = 50;
 135         //proj.glow_color = 45;
 136         proj.movetype = MOVETYPE_BOUNCE;
 137         W_SetupProjVelocity_Explicit(proj, v_forward, v_up, (autocvar_g_monster_spider_attack_web_speed), (autocvar_g_monster_spider_attack_web_speed_up), 0, 0, false);
 138         proj.touch = M_Spider_Attack_Web_Touch;
 139         setsize(proj, '-4 -4 -4', '4 4 4');
 140         proj.takedamage = DAMAGE_NO;
 141         proj.damageforcescale = 0;
 142         proj.health = 500;
 143         proj.event_damage = func_null;
 144         proj.flags = FL_PROJECTILE;
 145         proj.damagedbycontents = true;
 146
 147         proj.bouncefactor = 0.3;
 148         proj.bouncestop = 0.05;
 149         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 150
 151         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, true);
 152 }
 153
 154 bool M_Spider_Attack(int attack_type, entity targ)
 155 {SELFPARAM();
 156         switch(attack_type)
 157         {
 158                 Weapon wep = WEP_SPIDER_ATTACK;
 159                 case MONSTER_ATTACK_MELEE:
 160                 {
 161                         wep.wr_think(wep, self, false, true);
 162                         return true;
 163                 }
 164                 case MONSTER_ATTACK_RANGED:
 165                 {
 166                         wep.wr_think(wep, self, true, false);
 167                         return true;
 168                 }
 169         }
 170
 171         return false;
 172 }
 173
 174 void spawnfunc_monster_spider() { Monster_Spawn(MON_SPIDER.monsterid); }
 175 #endif // SVQC
 176
 177                 #ifdef SVQC
 178                 METHOD(Spider, mr_think, bool(Spider thismon))
 179                 {
 180                         return true;
 181                 }
 182                 METHOD(Spider, mr_pain, bool(Spider thismon))
 183                 {
 184                         return true;
 185                 }
 186                 METHOD(Spider, mr_death, bool(Spider thismon))
 187                 {
 188                         SELFPARAM();
 189                         setanim(self, self.anim_melee, false, true, true);
 190                         self.angles_x = 180;
 191                         return true;
 192                 }
 193                 #endif
 194                 #ifndef MENUQC
 195                 METHOD(Spider, mr_anim, bool(Spider thismon))
 196                 {
 197                         SELFPARAM();
 198                         vector none = '0 0 0';
 199                         self.anim_walk = animfixfps(self, '1 1 1', none);
 200                         self.anim_idle = animfixfps(self, '0 1 1', none);
 201                         self.anim_melee = animfixfps(self, '2 1 5', none); // analyze models and set framerate
 202                         self.anim_shoot = animfixfps(self, '3 1 5', none); // analyze models and set framerate
 203                         self.anim_run = animfixfps(self, '1 1 1', none);
 204
 205                         return true;
 206                 }
 207                 #endif
 208                 #ifdef SVQC
 209                 METHOD(Spider, mr_setup, bool(Spider thismon))
 210                 {
 211                         SELFPARAM();
 212                         if(!self.health) self.health = (autocvar_g_monster_spider_health);
 213                         if(!self.speed) { self.speed = (autocvar_g_monster_spider_speed_walk); }
 214                         if(!self.speed2) { self.speed2 = (autocvar_g_monster_spider_speed_run); }
 215                         if(!self.stopspeed) { self.stopspeed = (autocvar_g_monster_spider_speed_stop); }
 216                         if(!self.damageforcescale) { self.damageforcescale = (autocvar_g_monster_spider_damageforcescale); }
 217
 218                         self.monster_loot = spawnfunc_item_health_medium;
 219                         self.monster_attackfunc = M_Spider_Attack;
 220
 221                         return true;
 222                 }
 223                 METHOD(Spider, mr_precache, bool(Spider thismon))
 224                 {
 225                         return true;
 226                 }
 227                 #endif
 228
 229 #endif