qcsrc/common/monsters/monster/spider.qc

   1 #include "spider.qh"
   2
   3 #ifdef SVQC
   4
   5 .float spider_slowness; // effect time of slowness inflicted by spiders
   6
   7 .float spider_web_delay;
   8
   9 float autocvar_g_monster_spider_attack_web_damagetime;
  10 float autocvar_g_monster_spider_attack_web_speed;
  11 float autocvar_g_monster_spider_attack_web_speed_up;
  12 float autocvar_g_monster_spider_attack_web_delay;
  13
  14 float autocvar_g_monster_spider_attack_bite_damage;
  15 float autocvar_g_monster_spider_attack_bite_delay;
  16
  17 void M_Spider_Attack_Web(entity this);
  18
  19 REGISTER_MUTATOR(spiderweb, true);
  20
  21 MUTATOR_HOOKFUNCTION(spiderweb, PlayerPhysics)
  22 {
  23     entity player = M_ARGV(0, entity);
  24
  25         if (time >= player.spider_slowness)
  26                 return false;
  27         PHYS_MAXSPEED(player) *= 0.5; // half speed while slow from spider
  28         PHYS_MAXAIRSPEED(player) *= 0.5;
  29         PHYS_AIRSPEEDLIMIT_NONQW(player) *= 0.5;
  30         PHYS_AIRSTRAFEACCELERATE(player) *= 0.5;
  31 }
  32
  33 MUTATOR_HOOKFUNCTION(spiderweb, MonsterMove)
  34 {
  35     entity mon = M_ARGV(0, entity);
  36
  37         if(time < mon.spider_slowness)
  38         {
  39                 M_ARGV(1, float) *= 0.5; // run speed
  40                 M_ARGV(2, float) *= 0.5; // walk speed
  41         }
  42 }
  43
  44 MUTATOR_HOOKFUNCTION(spiderweb, PlayerSpawn)
  45 {
  46         entity player = M_ARGV(0, entity);
  47
  48         player.spider_slowness = 0;
  49         return false;
  50 }
  51
  52 MUTATOR_HOOKFUNCTION(spiderweb, MonsterSpawn)
  53 {
  54     entity mon = M_ARGV(0, entity);
  55
  56         mon.spider_slowness = 0;
  57 }
  58
  59 SOUND(SpiderAttack_FIRE, W_Sound("electro_fire"));
  60 METHOD(SpiderAttack, wr_think, void(SpiderAttack thiswep, entity actor, .entity weaponentity, int fire))
  61 {
  62     TC(SpiderAttack, thiswep);
  63     bool isPlayer = IS_PLAYER(actor);
  64     if (fire & 1)
  65     if ((!isPlayer && time >= actor.spider_web_delay) || weapon_prepareattack(thiswep, actor, weaponentity, false, autocvar_g_monster_spider_attack_web_delay)) {
  66                 if (!isPlayer) {
  67                         actor.spider_web_delay = time + 3;
  68                         setanim(actor, actor.anim_shoot, true, true, true);
  69                         actor.attack_finished_single[0] = time + (autocvar_g_monster_spider_attack_web_delay);
  70                         actor.anim_finished = time + 1;
  71                 }
  72         if (isPlayer) actor.enemy = Monster_FindTarget(actor);
  73         W_SetupShot_Dir(actor, weaponentity, v_forward, false, 0, SND_SpiderAttack_FIRE, CH_WEAPON_B, 0);
  74         if (!isPlayer) w_shotdir = normalize((actor.enemy.origin + '0 0 10') - actor.origin);
  75                 M_Spider_Attack_Web(actor);
  76         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, w_ready);
  77         return;
  78     }
  79     if (fire & 2)
  80     if (!isPlayer || weapon_prepareattack(thiswep, actor, weaponentity, true, 0.5)) {
  81         if (isPlayer) {
  82                 actor.enemy = Monster_FindTarget(actor);
  83                 actor.attack_range = 60;
  84         }
  85         Monster_Attack_Melee(actor, actor.enemy, (autocvar_g_monster_spider_attack_bite_damage), ((random() > 0.5) ? actor.anim_melee : actor.anim_shoot), actor.attack_range, (autocvar_g_monster_spider_attack_bite_delay), DEATH_MONSTER_SPIDER.m_id, true);
  86         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, 0, w_ready);
  87     }
  88 }
  89
  90 float autocvar_g_monster_spider_health;
  91 float autocvar_g_monster_spider_damageforcescale = 0.6;
  92 float autocvar_g_monster_spider_speed_stop;
  93 float autocvar_g_monster_spider_speed_run;
  94 float autocvar_g_monster_spider_speed_walk;
  95
  96 /*
  97 const float spider_anim_idle            = 0;
  98 const float spider_anim_walk            = 1;
  99 const float spider_anim_attack          = 2;
 100 const float spider_anim_attack2         = 3;
 101 */
 102
 103 void M_Spider_Attack_Web_Explode(entity this)
 104 {
 105         if(this)
 106         {
 107                 Send_Effect(EFFECT_ELECTRO_IMPACT, this.origin, '0 0 0', 1);
 108                 RadiusDamage(this, this.realowner, 0, 0, 25, NULL, NULL, 25, this.projectiledeathtype, NULL);
 109
 110                 FOREACH_ENTITY_RADIUS(this.origin, 25, it != this && it.takedamage && !IS_DEAD(it) && it.health > 0 && it.monsterid != MON_SPIDER.monsterid,
 111                 {
 112                         it.spider_slowness = time + (autocvar_g_monster_spider_attack_web_damagetime);
 113                 });
 114
 115                 delete(this);
 116         }
 117 }
 118
 119 void M_Spider_Attack_Web_Explode_use(entity this, entity actor, entity trigger)
 120 {
 121         M_Spider_Attack_Web_Explode(this);
 122 }
 123
 124 void M_Spider_Attack_Web_Touch(entity this, entity toucher)
 125 {
 126         PROJECTILE_TOUCH(this, toucher);
 127
 128         M_Spider_Attack_Web_Explode(this);
 129 }
 130
 131 void adaptor_think2use_hittype_splash(entity this);
 132
 133 void M_Spider_Attack_Web(entity this)
 134 {
 135         monster_makevectors(this, this.enemy);
 136
 137         sound(this, CH_SHOTS, SND_ELECTRO_FIRE2, VOL_BASE, ATTEN_NORM);
 138
 139         entity proj = new(plasma);
 140         proj.owner = proj.realowner = this;
 141         proj.use = M_Spider_Attack_Web_Explode_use;
 142         setthink(proj, adaptor_think2use_hittype_splash);
 143         proj.bot_dodge = true;
 144         proj.bot_dodgerating = 0;
 145         proj.nextthink = time + 5;
 146         PROJECTILE_MAKETRIGGER(proj);
 147         proj.projectiledeathtype = DEATH_MONSTER_SPIDER.m_id;
 148         setorigin(proj, CENTER_OR_VIEWOFS(this));
 149
 150         //proj.glow_size = 50;
 151         //proj.glow_color = 45;
 152         set_movetype(proj, MOVETYPE_BOUNCE);
 153         W_SetupProjVelocity_Explicit(proj, v_forward, v_up, (autocvar_g_monster_spider_attack_web_speed), (autocvar_g_monster_spider_attack_web_speed_up), 0, 0, false);
 154         settouch(proj, M_Spider_Attack_Web_Touch);
 155         setsize(proj, '-4 -4 -4', '4 4 4');
 156         proj.takedamage = DAMAGE_NO;
 157         proj.damageforcescale = 0;
 158         proj.health = 500;
 159         proj.event_damage = func_null;
 160         proj.flags = FL_PROJECTILE;
 161         IL_PUSH(g_projectiles, proj);
 162         IL_PUSH(g_bot_dodge, proj);
 163         proj.damagedbycontents = true;
 164         IL_PUSH(g_damagedbycontents, proj);
 165
 166         proj.bouncefactor = 0.3;
 167         proj.bouncestop = 0.05;
 168         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 169
 170         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, true);
 171 }
 172
 173 bool M_Spider_Attack(int attack_type, entity actor, entity targ)
 174 {
 175     .entity weaponentity = weaponentities[0];
 176         switch(attack_type)
 177         {
 178                 Weapon wep = WEP_SPIDER_ATTACK;
 179                 case MONSTER_ATTACK_MELEE:
 180                 {
 181                         wep.wr_think(wep, actor, weaponentity, 2);
 182                         return true;
 183                 }
 184                 case MONSTER_ATTACK_RANGED:
 185                 {
 186                         wep.wr_think(wep, actor, weaponentity, 1);
 187                         return true;
 188                 }
 189         }
 190
 191         return false;
 192 }
 193
 194 spawnfunc(monster_spider) { Monster_Spawn(this, true, MON_SPIDER.monsterid); }
 195 #endif // SVQC
 196
 197 #ifdef SVQC
 198 METHOD(Spider, mr_think, bool(Spider this, entity actor))
 199 {
 200     TC(Spider, this);
 201     return true;
 202 }
 203
 204 METHOD(Spider, mr_pain, float(Spider this, entity actor, float damage_take, entity attacker, float deathtype))
 205 {
 206     TC(Spider, this);
 207     return damage_take;
 208 }
 209
 210 METHOD(Spider, mr_death, bool(Spider this, entity actor))
 211 {
 212     TC(Spider, this);
 213     setanim(actor, actor.anim_melee, false, true, true);
 214     actor.angles_x = 180;
 215     return true;
 216 }
 217 #endif
 218 #ifdef GAMEQC
 219 METHOD(Spider, mr_anim, bool(Spider this, entity actor))
 220 {
 221     TC(Spider, this);
 222     vector none = '0 0 0';
 223     actor.anim_walk = animfixfps(actor, '1 1 1', none);
 224     actor.anim_idle = animfixfps(actor, '0 1 1', none);
 225     actor.anim_melee = animfixfps(actor, '2 1 5', none); // analyze models and set framerate
 226     actor.anim_shoot = animfixfps(actor, '3 1 5', none); // analyze models and set framerate
 227     actor.anim_run = animfixfps(actor, '1 1 1', none);
 228     return true;
 229 }
 230 #endif
 231 #ifdef SVQC
 232 spawnfunc(item_health_medium);
 233 METHOD(Spider, mr_setup, bool(Spider this, entity actor))
 234 {
 235     TC(Spider, this);
 236     if(!actor.health) actor.health = (autocvar_g_monster_spider_health);
 237     if(!actor.speed) { actor.speed = (autocvar_g_monster_spider_speed_walk); }
 238     if(!actor.speed2) { actor.speed2 = (autocvar_g_monster_spider_speed_run); }
 239     if(!actor.stopspeed) { actor.stopspeed = (autocvar_g_monster_spider_speed_stop); }
 240     if(!actor.damageforcescale) { actor.damageforcescale = (autocvar_g_monster_spider_damageforcescale); }
 241
 242     actor.monster_loot = spawnfunc_item_health_medium;
 243     actor.monster_attackfunc = M_Spider_Attack;
 244
 245     return true;
 246 }
 247
 248 METHOD(Spider, mr_precache, bool(Spider this))
 249 {
 250     TC(Spider, this);
 251     return true;
 252 }
 253 #endif