qcsrc/common/monsters/sv_monsters.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../../dpdefs/progsdefs.qh"
   5     #include "../../dpdefs/dpextensions.qh"
   6     #include "../../warpzonelib/common.qh"
   7     #include "../constants.qh"
   8     #include "../teams.qh"
   9     #include "../util.qh"
  10     #include "all.qh"
  11     #include "sv_monsters.qh"
  12     #include "../weapons/all.qh"
  13     #include "../../server/autocvars.qh"
  14     #include "../../server/defs.qh"
  15     #include "../deathtypes.qh"
  16     #include "../../server/mutators/mutators_include.qh"
  17         #include "../../server/steerlib.qh"
  18         #include "../turrets/sv_turrets.qh"
  19         #include "../turrets/util.qh"
  20     #include "../vehicles/all.qh"
  21     #include "../../server/campaign.qh"
  22     #include "../../server/command/common.qh"
  23     #include "../../server/command/cmd.qh"
  24         #include "../triggers/triggers.qh"
  25     #include "../../csqcmodellib/sv_model.qh"
  26     #include "../../server/round_handler.qh"
  27 #endif
  28
  29 void monsters_setstatus()
  30 {SELFPARAM();
  31         self.stat_monsters_total = monsters_total;
  32         self.stat_monsters_killed = monsters_killed;
  33 }
  34
  35 void monster_dropitem()
  36 {SELFPARAM();
  37         if(!self.candrop || !self.monster_loot)
  38                 return;
  39
  40         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  41         entity e = spawn();
  42
  43         e.monster_loot = self.monster_loot;
  44
  45         MUTATOR_CALLHOOK(MonsterDropItem, e);
  46         e = other;
  47
  48         if(e && e.monster_loot)
  49         {
  50                 setself(e);
  51                 e.noalign = true;
  52                 e.monster_loot();
  53                 e.gravity = 1;
  54                 e.movetype = MOVETYPE_TOSS;
  55                 e.reset = SUB_Remove;
  56                 setorigin(e, org);
  57                 e.velocity = randomvec() * 175 + '0 0 325';
  58                 e.item_spawnshieldtime = time + 0.7;
  59                 e.classname = "droppedweapon"; // use weapon handling to remove it on touch
  60                 SUB_SetFade(e, time + autocvar_g_monsters_drop_time, 1);
  61                 setself(this);
  62         }
  63 }
  64
  65 void monster_makevectors(entity e)
  66 {SELFPARAM();
  67         if(IS_MONSTER(self))
  68         {
  69                 vector v;
  70
  71                 v = e.origin + (e.mins + e.maxs) * 0.5;
  72                 self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
  73                 self.v_angle_x = -self.v_angle_x;
  74         }
  75
  76         makevectors(self.v_angle);
  77 }
  78
  79 // ===============
  80 // Target handling
  81 // ===============
  82
  83 bool Monster_ValidTarget(entity mon, entity player)
  84 {SELFPARAM();
  85         // ensure we're not checking nonexistent monster/target
  86         if(!mon || !player) { return false; }
  87
  88         if((player == mon)
  89         || (autocvar_g_monsters_lineofsight && !checkpvs(mon.origin + mon.view_ofs, player)) // enemy cannot be seen
  90         || (IS_VEHICLE(player) && !((get_monsterinfo(mon.monsterid)).spawnflags & MON_FLAG_RANGED)) // melee vs vehicle is useless
  91         || (time < game_starttime) // monsters do nothing before match has started
  92         || (player.takedamage == DAMAGE_NO)
  93         || (player.items & IT_INVISIBILITY)
  94         || (IS_SPEC(player) || IS_OBSERVER(player)) // don't attack spectators
  95         || (!IS_VEHICLE(player) && (player.deadflag != DEAD_NO || mon.deadflag != DEAD_NO || player.health <= 0 || mon.health <= 0))
  96         || (mon.monster_follow == player || player.monster_follow == mon)
  97         || (!IS_VEHICLE(player) && (player.flags & FL_NOTARGET))
  98         || (!autocvar_g_monsters_typefrag && player.BUTTON_CHAT)
  99         || (SAME_TEAM(player, mon))
 100         || (player.frozen)
 101         || (player.alpha != 0 && player.alpha < 0.5)
 102         )
 103         {
 104                 // if any of the above checks fail, target is not valid
 105                 return false;
 106         }
 107
 108         traceline(mon.origin + self.view_ofs, player.origin, 0, mon);
 109
 110         if((trace_fraction < 1) && (trace_ent != player))
 111                 return false;
 112
 113         if(autocvar_g_monsters_target_infront || (mon.spawnflags & MONSTERFLAG_INFRONT))
 114         if(mon.enemy != player)
 115         {
 116                 float dot;
 117
 118                 makevectors (mon.angles);
 119                 dot = normalize (player.origin - mon.origin) * v_forward;
 120
 121                 if(dot <= autocvar_g_monsters_target_infront_range) { return false; }
 122         }
 123
 124         return true; // this target is valid!
 125 }
 126
 127 entity Monster_FindTarget(entity mon)
 128 {
 129         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return mon.enemy; } // Handled by a mutator
 130
 131         entity head, closest_target = world;
 132         head = findradius(mon.origin, mon.target_range);
 133
 134         while(head) // find the closest acceptable target to pass to
 135         {
 136                 if(head.monster_attack)
 137                 if(Monster_ValidTarget(mon, head))
 138                 {
 139                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 140                         vector head_center = CENTER_OR_VIEWOFS(head);
 141                         vector ent_center = CENTER_OR_VIEWOFS(mon);
 142
 143                         if(closest_target)
 144                         {
 145                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 146                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 147                                         { closest_target = head; }
 148                         }
 149                         else { closest_target = head; }
 150                 }
 151
 152                 head = head.chain;
 153         }
 154
 155         return closest_target;
 156 }
 157
 158 void monster_setupcolors(entity mon)
 159 {
 160         if(IS_PLAYER(mon.realowner))
 161                 mon.colormap = mon.realowner.colormap;
 162         else if(teamplay && mon.team)
 163                 mon.colormap = 1024 + (mon.team - 1) * 17;
 164         else
 165         {
 166                 if(mon.monster_skill <= MONSTER_SKILL_EASY)
 167                         mon.colormap = 1029;
 168                 else if(mon.monster_skill <= MONSTER_SKILL_MEDIUM)
 169                         mon.colormap = 1027;
 170                 else if(mon.monster_skill <= MONSTER_SKILL_HARD)
 171                         mon.colormap = 1038;
 172                 else if(mon.monster_skill <= MONSTER_SKILL_INSANE)
 173                         mon.colormap = 1028;
 174                 else if(mon.monster_skill <= MONSTER_SKILL_NIGHTMARE)
 175                         mon.colormap = 1032;
 176                 else
 177                         mon.colormap = 1024;
 178         }
 179 }
 180
 181 void monster_changeteam(entity ent, float newteam)
 182 {
 183         if(!teamplay) { return; }
 184
 185         ent.team = newteam;
 186         ent.monster_attack = true; // new team, activate attacking
 187         monster_setupcolors(ent);
 188
 189         if(ent.sprite)
 190         {
 191                 WaypointSprite_UpdateTeamRadar(ent.sprite, RADARICON_DANGER, ((newteam) ? Team_ColorRGB(newteam) : '1 0 0'));
 192
 193                 ent.sprite.team = newteam;
 194                 ent.sprite.SendFlags |= 1;
 195         }
 196 }
 197
 198 void Monster_Delay_Action()
 199 {SELFPARAM();
 200         entity oldself = self;
 201         setself(self.owner);
 202         if(Monster_ValidTarget(self, self.enemy)) { oldself.use(); }
 203
 204         if(oldself.cnt > 0)
 205         {
 206                 oldself.cnt -= 1;
 207                 oldself.think = Monster_Delay_Action;
 208                 oldself.nextthink = time + oldself.respawn_time;
 209         }
 210         else
 211         {
 212                 oldself.think = SUB_Remove;
 213                 oldself.nextthink = time;
 214         }
 215 }
 216
 217 void Monster_Delay(float repeat_count, float repeat_defer, float defer_amnt, void() func)
 218 {SELFPARAM();
 219         // deferred attacking, checks if monster is still alive and target is still valid before attacking
 220         entity e = spawn();
 221
 222         e.think = Monster_Delay_Action;
 223         e.nextthink = time + defer_amnt;
 224         e.count = defer_amnt;
 225         e.owner = self;
 226         e.use = func;
 227         e.cnt = repeat_count;
 228         e.respawn_time = repeat_defer;
 229 }
 230
 231
 232 // ==============
 233 // Monster sounds
 234 // ==============
 235
 236 string get_monster_model_datafilename(string m, float sk, string fil)
 237 {
 238         if(m)
 239                 m = strcat(m, "_");
 240         else
 241                 m = "models/monsters/*_";
 242         if(sk >= 0)
 243                 m = strcat(m, ftos(sk));
 244         else
 245                 m = strcat(m, "*");
 246         return strcat(m, ".", fil);
 247 }
 248
 249 void Monster_Sound_Precache(string f)
 250 {
 251         float fh;
 252         string s;
 253         fh = fopen(f, FILE_READ);
 254         if(fh < 0)
 255                 return;
 256         while((s = fgets(fh)))
 257         {
 258                 if(tokenize_console(s) != 3)
 259                 {
 260                         LOG_TRACE("Invalid sound info line: ", s, "\n");
 261                         continue;
 262                 }
 263                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 264         }
 265         fclose(fh);
 266 }
 267
 268 void Monster_Sounds_Precache()
 269 {SELFPARAM();
 270         string m = (get_monsterinfo(self.monsterid)).model;
 271         float globhandle, n, i;
 272         string f;
 273
 274         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 275         if (globhandle < 0)
 276                 return;
 277         n = search_getsize(globhandle);
 278         for (i = 0; i < n; ++i)
 279         {
 280                 //print(search_getfilename(globhandle, i), "\n");
 281                 f = search_getfilename(globhandle, i);
 282                 Monster_Sound_Precache(f);
 283         }
 284         search_end(globhandle);
 285 }
 286
 287 void Monster_Sounds_Clear()
 288 {SELFPARAM();
 289 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 290         ALLMONSTERSOUNDS
 291 #undef _MSOUND
 292 }
 293
 294 .string Monster_Sound_SampleField(string type)
 295 {
 296         GetMonsterSoundSampleField_notFound = 0;
 297         switch(type)
 298         {
 299 #define _MSOUND(m) case #m: return monstersound_##m;
 300                 ALLMONSTERSOUNDS
 301 #undef _MSOUND
 302         }
 303         GetMonsterSoundSampleField_notFound = 1;
 304         return string_null;
 305 }
 306
 307 bool Monster_Sounds_Load(string f, int first)
 308 {SELFPARAM();
 309         float fh;
 310         string s;
 311         var .string field;
 312         fh = fopen(f, FILE_READ);
 313         if(fh < 0)
 314         {
 315                 LOG_TRACE("Monster sound file not found: ", f, "\n");
 316                 return false;
 317         }
 318         while((s = fgets(fh)))
 319         {
 320                 if(tokenize_console(s) != 3)
 321                         continue;
 322                 field = Monster_Sound_SampleField(argv(0));
 323                 if(GetMonsterSoundSampleField_notFound)
 324                         continue;
 325                 if (self.(field))
 326                         strunzone(self.(field));
 327                 self.(field) = strzone(strcat(argv(1), " ", argv(2)));
 328         }
 329         fclose(fh);
 330         return true;
 331 }
 332
 333 .int skin_for_monstersound;
 334 void Monster_Sounds_Update()
 335 {SELFPARAM();
 336         if(self.skin == self.skin_for_monstersound) { return; }
 337
 338         self.skin_for_monstersound = self.skin;
 339         Monster_Sounds_Clear();
 340         if(!Monster_Sounds_Load(get_monster_model_datafilename(self.model, self.skin, "sounds"), 0))
 341                 Monster_Sounds_Load(get_monster_model_datafilename(self.model, 0, "sounds"), 0);
 342 }
 343
 344 void Monster_Sound(.string samplefield, float sound_delay, float delaytoo, float chan)
 345 {SELFPARAM();
 346         if(!autocvar_g_monsters_sounds) { return; }
 347
 348         if(delaytoo)
 349         if(time < self.msound_delay)
 350                 return; // too early
 351         GlobalSound(self.(samplefield), chan, VOICETYPE_PLAYERSOUND);
 352
 353         self.msound_delay = time + sound_delay;
 354 }
 355
 356
 357 // =======================
 358 // Monster attack handlers
 359 // =======================
 360
 361 float Monster_Attack_Melee(entity targ, float damg, vector anim, float er, float animtime, int deathtype, float dostop)
 362 {SELFPARAM();
 363         if(dostop && (self.flags & FL_MONSTER)) { self.state = MONSTER_ATTACK_MELEE; }
 364
 365         setanim(self, anim, false, true, false);
 366
 367         if(self.animstate_endtime > time && (self.flags & FL_MONSTER))
 368                 self.attack_finished_single = self.anim_finished = self.animstate_endtime;
 369         else
 370                 self.attack_finished_single = self.anim_finished = time + animtime;
 371
 372         monster_makevectors(targ);
 373
 374         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 375
 376         if(trace_ent.takedamage)
 377                 Damage(trace_ent, self, self, damg * MONSTER_SKILLMOD(self), deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 378
 379         return true;
 380 }
 381
 382 float Monster_Attack_Leap_Check(vector vel)
 383 {SELFPARAM();
 384         if(self.state && (self.flags & FL_MONSTER))
 385                 return false; // already attacking
 386         if(!(self.flags & FL_ONGROUND))
 387                 return false; // not on the ground
 388         if(self.health <= 0)
 389                 return false; // called when dead?
 390         if(time < self.attack_finished_single)
 391                 return false; // still attacking
 392
 393         vector old = self.velocity;
 394
 395         self.velocity = vel;
 396         tracetoss(self, self);
 397         self.velocity = old;
 398         if (trace_ent != self.enemy)
 399                 return false;
 400
 401         return true;
 402 }
 403
 404 bool Monster_Attack_Leap(vector anm, void() touchfunc, vector vel, float animtime)
 405 {SELFPARAM();
 406         if(!Monster_Attack_Leap_Check(vel))
 407                 return false;
 408
 409         setanim(self, anm, false, true, false);
 410
 411         if(self.animstate_endtime > time && (self.flags & FL_MONSTER))
 412                 self.attack_finished_single = self.anim_finished = self.animstate_endtime;
 413         else
 414                 self.attack_finished_single = self.anim_finished = time + animtime;
 415
 416         if(self.flags & FL_MONSTER)
 417                 self.state = MONSTER_ATTACK_RANGED;
 418         self.touch = touchfunc;
 419         self.origin_z += 1;
 420         self.velocity = vel;
 421         self.flags &= ~FL_ONGROUND;
 422
 423         return true;
 424 }
 425
 426 void Monster_Attack_Check(entity e, entity targ)
 427 {
 428         if((e == world || targ == world)
 429         || (!e.monster_attackfunc)
 430         || (time < e.attack_finished_single)
 431         ) { return; }
 432
 433         float targ_vlen = vlen(targ.origin - e.origin);
 434
 435         if(targ_vlen <= e.attack_range)
 436         {
 437                 float attack_success = e.monster_attackfunc(MONSTER_ATTACK_MELEE);
 438                 if(attack_success == 1)
 439                         Monster_Sound(monstersound_melee, 0, false, CH_VOICE);
 440                 else if(attack_success > 0)
 441                         return;
 442         }
 443
 444         if(targ_vlen > e.attack_range)
 445         {
 446                 float attack_success = e.monster_attackfunc(MONSTER_ATTACK_RANGED);
 447                 if(attack_success == 1)
 448                         Monster_Sound(monstersound_melee, 0, false, CH_VOICE);
 449                 else if(attack_success > 0)
 450                         return;
 451         }
 452 }
 453
 454
 455 // ======================
 456 // Main monster functions
 457 // ======================
 458
 459 void Monster_UpdateModel()
 460 {SELFPARAM();
 461         // assume some defaults
 462         /*self.anim_idle   = animfixfps(self, '0 1 0.01', '0 0 0');
 463         self.anim_walk   = animfixfps(self, '1 1 0.01', '0 0 0');
 464         self.anim_run    = animfixfps(self, '2 1 0.01', '0 0 0');
 465         self.anim_fire1  = animfixfps(self, '3 1 0.01', '0 0 0');
 466         self.anim_fire2  = animfixfps(self, '4 1 0.01', '0 0 0');
 467         self.anim_melee  = animfixfps(self, '5 1 0.01', '0 0 0');
 468         self.anim_pain1  = animfixfps(self, '6 1 0.01', '0 0 0');
 469         self.anim_pain2  = animfixfps(self, '7 1 0.01', '0 0 0');
 470         self.anim_die1   = animfixfps(self, '8 1 0.01', '0 0 0');
 471         self.anim_die2   = animfixfps(self, '9 1 0.01', '0 0 0');*/
 472
 473         // then get the real values
 474         MON_ACTION(self.monsterid, MR_ANIM);
 475 }
 476
 477 void Monster_Touch()
 478 {SELFPARAM();
 479         if(other == world) { return; }
 480
 481         if(other.monster_attack)
 482         if(self.enemy != other)
 483         if(!IS_MONSTER(other))
 484         if(Monster_ValidTarget(self, other))
 485                 self.enemy = other;
 486 }
 487
 488 void Monster_Miniboss_Check()
 489 {SELFPARAM();
 490         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 491                 return;
 492
 493         float chance = random() * 100;
 494
 495         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 496         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 497         {
 498                 self.health += autocvar_g_monsters_miniboss_healthboost;
 499                 self.effects |= EF_RED;
 500                 if(!self.weapon)
 501                         self.weapon = WEP_VORTEX.m_id;
 502         }
 503 }
 504
 505 bool Monster_Respawn_Check()
 506 {SELFPARAM();
 507         if(self.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 508         if(MUTATOR_CALLHOOK(MonsterRespawn, self))
 509                 return true; // enabled by a mutator
 510
 511         if(self.spawnflags & MONSTERFLAG_NORESPAWN)
 512                 return false;
 513
 514         if(!autocvar_g_monsters_respawn)
 515                 return false;
 516
 517         return true;
 518 }
 519
 520 void Monster_Respawn() { SELFPARAM(); Monster_Spawn(self.monsterid); }
 521
 522 void Monster_Dead_Fade()
 523 {SELFPARAM();
 524         if(Monster_Respawn_Check())
 525         {
 526                 self.spawnflags |= MONSTERFLAG_RESPAWNED;
 527                 self.think = Monster_Respawn;
 528                 self.nextthink = time + self.respawntime;
 529                 self.monster_lifetime = 0;
 530                 self.deadflag = DEAD_RESPAWNING;
 531                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 532                 {
 533                         self.pos1 = self.origin;
 534                         self.pos2 = self.angles;
 535                 }
 536                 self.event_damage = func_null;
 537                 self.takedamage = DAMAGE_NO;
 538                 setorigin(self, self.pos1);
 539                 self.angles = self.pos2;
 540                 self.health = self.max_health;
 541                 setmodel(self, MDL_Null);
 542         }
 543         else
 544         {
 545                 // number of monsters spawned with mobspawn command
 546                 totalspawned -= 1;
 547
 548                 SUB_SetFade(self, time + 3, 1);
 549         }
 550 }
 551
 552 void Monster_Use()
 553 {SELFPARAM();
 554         if(Monster_ValidTarget(self, activator)) { self.enemy = activator; }
 555 }
 556
 557 vector Monster_Move_Target(entity targ)
 558 {SELFPARAM();
 559         // enemy is always preferred target
 560         if(self.enemy)
 561         {
 562                 vector targ_origin = ((self.enemy.absmin + self.enemy.absmax) * 0.5);
 563                 targ_origin = WarpZone_RefSys_TransformOrigin(self.enemy, self, targ_origin); // origin of target as seen by the monster (us)
 564                 WarpZone_TraceLine(self.origin, targ_origin, MOVE_NOMONSTERS, self);
 565
 566                 if((self.enemy == world)
 567                         || (self.enemy.deadflag != DEAD_NO || self.enemy.health < 1)
 568                         || (self.enemy.frozen)
 569                         || (self.enemy.flags & FL_NOTARGET)
 570                         || (self.enemy.alpha < 0.5 && self.enemy.alpha != 0)
 571                         || (self.enemy.takedamage == DAMAGE_NO)
 572                         || (vlen(self.origin - targ_origin) > self.target_range)
 573                         || ((trace_fraction < 1) && (trace_ent != self.enemy)))
 574                         //|| (time > self.ctf_droptime + autocvar_g_ctf_pass_timelimit)) // TODO: chase timelimit?
 575                 {
 576                         self.enemy = world;
 577                         self.pass_distance = 0;
 578                 }
 579
 580                 if(self.enemy)
 581                 {
 582                         /*WarpZone_TrailParticles(world, particleeffectnum(EFFECT_RED_PASS), self.origin, targ_origin);
 583                         print("Trace origin: ", vtos(targ_origin), "\n");
 584                         print("Target origin: ", vtos(self.enemy.origin), "\n");
 585                         print("My origin: ", vtos(self.origin), "\n"); */
 586
 587                         self.monster_movestate = MONSTER_MOVE_ENEMY;
 588                         self.last_trace = time + 1.2;
 589                         if(self.monster_moveto)
 590                                 return self.monster_moveto; // assumes code is properly setting this when monster has an enemy
 591                         else
 592                                 return targ_origin;
 593                 }
 594
 595                 /*makevectors(self.angles);
 596                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 597                 self.last_trace = time + 1.2;
 598                 return self.enemy.origin; */
 599         }
 600
 601         switch(self.monster_moveflags)
 602         {
 603                 case MONSTER_MOVE_FOLLOW:
 604                 {
 605                         self.monster_movestate = MONSTER_MOVE_FOLLOW;
 606                         self.last_trace = time + 0.3;
 607                         return (self.monster_follow) ? self.monster_follow.origin : self.origin;
 608                 }
 609                 case MONSTER_MOVE_SPAWNLOC:
 610                 {
 611                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 612                         self.last_trace = time + 2;
 613                         return self.pos1;
 614                 }
 615                 case MONSTER_MOVE_NOMOVE:
 616                 {
 617                         if(self.monster_moveto)
 618                         {
 619                                 self.last_trace = time + 0.5;
 620                                 return self.monster_moveto;
 621                         }
 622                         else
 623                         {
 624                                 self.monster_movestate = MONSTER_MOVE_NOMOVE;
 625                                 self.last_trace = time + 2;
 626                         }
 627                         return self.origin;
 628                 }
 629                 default:
 630                 case MONSTER_MOVE_WANDER:
 631                 {
 632                         vector pos;
 633                         self.monster_movestate = MONSTER_MOVE_WANDER;
 634
 635                         if(self.monster_moveto)
 636                         {
 637                                 self.last_trace = time + 0.5;
 638                                 pos = self.monster_moveto;
 639                         }
 640                         else if(targ)
 641                         {
 642                                 self.last_trace = time + 0.5;
 643                                 pos = targ.origin;
 644                         }
 645                         else
 646                         {
 647                                 self.last_trace = time + self.wander_delay;
 648
 649                                 self.angles_y = rint(random() * 500);
 650                                 makevectors(self.angles);
 651                                 pos = self.origin + v_forward * self.wander_distance;
 652
 653                                 if(((self.flags & FL_FLY) && (self.spawnflags & MONSTERFLAG_FLY_VERTICAL)) || (self.flags & FL_SWIM))
 654                                 {
 655                                         pos.z = random() * 200;
 656                                         if(random() >= 0.5)
 657                                                 pos.z *= -1;
 658                                 }
 659                         }
 660
 661                         return pos;
 662                 }
 663         }
 664 }
 665
 666 void Monster_CalculateVelocity(entity mon, vector to, vector from, float turnrate, float movespeed)
 667 {SELFPARAM();
 668         float current_distance = vlen((('1 0 0' * to.x) + ('0 1 0' * to.y)) - (('1 0 0' * from.x) + ('0 1 0' * from.y))); // for the sake of this check, exclude Z axis
 669         float initial_height = 0; //min(50, (targ_distance * tanh(20)));
 670         float current_height = (initial_height * min(1, (self.pass_distance) ? (current_distance / self.pass_distance) : current_distance));
 671         //print("current_height = ", ftos(current_height), ", initial_height = ", ftos(initial_height), ".\n");
 672
 673         vector targpos;
 674         if(current_height) // make sure we can actually do this arcing path
 675         {
 676                 targpos = (to + ('0 0 1' * current_height));
 677                 WarpZone_TraceLine(mon.origin, targpos, MOVE_NOMONSTERS, mon);
 678                 if(trace_fraction < 1)
 679                 {
 680                         //print("normal arc line failed, trying to find new pos...");
 681                         WarpZone_TraceLine(to, targpos, MOVE_NOMONSTERS, mon);
 682                         targpos = (trace_endpos + '0 0 -10');
 683                         WarpZone_TraceLine(mon.origin, targpos, MOVE_NOMONSTERS, mon);
 684                         if(trace_fraction < 1) { targpos = to; /* print(" ^1FAILURE^7, reverting to original direction.\n"); */ }
 685                         /*else { print(" ^3SUCCESS^7, using new arc line.\n"); } */
 686                 }
 687         }
 688         else { targpos = to; }
 689
 690         //mon.angles = normalize(('0 1 0' * to_y) - ('0 1 0' * from_y));
 691
 692         vector desired_direction = normalize(targpos - from);
 693         if(turnrate) { mon.velocity = (normalize(normalize(mon.velocity) + (desired_direction * 50)) * movespeed); }
 694         else { mon.velocity = (desired_direction * movespeed); }
 695
 696         //mon.steerto = steerlib_attract2(targpos, 0.5, 500, 0.95);
 697         //mon.angles = vectoangles(mon.velocity);
 698 }
 699
 700 void Monster_Move(float runspeed, float walkspeed, float stpspeed)
 701 {SELFPARAM();
 702         if(self.target2) { self.goalentity = find(world, targetname, self.target2); }
 703
 704         entity targ;
 705
 706         if(self.frozen == 2)
 707         {
 708                 self.revive_progress = bound(0, self.revive_progress + self.ticrate * self.revive_speed, 1);
 709                 self.health = max(1, self.revive_progress * self.max_health);
 710                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
 711
 712                 if(!(self.spawnflags & MONSTERFLAG_INVINCIBLE) && self.sprite)
 713                         WaypointSprite_UpdateHealth(self.sprite, self.health);
 714
 715                 movelib_beak_simple(stpspeed);
 716                 setanim(self, self.anim_idle, true, false, false);
 717
 718                 self.enemy = world;
 719                 self.nextthink = time + self.ticrate;
 720
 721                 if(self.revive_progress >= 1)
 722                         Unfreeze(self);
 723
 724                 return;
 725         }
 726         else if(self.frozen == 3)
 727         {
 728                 self.revive_progress = bound(0, self.revive_progress - self.ticrate * self.revive_speed, 1);
 729                 self.health = max(0, autocvar_g_nades_ice_health + (self.max_health-autocvar_g_nades_ice_health) * self.revive_progress );
 730
 731                 if(!(self.spawnflags & MONSTERFLAG_INVINCIBLE) && self.sprite)
 732                         WaypointSprite_UpdateHealth(self.sprite, self.health);
 733
 734                 movelib_beak_simple(stpspeed);
 735                 setanim(self, self.anim_idle, true, false, false);
 736
 737                 self.enemy = world;
 738                 self.nextthink = time + self.ticrate;
 739
 740                 if(self.health < 1)
 741                 {
 742                         Unfreeze(self);
 743                         self.health = 0;
 744                         if(self.event_damage)
 745                                 self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
 746                 }
 747
 748                 else if ( self.revive_progress <= 0 )
 749                         Unfreeze(self);
 750
 751                 return;
 752         }
 753
 754         if(self.flags & FL_SWIM)
 755         {
 756                 if(self.waterlevel < WATERLEVEL_WETFEET)
 757                 {
 758                         if(time >= self.last_trace)
 759                         {
 760                                 self.last_trace = time + 0.4;
 761
 762                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 763                                 self.angles = '90 90 0';
 764                                 if(random() < 0.5)
 765                                 {
 766                                         self.velocity_y += random() * 50;
 767                                         self.velocity_x -= random() * 50;
 768                                 }
 769                                 else
 770                                 {
 771                                         self.velocity_y -= random() * 50;
 772                                         self.velocity_x += random() * 50;
 773                                 }
 774                                 self.velocity_z += random() * 150;
 775                         }
 776
 777
 778                         self.movetype = MOVETYPE_BOUNCE;
 779                         //self.velocity_z = -200;
 780
 781                         return;
 782                 }
 783                 else if(self.movetype == MOVETYPE_BOUNCE)
 784                 {
 785                         self.angles_x = 0;
 786                         self.movetype = MOVETYPE_WALK;
 787                 }
 788         }
 789
 790         targ = self.goalentity;
 791
 792         if (MUTATOR_CALLHOOK(MonsterMove, runspeed, walkspeed, targ)
 793                 || gameover
 794                 || self.draggedby != world
 795                 || (round_handler_IsActive() && !round_handler_IsRoundStarted())
 796                 || time < game_starttime
 797                 || (autocvar_g_campaign && !campaign_bots_may_start)
 798                 || time < self.spawn_time)
 799         {
 800                 runspeed = walkspeed = 0;
 801                 if(time >= self.spawn_time)
 802                         setanim(self, self.anim_idle, true, false, false);
 803                 movelib_beak_simple(stpspeed);
 804                 return;
 805         }
 806
 807         targ = monster_target;
 808         runspeed = bound(0, monster_speed_run * MONSTER_SKILLMOD(self), runspeed * 2.5); // limit maxspeed to prevent craziness
 809         walkspeed = bound(0, monster_speed_walk * MONSTER_SKILLMOD(self), walkspeed * 2.5); // limit maxspeed to prevent craziness
 810
 811         if(time < self.spider_slowness)
 812         {
 813                 runspeed *= 0.5;
 814                 walkspeed *= 0.5;
 815         }
 816
 817         if(teamplay)
 818         if(autocvar_g_monsters_teams)
 819         if(DIFF_TEAM(self.monster_follow, self))
 820                 self.monster_follow = world;
 821
 822         if(time >= self.last_enemycheck)
 823         {
 824                 if(!self.enemy)
 825                 {
 826                         self.enemy = Monster_FindTarget(self);
 827                         if(self.enemy)
 828                         {
 829                                 WarpZone_RefSys_Copy(self.enemy, self);
 830                                 WarpZone_RefSys_AddInverse(self.enemy, self); // wz1^-1 ... wzn^-1 receiver
 831                                 self.moveto = WarpZone_RefSys_TransformOrigin(self.enemy, self, (0.5 * (self.enemy.absmin + self.enemy.absmax)));
 832                                 self.monster_moveto = '0 0 0';
 833                                 self.monster_face = '0 0 0';
 834
 835                                 self.pass_distance = vlen((('1 0 0' * self.enemy.origin_x) + ('0 1 0' * self.enemy.origin_y)) - (('1 0 0' *  self.origin_x) + ('0 1 0' *  self.origin_y)));
 836                                 Monster_Sound(monstersound_sight, 0, false, CH_VOICE);
 837                         }
 838                 }
 839
 840                 self.last_enemycheck = time + 1; // check for enemies every second
 841         }
 842
 843         if(self.state == MONSTER_ATTACK_RANGED && (self.flags & FL_ONGROUND))
 844         {
 845                 self.state = 0;
 846                 self.touch = Monster_Touch;
 847         }
 848
 849         if(self.state && time >= self.attack_finished_single)
 850                 self.state = 0; // attack is over
 851
 852         if(self.state != MONSTER_ATTACK_MELEE) // don't move if set
 853         if(time >= self.last_trace || self.enemy) // update enemy or rider instantly
 854                 self.moveto = Monster_Move_Target(targ);
 855
 856         if(!self.enemy)
 857                 Monster_Sound(monstersound_idle, 7, true, CH_VOICE);
 858
 859         if(self.state == MONSTER_ATTACK_MELEE)
 860                 self.moveto = self.origin;
 861
 862         if(self.enemy && self.enemy.vehicle)
 863                 runspeed = 0;
 864
 865         if(!(self.spawnflags & MONSTERFLAG_FLY_VERTICAL) && !(self.flags & FL_SWIM))
 866                 self.moveto_z = self.origin_z;
 867
 868         if(vlen(self.origin - self.moveto) > 100)
 869         {
 870                 float do_run = (self.enemy || self.monster_moveto);
 871                 if((self.flags & FL_ONGROUND) || ((self.flags & FL_FLY) || (self.flags & FL_SWIM)))
 872                         Monster_CalculateVelocity(self, self.moveto, self.origin, true, ((do_run) ? runspeed : walkspeed));
 873
 874                 if(time > self.pain_finished) // TODO: use anim_finished instead!
 875                 if(!self.state)
 876                 if(time > self.anim_finished)
 877                 if(vlen(self.velocity) > 10)
 878                         setanim(self, ((do_run) ? self.anim_run : self.anim_walk), true, false, false);
 879                 else
 880                         setanim(self, self.anim_idle, true, false, false);
 881         }
 882         else
 883         {
 884                 entity e = find(world, targetname, self.target2);
 885                 if(e.target2)
 886                         self.target2 = e.target2;
 887                 else if(e.target)
 888                         self.target2 = e.target;
 889
 890                 movelib_beak_simple(stpspeed);
 891                 if(time > self.anim_finished)
 892                 if(time > self.pain_finished)
 893                 if(!self.state)
 894                 if(vlen(self.velocity) <= 30)
 895                         setanim(self, self.anim_idle, true, false, false);
 896         }
 897
 898         self.steerto = steerlib_attract2(((self.monster_face) ? self.monster_face : self.moveto), 0.5, 500, 0.95);
 899
 900         vector real_angle = vectoangles(self.steerto) - self.angles;
 901         float turny = 25;
 902         if(self.state == MONSTER_ATTACK_MELEE)
 903                 turny = 0;
 904         if(turny)
 905         {
 906                 turny = bound(turny * -1, shortangle_f(real_angle.y, self.angles.y), turny);
 907                 self.angles_y += turny;
 908         }
 909
 910         Monster_Attack_Check(self, self.enemy);
 911 }
 912
 913 void Monster_Remove(entity mon)
 914 {
 915         if(!mon) { return; }
 916
 917         if(!MUTATOR_CALLHOOK(MonsterRemove, mon))
 918                 Send_Effect(EFFECT_ITEM_PICKUP, mon.origin, '0 0 0', 1);
 919
 920         if(mon.weaponentity) { remove(mon.weaponentity); }
 921         if(mon.iceblock) { remove(mon.iceblock); }
 922         WaypointSprite_Kill(mon.sprite);
 923         remove(mon);
 924 }
 925
 926 void Monster_Dead_Think()
 927 {SELFPARAM();
 928         self.nextthink = time + self.ticrate;
 929
 930         if(self.monster_lifetime != 0)
 931         if(time >= self.monster_lifetime)
 932         {
 933                 Monster_Dead_Fade();
 934                 return;
 935         }
 936 }
 937
 938 void Monster_Appear()
 939 {SELFPARAM();
 940         self.enemy = activator;
 941         self.spawnflags &= ~MONSTERFLAG_APPEAR; // otherwise, we get an endless loop
 942         Monster_Spawn(self.monsterid);
 943 }
 944
 945 float Monster_Appear_Check(entity ent, float monster_id)
 946 {
 947         if(!(ent.spawnflags & MONSTERFLAG_APPEAR))
 948                 return false;
 949
 950         ent.think = func_null;
 951         ent.monsterid = monster_id; // set so this monster is properly registered (otherwise, normal initialization is used)
 952         ent.nextthink = 0;
 953         ent.use = Monster_Appear;
 954         ent.flags = FL_MONSTER; // set so this monster can get butchered
 955
 956         return true;
 957 }
 958
 959 void Monster_Reset()
 960 {SELFPARAM();
 961         setorigin(self, self.pos1);
 962         self.angles = self.pos2;
 963
 964         Unfreeze(self); // remove any icy remains
 965
 966         self.health = self.max_health;
 967         self.velocity = '0 0 0';
 968         self.enemy = world;
 969         self.goalentity = world;
 970         self.attack_finished_single = 0;
 971         self.moveto = self.origin;
 972 }
 973
 974 void Monster_Dead_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 975 {SELFPARAM();
 976         self.health -= damage;
 977
 978         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 979
 980         if(self.health <= -100) // 100 health until gone?
 981         {
 982                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 983
 984                 // number of monsters spawned with mobspawn command
 985                 totalspawned -= 1;
 986
 987                 self.think = SUB_Remove;
 988                 self.nextthink = time + 0.1;
 989                 self.event_damage = func_null;
 990         }
 991 }
 992
 993 void Monster_Dead(entity attacker, float gibbed)
 994 {SELFPARAM();
 995         self.think = Monster_Dead_Think;
 996         self.nextthink = time;
 997         self.monster_lifetime = time + 5;
 998
 999         if(self.frozen)
1000         {
1001                 Unfreeze(self); // remove any icy remains
1002                 self.health = 0; // reset by Unfreeze
1003         }
1004
1005         monster_dropitem();
1006
1007         Monster_Sound(monstersound_death, 0, false, CH_VOICE);
1008
1009         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !(self.spawnflags & MONSTERFLAG_RESPAWNED))
1010                 monsters_killed += 1;
1011
1012         if(IS_PLAYER(attacker))
1013         if(autocvar_g_monsters_score_spawned || !((self.spawnflags & MONSTERFLAG_SPAWNED) || (self.spawnflags & MONSTERFLAG_RESPAWNED)))
1014                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
1015
1016         if(gibbed)
1017         {
1018                 // number of monsters spawned with mobspawn command
1019                 totalspawned -= 1;
1020         }
1021
1022         self.event_damage       = ((gibbed) ? func_null : Monster_Dead_Damage);
1023         self.solid                      = SOLID_CORPSE;
1024         self.takedamage         = DAMAGE_AIM;
1025         self.deadflag           = DEAD_DEAD;
1026         self.enemy                      = world;
1027         self.movetype           = MOVETYPE_TOSS;
1028         self.moveto                     = self.origin;
1029         self.touch                      = Monster_Touch; // reset incase monster was pouncing
1030         self.reset                      = func_null;
1031         self.state                      = 0;
1032         self.attack_finished_single = 0;
1033         self.effects = 0;
1034
1035         if(!((self.flags & FL_FLY) || (self.flags & FL_SWIM)))
1036                 self.velocity = '0 0 0';
1037
1038         CSQCModel_UnlinkEntity();
1039
1040         MON_ACTION(self.monsterid, MR_DEATH);
1041
1042         if(self.candrop && self.weapon)
1043                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
1044 }
1045
1046 void Monster_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1047 {SELFPARAM();
1048         if((self.spawnflags & MONSTERFLAG_INVINCIBLE) && deathtype != DEATH_KILL)
1049                 return;
1050
1051         if(self.frozen && deathtype != DEATH_KILL && deathtype != DEATH_NADE_ICE_FREEZE)
1052                 return;
1053
1054         //if(time < self.pain_finished && deathtype != DEATH_KILL)
1055                 //return;
1056
1057         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
1058                 return;
1059
1060         if(deathtype == DEATH_FALL && self.draggedby != world)
1061                 return;
1062
1063         vector v;
1064         float take, save;
1065
1066         v = healtharmor_applydamage(100, self.armorvalue / 100, deathtype, damage);
1067         take = v_x;
1068         save = v_y;
1069
1070         damage_take = take;
1071         frag_attacker = attacker;
1072         frag_deathtype = deathtype;
1073         MON_ACTION(self.monsterid, MR_PAIN);
1074         take = damage_take;
1075
1076         if(take)
1077         {
1078                 self.health -= take;
1079                 Monster_Sound(monstersound_pain, 1.2, true, CH_PAIN);
1080         }
1081
1082         if(self.sprite)
1083                 WaypointSprite_UpdateHealth(self.sprite, self.health);
1084
1085         self.dmg_time = time;
1086
1087         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
1088                 spamsound (self, CH_PAIN, SND(BODYIMPACT1), VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
1089
1090         self.velocity += force * self.damageforcescale;
1091
1092         if(deathtype != DEATH_DROWN && take)
1093         {
1094                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
1095                 if (take > 50)
1096                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
1097                 if (take > 100)
1098                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
1099         }
1100
1101         if(self.health <= 0)
1102         {
1103                 if(deathtype == DEATH_KILL)
1104                         self.candrop = false; // killed by mobkill command
1105
1106                 // TODO: fix this?
1107                 activator = attacker;
1108                 other = self.enemy;
1109                 SUB_UseTargets();
1110                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
1111
1112                 Monster_Dead(attacker, (self.health <= -100 || deathtype == DEATH_KILL));
1113
1114                 WaypointSprite_Kill(self.sprite);
1115
1116                 frag_target = self;
1117                 MUTATOR_CALLHOOK(MonsterDies, attacker);
1118
1119                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
1120                 {
1121                         Violence_GibSplash(self, 1, 0.5, attacker);
1122
1123                         self.think = SUB_Remove;
1124                         self.nextthink = time + 0.1;
1125                 }
1126         }
1127 }
1128
1129 // don't check for enemies, just keep walking in a straight line
1130 void Monster_Move_2D(float mspeed, float allow_jumpoff)
1131 {SELFPARAM();
1132         if(gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || self.draggedby != world || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
1133         {
1134                 mspeed = 0;
1135                 if(time >= self.spawn_time)
1136                         setanim(self, self.anim_idle, true, false, false);
1137                 movelib_beak_simple(0.6);
1138                 return;
1139         }
1140
1141         float reverse = FALSE;
1142         vector a, b;
1143
1144         makevectors(self.angles);
1145         a = self.origin + '0 0 16';
1146         b = self.origin + '0 0 16' + v_forward * 32;
1147
1148         traceline(a, b, MOVE_NORMAL, self);
1149
1150         if(trace_fraction != 1.0)
1151         {
1152                 reverse = TRUE;
1153
1154                 if(trace_ent)
1155                 if(IS_PLAYER(trace_ent) && !(trace_ent.items & IT_STRENGTH))
1156                         reverse = FALSE;
1157         }
1158
1159         // TODO: fix this... tracing is broken if the floor is thin
1160         /*
1161         if(!allow_jumpoff)
1162         {
1163                 a = b - '0 0 32';
1164                 traceline(b, a, MOVE_WORLDONLY, self);
1165                 if(trace_fraction == 1.0)
1166                         reverse = TRUE;
1167         } */
1168
1169         if(reverse)
1170         {
1171                 self.angles_y = anglemods(self.angles_y - 180);
1172                 makevectors(self.angles);
1173         }
1174
1175         movelib_move_simple_gravity(v_forward, mspeed, 1);
1176
1177         if(time > self.pain_finished)
1178         if(time > self.attack_finished_single)
1179         if(vlen(self.velocity) > 10)
1180                 setanim(self, self.anim_walk, true, false, false);
1181         else
1182                 setanim(self, self.anim_idle, true, false, false);
1183 }
1184
1185 void Monster_Anim()
1186 {SELFPARAM();
1187         int deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
1188         if(self.deadflag)
1189         {
1190                 if (!deadbits)
1191                 {
1192                         // Decide on which death animation to use.
1193                         if(random() < 0.5)
1194                                 deadbits = ANIMSTATE_DEAD1;
1195                         else
1196                                 deadbits = ANIMSTATE_DEAD2;
1197                 }
1198         }
1199         else
1200         {
1201                 // Clear a previous death animation.
1202                 deadbits = 0;
1203         }
1204         int animbits = deadbits;
1205         if(self.frozen)
1206                 animbits |= ANIMSTATE_FROZEN;
1207         if(self.crouch)
1208                 animbits |= ANIMSTATE_DUCK; // not that monsters can crouch currently...
1209         animdecide_setstate(self, animbits, false);
1210         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
1211
1212         /* // weapon entities for monsters?
1213         if (self.weaponentity)
1214         {
1215                 updateanim(self.weaponentity);
1216                 if (!self.weaponentity.animstate_override)
1217                         setanim(self.weaponentity, self.weaponentity.anim_idle, true, false, false);
1218         }
1219         */
1220 }
1221
1222 void Monster_Think()
1223 {SELFPARAM();
1224         self.think = Monster_Think;
1225         self.nextthink = self.ticrate;
1226
1227         if(self.monster_lifetime)
1228         if(time >= self.monster_lifetime)
1229         {
1230                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
1231                 return;
1232         }
1233
1234         if(MON_ACTION(self.monsterid, MR_THINK))
1235                 Monster_Move(self.speed2, self.speed, self.stopspeed);
1236
1237         Monster_Anim();
1238
1239         CSQCMODEL_AUTOUPDATE(self);
1240 }
1241
1242 float Monster_Spawn_Setup()
1243 {SELFPARAM();
1244         MON_ACTION(self.monsterid, MR_SETUP);
1245
1246         // ensure some basic needs are met
1247         if(!self.health) { self.health = 100; }
1248         if(!self.armorvalue) { self.armorvalue = bound(0.2, 0.5 * MONSTER_SKILLMOD(self), 0.9); }
1249         if(!self.target_range) { self.target_range = autocvar_g_monsters_target_range; }
1250         if(!self.respawntime) { self.respawntime = autocvar_g_monsters_respawn_delay; }
1251         if(!self.monster_moveflags) { self.monster_moveflags = MONSTER_MOVE_WANDER; }
1252         if(!self.attack_range) { self.attack_range = autocvar_g_monsters_attack_range; }
1253         if(!self.damageforcescale) { self.damageforcescale = autocvar_g_monsters_damageforcescale; }
1254
1255         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1256         {
1257                 Monster_Miniboss_Check();
1258                 self.health *= MONSTER_SKILLMOD(self);
1259
1260                 if(!self.skin)
1261                         self.skin = rint(random() * 4);
1262         }
1263
1264         self.max_health = self.health;
1265         self.pain_finished = self.nextthink;
1266
1267         if(IS_PLAYER(self.monster_follow))
1268                 self.effects |= EF_DIMLIGHT;
1269
1270         if(!self.wander_delay) { self.wander_delay = 2; }
1271         if(!self.wander_distance) { self.wander_distance = 600; }
1272
1273         Monster_Sounds_Precache();
1274         Monster_Sounds_Update();
1275
1276         if(teamplay)
1277                 self.monster_attack = true; // we can have monster enemies in team games
1278
1279         Monster_Sound(monstersound_spawn, 0, false, CH_VOICE);
1280
1281         if(autocvar_g_monsters_healthbars)
1282         {
1283                 entity wp = WaypointSprite_Spawn(WP_Monster, 0, 1024, self, '0 0 1' * (self.maxs.z + 15), world, self.team, self, sprite, true, RADARICON_DANGER);
1284                 wp.wp_extra = self.monsterid;
1285                 wp.colormod = ((self.team) ? Team_ColorRGB(self.team) : '1 0 0');
1286                 if(!(self.spawnflags & MONSTERFLAG_INVINCIBLE))
1287                 {
1288                         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
1289                         WaypointSprite_UpdateHealth(self.sprite, self.health);
1290                 }
1291         }
1292
1293         self.think = Monster_Think;
1294         self.nextthink = time + self.ticrate;
1295
1296         if(MUTATOR_CALLHOOK(MonsterSpawn))
1297                 return false;
1298
1299         return true;
1300 }
1301
1302 bool Monster_Spawn(int mon_id)
1303 {SELFPARAM();
1304         // setup the basic required properties for a monster
1305         entity mon = get_monsterinfo(mon_id);
1306         if(!mon.monsterid) { return false; } // invalid monster
1307
1308         if(!autocvar_g_monsters) { Monster_Remove(self); return false; }
1309
1310         self.mdl = mon.model;
1311         if(Monster_Appear_Check(self, mon_id)) { return true; } // return true so the monster isn't removed
1312
1313         if(!self.monster_skill)
1314                 self.monster_skill = cvar("g_monsters_skill");
1315
1316         // support for quake style removing monsters based on skill
1317         if(self.monster_skill == MONSTER_SKILL_EASY) if(self.spawnflags & MONSTERSKILL_NOTEASY) { Monster_Remove(self); return false; }
1318         if(self.monster_skill == MONSTER_SKILL_MEDIUM) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { Monster_Remove(self); return false; }
1319         if(self.monster_skill == MONSTER_SKILL_HARD) if(self.spawnflags & MONSTERSKILL_NOTHARD) { Monster_Remove(self); return false; }
1320
1321         if(self.team && !teamplay)
1322                 self.team = 0;
1323
1324         if(!(self.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1325         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED)) // don't count re-spawning monsters either
1326                 monsters_total += 1;
1327
1328         _setmodel(self, self.mdl);
1329         self.flags                              = FL_MONSTER;
1330         self.classname                  = "monster";
1331         self.takedamage                 = DAMAGE_AIM;
1332         self.bot_attack                 = true;
1333         self.iscreature                 = true;
1334         self.teleportable               = true;
1335         self.damagedbycontents  = true;
1336         self.monsterid                  = mon_id;
1337         self.event_damage               = Monster_Damage;
1338         self.touch                              = Monster_Touch;
1339         self.use                                = Monster_Use;
1340         self.solid                              = SOLID_BBOX;
1341         self.movetype                   = MOVETYPE_WALK;
1342         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1343         self.enemy                              = world;
1344         self.velocity                   = '0 0 0';
1345         self.moveto                             = self.origin;
1346         self.pos1                               = self.origin;
1347         self.pos2                               = self.angles;
1348         self.reset                              = Monster_Reset;
1349         self.netname                    = mon.netname;
1350         self.monster_attackfunc = mon.monster_attackfunc;
1351         self.monster_name               = mon.monster_name;
1352         self.candrop                    = true;
1353         self.view_ofs                   = '0 0 0.7' * (self.maxs_z * 0.5);
1354         self.oldtarget2                 = self.target2;
1355         self.pass_distance              = 0;
1356         self.deadflag                   = DEAD_NO;
1357         self.noalign                    = ((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM));
1358         self.spawn_time                 = time;
1359         self.spider_slowness    = 0;
1360         self.gravity                    = 1;
1361         self.monster_moveto             = '0 0 0';
1362         self.monster_face               = '0 0 0';
1363         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1364
1365         if(!self.scale) { self.scale = 1; }
1366         if(autocvar_g_monsters_edit) { self.grab = 1; }
1367         if(autocvar_g_fullbrightplayers) { self.effects |= EF_FULLBRIGHT; }
1368         if(autocvar_g_nodepthtestplayers) { self.effects |= EF_NODEPTHTEST; }
1369         if(mon.spawnflags & MONSTER_TYPE_SWIM) { self.flags |= FL_SWIM; }
1370
1371         if(mon.spawnflags & MONSTER_TYPE_FLY)
1372         {
1373                 self.flags |= FL_FLY;
1374                 self.movetype = MOVETYPE_FLY;
1375         }
1376
1377         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1378         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1379                 self.scale *= 1.3;
1380
1381         setsize(self, mon.mins * self.scale, mon.maxs * self.scale);
1382
1383         self.ticrate = bound(sys_frametime, ((!self.ticrate) ? autocvar_g_monsters_think_delay : self.ticrate), 60);
1384
1385         Monster_UpdateModel();
1386
1387         if(!Monster_Spawn_Setup())
1388         {
1389                 Monster_Remove(self);
1390                 return false;
1391         }
1392
1393         if(!self.noalign)
1394         {
1395                 setorigin(self, self.origin + '0 0 20');
1396                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1397                 setorigin(self, trace_endpos);
1398         }
1399
1400         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1401                 monster_setupcolors(self);
1402
1403         CSQCMODEL_AUTOINIT(self);
1404
1405         return true;
1406 }