qcsrc/common/monsters/monster/spider.qc

   1 #ifndef MENUQC
   2 bool m_spider(int);
   3 #endif
   4 REGISTER_MONSTER_SIMPLE(
   5 /* MON_##id   */ SPIDER,
   6 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_RANGED,
   7 /* mins,maxs  */ '-18 -18 -25', '18 18 30',
   8 /* model      */ "spider.dpm",
   9 /* netname    */ "spider",
  10 /* fullname   */ _("Spider")
  11 ) {
  12 #ifndef MENUQC
  13         this.monster_func = m_spider;
  14 #endif
  15 }
  16
  17 #ifdef SVQC
  18 float autocvar_g_monster_spider_health;
  19 float autocvar_g_monster_spider_attack_bite_damage;
  20 float autocvar_g_monster_spider_attack_bite_delay;
  21 float autocvar_g_monster_spider_attack_web_damagetime;
  22 float autocvar_g_monster_spider_attack_web_speed;
  23 float autocvar_g_monster_spider_attack_web_speed_up;
  24 float autocvar_g_monster_spider_attack_web_delay;
  25 float autocvar_g_monster_spider_speed_stop;
  26 float autocvar_g_monster_spider_speed_run;
  27 float autocvar_g_monster_spider_speed_walk;
  28
  29 const float spider_anim_idle            = 0;
  30 const float spider_anim_walk            = 1;
  31 const float spider_anim_attack          = 2;
  32 const float spider_anim_attack2         = 3;
  33
  34 .float spider_web_delay;
  35
  36 void spider_web_explode()
  37 {
  38         entity e;
  39         if(self)
  40         {
  41                 Send_Effect(EFFECT_ELECTRO_IMPACT, self.origin, '0 0 0', 1);
  42                 RadiusDamage(self, self.realowner, 0, 0, 25, world, world, 25, self.projectiledeathtype, world);
  43
  44                 for(e = findradius(self.origin, 25); e; e = e.chain) if(e != self) if(e.takedamage && e.deadflag == DEAD_NO) if(e.health > 0) if(e.monsterid != MON_SPIDER.monsterid)
  45                         e.spider_slowness = time + (autocvar_g_monster_spider_attack_web_damagetime);
  46
  47                 remove(self);
  48         }
  49 }
  50
  51 void spider_web_touch()
  52 {
  53         PROJECTILE_TOUCH;
  54
  55         spider_web_explode();
  56 }
  57
  58 void spider_shootweb()
  59 {
  60         monster_makevectors(self.enemy);
  61
  62         sound(self, CH_SHOTS, W_Sound("electro_fire2"), VOL_BASE, ATTEN_NORM);
  63
  64         entity proj = spawn ();
  65         proj.classname = "plasma";
  66         proj.owner = proj.realowner = self;
  67         proj.use = spider_web_touch;
  68         proj.think = adaptor_think2use_hittype_splash;
  69         proj.bot_dodge = true;
  70         proj.bot_dodgerating = 0;
  71         proj.nextthink = time + 5;
  72         PROJECTILE_MAKETRIGGER(proj);
  73         proj.projectiledeathtype = DEATH_MONSTER_SPIDER;
  74         setorigin(proj, CENTER_OR_VIEWOFS(self));
  75
  76         //proj.glow_size = 50;
  77         //proj.glow_color = 45;
  78         proj.movetype = MOVETYPE_BOUNCE;
  79         W_SetupProjVelocity_Explicit(proj, v_forward, v_up, (autocvar_g_monster_spider_attack_web_speed), (autocvar_g_monster_spider_attack_web_speed_up), 0, 0, false);
  80         proj.touch = spider_web_touch;
  81         setsize(proj, '-4 -4 -4', '4 4 4');
  82         proj.takedamage = DAMAGE_NO;
  83         proj.damageforcescale = 0;
  84         proj.health = 500;
  85         proj.event_damage = func_null;
  86         proj.flags = FL_PROJECTILE;
  87         proj.damagedbycontents = true;
  88
  89         proj.bouncefactor = 0.3;
  90         proj.bouncestop = 0.05;
  91         proj.missile_flags = MIF_SPLASH | MIF_ARC;
  92
  93         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, true);
  94 }
  95
  96 float spider_attack(float attack_type)
  97 {
  98         switch(attack_type)
  99         {
 100                 case MONSTER_ATTACK_MELEE:
 101                 {
 102                         return monster_melee(self.enemy, (autocvar_g_monster_spider_attack_bite_damage), ((random() > 0.5) ? spider_anim_attack : spider_anim_attack2), self.attack_range, (autocvar_g_monster_spider_attack_bite_delay), DEATH_MONSTER_SPIDER, true);
 103                 }
 104                 case MONSTER_ATTACK_RANGED:
 105                 {
 106                         if(time >= self.spider_web_delay)
 107                         {
 108                                 self.frame = spider_anim_attack2;
 109                                 self.attack_finished_single = time + (autocvar_g_monster_spider_attack_web_delay);
 110                                 spider_shootweb();
 111                                 self.spider_web_delay = time + 3;
 112                                 return true;
 113                         }
 114
 115                         return false;
 116                 }
 117         }
 118
 119         return false;
 120 }
 121
 122 void spawnfunc_monster_spider()
 123 {
 124         self.classname = "monster_spider";
 125
 126         if(!monster_initialize(MON_SPIDER.monsterid)) { remove(self); return; }
 127 }
 128
 129 float m_spider(float req)
 130 {
 131         switch(req)
 132         {
 133                 case MR_THINK:
 134                 {
 135                         monster_move((autocvar_g_monster_spider_speed_run), (autocvar_g_monster_spider_speed_walk), (autocvar_g_monster_spider_speed_stop), spider_anim_walk, spider_anim_walk, spider_anim_idle);
 136                         return true;
 137                 }
 138                 case MR_DEATH:
 139                 {
 140                         self.frame = spider_anim_attack;
 141                         self.angles_x = 180;
 142                         return true;
 143                 }
 144                 case MR_SETUP:
 145                 {
 146                         if(!self.health) self.health = (autocvar_g_monster_spider_health);
 147
 148                         self.monster_loot = spawnfunc_item_health_medium;
 149                         self.monster_attackfunc = spider_attack;
 150                         self.frame = spider_anim_idle;
 151
 152                         return true;
 153                 }
 154                 case MR_PRECACHE:
 155                 {
 156                         precache_model("models/monsters/spider.dpm");
 157                         precache_sound (W_Sound("electro_fire2"));
 158                         return true;
 159                 }
 160         }
 161
 162         return true;
 163 }
 164
 165 #endif // SVQC
 166 #ifdef CSQC
 167 float m_spider(float req)
 168 {
 169         switch(req)
 170         {
 171                 case MR_PRECACHE:
 172                 {
 173                         return true;
 174                 }
 175         }
 176
 177         return true;
 178 }
 179
 180 #endif // CSQC