Remove SELFPARAM() from .think and .touch
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / monsters / sv_monsters.qc
1 #if defined(CSQC)
2 #elif defined(MENUQC)
3 #elif defined(SVQC)
4     #include <lib/warpzone/common.qh>
5     #include "../constants.qh"
6     #include "../teams.qh"
7     #include "../util.qh"
8     #include "all.qh"
9     #include "sv_monsters.qh"
10         #include "../physics/movelib.qh"
11     #include "../weapons/all.qh"
12     #include <server/autocvars.qh>
13     #include <server/defs.qh>
14     #include "../deathtypes/all.qh"
15     #include <server/mutators/all.qh>
16         #include <server/steerlib.qh>
17         #include "../turrets/sv_turrets.qh"
18         #include "../turrets/util.qh"
19     #include "../vehicles/all.qh"
20     #include <server/campaign.qh>
21     #include <server/command/common.qh>
22     #include <server/command/cmd.qh>
23         #include "../triggers/triggers.qh"
24     #include <lib/csqcmodel/sv_model.qh>
25     #include <server/round_handler.qh>
26 #endif
27
28 void monsters_setstatus(entity this)
29 {
30         this.stat_monsters_total = monsters_total;
31         this.stat_monsters_killed = monsters_killed;
32 }
33
34 void monster_dropitem(entity this)
35 {
36         if(!this.candrop || !this.monster_loot)
37                 return;
38
39         vector org = this.origin + ((this.mins + this.maxs) * 0.5);
40         entity e = new(droppedweapon); // use weapon handling to remove it on touch
41         e.spawnfunc_checked = true;
42
43         e.monster_loot = this.monster_loot;
44
45         MUTATOR_CALLHOOK(MonsterDropItem, e);
46         e = other;
47
48         if(e && e.monster_loot)
49         {
50                 e.noalign = true;
51                 WITHSELF(e, e.monster_loot(e));
52                 e.gravity = 1;
53                 e.movetype = MOVETYPE_TOSS;
54                 e.reset = SUB_Remove;
55                 setorigin(e, org);
56                 e.velocity = randomvec() * 175 + '0 0 325';
57                 e.item_spawnshieldtime = time + 0.7;
58                 SUB_SetFade(e, time + autocvar_g_monsters_drop_time, 1);
59         }
60 }
61
62 void monster_makevectors(entity this, entity targ)
63 {
64         if(IS_MONSTER(this))
65         {
66                 vector v = targ.origin + (targ.mins + targ.maxs) * 0.5;
67                 this.v_angle = vectoangles(v - (this.origin + this.view_ofs));
68                 this.v_angle_x = -this.v_angle_x;
69         }
70
71         makevectors(this.v_angle);
72 }
73
74 // ===============
75 // Target handling
76 // ===============
77
78 bool Monster_ValidTarget(entity this, entity targ)
79 {
80         // ensure we're not checking nonexistent monster/target
81         if(!this || !targ) { return false; }
82
83         if((targ == this)
84         || (autocvar_g_monsters_lineofsight && !checkpvs(this.origin + this.view_ofs, targ)) // enemy cannot be seen
85         || (IS_VEHICLE(targ) && !((get_monsterinfo(this.monsterid)).spawnflags & MON_FLAG_RANGED)) // melee vs vehicle is useless
86         || (time < game_starttime) // monsters do nothing before match has started
87         || (targ.takedamage == DAMAGE_NO)
88         || (targ.items & IT_INVISIBILITY)
89         || (IS_SPEC(targ) || IS_OBSERVER(targ)) // don't attack spectators
90         || (!IS_VEHICLE(targ) && (IS_DEAD(targ) || IS_DEAD(this) || targ.health <= 0 || this.health <= 0))
91         || (this.monster_follow == targ || targ.monster_follow == this)
92         || (!IS_VEHICLE(targ) && (targ.flags & FL_NOTARGET))
93         || (!autocvar_g_monsters_typefrag && PHYS_INPUT_BUTTON_CHAT(targ))
94         || (SAME_TEAM(targ, this))
95         || (STAT(FROZEN, targ))
96         || (targ.alpha != 0 && targ.alpha < 0.5)
97         )
98         {
99                 // if any of the above checks fail, target is not valid
100                 return false;
101         }
102
103         traceline(this.origin + this.view_ofs, targ.origin, 0, this);
104
105         if((trace_fraction < 1) && (trace_ent != targ))
106                 return false;
107
108         if(autocvar_g_monsters_target_infront || (this.spawnflags & MONSTERFLAG_INFRONT))
109         if(this.enemy != targ)
110         {
111                 float dot;
112
113                 makevectors (this.angles);
114                 dot = normalize (targ.origin - this.origin) * v_forward;
115
116                 if(dot <= autocvar_g_monsters_target_infront_range) { return false; }
117         }
118
119         return true; // this target is valid!
120 }
121
122 entity Monster_FindTarget(entity mon)
123 {
124         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return mon.enemy; } // Handled by a mutator
125
126         entity head, closest_target = world;
127         head = findradius(mon.origin, mon.target_range);
128
129         while(head) // find the closest acceptable target to pass to
130         {
131                 if(head.monster_attack)
132                 if(Monster_ValidTarget(mon, head))
133                 {
134                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
135                         vector head_center = CENTER_OR_VIEWOFS(head);
136                         vector ent_center = CENTER_OR_VIEWOFS(mon);
137
138                         if(closest_target)
139                         {
140                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
141                                 if(vlen2(ent_center - head_center) < vlen2(ent_center - closest_target_center))
142                                         { closest_target = head; }
143                         }
144                         else { closest_target = head; }
145                 }
146
147                 head = head.chain;
148         }
149
150         return closest_target;
151 }
152
153 void monster_setupcolors(entity mon)
154 {
155         if(IS_PLAYER(mon.realowner))
156                 mon.colormap = mon.realowner.colormap;
157         else if(teamplay && mon.team)
158                 mon.colormap = 1024 + (mon.team - 1) * 17;
159         else
160         {
161                 if(mon.monster_skill <= MONSTER_SKILL_EASY)
162                         mon.colormap = 1029;
163                 else if(mon.monster_skill <= MONSTER_SKILL_MEDIUM)
164                         mon.colormap = 1027;
165                 else if(mon.monster_skill <= MONSTER_SKILL_HARD)
166                         mon.colormap = 1038;
167                 else if(mon.monster_skill <= MONSTER_SKILL_INSANE)
168                         mon.colormap = 1028;
169                 else if(mon.monster_skill <= MONSTER_SKILL_NIGHTMARE)
170                         mon.colormap = 1032;
171                 else
172                         mon.colormap = 1024;
173         }
174 }
175
176 void monster_changeteam(entity ent, float newteam)
177 {
178         if(!teamplay) { return; }
179
180         ent.team = newteam;
181         ent.monster_attack = true; // new team, activate attacking
182         monster_setupcolors(ent);
183
184         if(ent.sprite)
185         {
186                 WaypointSprite_UpdateTeamRadar(ent.sprite, RADARICON_DANGER, ((newteam) ? Team_ColorRGB(newteam) : '1 0 0'));
187
188                 ent.sprite.team = newteam;
189                 ent.sprite.SendFlags |= 1;
190         }
191 }
192
193 .void(entity) monster_delayedfunc;
194 void Monster_Delay_Action(entity this)
195 {
196         if(Monster_ValidTarget(this.owner, this.owner.enemy)) { this.monster_delayedfunc(this.owner); }
197
198         if(this.cnt > 1)
199         {
200                 this.cnt -= 1;
201                 setthink(this, Monster_Delay_Action);
202                 this.nextthink = time + this.count;
203         }
204         else
205         {
206                 setthink(this, SUB_Remove);
207                 this.nextthink = time;
208         }
209 }
210
211 void Monster_Delay(entity this, int repeat_count, float defer_amnt, void(entity) func)
212 {
213         // deferred attacking, checks if monster is still alive and target is still valid before attacking
214         entity e = spawn();
215
216         setthink(e, Monster_Delay_Action);
217         e.nextthink = time + defer_amnt;
218         e.count = defer_amnt;
219         e.owner = this;
220         e.monster_delayedfunc = func;
221         e.cnt = repeat_count;
222 }
223
224
225 // ==============
226 // Monster sounds
227 // ==============
228
229 string get_monster_model_datafilename(string m, float sk, string fil)
230 {
231         if(m)
232                 m = strcat(m, "_");
233         else
234                 m = "models/monsters/*_";
235         if(sk >= 0)
236                 m = strcat(m, ftos(sk));
237         else
238                 m = strcat(m, "*");
239         return strcat(m, ".", fil);
240 }
241
242 void Monster_Sound_Precache(string f)
243 {
244         float fh;
245         string s;
246         fh = fopen(f, FILE_READ);
247         if(fh < 0)
248                 return;
249         while((s = fgets(fh)))
250         {
251                 if(tokenize_console(s) != 3)
252                 {
253                         LOG_TRACE("Invalid sound info line: ", s, "\n");
254                         continue;
255                 }
256                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
257         }
258         fclose(fh);
259 }
260
261 void Monster_Sounds_Precache(entity this)
262 {
263         string m = (Monsters_from(this.monsterid)).m_model.model_str();
264         float globhandle, n, i;
265         string f;
266
267         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
268         if (globhandle < 0)
269                 return;
270         n = search_getsize(globhandle);
271         for (i = 0; i < n; ++i)
272         {
273                 //print(search_getfilename(globhandle, i), "\n");
274                 f = search_getfilename(globhandle, i);
275                 Monster_Sound_Precache(f);
276         }
277         search_end(globhandle);
278 }
279
280 void Monster_Sounds_Clear(entity this)
281 {
282 #define _MSOUND(m) if(this.monstersound_##m) { strunzone(this.monstersound_##m); this.monstersound_##m = string_null; }
283         ALLMONSTERSOUNDS
284 #undef _MSOUND
285 }
286
287 .string Monster_Sound_SampleField(string type)
288 {
289         GetMonsterSoundSampleField_notFound = 0;
290         switch(type)
291         {
292 #define _MSOUND(m) case #m: return monstersound_##m;
293                 ALLMONSTERSOUNDS
294 #undef _MSOUND
295         }
296         GetMonsterSoundSampleField_notFound = 1;
297         return string_null;
298 }
299
300 bool Monster_Sounds_Load(entity this, string f, int first)
301 {
302         float fh;
303         string s;
304         var .string field;
305         fh = fopen(f, FILE_READ);
306         if(fh < 0)
307         {
308                 LOG_TRACE("Monster sound file not found: ", f, "\n");
309                 return false;
310         }
311         while((s = fgets(fh)))
312         {
313                 if(tokenize_console(s) != 3)
314                         continue;
315                 field = Monster_Sound_SampleField(argv(0));
316                 if(GetMonsterSoundSampleField_notFound)
317                         continue;
318                 if (this.(field))
319                         strunzone(this.(field));
320                 this.(field) = strzone(strcat(argv(1), " ", argv(2)));
321         }
322         fclose(fh);
323         return true;
324 }
325
326 .int skin_for_monstersound;
327 void Monster_Sounds_Update(entity this)
328 {
329         if(this.skin == this.skin_for_monstersound) { return; }
330
331         this.skin_for_monstersound = this.skin;
332         Monster_Sounds_Clear(this);
333         if(!Monster_Sounds_Load(this, get_monster_model_datafilename(this.model, this.skin, "sounds"), 0))
334                 Monster_Sounds_Load(this, get_monster_model_datafilename(this.model, 0, "sounds"), 0);
335 }
336
337 void Monster_Sound(entity this, .string samplefield, float sound_delay, float delaytoo, float chan)
338 {
339         if(!autocvar_g_monsters_sounds) { return; }
340
341         if(delaytoo)
342         if(time < this.msound_delay)
343                 return; // too early
344         GlobalSound_string(this, this.(samplefield), chan, VOICETYPE_PLAYERSOUND);
345
346         this.msound_delay = time + sound_delay;
347 }
348
349
350 // =======================
351 // Monster attack handlers
352 // =======================
353
354 bool Monster_Attack_Melee(entity this, entity targ, float damg, vector anim, float er, float animtime, int deathtype, bool dostop)
355 {
356         if(dostop && IS_MONSTER(this)) { this.state = MONSTER_ATTACK_MELEE; }
357
358         setanim(this, anim, false, true, false);
359
360         if(this.animstate_endtime > time && IS_MONSTER(this))
361                 this.attack_finished_single[0] = this.anim_finished = this.animstate_endtime;
362         else
363                 this.attack_finished_single[0] = this.anim_finished = time + animtime;
364
365         monster_makevectors(this, targ);
366
367         traceline(this.origin + this.view_ofs, this.origin + v_forward * er, 0, this);
368
369         if(trace_ent.takedamage)
370                 Damage(trace_ent, this, this, damg * MONSTER_SKILLMOD(this), deathtype, trace_ent.origin, normalize(trace_ent.origin - this.origin));
371
372         return true;
373 }
374
375 bool Monster_Attack_Leap_Check(entity this, vector vel)
376 {
377         if(this.state && IS_MONSTER(this))
378                 return false; // already attacking
379         if(!IS_ONGROUND(this))
380                 return false; // not on the ground
381         if(this.health <= 0 || IS_DEAD(this))
382                 return false; // called when dead?
383         if(time < this.attack_finished_single[0])
384                 return false; // still attacking
385
386         vector old = this.velocity;
387
388         this.velocity = vel;
389         tracetoss(this, this);
390         this.velocity = old;
391         if (trace_ent != this.enemy)
392                 return false;
393
394         return true;
395 }
396
397 bool Monster_Attack_Leap(entity this, vector anm, void(entity this) touchfunc, vector vel, float animtime)
398 {
399         if(!Monster_Attack_Leap_Check(this, vel))
400                 return false;
401
402         setanim(this, anm, false, true, false);
403
404         if(this.animstate_endtime > time && (this.flags & FL_MONSTER))
405                 this.attack_finished_single[0] = this.anim_finished = this.animstate_endtime;
406         else
407                 this.attack_finished_single[0] = this.anim_finished = time + animtime;
408
409         if(this.flags & FL_MONSTER)
410                 this.state = MONSTER_ATTACK_RANGED;
411         settouch(this, touchfunc);
412         this.origin_z += 1;
413         this.velocity = vel;
414         UNSET_ONGROUND(this);
415
416         return true;
417 }
418
419 void Monster_Attack_Check(entity this, entity targ)
420 {
421         if((this == world || targ == world)
422         || (!this.monster_attackfunc)
423         || (time < this.attack_finished_single[0])
424         ) { return; }
425
426         if(vdist(targ.origin - this.origin, <=, this.attack_range))
427         {
428                 bool attack_success = this.monster_attackfunc(MONSTER_ATTACK_MELEE, this, targ);
429                 if(attack_success == 1)
430                         Monster_Sound(this, monstersound_melee, 0, false, CH_VOICE);
431                 else if(attack_success > 0)
432                         return;
433         }
434
435         if(vdist(targ.origin - this.origin, >, this.attack_range))
436         {
437                 float attack_success = this.monster_attackfunc(MONSTER_ATTACK_RANGED, this, targ);
438                 if(attack_success == 1)
439                         Monster_Sound(this, monstersound_melee, 0, false, CH_VOICE);
440                 else if(attack_success > 0)
441                         return;
442         }
443 }
444
445
446 // ======================
447 // Main monster functions
448 // ======================
449
450 void Monster_UpdateModel(entity this)
451 {
452         // assume some defaults
453         /*this.anim_idle   = animfixfps(this, '0 1 0.01', '0 0 0');
454         this.anim_walk   = animfixfps(this, '1 1 0.01', '0 0 0');
455         this.anim_run    = animfixfps(this, '2 1 0.01', '0 0 0');
456         this.anim_fire1  = animfixfps(this, '3 1 0.01', '0 0 0');
457         this.anim_fire2  = animfixfps(this, '4 1 0.01', '0 0 0');
458         this.anim_melee  = animfixfps(this, '5 1 0.01', '0 0 0');
459         this.anim_pain1  = animfixfps(this, '6 1 0.01', '0 0 0');
460         this.anim_pain2  = animfixfps(this, '7 1 0.01', '0 0 0');
461         this.anim_die1   = animfixfps(this, '8 1 0.01', '0 0 0');
462         this.anim_die2   = animfixfps(this, '9 1 0.01', '0 0 0');*/
463
464         // then get the real values
465         Monster mon = get_monsterinfo(this.monsterid);
466         mon.mr_anim(mon, this);
467 }
468
469 void Monster_Touch(entity this)
470 {
471         if(other == world) { return; }
472
473         if(other.monster_attack)
474         if(this.enemy != other)
475         if(!IS_MONSTER(other))
476         if(Monster_ValidTarget(this, other))
477                 this.enemy = other;
478 }
479
480 void Monster_Miniboss_Check(entity this)
481 {
482         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag, this))
483                 return;
484
485         float chance = random() * 100;
486
487         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
488         if ((this.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
489         {
490                 this.health += autocvar_g_monsters_miniboss_healthboost;
491                 this.effects |= EF_RED;
492                 if(!this.weapon)
493                         this.weapon = WEP_VORTEX.m_id;
494         }
495 }
496
497 bool Monster_Respawn_Check(entity this)
498 {
499         if(this.deadflag == DEAD_DEAD) // don't call when monster isn't dead
500         if(MUTATOR_CALLHOOK(MonsterRespawn, this))
501                 return true; // enabled by a mutator
502
503         if(this.spawnflags & MONSTERFLAG_NORESPAWN)
504                 return false;
505
506         if(!autocvar_g_monsters_respawn)
507                 return false;
508
509         return true;
510 }
511
512 void Monster_Respawn(entity this) { Monster_Spawn(this, this.monsterid); }
513
514 void Monster_Dead_Fade(entity this)
515 {
516         if(Monster_Respawn_Check(this))
517         {
518                 this.spawnflags |= MONSTERFLAG_RESPAWNED;
519                 setthink(this, Monster_Respawn);
520                 this.nextthink = time + this.respawntime;
521                 this.monster_lifetime = 0;
522                 this.deadflag = DEAD_RESPAWNING;
523                 if(this.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
524                 {
525                         this.pos1 = this.origin;
526                         this.pos2 = this.angles;
527                 }
528                 this.event_damage = func_null;
529                 this.takedamage = DAMAGE_NO;
530                 setorigin(this, this.pos1);
531                 this.angles = this.pos2;
532                 this.health = this.max_health;
533                 setmodel(this, MDL_Null);
534         }
535         else
536         {
537                 // number of monsters spawned with mobspawn command
538                 totalspawned -= 1;
539
540                 SUB_SetFade(this, time + 3, 1);
541         }
542 }
543
544 void Monster_Use(entity this, entity actor, entity trigger)
545 {
546         if(Monster_ValidTarget(this, actor)) { this.enemy = actor; }
547 }
548
549 vector Monster_Move_Target(entity this, entity targ)
550 {
551         // enemy is always preferred target
552         if(this.enemy)
553         {
554                 vector targ_origin = ((this.enemy.absmin + this.enemy.absmax) * 0.5);
555                 targ_origin = WarpZone_RefSys_TransformOrigin(this.enemy, this, targ_origin); // origin of target as seen by the monster (us)
556                 WarpZone_TraceLine(this.origin, targ_origin, MOVE_NOMONSTERS, this);
557
558                 if((this.enemy == world)
559                         || (IS_DEAD(this.enemy) || this.enemy.health < 1)
560                         || (STAT(FROZEN, this.enemy))
561                         || (this.enemy.flags & FL_NOTARGET)
562                         || (this.enemy.alpha < 0.5 && this.enemy.alpha != 0)
563                         || (this.enemy.takedamage == DAMAGE_NO)
564                         || (vdist(this.origin - targ_origin, >, this.target_range))
565                         || ((trace_fraction < 1) && (trace_ent != this.enemy)))
566                 {
567                         this.enemy = world;
568                         this.pass_distance = 0;
569                 }
570
571                 if(this.enemy)
572                 {
573                         /*WarpZone_TrailParticles(world, particleeffectnum(EFFECT_RED_PASS), this.origin, targ_origin);
574                         print("Trace origin: ", vtos(targ_origin), "\n");
575                         print("Target origin: ", vtos(this.enemy.origin), "\n");
576                         print("My origin: ", vtos(this.origin), "\n"); */
577
578                         this.monster_movestate = MONSTER_MOVE_ENEMY;
579                         this.last_trace = time + 1.2;
580                         if(this.monster_moveto)
581                                 return this.monster_moveto; // assumes code is properly setting this when monster has an enemy
582                         else
583                                 return targ_origin;
584                 }
585
586                 /*makevectors(this.angles);
587                 this.monster_movestate = MONSTER_MOVE_ENEMY;
588                 this.last_trace = time + 1.2;
589                 return this.enemy.origin; */
590         }
591
592         switch(this.monster_moveflags)
593         {
594                 case MONSTER_MOVE_FOLLOW:
595                 {
596                         this.monster_movestate = MONSTER_MOVE_FOLLOW;
597                         this.last_trace = time + 0.3;
598                         return (this.monster_follow) ? this.monster_follow.origin : this.origin;
599                 }
600                 case MONSTER_MOVE_SPAWNLOC:
601                 {
602                         this.monster_movestate = MONSTER_MOVE_SPAWNLOC;
603                         this.last_trace = time + 2;
604                         return this.pos1;
605                 }
606                 case MONSTER_MOVE_NOMOVE:
607                 {
608                         if(this.monster_moveto)
609                         {
610                                 this.last_trace = time + 0.5;
611                                 return this.monster_moveto;
612                         }
613                         else
614                         {
615                                 this.monster_movestate = MONSTER_MOVE_NOMOVE;
616                                 this.last_trace = time + 2;
617                         }
618                         return this.origin;
619                 }
620                 default:
621                 case MONSTER_MOVE_WANDER:
622                 {
623                         vector pos;
624                         this.monster_movestate = MONSTER_MOVE_WANDER;
625
626                         if(this.monster_moveto)
627                         {
628                                 this.last_trace = time + 0.5;
629                                 pos = this.monster_moveto;
630                         }
631                         else if(targ)
632                         {
633                                 this.last_trace = time + 0.5;
634                                 pos = targ.origin;
635                         }
636                         else
637                         {
638                                 this.last_trace = time + this.wander_delay;
639
640                                 this.angles_y = rint(random() * 500);
641                                 makevectors(this.angles);
642                                 pos = this.origin + v_forward * this.wander_distance;
643
644                                 if(((this.flags & FL_FLY) && (this.spawnflags & MONSTERFLAG_FLY_VERTICAL)) || (this.flags & FL_SWIM))
645                                 {
646                                         pos.z = random() * 200;
647                                         if(random() >= 0.5)
648                                                 pos.z *= -1;
649                                 }
650                         }
651
652                         return pos;
653                 }
654         }
655 }
656
657 void Monster_CalculateVelocity(entity this, vector to, vector from, float turnrate, float movespeed)
658 {
659         float current_distance = vlen((('1 0 0' * to.x) + ('0 1 0' * to.y)) - (('1 0 0' * from.x) + ('0 1 0' * from.y))); // for the sake of this check, exclude Z axis
660         float initial_height = 0; //min(50, (targ_distance * tanh(20)));
661         float current_height = (initial_height * min(1, (this.pass_distance) ? (current_distance / this.pass_distance) : current_distance));
662         //print("current_height = ", ftos(current_height), ", initial_height = ", ftos(initial_height), ".\n");
663
664         vector targpos;
665         if(current_height) // make sure we can actually do this arcing path
666         {
667                 targpos = (to + ('0 0 1' * current_height));
668                 WarpZone_TraceLine(this.origin, targpos, MOVE_NOMONSTERS, this);
669                 if(trace_fraction < 1)
670                 {
671                         //print("normal arc line failed, trying to find new pos...");
672                         WarpZone_TraceLine(to, targpos, MOVE_NOMONSTERS, this);
673                         targpos = (trace_endpos + '0 0 -10');
674                         WarpZone_TraceLine(this.origin, targpos, MOVE_NOMONSTERS, this);
675                         if(trace_fraction < 1) { targpos = to; /* print(" ^1FAILURE^7, reverting to original direction.\n"); */ }
676                         /*else { print(" ^3SUCCESS^7, using new arc line.\n"); } */
677                 }
678         }
679         else { targpos = to; }
680
681         //this.angles = normalize(('0 1 0' * to_y) - ('0 1 0' * from_y));
682
683         vector desired_direction = normalize(targpos - from);
684         if(turnrate) { this.velocity = (normalize(normalize(this.velocity) + (desired_direction * 50)) * movespeed); }
685         else { this.velocity = (desired_direction * movespeed); }
686
687         //this.steerto = steerlib_attract2(targpos, 0.5, 500, 0.95);
688         //this.angles = vectoangles(this.velocity);
689 }
690
691 void Monster_Move(entity this, float runspeed, float walkspeed, float stpspeed)
692 {
693         if(this.target2) { this.goalentity = find(world, targetname, this.target2); }
694
695         entity targ;
696
697         if(STAT(FROZEN, this) == 2)
698         {
699                 this.revive_progress = bound(0, this.revive_progress + this.ticrate * this.revive_speed, 1);
700                 this.health = max(1, this.revive_progress * this.max_health);
701                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
702
703                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE) && this.sprite)
704                         WaypointSprite_UpdateHealth(this.sprite, this.health);
705
706                 movelib_brake_simple(this, stpspeed);
707                 setanim(this, this.anim_idle, true, false, false);
708
709                 this.enemy = world;
710                 this.nextthink = time + this.ticrate;
711
712                 if(this.revive_progress >= 1)
713                         Unfreeze(this);
714
715                 return;
716         }
717         else if(STAT(FROZEN, this) == 3)
718         {
719                 this.revive_progress = bound(0, this.revive_progress - this.ticrate * this.revive_speed, 1);
720                 this.health = max(0, autocvar_g_nades_ice_health + (this.max_health-autocvar_g_nades_ice_health) * this.revive_progress );
721
722                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE) && this.sprite)
723                         WaypointSprite_UpdateHealth(this.sprite, this.health);
724
725                 movelib_brake_simple(this, stpspeed);
726                 setanim(this, this.anim_idle, true, false, false);
727
728                 this.enemy = world;
729                 this.nextthink = time + this.ticrate;
730
731                 if(this.health < 1)
732                 {
733                         Unfreeze(this);
734                         this.health = 0;
735                         if(this.event_damage)
736                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
737                 }
738
739                 else if ( this.revive_progress <= 0 )
740                         Unfreeze(this);
741
742                 return;
743         }
744
745         if(this.flags & FL_SWIM)
746         {
747                 if(this.waterlevel < WATERLEVEL_WETFEET)
748                 {
749                         if(time >= this.last_trace)
750                         {
751                                 this.last_trace = time + 0.4;
752
753                                 Damage (this, world, world, 2, DEATH_DROWN.m_id, this.origin, '0 0 0');
754                                 this.angles = '90 90 0';
755                                 if(random() < 0.5)
756                                 {
757                                         this.velocity_y += random() * 50;
758                                         this.velocity_x -= random() * 50;
759                                 }
760                                 else
761                                 {
762                                         this.velocity_y -= random() * 50;
763                                         this.velocity_x += random() * 50;
764                                 }
765                                 this.velocity_z += random() * 150;
766                         }
767
768
769                         this.movetype = MOVETYPE_BOUNCE;
770                         //this.velocity_z = -200;
771
772                         return;
773                 }
774                 else if(this.movetype == MOVETYPE_BOUNCE)
775                 {
776                         this.angles_x = 0;
777                         this.movetype = MOVETYPE_WALK;
778                 }
779         }
780
781         targ = this.goalentity;
782
783         if (MUTATOR_CALLHOOK(MonsterMove, this, runspeed, walkspeed, targ)
784                 || gameover
785                 || this.draggedby != world
786                 || (round_handler_IsActive() && !round_handler_IsRoundStarted())
787                 || time < game_starttime
788                 || (autocvar_g_campaign && !campaign_bots_may_start)
789                 || time < this.spawn_time)
790         {
791                 runspeed = walkspeed = 0;
792                 if(time >= this.spawn_time)
793                         setanim(this, this.anim_idle, true, false, false);
794                 movelib_brake_simple(this, stpspeed);
795                 return;
796         }
797
798         targ = monster_target;
799         runspeed = bound(0, monster_speed_run * MONSTER_SKILLMOD(this), runspeed * 2.5); // limit maxspeed to prevent craziness
800         walkspeed = bound(0, monster_speed_walk * MONSTER_SKILLMOD(this), walkspeed * 2.5); // limit maxspeed to prevent craziness
801
802         if(teamplay)
803         if(autocvar_g_monsters_teams)
804         if(DIFF_TEAM(this.monster_follow, this))
805                 this.monster_follow = world;
806
807         if(time >= this.last_enemycheck)
808         {
809                 if(!this.enemy)
810                 {
811                         this.enemy = Monster_FindTarget(this);
812                         if(this.enemy)
813                         {
814                                 WarpZone_RefSys_Copy(this.enemy, this);
815                                 WarpZone_RefSys_AddInverse(this.enemy, this); // wz1^-1 ... wzn^-1 receiver
816                                 this.moveto = WarpZone_RefSys_TransformOrigin(this.enemy, this, (0.5 * (this.enemy.absmin + this.enemy.absmax)));
817                                 this.monster_moveto = '0 0 0';
818                                 this.monster_face = '0 0 0';
819
820                                 this.pass_distance = vlen((('1 0 0' * this.enemy.origin_x) + ('0 1 0' * this.enemy.origin_y)) - (('1 0 0' *  this.origin_x) + ('0 1 0' *  this.origin_y)));
821                                 Monster_Sound(this, monstersound_sight, 0, false, CH_VOICE);
822                         }
823                 }
824
825                 this.last_enemycheck = time + 1; // check for enemies every second
826         }
827
828         if(this.state == MONSTER_ATTACK_RANGED && IS_ONGROUND(this))
829         {
830                 this.state = 0;
831                 settouch(this, Monster_Touch);
832         }
833
834         if(this.state && time >= this.attack_finished_single[0])
835                 this.state = 0; // attack is over
836
837         if(this.state != MONSTER_ATTACK_MELEE) // don't move if set
838         if(time >= this.last_trace || this.enemy) // update enemy or rider instantly
839                 this.moveto = Monster_Move_Target(this, targ);
840
841         if(!this.enemy)
842                 Monster_Sound(this, monstersound_idle, 7, true, CH_VOICE);
843
844         if(this.state == MONSTER_ATTACK_MELEE)
845                 this.moveto = this.origin;
846
847         if(this.enemy && this.enemy.vehicle)
848                 runspeed = 0;
849
850         if(!(this.spawnflags & MONSTERFLAG_FLY_VERTICAL) && !(this.flags & FL_SWIM))
851                 this.moveto_z = this.origin_z;
852
853         if(vdist(this.origin - this.moveto, >, 100))
854         {
855                 float do_run = (this.enemy || this.monster_moveto);
856                 if(IS_ONGROUND(this) || ((this.flags & FL_FLY) || (this.flags & FL_SWIM)))
857                         Monster_CalculateVelocity(this, this.moveto, this.origin, true, ((do_run) ? runspeed : walkspeed));
858
859                 if(time > this.pain_finished) // TODO: use anim_finished instead!
860                 if(!this.state)
861                 if(time > this.anim_finished)
862                 if(vdist(this.velocity, >, 10))
863                         setanim(this, ((do_run) ? this.anim_run : this.anim_walk), true, false, false);
864                 else
865                         setanim(this, this.anim_idle, true, false, false);
866         }
867         else
868         {
869                 entity e = find(world, targetname, this.target2);
870                 if(e.target2)
871                         this.target2 = e.target2;
872                 else if(e.target)
873                         this.target2 = e.target;
874
875                 movelib_brake_simple(this, stpspeed);
876                 if(time > this.anim_finished)
877                 if(time > this.pain_finished)
878                 if(!this.state)
879                 if(vdist(this.velocity, <=, 30))
880                         setanim(this, this.anim_idle, true, false, false);
881         }
882
883         this.steerto = steerlib_attract2(this, ((this.monster_face) ? this.monster_face : this.moveto), 0.5, 500, 0.95);
884
885         vector real_angle = vectoangles(this.steerto) - this.angles;
886         float turny = 25;
887         if(this.state == MONSTER_ATTACK_MELEE)
888                 turny = 0;
889         if(turny)
890         {
891                 turny = bound(turny * -1, shortangle_f(real_angle.y, this.angles.y), turny);
892                 this.angles_y += turny;
893         }
894
895         Monster_Attack_Check(this, this.enemy);
896 }
897
898 void Monster_Remove(entity this)
899 {
900         if(IS_CLIENT(this))
901                 return; // don't remove it?
902
903         .entity weaponentity = weaponentities[0];
904         if(!this) { return; }
905
906         if(!MUTATOR_CALLHOOK(MonsterRemove, this))
907                 Send_Effect(EFFECT_ITEM_PICKUP, this.origin, '0 0 0', 1);
908
909         if(this.(weaponentity)) { remove(this.(weaponentity)); }
910         if(this.iceblock) { remove(this.iceblock); }
911         WaypointSprite_Kill(this.sprite);
912         remove(this);
913 }
914
915 void Monster_Dead_Think(entity this)
916 {
917         this.nextthink = time + this.ticrate;
918
919         if(this.monster_lifetime != 0)
920         if(time >= this.monster_lifetime)
921         {
922                 Monster_Dead_Fade(this);
923                 return;
924         }
925 }
926
927 void Monster_Appear(entity this, entity actor, entity trigger)
928 {
929         this.enemy = actor;
930         this.spawnflags &= ~MONSTERFLAG_APPEAR; // otherwise, we get an endless loop
931         Monster_Spawn(this, this.monsterid);
932 }
933
934 bool Monster_Appear_Check(entity this, int monster_id)
935 {
936         if(!(this.spawnflags & MONSTERFLAG_APPEAR))
937                 return false;
938
939         setthink(this, func_null);
940         this.monsterid = monster_id; // set so this monster is properly registered (otherwise, normal initialization is used)
941         this.nextthink = 0;
942         this.use = Monster_Appear;
943         this.flags = FL_MONSTER; // set so this monster can get butchered
944
945         return true;
946 }
947
948 void Monster_Reset(entity this)
949 {
950         setorigin(this, this.pos1);
951         this.angles = this.pos2;
952
953         Unfreeze(this); // remove any icy remains
954
955         this.health = this.max_health;
956         this.velocity = '0 0 0';
957         this.enemy = world;
958         this.goalentity = world;
959         this.attack_finished_single[0] = 0;
960         this.moveto = this.origin;
961 }
962
963 void Monster_Dead_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
964 {
965         this.health -= damage;
966
967         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
968
969         if(this.health <= -50) // 100 health until gone?
970         {
971                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
972
973                 // number of monsters spawned with mobspawn command
974                 totalspawned -= 1;
975
976                 setthink(this, SUB_Remove);
977                 this.nextthink = time + 0.1;
978                 this.event_damage = func_null;
979         }
980 }
981
982 void Monster_Dead(entity this, entity attacker, float gibbed)
983 {
984         setthink(this, Monster_Dead_Think);
985         this.nextthink = time;
986         this.monster_lifetime = time + 5;
987
988         if(STAT(FROZEN, this))
989         {
990                 Unfreeze(this); // remove any icy remains
991                 this.health = 0; // reset by Unfreeze
992         }
993
994         monster_dropitem(this);
995
996         Monster_Sound(this, monstersound_death, 0, false, CH_VOICE);
997
998         if(!(this.spawnflags & MONSTERFLAG_SPAWNED) && !(this.spawnflags & MONSTERFLAG_RESPAWNED))
999                 monsters_killed += 1;
1000
1001         if(IS_PLAYER(attacker))
1002         if(autocvar_g_monsters_score_spawned || !((this.spawnflags & MONSTERFLAG_SPAWNED) || (this.spawnflags & MONSTERFLAG_RESPAWNED)))
1003                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
1004
1005         if(gibbed)
1006         {
1007                 // number of monsters spawned with mobspawn command
1008                 totalspawned -= 1;
1009         }
1010
1011         this.event_damage       = ((gibbed) ? func_null : Monster_Dead_Damage);
1012         this.solid                      = SOLID_CORPSE;
1013         this.takedamage         = DAMAGE_AIM;
1014         this.deadflag           = DEAD_DEAD;
1015         this.enemy                      = world;
1016         this.movetype           = MOVETYPE_TOSS;
1017         this.moveto                     = this.origin;
1018         settouch(this, Monster_Touch); // reset incase monster was pouncing
1019         this.reset                      = func_null;
1020         this.state                      = 0;
1021         this.attack_finished_single[0] = 0;
1022         this.effects = 0;
1023
1024         if(!((this.flags & FL_FLY) || (this.flags & FL_SWIM)))
1025                 this.velocity = '0 0 0';
1026
1027         CSQCModel_UnlinkEntity(this);
1028
1029         Monster mon = get_monsterinfo(this.monsterid);
1030         mon.mr_death(mon, this);
1031
1032         if(this.candrop && this.weapon)
1033                 W_ThrowNewWeapon(this, this.weapon, 0, this.origin, randomvec() * 150 + '0 0 325');
1034 }
1035
1036 void Monster_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1037 {
1038         if((this.spawnflags & MONSTERFLAG_INVINCIBLE) && deathtype != DEATH_KILL.m_id && !ITEM_DAMAGE_NEEDKILL(deathtype))
1039                 return;
1040
1041         if(STAT(FROZEN, this) && deathtype != DEATH_KILL.m_id && deathtype != DEATH_NADE_ICE_FREEZE.m_id)
1042                 return;
1043
1044         //if(time < this.pain_finished && deathtype != DEATH_KILL.m_id)
1045                 //return;
1046
1047         if(time < this.spawnshieldtime && deathtype != DEATH_KILL.m_id)
1048                 return;
1049
1050         if(deathtype == DEATH_FALL.m_id && this.draggedby != world)
1051                 return;
1052
1053         vector v;
1054         float take, save;
1055
1056         v = healtharmor_applydamage(100, this.armorvalue / 100, deathtype, damage);
1057         take = v_x;
1058         save = v_y;
1059
1060         damage_take = take;
1061         frag_attacker = attacker;
1062         frag_deathtype = deathtype;
1063         Monster mon = get_monsterinfo(this.monsterid);
1064         mon.mr_pain(mon, this);
1065         take = damage_take;
1066
1067         if(take)
1068         {
1069                 this.health -= take;
1070                 Monster_Sound(this, monstersound_pain, 1.2, true, CH_PAIN);
1071         }
1072
1073         if(this.sprite)
1074                 WaypointSprite_UpdateHealth(this.sprite, this.health);
1075
1076         this.dmg_time = time;
1077
1078         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN.m_id)
1079                 spamsound (this, CH_PAIN, SND(BODYIMPACT1), VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
1080
1081         this.velocity += force * this.damageforcescale;
1082
1083         if(deathtype != DEATH_DROWN.m_id && take)
1084         {
1085                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, this, attacker);
1086                 if (take > 50)
1087                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
1088                 if (take > 100)
1089                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
1090         }
1091
1092         if(this.health <= 0)
1093         {
1094                 if(deathtype == DEATH_KILL.m_id)
1095                         this.candrop = false; // killed by mobkill command
1096
1097                 // TODO: fix this?
1098                 SUB_UseTargets(this, attacker, this.enemy);
1099                 this.target2 = this.oldtarget2; // reset to original target on death, incase we respawn
1100
1101                 Monster_Dead(this, attacker, (this.health <= -100 || deathtype == DEATH_KILL.m_id));
1102
1103                 WaypointSprite_Kill(this.sprite);
1104
1105                 MUTATOR_CALLHOOK(MonsterDies, this, attacker);
1106
1107                 if(this.health <= -100 || deathtype == DEATH_KILL.m_id) // check if we're already gibbed
1108                 {
1109                         Violence_GibSplash(this, 1, 0.5, attacker);
1110
1111                         setthink(this, SUB_Remove);
1112                         this.nextthink = time + 0.1;
1113                 }
1114         }
1115 }
1116
1117 // don't check for enemies, just keep walking in a straight line
1118 void Monster_Move_2D(entity this, float mspeed, bool allow_jumpoff)
1119 {
1120         if(gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || this.draggedby != world || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < this.spawn_time)
1121         {
1122                 mspeed = 0;
1123                 if(time >= this.spawn_time)
1124                         setanim(this, this.anim_idle, true, false, false);
1125                 movelib_brake_simple(this, 0.6);
1126                 return;
1127         }
1128
1129         float reverse = false;
1130         vector a, b;
1131
1132         makevectors(this.angles);
1133         a = this.origin + '0 0 16';
1134         b = this.origin + '0 0 16' + v_forward * 32;
1135
1136         traceline(a, b, MOVE_NORMAL, this);
1137
1138         if(trace_fraction != 1.0)
1139         {
1140                 reverse = true;
1141
1142                 if(trace_ent)
1143                 if(IS_PLAYER(trace_ent) && !(trace_ent.items & IT_STRENGTH))
1144                         reverse = false;
1145         }
1146
1147         // TODO: fix this... tracing is broken if the floor is thin
1148         /*
1149         if(!allow_jumpoff)
1150         {
1151                 a = b - '0 0 32';
1152                 traceline(b, a, MOVE_WORLDONLY, this);
1153                 if(trace_fraction == 1.0)
1154                         reverse = true;
1155         } */
1156
1157         if(reverse)
1158         {
1159                 this.angles_y = anglemods(this.angles_y - 180);
1160                 makevectors(this.angles);
1161         }
1162
1163         movelib_move_simple_gravity(this, v_forward, mspeed, 1);
1164
1165         if(time > this.pain_finished)
1166         if(time > this.attack_finished_single[0])
1167         if(vdist(this.velocity, >, 10))
1168                 setanim(this, this.anim_walk, true, false, false);
1169         else
1170                 setanim(this, this.anim_idle, true, false, false);
1171 }
1172
1173 void Monster_Anim(entity this)
1174 {
1175         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
1176         if(IS_DEAD(this))
1177         {
1178                 if (!deadbits)
1179                 {
1180                         // Decide on which death animation to use.
1181                         if(random() < 0.5)
1182                                 deadbits = ANIMSTATE_DEAD1;
1183                         else
1184                                 deadbits = ANIMSTATE_DEAD2;
1185                 }
1186         }
1187         else
1188         {
1189                 // Clear a previous death animation.
1190                 deadbits = 0;
1191         }
1192         int animbits = deadbits;
1193         if(STAT(FROZEN, this))
1194                 animbits |= ANIMSTATE_FROZEN;
1195         if(this.crouch)
1196                 animbits |= ANIMSTATE_DUCK; // not that monsters can crouch currently...
1197         animdecide_setstate(this, animbits, false);
1198         animdecide_setimplicitstate(this, (IS_ONGROUND(this)));
1199
1200         /* // weapon entities for monsters?
1201         if (this.weaponentity)
1202         {
1203                 updateanim(this.weaponentity);
1204                 if (!this.weaponentity.animstate_override)
1205                         setanim(this.weaponentity, this.weaponentity.anim_idle, true, false, false);
1206         }
1207         */
1208 }
1209
1210 void Monster_Think(entity this)
1211 {
1212         setthink(this, Monster_Think);
1213         this.nextthink = this.ticrate;
1214
1215         if(this.monster_lifetime)
1216         if(time >= this.monster_lifetime)
1217         {
1218                 Damage(this, this, this, this.health + this.max_health, DEATH_KILL.m_id, this.origin, this.origin);
1219                 return;
1220         }
1221
1222         Monster mon = get_monsterinfo(this.monsterid);
1223         if(mon.mr_think(mon, this))
1224                 Monster_Move(this, this.speed2, this.speed, this.stopspeed);
1225
1226         Monster_Anim(this);
1227
1228         CSQCMODEL_AUTOUPDATE(this);
1229 }
1230
1231 bool Monster_Spawn_Setup(entity this)
1232 {
1233         Monster mon = Monsters_from(this.monsterid);
1234         mon.mr_setup(mon, this);
1235
1236         // ensure some basic needs are met
1237         if(!this.health) { this.health = 100; }
1238         if(!this.armorvalue) { this.armorvalue = bound(0.2, 0.5 * MONSTER_SKILLMOD(this), 0.9); }
1239         if(!this.target_range) { this.target_range = autocvar_g_monsters_target_range; }
1240         if(!this.respawntime) { this.respawntime = autocvar_g_monsters_respawn_delay; }
1241         if(!this.monster_moveflags) { this.monster_moveflags = MONSTER_MOVE_WANDER; }
1242         if(!this.attack_range) { this.attack_range = autocvar_g_monsters_attack_range; }
1243         if(!this.damageforcescale) { this.damageforcescale = autocvar_g_monsters_damageforcescale; }
1244
1245         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1246         {
1247                 Monster_Miniboss_Check(this);
1248                 this.health *= MONSTER_SKILLMOD(this);
1249
1250                 if(!this.skin)
1251                         this.skin = rint(random() * 4);
1252         }
1253
1254         this.max_health = this.health;
1255         this.pain_finished = this.nextthink;
1256
1257         if(IS_PLAYER(this.monster_follow))
1258                 this.effects |= EF_DIMLIGHT;
1259
1260         if(!this.wander_delay) { this.wander_delay = 2; }
1261         if(!this.wander_distance) { this.wander_distance = 600; }
1262
1263         Monster_Sounds_Precache(this);
1264         Monster_Sounds_Update(this);
1265
1266         if(teamplay)
1267                 this.monster_attack = true; // we can have monster enemies in team games
1268
1269         Monster_Sound(this, monstersound_spawn, 0, false, CH_VOICE);
1270
1271         if(autocvar_g_monsters_healthbars)
1272         {
1273                 entity wp = WaypointSprite_Spawn(WP_Monster, 0, 1024, this, '0 0 1' * (this.maxs.z + 15), world, this.team, this, sprite, true, RADARICON_DANGER);
1274                 wp.wp_extra = this.monsterid;
1275                 wp.colormod = ((this.team) ? Team_ColorRGB(this.team) : '1 0 0');
1276                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE))
1277                 {
1278                         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
1279                         WaypointSprite_UpdateHealth(this.sprite, this.health);
1280                 }
1281         }
1282
1283         setthink(this, Monster_Think);
1284         this.nextthink = time + this.ticrate;
1285
1286         if(MUTATOR_CALLHOOK(MonsterSpawn, this))
1287                 return false;
1288
1289         return true;
1290 }
1291
1292 bool Monster_Spawn(entity this, int mon_id)
1293 {
1294         // setup the basic required properties for a monster
1295         entity mon = Monsters_from(mon_id);
1296         if(!mon.monsterid) { return false; } // invalid monster
1297
1298         if(!autocvar_g_monsters) { Monster_Remove(this); return false; }
1299
1300         if(Monster_Appear_Check(this, mon_id)) { return true; } // return true so the monster isn't removed
1301
1302         if(!this.monster_skill)
1303                 this.monster_skill = cvar("g_monsters_skill");
1304
1305         // support for quake style removing monsters based on skill
1306         if(this.monster_skill == MONSTER_SKILL_EASY) if(this.spawnflags & MONSTERSKILL_NOTEASY) { Monster_Remove(this); return false; }
1307         if(this.monster_skill == MONSTER_SKILL_MEDIUM) if(this.spawnflags & MONSTERSKILL_NOTMEDIUM) { Monster_Remove(this); return false; }
1308         if(this.monster_skill == MONSTER_SKILL_HARD) if(this.spawnflags & MONSTERSKILL_NOTHARD) { Monster_Remove(this); return false; }
1309
1310         if(this.team && !teamplay)
1311                 this.team = 0;
1312
1313         if(!(this.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1314         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED)) // don't count re-spawning monsters either
1315                 monsters_total += 1;
1316
1317         setmodel(this, mon.m_model);
1318         this.flags                              = FL_MONSTER;
1319         this.classname                  = "monster";
1320         this.takedamage                 = DAMAGE_AIM;
1321         this.bot_attack                 = true;
1322         this.iscreature                 = true;
1323         this.teleportable               = true;
1324         this.damagedbycontents  = true;
1325         this.monsterid                  = mon_id;
1326         this.event_damage               = Monster_Damage;
1327         settouch(this, Monster_Touch);
1328         this.use                                = Monster_Use;
1329         this.solid                              = SOLID_BBOX;
1330         this.movetype                   = MOVETYPE_WALK;
1331         this.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1332         this.enemy                              = world;
1333         this.velocity                   = '0 0 0';
1334         this.moveto                             = this.origin;
1335         this.pos1                               = this.origin;
1336         this.pos2                               = this.angles;
1337         this.reset                              = Monster_Reset;
1338         this.netname                    = mon.netname;
1339         this.monster_attackfunc = mon.monster_attackfunc;
1340         this.monster_name               = mon.monster_name;
1341         this.candrop                    = true;
1342         this.view_ofs                   = '0 0 0.7' * (this.maxs_z * 0.5);
1343         this.oldtarget2                 = this.target2;
1344         this.pass_distance              = 0;
1345         this.deadflag                   = DEAD_NO;
1346         this.noalign                    = ((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM));
1347         this.spawn_time                 = time;
1348         this.gravity                    = 1;
1349         this.monster_moveto             = '0 0 0';
1350         this.monster_face               = '0 0 0';
1351         this.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1352
1353         if(!this.scale) { this.scale = 1; }
1354         if(autocvar_g_monsters_edit) { this.grab = 1; }
1355         if(autocvar_g_fullbrightplayers) { this.effects |= EF_FULLBRIGHT; }
1356         if(autocvar_g_nodepthtestplayers) { this.effects |= EF_NODEPTHTEST; }
1357         if(mon.spawnflags & MONSTER_TYPE_SWIM) { this.flags |= FL_SWIM; }
1358
1359         if(autocvar_g_playerclip_collisions)
1360                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1361
1362         if(mon.spawnflags & MONSTER_TYPE_FLY)
1363         {
1364                 this.flags |= FL_FLY;
1365                 this.movetype = MOVETYPE_FLY;
1366         }
1367
1368         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1369         {
1370                 if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1371                         this.scale *= 1.3;
1372
1373                 if(mon.spawnflags & MONSTER_SIZE_QUAKE)
1374                 if(autocvar_g_monsters_quake_resize)
1375                         this.scale *= 1.3;
1376         }
1377
1378         setsize(this, mon.mins * this.scale, mon.maxs * this.scale);
1379
1380         this.ticrate = bound(sys_frametime, ((!this.ticrate) ? autocvar_g_monsters_think_delay : this.ticrate), 60);
1381
1382         Monster_UpdateModel(this);
1383
1384         if(!Monster_Spawn_Setup(this))
1385         {
1386                 Monster_Remove(this);
1387                 return false;
1388         }
1389
1390         if(!this.noalign)
1391         {
1392                 setorigin(this, this.origin + '0 0 20');
1393                 tracebox(this.origin + '0 0 64', this.mins, this.maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1394                 setorigin(this, trace_endpos);
1395         }
1396
1397         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1398                 monster_setupcolors(this);
1399
1400         CSQCMODEL_AUTOINIT(this);
1401
1402         return true;
1403 }