qcsrc/common/monsters/monster/spider.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SPIDER,
   4 /* function   */ m_spider,
   5 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-18 -18 -25', '18 18 30',
   7 /* model      */ "spider.dpm",
   8 /* netname    */ "spider",
   9 /* fullname   */ _("Spider")
  10 );
  11
  12 #define SPIDER_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_bite_damage) \
  15         MON_ADD_CVAR(monster, attack_bite_delay) \
  16         MON_ADD_CVAR(monster, attack_web_damagetime) \
  17         MON_ADD_CVAR(monster, attack_web_speed) \
  18         MON_ADD_CVAR(monster, attack_web_speed_up) \
  19         MON_ADD_CVAR(monster, attack_web_delay) \
  20         MON_ADD_CVAR(monster, attack_type) \
  21         MON_ADD_CVAR(monster, speed_stop) \
  22         MON_ADD_CVAR(monster, speed_run) \
  23         MON_ADD_CVAR(monster, speed_walk)
  24
  25 #ifdef SVQC
  26 SPIDER_SETTINGS(spider)
  27 #endif // SVQC
  28 #else
  29 #ifdef SVQC
  30 const float spider_anim_idle            = 0;
  31 const float spider_anim_walk            = 1;
  32 const float spider_anim_attack          = 2;
  33 const float spider_anim_attack2         = 3;
  34
  35 .float spider_type; // used to switch between fire & ice attacks
  36 const float SPIDER_TYPE_ICE             = 0;
  37 const float SPIDER_TYPE_FIRE    = 1;
  38
  39 void spider_web_explode()
  40 {
  41         entity e;
  42         if(self)
  43         {
  44                 float damg = 0, edamg = 0, rad = 1;
  45                 switch(self.realowner.spider_type)
  46                 {
  47                         case SPIDER_TYPE_ICE:
  48                                 rad = 25;
  49                                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
  50                                 break;
  51                         case SPIDER_TYPE_FIRE:
  52                                 pointparticles(particleeffectnum("fireball_explode"), self.origin, '0 0 0', 1);
  53                                 damg = 15;
  54                                 rad = 25;
  55                                 edamg = 6;
  56                                 break;
  57                 }
  58
  59                 RadiusDamage(self, self.realowner, damg, edamg, rad, world, rad, DEATH_MONSTER_SPIDER_FIRE, world); // ice deals no damage anyway
  60
  61                 for(e = findradius(self.origin, rad); e; e = e.chain) if(e != self) if(e.takedamage && e.deadflag == DEAD_NO) if(e.health > 0)
  62                 {
  63                         switch(self.realowner.spider_type)
  64                         {
  65                                 case SPIDER_TYPE_ICE:
  66                                         Freeze(e, 0.3, 2, FALSE);
  67                                         break;
  68                                 case SPIDER_TYPE_FIRE:
  69                                         Fire_AddDamage(e, self.realowner, 5 * monster_skill, MON_CVAR(spider, attack_web_damagetime), DEATH_MONSTER_SPIDER_FIRE);
  70                                         break;
  71                         }
  72                 }
  73
  74                 remove(self);
  75         }
  76 }
  77
  78 void spider_web_touch()
  79 {
  80         PROJECTILE_TOUCH;
  81
  82         spider_web_explode();
  83 }
  84
  85 void spider_shootweb(float ptype)
  86 {
  87         float p = 0;
  88         string snd = "";
  89         switch(ptype)
  90         {
  91                 case SPIDER_TYPE_ICE:
  92                         p = PROJECTILE_ELECTRO;
  93                         snd = "weapons/electro_fire2.wav";
  94                         break;
  95                 case SPIDER_TYPE_FIRE:
  96                         p = PROJECTILE_FIREMINE;
  97                         snd = "weapons/fireball_fire.wav";
  98                         break;
  99         }
 100
 101         monster_makevectors(self.enemy);
 102
 103         sound(self, CH_SHOTS, snd, VOL_BASE, ATTEN_NORM);
 104
 105         entity proj = spawn ();
 106         proj.classname = "plasma";
 107         proj.owner = proj.realowner = self;
 108         proj.use = spider_web_touch;
 109         proj.think = adaptor_think2use_hittype_splash;
 110         proj.bot_dodge = TRUE;
 111         proj.bot_dodgerating = 0;
 112         proj.nextthink = time + 5;
 113         PROJECTILE_MAKETRIGGER(proj);
 114         proj.projectiledeathtype = DEATH_MONSTER_SPIDER_FIRE;
 115         setorigin(proj, CENTER_OR_VIEWOFS(self));
 116
 117         //proj.glow_size = 50;
 118         //proj.glow_color = 45;
 119         proj.movetype = MOVETYPE_BOUNCE;
 120         W_SetupProjectileVelocityEx(proj, v_forward, v_up, MON_CVAR(spider, attack_web_speed), MON_CVAR(spider, attack_web_speed_up), 0, 0, FALSE);
 121         proj.touch = spider_web_touch;
 122         setsize(proj, '-4 -4 -4', '4 4 4');
 123         proj.takedamage = DAMAGE_NO;
 124         proj.damageforcescale = 0;
 125         proj.health = 500;
 126         proj.event_damage = func_null;
 127         proj.flags = FL_PROJECTILE;
 128         proj.damagedbycontents = TRUE;
 129
 130         proj.bouncefactor = 0.3;
 131         proj.bouncestop = 0.05;
 132         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 133
 134         CSQCProjectile(proj, TRUE, p, TRUE);
 135 }
 136
 137 float spider_attack(float attack_type)
 138 {
 139         switch(attack_type)
 140         {
 141                 case MONSTER_ATTACK_MELEE:
 142                 {
 143                         return monster_melee(self.enemy, MON_CVAR(spider, attack_bite_damage), ((random() > 0.5) ? spider_anim_attack : spider_anim_attack2), self.attack_range, MON_CVAR(spider, attack_bite_delay), DEATH_MONSTER_SPIDER, TRUE);
 144                 }
 145                 case MONSTER_ATTACK_RANGED:
 146                 {
 147                         if(self.enemy.frozen)
 148                                 return FALSE;
 149
 150                         monsters_setframe(spider_anim_attack2);
 151                         self.attack_finished_single = time + MON_CVAR(spider, attack_web_delay);
 152                         spider_shootweb(self.spider_type);
 153
 154                         return TRUE;
 155                 }
 156         }
 157
 158         return FALSE;
 159 }
 160
 161 void spawnfunc_monster_spider()
 162 {
 163         self.classname = "monster_spider";
 164
 165         self.monster_spawnfunc = spawnfunc_monster_spider;
 166
 167         if(Monster_CheckAppearFlags(self))
 168                 return;
 169
 170         if not(monster_initialize(MON_SPIDER, FALSE)) { remove(self); return; }
 171 }
 172
 173 float m_spider(float req)
 174 {
 175         switch(req)
 176         {
 177                 case MR_THINK:
 178                 {
 179                         monster_move(MON_CVAR(spider, speed_run), MON_CVAR(spider, speed_walk), MON_CVAR(spider, speed_stop), spider_anim_walk, spider_anim_walk, spider_anim_idle);
 180                         return TRUE;
 181                 }
 182                 case MR_DEATH:
 183                 {
 184                         monsters_setframe(spider_anim_attack);
 185                         self.angles_x = 180;
 186                         self.SendFlags |= MSF_ANG;
 187                         return TRUE;
 188                 }
 189                 case MR_SETUP:
 190                 {
 191                         if not(self.health) self.health = MON_CVAR(spider, health);
 192                         if not(self.spider_type) self.spider_type = MON_CVAR(spider, attack_type);
 193
 194                         self.monster_loot = spawnfunc_item_health_medium;
 195                         self.monster_attackfunc = spider_attack;
 196                         monsters_setframe(spider_anim_idle);
 197
 198                         return TRUE;
 199                 }
 200                 case MR_INIT:
 201                 {
 202                         precache_model ("models/ice/ice.md3");
 203                         precache_sound ("weapons/electro_fire2.wav");
 204                         precache_sound ("weapons/fireball_fire.wav");
 205                         return TRUE;
 206                 }
 207                 case MR_CONFIG:
 208                 {
 209                         MON_CONFIG_SETTINGS(SPIDER_SETTINGS(spider))
 210                         return TRUE;
 211                 }
 212         }
 213
 214         return TRUE;
 215 }
 216
 217 #endif // SVQC
 218 #ifdef CSQC
 219 float m_spider(float req)
 220 {
 221         switch(req)
 222         {
 223                 case MR_DEATH:
 224                 {
 225                         // nothing
 226                         return TRUE;
 227                 }
 228                 case MR_INIT:
 229                 {
 230                         precache_model ("models/monsters/spider.dpm");
 231                         return TRUE;
 232                 }
 233         }
 234
 235         return TRUE;
 236 }
 237
 238 #endif // CSQC
 239 #endif // REGISTER_MONSTER