qcsrc/common/monsters/monster/wyvern.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ WYVERN,
   4 /* function   */ m_wyvern,
   5 /* spawnflags */ MONSTER_TYPE_FLY | MONSTER_SIZE_BROKEN | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-20 -20 -58', '20 20 20',
   7 /* model      */ "wizard.mdl",
   8 /* netname    */ "wyvern",
   9 /* fullname   */ _("Wyvern")
  10 );
  11
  12 #define WYVERN_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_fireball_damage) \
  15         MON_ADD_CVAR(monster, attack_fireball_edgedamage) \
  16         MON_ADD_CVAR(monster, attack_fireball_damagetime) \
  17         MON_ADD_CVAR(monster, attack_fireball_force) \
  18         MON_ADD_CVAR(monster, attack_fireball_radius) \
  19         MON_ADD_CVAR(monster, attack_fireball_speed) \
  20         MON_ADD_CVAR(monster, speed_stop) \
  21         MON_ADD_CVAR(monster, speed_run) \
  22         MON_ADD_CVAR(monster, speed_walk)
  23
  24 #ifdef SVQC
  25 WYVERN_SETTINGS(wyvern)
  26 #endif // SVQC
  27 #else
  28 #ifdef SVQC
  29 const float wyvern_anim_hover   = 0;
  30 const float wyvern_anim_fly     = 1;
  31 const float wyvern_anim_magic   = 2;
  32 const float wyvern_anim_pain    = 3;
  33 const float wyvern_anim_death   = 4;
  34
  35 void wyvern_fireball_explode()
  36 {
  37         entity e;
  38         if(self)
  39         {
  40                 pointparticles(particleeffectnum("fireball_explode"), self.origin, '0 0 0', 1);
  41
  42                 RadiusDamage(self, self.realowner, MON_CVAR(wyvern, attack_fireball_damage), MON_CVAR(wyvern, attack_fireball_edgedamage), MON_CVAR(wyvern, attack_fireball_force), world, MON_CVAR(wyvern, attack_fireball_radius), self.projectiledeathtype, world);
  43
  44                 for(e = world; (e = findfloat(e, takedamage, DAMAGE_AIM)); ) if(vlen(e.origin - self.origin) <= MON_CVAR(wyvern, attack_fireball_radius))
  45                         Fire_AddDamage(e, self, 5 * monster_skill, MON_CVAR(wyvern, attack_fireball_damagetime), self.projectiledeathtype);
  46
  47                 remove(self);
  48         }
  49 }
  50
  51 void wyvern_fireball_touch()
  52 {
  53         PROJECTILE_TOUCH;
  54
  55         wyvern_fireball_explode();
  56 }
  57
  58 void wyvern_fireball()
  59 {
  60         entity missile = spawn();
  61         vector dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
  62
  63         monster_makevectors(self.enemy);
  64
  65         missile.owner = missile.realowner = self;
  66         missile.solid = SOLID_TRIGGER;
  67         missile.movetype = MOVETYPE_FLYMISSILE;
  68         missile.projectiledeathtype = DEATH_MONSTER_WYVERN;
  69         setsize(missile, '-6 -6 -6', '6 6 6');
  70         setorigin(missile, self.origin + self.view_ofs + v_forward * 14);
  71         missile.flags = FL_PROJECTILE;
  72         missile.velocity = dir * MON_CVAR(wyvern, attack_fireball_speed);
  73         missile.avelocity = '300 300 300';
  74         missile.nextthink = time + 5;
  75         missile.think = wyvern_fireball_explode;
  76         missile.enemy = self.enemy;
  77         missile.touch = wyvern_fireball_touch;
  78         CSQCProjectile(missile, TRUE, PROJECTILE_FIREMINE, TRUE);
  79 }
  80
  81 float wyvern_attack(float attack_type)
  82 {
  83         switch(attack_type)
  84         {
  85                 case MONSTER_ATTACK_MELEE:
  86                 case MONSTER_ATTACK_RANGED:
  87                 {
  88                         self.attack_finished_single = time + 1.2;
  89
  90                         wyvern_fireball();
  91
  92                         return TRUE;
  93                 }
  94         }
  95
  96         return FALSE;
  97 }
  98
  99 void spawnfunc_monster_wyvern()
 100 {
 101         self.classname = "monster_wyvern";
 102
 103         self.monster_spawnfunc = spawnfunc_monster_wyvern;
 104
 105         if(Monster_CheckAppearFlags(self))
 106                 return;
 107
 108         if not(monster_initialize(MON_WYVERN, TRUE)) { remove(self); return; }
 109 }
 110
 111 // compatibility with old spawns
 112 void spawnfunc_monster_wizard() { spawnfunc_monster_wyvern(); }
 113
 114 float m_wyvern(float req)
 115 {
 116         switch(req)
 117         {
 118                 case MR_THINK:
 119                 {
 120                         monster_move(MON_CVAR(wyvern, speed_run), MON_CVAR(wyvern, speed_walk), MON_CVAR(wyvern, speed_stop), wyvern_anim_fly, wyvern_anim_hover, wyvern_anim_hover);
 121                         return TRUE;
 122                 }
 123                 case MR_DEATH:
 124                 {
 125                         monsters_setframe(wyvern_anim_death);
 126                         self.velocity_x = -200 + 400 * random();
 127                         self.velocity_y = -200 + 400 * random();
 128                         self.velocity_z = 100 + 100 * random();
 129                         return TRUE;
 130                 }
 131                 case MR_SETUP:
 132                 {
 133                         if not(self.health) self.health = MON_CVAR(wyvern, health);
 134
 135                         self.monster_loot = spawnfunc_item_cells;
 136                         self.monster_attackfunc = wyvern_attack;
 137                         monsters_setframe(wyvern_anim_hover);
 138
 139                         return TRUE;
 140                 }
 141                 case MR_INIT:
 142                 {
 143                         // nothing
 144                         return TRUE;
 145                 }
 146                 case MR_CONFIG:
 147                 {
 148                         MON_CONFIG_SETTINGS(WYVERN_SETTINGS(wyvern))
 149                         return TRUE;
 150                 }
 151         }
 152
 153         return TRUE;
 154 }
 155
 156 #endif // SVQC
 157 #ifdef CSQC
 158 float m_wyvern(float req)
 159 {
 160         switch(req)
 161         {
 162                 case MR_DEATH:
 163                 {
 164                         // nothing
 165                         return TRUE;
 166                 }
 167                 case MR_INIT:
 168                 {
 169                         precache_model ("models/monsters/wizard.mdl");
 170                         return TRUE;
 171                 }
 172         }
 173
 174         return TRUE;
 175 }
 176
 177 #endif // CSQC
 178 #endif // REGISTER_MONSTER