qcsrc/common/monsters/monster/spider.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SPIDER,
   4 /* function   */ m_spider,
   5 /* spawnflags */ 0,
   6 /* mins,maxs  */ '-18 -18 -25', '18 18 30',
   7 /* model      */ "spider.dpm",
   8 /* netname    */ "spider",
   9 /* fullname   */ _("Spider")
  10 );
  11
  12 #define SPIDER_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_bite_damage) \
  15         MON_ADD_CVAR(monster, attack_bite_delay) \
  16         MON_ADD_CVAR(monster, attack_web_damagetime) \
  17         MON_ADD_CVAR(monster, attack_web_speed) \
  18         MON_ADD_CVAR(monster, attack_web_speed_up) \
  19         MON_ADD_CVAR(monster, attack_web_delay) \
  20         MON_ADD_CVAR(monster, attack_type) \
  21         MON_ADD_CVAR(monster, speed_stop) \
  22         MON_ADD_CVAR(monster, speed_run) \
  23         MON_ADD_CVAR(monster, speed_walk)
  24
  25 #ifdef SVQC
  26 SPIDER_SETTINGS(spider)
  27 #endif // SVQC
  28 #else
  29 #ifdef SVQC
  30 const float spider_anim_idle            = 0;
  31 const float spider_anim_walk            = 1;
  32 const float spider_anim_attack          = 2;
  33 const float spider_anim_attack2         = 3;
  34
  35 .float spider_type; // used to switch between fire & ice attacks
  36 const float SPIDER_TYPE_ICE             = 0;
  37 const float SPIDER_TYPE_FIRE    = 1;
  38
  39 void spider_web_explode()
  40 {
  41         entity e;
  42         if(self)
  43         {
  44                 float damg = 0, edamg = 0, rad = 1;
  45                 switch(self.realowner.spider_type)
  46                 {
  47                         case SPIDER_TYPE_ICE:
  48                                 rad = 25;
  49                                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
  50                                 break;
  51                         case SPIDER_TYPE_FIRE:
  52                                 pointparticles(particleeffectnum("fireball_explode"), self.origin, '0 0 0', 1);
  53                                 damg = 15;
  54                                 rad = 25;
  55                                 edamg = 6;
  56                                 break;
  57                 }
  58
  59                 RadiusDamage(self, self.realowner, damg, edamg, 0, world, rad, DEATH_MONSTER_SPIDER_FIRE, world); // ice deals no damage anyway
  60
  61                 for(e = findradius(self.origin, rad); e; e = e.chain) if(e != self) if(e.takedamage && e.deadflag == DEAD_NO) if(e.health > 0)
  62                 {
  63                         switch(self.realowner.spider_type)
  64                         {
  65                                 case SPIDER_TYPE_ICE:
  66                                         Freeze(e, 0.3, 2, FALSE);
  67                                         break;
  68                                 case SPIDER_TYPE_FIRE:
  69                                         Fire_AddDamage(e, self.realowner, 5 * monster_skill, MON_CVAR(spider, attack_web_damagetime), DEATH_MONSTER_SPIDER_FIRE);
  70                                         break;
  71                         }
  72                 }
  73
  74                 remove(self);
  75         }
  76 }
  77
  78 void spider_web_touch()
  79 {
  80         PROJECTILE_TOUCH;
  81
  82         spider_web_explode();
  83 }
  84
  85 void spider_shootweb(float ptype)
  86 {
  87         float p = 0;
  88         string snd = "";
  89         switch(ptype)
  90         {
  91                 case SPIDER_TYPE_ICE:
  92                         p = PROJECTILE_ELECTRO;
  93                         snd = "weapons/electro_fire2.wav";
  94                         break;
  95                 case SPIDER_TYPE_FIRE:
  96                         p = PROJECTILE_FIREMINE;
  97                         snd = "weapons/fireball_fire.wav";
  98                         break;
  99         }
 100
 101         vector fmins = '-4 -4 -4', fmaxs = '4 4 4';
 102
 103         monster_makevectors(self.enemy);
 104
 105         sound(self, CH_SHOTS, snd, VOL_BASE, ATTN_NORM);
 106
 107         entity proj = spawn ();
 108         proj.classname = "plasma";
 109         proj.owner = proj.realowner = self;
 110         proj.use = spider_web_touch;
 111         proj.think = adaptor_think2use_hittype_splash;
 112         proj.bot_dodge = TRUE;
 113         proj.bot_dodgerating = 0;
 114         proj.nextthink = time + 5;
 115         PROJECTILE_MAKETRIGGER(proj);
 116         proj.projectiledeathtype = DEATH_MONSTER_SPIDER_FIRE;
 117         setorigin(proj, CENTER_OR_VIEWOFS(self));
 118
 119         //proj.glow_size = 50;
 120         //proj.glow_color = 45;
 121         proj.movetype = MOVETYPE_BOUNCE;
 122         W_SetupProjectileVelocityEx(proj, v_forward, v_up, MON_CVAR(spider, attack_web_speed), MON_CVAR(spider, attack_web_speed_up), 0, 0, FALSE);
 123         proj.touch = spider_web_touch;
 124         setsize(proj, fmins, fmaxs);
 125         proj.takedamage = DAMAGE_NO;
 126         proj.damageforcescale = 0;
 127         proj.health = 500;
 128         proj.event_damage = func_null;
 129         proj.flags = FL_PROJECTILE;
 130         proj.damagedbycontents = TRUE;
 131
 132         proj.bouncefactor = 0.3;
 133         proj.bouncestop = 0.05;
 134         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 135
 136         CSQCProjectile(proj, TRUE, p, TRUE);
 137 }
 138
 139 float spider_attack(float attack_type)
 140 {
 141         switch(attack_type)
 142         {
 143                 case MONSTER_ATTACK_MELEE:
 144                 {
 145                         monster_melee(self.enemy, MON_CVAR(spider, attack_bite_damage), 0.3, DEATH_MONSTER_SPIDER, TRUE);
 146                         monsters_setframe((random() > 0.5) ? spider_anim_attack : spider_anim_attack2);
 147                         self.attack_finished_single = time + MON_CVAR(spider, attack_bite_delay);
 148
 149                         return TRUE;
 150                 }
 151                 case MONSTER_ATTACK_RANGED:
 152                 {
 153                         if(self.enemy.frozen)
 154                                 return FALSE;
 155
 156                         monsters_setframe(spider_anim_attack2);
 157                         self.attack_finished_single = time + MON_CVAR(spider, attack_web_delay);
 158                         spider_shootweb(self.spider_type);
 159
 160                         return TRUE;
 161                 }
 162         }
 163
 164         return FALSE;
 165 }
 166
 167 void spawnfunc_monster_spider()
 168 {
 169         self.classname = "monster_spider";
 170
 171         self.monster_spawnfunc = spawnfunc_monster_spider;
 172
 173         if(Monster_CheckAppearFlags(self))
 174                 return;
 175
 176         if not(monster_initialize(MON_SPIDER, FALSE)) { remove(self); return; }
 177 }
 178
 179 float m_spider(float req)
 180 {
 181         switch(req)
 182         {
 183                 case MR_THINK:
 184                 {
 185                         monster_move(MON_CVAR(spider, speed_run), MON_CVAR(spider, speed_walk), MON_CVAR(spider, speed_stop), spider_anim_walk, spider_anim_walk, spider_anim_idle);
 186                         return TRUE;
 187                 }
 188                 case MR_DEATH:
 189                 {
 190                         monsters_setframe(spider_anim_attack);
 191                         self.angles += '180 0 0';
 192                         self.SendFlags |= MSF_ANG;
 193                         return TRUE;
 194                 }
 195                 case MR_SETUP:
 196                 {
 197                         if not(self.health) self.health = MON_CVAR(spider, health);
 198                         if not(self.spider_type) self.spider_type = MON_CVAR(spider, attack_type);
 199
 200                         self.monster_loot = spawnfunc_item_health_medium;
 201                         self.monster_attackfunc = spider_attack;
 202                         monsters_setframe(spider_anim_idle);
 203
 204                         return TRUE;
 205                 }
 206                 case MR_INIT:
 207                 {
 208                         // nothing
 209                         return TRUE;
 210                 }
 211                 case MR_CONFIG:
 212                 {
 213                         MON_CONFIG_SETTINGS(SPIDER_SETTINGS(spider))
 214                         return TRUE;
 215                 }
 216         }
 217
 218         return TRUE;
 219 }
 220
 221 #endif // SVQC
 222 #ifdef CSQC
 223 float m_spider(float req)
 224 {
 225         switch(req)
 226         {
 227                 case MR_DEATH:
 228                 {
 229                         // nothing
 230                         return TRUE;
 231                 }
 232                 case MR_INIT:
 233                 {
 234                         precache_model ("models/monsters/spider.dpm");
 235                         return TRUE;
 236                 }
 237         }
 238
 239         return TRUE;
 240 }
 241
 242 #endif // CSQC
 243 #endif // REGISTER_MONSTER