qcsrc/common/monsters/monster/zombie.qc

   1 CLASS(Zombie, Monster)
   2     ATTRIB(Zombie, spawnflags, int, MON_FLAG_MELEE | MON_FLAG_RIDE);
   3     ATTRIB(Zombie, mins, vector, '-18 -18 -25');
   4     ATTRIB(Zombie, maxs, vector, '18 18 47');
   5     ATTRIB(Zombie, mdl, string, "zombie.dpm");
   6     ATTRIB(Zombie, model, string, strzone(strcat("models/monsters/", this.mdl)));
   7     ATTRIB(Zombie, netname, string, "zombie");
   8     ATTRIB(Zombie, monster_name, string, _("Zombie"));
   9 ENDCLASS(Zombie)
  10
  11 REGISTER_MONSTER(ZOMBIE, NEW(Zombie)) {
  12 #ifndef MENUQC
  13     MON_ACTION(this, MR_PRECACHE);
  14 #endif
  15 }
  16
  17 #ifdef SVQC
  18 float autocvar_g_monster_zombie_health;
  19 float autocvar_g_monster_zombie_damageforcescale = 0.55;
  20 float autocvar_g_monster_zombie_attack_melee_damage;
  21 float autocvar_g_monster_zombie_attack_melee_delay;
  22 float autocvar_g_monster_zombie_attack_leap_damage;
  23 float autocvar_g_monster_zombie_attack_leap_force;
  24 float autocvar_g_monster_zombie_attack_leap_speed;
  25 float autocvar_g_monster_zombie_attack_leap_delay;
  26 float autocvar_g_monster_zombie_speed_stop;
  27 float autocvar_g_monster_zombie_speed_run;
  28 float autocvar_g_monster_zombie_speed_walk;
  29
  30 /*
  31 const float zombie_anim_attackleap                      = 0;
  32 const float zombie_anim_attackrun1                      = 1;
  33 const float zombie_anim_attackrun2                      = 2;
  34 const float zombie_anim_attackrun3                      = 3;
  35 const float zombie_anim_attackstanding1         = 4;
  36 const float zombie_anim_attackstanding2         = 5;
  37 const float zombie_anim_attackstanding3         = 6;
  38 const float zombie_anim_blockend                        = 7;
  39 const float zombie_anim_blockstart                      = 8;
  40 const float zombie_anim_deathback1                      = 9;
  41 const float zombie_anim_deathback2                      = 10;
  42 const float zombie_anim_deathback3                      = 11;
  43 const float zombie_anim_deathfront1                     = 12;
  44 const float zombie_anim_deathfront2                     = 13;
  45 const float zombie_anim_deathfront3                     = 14;
  46 const float zombie_anim_deathleft1                      = 15;
  47 const float zombie_anim_deathleft2                      = 16;
  48 const float zombie_anim_deathright1                     = 17;
  49 const float zombie_anim_deathright2                     = 18;
  50 const float zombie_anim_idle                            = 19;
  51 const float zombie_anim_painback1                       = 20;
  52 const float zombie_anim_painback2                       = 21;
  53 const float zombie_anim_painfront1                      = 22;
  54 const float zombie_anim_painfront2                      = 23;
  55 const float zombie_anim_runbackwards            = 24;
  56 const float zombie_anim_runbackwardsleft        = 25;
  57 const float zombie_anim_runbackwardsright       = 26;
  58 const float zombie_anim_runforward                      = 27;
  59 const float zombie_anim_runforwardleft          = 28;
  60 const float zombie_anim_runforwardright         = 29;
  61 const float zombie_anim_spawn                           = 30;
  62 */
  63
  64 void M_Zombie_Attack_Leap_Touch()
  65 {SELFPARAM();
  66         if (self.health <= 0)
  67                 return;
  68
  69         vector angles_face;
  70
  71         if(other.takedamage)
  72         {
  73                 angles_face = vectoangles(self.moveto - self.origin);
  74                 angles_face = normalize(angles_face) * (autocvar_g_monster_zombie_attack_leap_force);
  75                 Damage(other, self, self, (autocvar_g_monster_zombie_attack_leap_damage) * MONSTER_SKILLMOD(self), DEATH_MONSTER_ZOMBIE_JUMP, other.origin, angles_face);
  76                 self.touch = Monster_Touch; // instantly turn it off to stop damage spam
  77                 self.state = 0;
  78         }
  79
  80         if (trace_dphitcontents)
  81         {
  82                 self.state = 0;
  83                 self.touch = Monster_Touch;
  84         }
  85 }
  86
  87 void M_Zombie_Defend_Block_End()
  88 {SELFPARAM();
  89         if(self.health <= 0)
  90                 return;
  91
  92         setanim(self, self.anim_blockend, false, true, true);
  93         self.armorvalue = autocvar_g_monsters_armor_blockpercent;
  94 }
  95
  96 float M_Zombie_Defend_Block()
  97 {SELFPARAM();
  98         self.armorvalue = 0.9;
  99         self.state = MONSTER_ATTACK_MELEE; // freeze monster
 100         self.attack_finished_single = time + 2.1;
 101         self.anim_finished = self.attack_finished_single;
 102         setanim(self, self.anim_blockstart, false, true, true);
 103
 104         Monster_Delay(1, 0, 2, M_Zombie_Defend_Block_End);
 105
 106         return true;
 107 }
 108
 109 float M_Zombie_Attack(float attack_type)
 110 {SELFPARAM();
 111         switch(attack_type)
 112         {
 113                 case MONSTER_ATTACK_MELEE:
 114                 {
 115                         if(random() < 0.3 && self.health < 75 && self.enemy.health > 10)
 116                                 return M_Zombie_Defend_Block();
 117
 118                         float rand = random();
 119                         vector chosen_anim;
 120
 121                         if(rand < 0.33)
 122                                 chosen_anim = self.anim_melee1;
 123                         else if(rand < 0.66)
 124                                 chosen_anim = self.anim_melee2;
 125                         else
 126                                 chosen_anim = self.anim_melee3;
 127
 128                         return Monster_Attack_Melee(self.enemy, (autocvar_g_monster_zombie_attack_melee_damage), chosen_anim, self.attack_range, (autocvar_g_monster_zombie_attack_melee_delay), DEATH_MONSTER_ZOMBIE_MELEE, true);
 129                 }
 130                 case MONSTER_ATTACK_RANGED:
 131                 {
 132                         makevectors(self.angles);
 133                         return Monster_Attack_Leap(self.anim_shoot, M_Zombie_Attack_Leap_Touch, v_forward * (autocvar_g_monster_zombie_attack_leap_speed) + '0 0 200', (autocvar_g_monster_zombie_attack_leap_delay));
 134                 }
 135         }
 136
 137         return false;
 138 }
 139
 140 void spawnfunc_monster_zombie() { Monster_Spawn(MON_ZOMBIE.monsterid); }
 141 #endif // SVQC
 142
 143                 #ifdef SVQC
 144                 METHOD(Zombie, mr_think, bool(Zombie thismon))
 145                 {
 146                         SELFPARAM();
 147                         if(time >= self.spawn_time)
 148                                 self.damageforcescale = autocvar_g_monster_zombie_damageforcescale;
 149                         return true;
 150                 }
 151                 METHOD(Zombie, mr_pain, bool(Zombie thismon))
 152                 {
 153                         SELFPARAM();
 154                         self.pain_finished = time + 0.34;
 155                         setanim(self, ((random() > 0.5) ? self.anim_pain1 : self.anim_pain2), true, true, false);
 156                         return true;
 157                 }
 158                 METHOD(Zombie, mr_death, bool(Zombie thismon))
 159                 {
 160                         SELFPARAM();
 161                         self.armorvalue = autocvar_g_monsters_armor_blockpercent;
 162
 163                         setanim(self, ((random() > 0.5) ? self.anim_die1 : self.anim_die2), false, true, true);
 164                         return true;
 165                 }
 166                 #endif
 167                 #ifndef MENUQC
 168                 METHOD(Zombie, mr_anim, bool(Zombie thismon))
 169                 {
 170                         SELFPARAM();
 171                         vector none = '0 0 0';
 172                         self.anim_die1 = animfixfps(self, '9 1 0.5', none); // 2 seconds
 173                         self.anim_die2 = animfixfps(self, '12 1 0.5', none); // 2 seconds
 174                         self.anim_spawn = animfixfps(self, '30 1 3', none);
 175                         self.anim_walk = animfixfps(self, '27 1 1', none);
 176                         self.anim_idle = animfixfps(self, '19 1 1', none);
 177                         self.anim_pain1 = animfixfps(self, '20 1 2', none); // 0.5 seconds
 178                         self.anim_pain2 = animfixfps(self, '22 1 2', none); // 0.5 seconds
 179                         self.anim_melee1 = animfixfps(self, '4 1 5', none); // analyze models and set framerate
 180                         self.anim_melee2 = animfixfps(self, '4 1 5', none); // analyze models and set framerate
 181                         self.anim_melee3 = animfixfps(self, '4 1 5', none); // analyze models and set framerate
 182                         self.anim_shoot = animfixfps(self, '0 1 5', none); // analyze models and set framerate
 183                         self.anim_run = animfixfps(self, '27 1 1', none);
 184                         self.anim_blockstart = animfixfps(self, '8 1 1', none);
 185                         self.anim_blockend = animfixfps(self, '7 1 1', none);
 186
 187                         return true;
 188                 }
 189                 #endif
 190                 #ifdef SVQC
 191                 METHOD(Zombie, mr_setup, bool(Zombie thismon))
 192                 {
 193                         if(!self.health) self.health = (autocvar_g_monster_zombie_health);
 194                         if(!self.speed) { self.speed = (autocvar_g_monster_zombie_speed_walk); }
 195                         if(!self.speed2) { self.speed2 = (autocvar_g_monster_zombie_speed_run); }
 196                         if(!self.stopspeed) { self.stopspeed = (autocvar_g_monster_zombie_speed_stop); }
 197
 198                         if(self.spawnflags & MONSTERFLAG_NORESPAWN)
 199                                 self.spawnflags &= ~MONSTERFLAG_NORESPAWN; // zombies always respawn
 200
 201                         self.spawnflags |= MONSTER_RESPAWN_DEATHPOINT;
 202
 203                         self.monster_loot = spawnfunc_item_health_medium;
 204                         self.monster_attackfunc = M_Zombie_Attack;
 205                         self.spawnshieldtime = self.spawn_time;
 206                         self.respawntime = 0.2;
 207                         self.damageforcescale = 0.0001; // no push while spawning
 208
 209                         setanim(self, self.anim_spawn, false, true, true);
 210                         self.spawn_time = self.animstate_endtime;
 211
 212                         return true;
 213                 }
 214                 METHOD(Zombie, mr_precache, bool(Zombie thismon))
 215                 {
 216                         return true;
 217                 }
 218                 #endif