5e9eaef32fa6633f52ef52459e1ff6195b63cf5e
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / monsters / sv_monsters.qc
1 #if defined(CSQC)
2 #elif defined(MENUQC)
3 #elif defined(SVQC)
4     #include <lib/warpzone/common.qh>
5     #include "../constants.qh"
6     #include "../teams.qh"
7     #include "../util.qh"
8     #include "all.qh"
9     #include "sv_monsters.qh"
10         #include "../physics/movelib.qh"
11     #include "../weapons/all.qh"
12     #include <server/autocvars.qh>
13     #include <server/defs.qh>
14     #include "../deathtypes/all.qh"
15     #include <server/mutators/all.qh>
16         #include <server/steerlib.qh>
17         #include "../turrets/sv_turrets.qh"
18         #include "../turrets/util.qh"
19     #include "../vehicles/all.qh"
20     #include <server/campaign.qh>
21     #include <server/command/common.qh>
22     #include <server/command/cmd.qh>
23         #include "../triggers/triggers.qh"
24     #include <lib/csqcmodel/sv_model.qh>
25     #include <server/round_handler.qh>
26 #endif
27
28 void monsters_setstatus(entity this)
29 {
30         this.stat_monsters_total = monsters_total;
31         this.stat_monsters_killed = monsters_killed;
32 }
33
34 void monster_dropitem(entity this, entity attacker)
35 {
36         if(!this.candrop || !this.monster_loot)
37                 return;
38
39         vector org = this.origin + ((this.mins + this.maxs) * 0.5);
40         entity e = new(droppedweapon); // use weapon handling to remove it on touch
41         e.spawnfunc_checked = true;
42
43         e.monster_loot = this.monster_loot;
44
45         MUTATOR_CALLHOOK(MonsterDropItem, this, e, attacker);
46         e = M_ARGV(1, entity);
47
48         if(e && e.monster_loot)
49         {
50                 e.noalign = true;
51                 e.monster_loot(e);
52                 e.gravity = 1;
53                 e.movetype = MOVETYPE_TOSS;
54                 e.reset = SUB_Remove;
55                 setorigin(e, org);
56                 e.velocity = randomvec() * 175 + '0 0 325';
57                 e.item_spawnshieldtime = time + 0.7;
58                 SUB_SetFade(e, time + autocvar_g_monsters_drop_time, 1);
59         }
60 }
61
62 void monster_makevectors(entity this, entity targ)
63 {
64         if(IS_MONSTER(this))
65         {
66                 vector v = targ.origin + (targ.mins + targ.maxs) * 0.5;
67                 this.v_angle = vectoangles(v - (this.origin + this.view_ofs));
68                 this.v_angle_x = -this.v_angle_x;
69         }
70
71         makevectors(this.v_angle);
72 }
73
74 // ===============
75 // Target handling
76 // ===============
77
78 bool Monster_ValidTarget(entity this, entity targ)
79 {
80         // ensure we're not checking nonexistent monster/target
81         if(!this || !targ) { return false; }
82
83         if((targ == this)
84         || (autocvar_g_monsters_lineofsight && !checkpvs(this.origin + this.view_ofs, targ)) // enemy cannot be seen
85         || (IS_VEHICLE(targ) && !((get_monsterinfo(this.monsterid)).spawnflags & MON_FLAG_RANGED)) // melee vs vehicle is useless
86         || (time < game_starttime) // monsters do nothing before match has started
87         || (targ.takedamage == DAMAGE_NO)
88         || (targ.items & IT_INVISIBILITY)
89         || (IS_SPEC(targ) || IS_OBSERVER(targ)) // don't attack spectators
90         || (!IS_VEHICLE(targ) && (IS_DEAD(targ) || IS_DEAD(this) || targ.health <= 0 || this.health <= 0))
91         || (this.monster_follow == targ || targ.monster_follow == this)
92         || (!IS_VEHICLE(targ) && (targ.flags & FL_NOTARGET))
93         || (!autocvar_g_monsters_typefrag && PHYS_INPUT_BUTTON_CHAT(targ))
94         || (SAME_TEAM(targ, this))
95         || (STAT(FROZEN, targ))
96         || (targ.alpha != 0 && targ.alpha < 0.5)
97         )
98         {
99                 // if any of the above checks fail, target is not valid
100                 return false;
101         }
102
103         traceline(this.origin + this.view_ofs, targ.origin, 0, this);
104
105         if((trace_fraction < 1) && (trace_ent != targ))
106                 return false;
107
108         if(autocvar_g_monsters_target_infront || (this.spawnflags & MONSTERFLAG_INFRONT))
109         if(this.enemy != targ)
110         {
111                 float dot;
112
113                 makevectors (this.angles);
114                 dot = normalize (targ.origin - this.origin) * v_forward;
115
116                 if(dot <= autocvar_g_monsters_target_infront_range) { return false; }
117         }
118
119         return true; // this target is valid!
120 }
121
122 entity Monster_FindTarget(entity mon)
123 {
124         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return mon.enemy; } // Handled by a mutator
125
126         entity closest_target = NULL;
127
128         // find the closest acceptable target to pass to
129         FOREACH_ENTITY_RADIUS(mon.origin, mon.target_range, it.monster_attack,
130         {
131                 if(Monster_ValidTarget(mon, it))
132                 {
133                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
134                         vector head_center = CENTER_OR_VIEWOFS(it);
135                         vector ent_center = CENTER_OR_VIEWOFS(mon);
136
137                         if(closest_target)
138                         {
139                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
140                                 if(vlen2(ent_center - head_center) < vlen2(ent_center - closest_target_center))
141                                         { closest_target = it; }
142                         }
143                         else { closest_target = it; }
144                 }
145         });
146
147         return closest_target;
148 }
149
150 void monster_setupcolors(entity mon)
151 {
152         if(IS_PLAYER(mon.realowner))
153                 mon.colormap = mon.realowner.colormap;
154         else if(teamplay && mon.team)
155                 mon.colormap = 1024 + (mon.team - 1) * 17;
156         else
157         {
158                 if(mon.monster_skill <= MONSTER_SKILL_EASY)
159                         mon.colormap = 1029;
160                 else if(mon.monster_skill <= MONSTER_SKILL_MEDIUM)
161                         mon.colormap = 1027;
162                 else if(mon.monster_skill <= MONSTER_SKILL_HARD)
163                         mon.colormap = 1038;
164                 else if(mon.monster_skill <= MONSTER_SKILL_INSANE)
165                         mon.colormap = 1028;
166                 else if(mon.monster_skill <= MONSTER_SKILL_NIGHTMARE)
167                         mon.colormap = 1032;
168                 else
169                         mon.colormap = 1024;
170         }
171 }
172
173 void monster_changeteam(entity ent, float newteam)
174 {
175         if(!teamplay) { return; }
176
177         ent.team = newteam;
178         ent.monster_attack = true; // new team, activate attacking
179         monster_setupcolors(ent);
180
181         if(ent.sprite)
182         {
183                 WaypointSprite_UpdateTeamRadar(ent.sprite, RADARICON_DANGER, ((newteam) ? Team_ColorRGB(newteam) : '1 0 0'));
184
185                 ent.sprite.team = newteam;
186                 ent.sprite.SendFlags |= 1;
187         }
188 }
189
190 .void(entity) monster_delayedfunc;
191 void Monster_Delay_Action(entity this)
192 {
193         if(Monster_ValidTarget(this.owner, this.owner.enemy)) { this.monster_delayedfunc(this.owner); }
194
195         if(this.cnt > 1)
196         {
197                 this.cnt -= 1;
198                 setthink(this, Monster_Delay_Action);
199                 this.nextthink = time + this.count;
200         }
201         else
202         {
203                 setthink(this, SUB_Remove);
204                 this.nextthink = time;
205         }
206 }
207
208 void Monster_Delay(entity this, int repeat_count, float defer_amnt, void(entity) func)
209 {
210         // deferred attacking, checks if monster is still alive and target is still valid before attacking
211         entity e = spawn();
212
213         setthink(e, Monster_Delay_Action);
214         e.nextthink = time + defer_amnt;
215         e.count = defer_amnt;
216         e.owner = this;
217         e.monster_delayedfunc = func;
218         e.cnt = repeat_count;
219 }
220
221
222 // ==============
223 // Monster sounds
224 // ==============
225
226 string get_monster_model_datafilename(string m, float sk, string fil)
227 {
228         if(m)
229                 m = strcat(m, "_");
230         else
231                 m = "models/monsters/*_";
232         if(sk >= 0)
233                 m = strcat(m, ftos(sk));
234         else
235                 m = strcat(m, "*");
236         return strcat(m, ".", fil);
237 }
238
239 void Monster_Sound_Precache(string f)
240 {
241         float fh;
242         string s;
243         fh = fopen(f, FILE_READ);
244         if(fh < 0)
245                 return;
246         while((s = fgets(fh)))
247         {
248                 if(tokenize_console(s) != 3)
249                 {
250                         LOG_TRACE("Invalid sound info line: ", s, "\n");
251                         continue;
252                 }
253                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
254         }
255         fclose(fh);
256 }
257
258 void Monster_Sounds_Precache(entity this)
259 {
260         string m = (Monsters_from(this.monsterid)).m_model.model_str();
261         float globhandle, n, i;
262         string f;
263
264         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
265         if (globhandle < 0)
266                 return;
267         n = search_getsize(globhandle);
268         for (i = 0; i < n; ++i)
269         {
270                 //print(search_getfilename(globhandle, i), "\n");
271                 f = search_getfilename(globhandle, i);
272                 Monster_Sound_Precache(f);
273         }
274         search_end(globhandle);
275 }
276
277 void Monster_Sounds_Clear(entity this)
278 {
279 #define _MSOUND(m) if(this.monstersound_##m) { strunzone(this.monstersound_##m); this.monstersound_##m = string_null; }
280         ALLMONSTERSOUNDS
281 #undef _MSOUND
282 }
283
284 .string Monster_Sound_SampleField(string type)
285 {
286         GetMonsterSoundSampleField_notFound = 0;
287         switch(type)
288         {
289 #define _MSOUND(m) case #m: return monstersound_##m;
290                 ALLMONSTERSOUNDS
291 #undef _MSOUND
292         }
293         GetMonsterSoundSampleField_notFound = 1;
294         return string_null;
295 }
296
297 bool Monster_Sounds_Load(entity this, string f, int first)
298 {
299         float fh;
300         string s;
301         var .string field;
302         fh = fopen(f, FILE_READ);
303         if(fh < 0)
304         {
305                 LOG_TRACE("Monster sound file not found: ", f, "\n");
306                 return false;
307         }
308         while((s = fgets(fh)))
309         {
310                 if(tokenize_console(s) != 3)
311                         continue;
312                 field = Monster_Sound_SampleField(argv(0));
313                 if(GetMonsterSoundSampleField_notFound)
314                         continue;
315                 if (this.(field))
316                         strunzone(this.(field));
317                 this.(field) = strzone(strcat(argv(1), " ", argv(2)));
318         }
319         fclose(fh);
320         return true;
321 }
322
323 .int skin_for_monstersound;
324 void Monster_Sounds_Update(entity this)
325 {
326         if(this.skin == this.skin_for_monstersound) { return; }
327
328         this.skin_for_monstersound = this.skin;
329         Monster_Sounds_Clear(this);
330         if(!Monster_Sounds_Load(this, get_monster_model_datafilename(this.model, this.skin, "sounds"), 0))
331                 Monster_Sounds_Load(this, get_monster_model_datafilename(this.model, 0, "sounds"), 0);
332 }
333
334 void Monster_Sound(entity this, .string samplefield, float sound_delay, float delaytoo, float chan)
335 {
336         if(!autocvar_g_monsters_sounds) { return; }
337
338         if(delaytoo)
339         if(time < this.msound_delay)
340                 return; // too early
341         GlobalSound_string(this, this.(samplefield), chan, VOICETYPE_PLAYERSOUND);
342
343         this.msound_delay = time + sound_delay;
344 }
345
346
347 // =======================
348 // Monster attack handlers
349 // =======================
350
351 bool Monster_Attack_Melee(entity this, entity targ, float damg, vector anim, float er, float animtime, int deathtype, bool dostop)
352 {
353         if(dostop && IS_MONSTER(this)) { this.state = MONSTER_ATTACK_MELEE; }
354
355         setanim(this, anim, false, true, false);
356
357         if(this.animstate_endtime > time && IS_MONSTER(this))
358                 this.attack_finished_single[0] = this.anim_finished = this.animstate_endtime;
359         else
360                 this.attack_finished_single[0] = this.anim_finished = time + animtime;
361
362         monster_makevectors(this, targ);
363
364         traceline(this.origin + this.view_ofs, this.origin + v_forward * er, 0, this);
365
366         if(trace_ent.takedamage)
367                 Damage(trace_ent, this, this, damg * MONSTER_SKILLMOD(this), deathtype, trace_ent.origin, normalize(trace_ent.origin - this.origin));
368
369         return true;
370 }
371
372 bool Monster_Attack_Leap_Check(entity this, vector vel)
373 {
374         if(this.state && IS_MONSTER(this))
375                 return false; // already attacking
376         if(!IS_ONGROUND(this))
377                 return false; // not on the ground
378         if(this.health <= 0 || IS_DEAD(this))
379                 return false; // called when dead?
380         if(time < this.attack_finished_single[0])
381                 return false; // still attacking
382
383         vector old = this.velocity;
384
385         this.velocity = vel;
386         tracetoss(this, this);
387         this.velocity = old;
388         if (trace_ent != this.enemy)
389                 return false;
390
391         return true;
392 }
393
394 bool Monster_Attack_Leap(entity this, vector anm, void(entity this) touchfunc, vector vel, float animtime)
395 {
396         if(!Monster_Attack_Leap_Check(this, vel))
397                 return false;
398
399         setanim(this, anm, false, true, false);
400
401         if(this.animstate_endtime > time && (this.flags & FL_MONSTER))
402                 this.attack_finished_single[0] = this.anim_finished = this.animstate_endtime;
403         else
404                 this.attack_finished_single[0] = this.anim_finished = time + animtime;
405
406         if(this.flags & FL_MONSTER)
407                 this.state = MONSTER_ATTACK_RANGED;
408         settouch(this, touchfunc);
409         this.origin_z += 1;
410         this.velocity = vel;
411         UNSET_ONGROUND(this);
412
413         return true;
414 }
415
416 void Monster_Attack_Check(entity this, entity targ)
417 {
418         if((this == NULL || targ == NULL)
419         || (!this.monster_attackfunc)
420         || (time < this.attack_finished_single[0])
421         ) { return; }
422
423         if(vdist(targ.origin - this.origin, <=, this.attack_range))
424         {
425                 bool attack_success = this.monster_attackfunc(MONSTER_ATTACK_MELEE, this, targ);
426                 if(attack_success == 1)
427                         Monster_Sound(this, monstersound_melee, 0, false, CH_VOICE);
428                 else if(attack_success > 0)
429                         return;
430         }
431
432         if(vdist(targ.origin - this.origin, >, this.attack_range))
433         {
434                 float attack_success = this.monster_attackfunc(MONSTER_ATTACK_RANGED, this, targ);
435                 if(attack_success == 1)
436                         Monster_Sound(this, monstersound_melee, 0, false, CH_VOICE);
437                 else if(attack_success > 0)
438                         return;
439         }
440 }
441
442
443 // ======================
444 // Main monster functions
445 // ======================
446
447 void Monster_UpdateModel(entity this)
448 {
449         // assume some defaults
450         /*this.anim_idle   = animfixfps(this, '0 1 0.01', '0 0 0');
451         this.anim_walk   = animfixfps(this, '1 1 0.01', '0 0 0');
452         this.anim_run    = animfixfps(this, '2 1 0.01', '0 0 0');
453         this.anim_fire1  = animfixfps(this, '3 1 0.01', '0 0 0');
454         this.anim_fire2  = animfixfps(this, '4 1 0.01', '0 0 0');
455         this.anim_melee  = animfixfps(this, '5 1 0.01', '0 0 0');
456         this.anim_pain1  = animfixfps(this, '6 1 0.01', '0 0 0');
457         this.anim_pain2  = animfixfps(this, '7 1 0.01', '0 0 0');
458         this.anim_die1   = animfixfps(this, '8 1 0.01', '0 0 0');
459         this.anim_die2   = animfixfps(this, '9 1 0.01', '0 0 0');*/
460
461         // then get the real values
462         Monster mon = get_monsterinfo(this.monsterid);
463         mon.mr_anim(mon, this);
464 }
465
466 void Monster_Touch(entity this)
467 {
468         if(other == NULL) { return; }
469
470         if(other.monster_attack)
471         if(this.enemy != other)
472         if(!IS_MONSTER(other))
473         if(Monster_ValidTarget(this, other))
474                 this.enemy = other;
475 }
476
477 void Monster_Miniboss_Check(entity this)
478 {
479         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag, this))
480                 return;
481
482         float chance = random() * 100;
483
484         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
485         if ((this.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
486         {
487                 this.health += autocvar_g_monsters_miniboss_healthboost;
488                 this.effects |= EF_RED;
489                 if(!this.weapon)
490                         this.weapon = WEP_VORTEX.m_id;
491         }
492 }
493
494 bool Monster_Respawn_Check(entity this)
495 {
496         if(this.deadflag == DEAD_DEAD) // don't call when monster isn't dead
497         if(MUTATOR_CALLHOOK(MonsterRespawn, this))
498                 return true; // enabled by a mutator
499
500         if(this.spawnflags & MONSTERFLAG_NORESPAWN)
501                 return false;
502
503         if(!autocvar_g_monsters_respawn)
504                 return false;
505
506         return true;
507 }
508
509 void Monster_Respawn(entity this) { Monster_Spawn(this, this.monsterid); }
510
511 void Monster_Dead_Fade(entity this)
512 {
513         if(Monster_Respawn_Check(this))
514         {
515                 this.spawnflags |= MONSTERFLAG_RESPAWNED;
516                 setthink(this, Monster_Respawn);
517                 this.nextthink = time + this.respawntime;
518                 this.monster_lifetime = 0;
519                 this.deadflag = DEAD_RESPAWNING;
520                 if(this.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
521                 {
522                         this.pos1 = this.origin;
523                         this.pos2 = this.angles;
524                 }
525                 this.event_damage = func_null;
526                 this.takedamage = DAMAGE_NO;
527                 setorigin(this, this.pos1);
528                 this.angles = this.pos2;
529                 this.health = this.max_health;
530                 setmodel(this, MDL_Null);
531         }
532         else
533         {
534                 // number of monsters spawned with mobspawn command
535                 totalspawned -= 1;
536
537                 SUB_SetFade(this, time + 3, 1);
538         }
539 }
540
541 void Monster_Use(entity this, entity actor, entity trigger)
542 {
543         if(Monster_ValidTarget(this, actor)) { this.enemy = actor; }
544 }
545
546 vector Monster_Move_Target(entity this, entity targ)
547 {
548         // enemy is always preferred target
549         if(this.enemy)
550         {
551                 vector targ_origin = ((this.enemy.absmin + this.enemy.absmax) * 0.5);
552                 targ_origin = WarpZone_RefSys_TransformOrigin(this.enemy, this, targ_origin); // origin of target as seen by the monster (us)
553                 WarpZone_TraceLine(this.origin, targ_origin, MOVE_NOMONSTERS, this);
554
555                 if((this.enemy == NULL)
556                         || (IS_DEAD(this.enemy) || this.enemy.health < 1)
557                         || (STAT(FROZEN, this.enemy))
558                         || (this.enemy.flags & FL_NOTARGET)
559                         || (this.enemy.alpha < 0.5 && this.enemy.alpha != 0)
560                         || (this.enemy.takedamage == DAMAGE_NO)
561                         || (vdist(this.origin - targ_origin, >, this.target_range))
562                         || ((trace_fraction < 1) && (trace_ent != this.enemy)))
563                 {
564                         this.enemy = NULL;
565                         this.pass_distance = 0;
566                 }
567
568                 if(this.enemy)
569                 {
570                         /*WarpZone_TrailParticles(NULL, particleeffectnum(EFFECT_RED_PASS), this.origin, targ_origin);
571                         print("Trace origin: ", vtos(targ_origin), "\n");
572                         print("Target origin: ", vtos(this.enemy.origin), "\n");
573                         print("My origin: ", vtos(this.origin), "\n"); */
574
575                         this.monster_movestate = MONSTER_MOVE_ENEMY;
576                         this.last_trace = time + 1.2;
577                         if(this.monster_moveto)
578                                 return this.monster_moveto; // assumes code is properly setting this when monster has an enemy
579                         else
580                                 return targ_origin;
581                 }
582
583                 /*makevectors(this.angles);
584                 this.monster_movestate = MONSTER_MOVE_ENEMY;
585                 this.last_trace = time + 1.2;
586                 return this.enemy.origin; */
587         }
588
589         switch(this.monster_moveflags)
590         {
591                 case MONSTER_MOVE_FOLLOW:
592                 {
593                         this.monster_movestate = MONSTER_MOVE_FOLLOW;
594                         this.last_trace = time + 0.3;
595                         return (this.monster_follow) ? this.monster_follow.origin : this.origin;
596                 }
597                 case MONSTER_MOVE_SPAWNLOC:
598                 {
599                         this.monster_movestate = MONSTER_MOVE_SPAWNLOC;
600                         this.last_trace = time + 2;
601                         return this.pos1;
602                 }
603                 case MONSTER_MOVE_NOMOVE:
604                 {
605                         if(this.monster_moveto)
606                         {
607                                 this.last_trace = time + 0.5;
608                                 return this.monster_moveto;
609                         }
610                         else
611                         {
612                                 this.monster_movestate = MONSTER_MOVE_NOMOVE;
613                                 this.last_trace = time + 2;
614                         }
615                         return this.origin;
616                 }
617                 default:
618                 case MONSTER_MOVE_WANDER:
619                 {
620                         vector pos;
621                         this.monster_movestate = MONSTER_MOVE_WANDER;
622
623                         if(this.monster_moveto)
624                         {
625                                 this.last_trace = time + 0.5;
626                                 pos = this.monster_moveto;
627                         }
628                         else if(targ)
629                         {
630                                 this.last_trace = time + 0.5;
631                                 pos = targ.origin;
632                         }
633                         else
634                         {
635                                 this.last_trace = time + this.wander_delay;
636
637                                 this.angles_y = rint(random() * 500);
638                                 makevectors(this.angles);
639                                 pos = this.origin + v_forward * this.wander_distance;
640
641                                 if(((this.flags & FL_FLY) && (this.spawnflags & MONSTERFLAG_FLY_VERTICAL)) || (this.flags & FL_SWIM))
642                                 {
643                                         pos.z = random() * 200;
644                                         if(random() >= 0.5)
645                                                 pos.z *= -1;
646                                 }
647                         }
648
649                         return pos;
650                 }
651         }
652 }
653
654 void Monster_CalculateVelocity(entity this, vector to, vector from, float turnrate, float movespeed)
655 {
656         float current_distance = vlen((('1 0 0' * to.x) + ('0 1 0' * to.y)) - (('1 0 0' * from.x) + ('0 1 0' * from.y))); // for the sake of this check, exclude Z axis
657         float initial_height = 0; //min(50, (targ_distance * tanh(20)));
658         float current_height = (initial_height * min(1, (this.pass_distance) ? (current_distance / this.pass_distance) : current_distance));
659         //print("current_height = ", ftos(current_height), ", initial_height = ", ftos(initial_height), ".\n");
660
661         vector targpos;
662         if(current_height) // make sure we can actually do this arcing path
663         {
664                 targpos = (to + ('0 0 1' * current_height));
665                 WarpZone_TraceLine(this.origin, targpos, MOVE_NOMONSTERS, this);
666                 if(trace_fraction < 1)
667                 {
668                         //print("normal arc line failed, trying to find new pos...");
669                         WarpZone_TraceLine(to, targpos, MOVE_NOMONSTERS, this);
670                         targpos = (trace_endpos + '0 0 -10');
671                         WarpZone_TraceLine(this.origin, targpos, MOVE_NOMONSTERS, this);
672                         if(trace_fraction < 1) { targpos = to; /* print(" ^1FAILURE^7, reverting to original direction.\n"); */ }
673                         /*else { print(" ^3SUCCESS^7, using new arc line.\n"); } */
674                 }
675         }
676         else { targpos = to; }
677
678         //this.angles = normalize(('0 1 0' * to_y) - ('0 1 0' * from_y));
679
680         vector desired_direction = normalize(targpos - from);
681         if(turnrate) { this.velocity = (normalize(normalize(this.velocity) + (desired_direction * 50)) * movespeed); }
682         else { this.velocity = (desired_direction * movespeed); }
683
684         //this.steerto = steerlib_attract2(targpos, 0.5, 500, 0.95);
685         //this.angles = vectoangles(this.velocity);
686 }
687
688 void Monster_Move(entity this, float runspeed, float walkspeed, float stpspeed)
689 {
690         if(this.target2) { this.goalentity = find(NULL, targetname, this.target2); }
691
692         entity targ;
693
694         if(STAT(FROZEN, this) == 2)
695         {
696                 this.revive_progress = bound(0, this.revive_progress + this.ticrate * this.revive_speed, 1);
697                 this.health = max(1, this.revive_progress * this.max_health);
698                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
699
700                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE) && this.sprite)
701                         WaypointSprite_UpdateHealth(this.sprite, this.health);
702
703                 movelib_brake_simple(this, stpspeed);
704                 setanim(this, this.anim_idle, true, false, false);
705
706                 this.enemy = NULL;
707                 this.nextthink = time + this.ticrate;
708
709                 if(this.revive_progress >= 1)
710                         Unfreeze(this);
711
712                 return;
713         }
714         else if(STAT(FROZEN, this) == 3)
715         {
716                 this.revive_progress = bound(0, this.revive_progress - this.ticrate * this.revive_speed, 1);
717                 this.health = max(0, autocvar_g_nades_ice_health + (this.max_health-autocvar_g_nades_ice_health) * this.revive_progress );
718
719                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE) && this.sprite)
720                         WaypointSprite_UpdateHealth(this.sprite, this.health);
721
722                 movelib_brake_simple(this, stpspeed);
723                 setanim(this, this.anim_idle, true, false, false);
724
725                 this.enemy = NULL;
726                 this.nextthink = time + this.ticrate;
727
728                 if(this.health < 1)
729                 {
730                         Unfreeze(this);
731                         this.health = 0;
732                         if(this.event_damage)
733                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
734                 }
735
736                 else if ( this.revive_progress <= 0 )
737                         Unfreeze(this);
738
739                 return;
740         }
741
742         if(this.flags & FL_SWIM)
743         {
744                 if(this.waterlevel < WATERLEVEL_WETFEET)
745                 {
746                         if(time >= this.last_trace)
747                         {
748                                 this.last_trace = time + 0.4;
749
750                                 Damage (this, NULL, NULL, 2, DEATH_DROWN.m_id, this.origin, '0 0 0');
751                                 this.angles = '90 90 0';
752                                 if(random() < 0.5)
753                                 {
754                                         this.velocity_y += random() * 50;
755                                         this.velocity_x -= random() * 50;
756                                 }
757                                 else
758                                 {
759                                         this.velocity_y -= random() * 50;
760                                         this.velocity_x += random() * 50;
761                                 }
762                                 this.velocity_z += random() * 150;
763                         }
764
765
766                         this.movetype = MOVETYPE_BOUNCE;
767                         //this.velocity_z = -200;
768
769                         return;
770                 }
771                 else if(this.movetype == MOVETYPE_BOUNCE)
772                 {
773                         this.angles_x = 0;
774                         this.movetype = MOVETYPE_WALK;
775                 }
776         }
777
778         targ = this.goalentity;
779
780         if (MUTATOR_CALLHOOK(MonsterMove, this, runspeed, walkspeed, targ)
781                 || gameover
782                 || this.draggedby != NULL
783                 || (round_handler_IsActive() && !round_handler_IsRoundStarted())
784                 || time < game_starttime
785                 || (autocvar_g_campaign && !campaign_bots_may_start)
786                 || time < this.spawn_time)
787         {
788                 runspeed = walkspeed = 0;
789                 if(time >= this.spawn_time)
790                         setanim(this, this.anim_idle, true, false, false);
791                 movelib_brake_simple(this, stpspeed);
792                 return;
793         }
794
795         targ = M_ARGV(3, entity);
796         runspeed = bound(0, M_ARGV(1, float) * MONSTER_SKILLMOD(this), runspeed * 2.5); // limit maxspeed to prevent craziness
797         walkspeed = bound(0, M_ARGV(2, float) * MONSTER_SKILLMOD(this), walkspeed * 2.5); // limit maxspeed to prevent craziness
798
799         if(teamplay)
800         if(autocvar_g_monsters_teams)
801         if(DIFF_TEAM(this.monster_follow, this))
802                 this.monster_follow = NULL;
803
804         if(time >= this.last_enemycheck)
805         {
806                 if(!this.enemy)
807                 {
808                         this.enemy = Monster_FindTarget(this);
809                         if(this.enemy)
810                         {
811                                 WarpZone_RefSys_Copy(this.enemy, this);
812                                 WarpZone_RefSys_AddInverse(this.enemy, this); // wz1^-1 ... wzn^-1 receiver
813                                 this.moveto = WarpZone_RefSys_TransformOrigin(this.enemy, this, (0.5 * (this.enemy.absmin + this.enemy.absmax)));
814                                 this.monster_moveto = '0 0 0';
815                                 this.monster_face = '0 0 0';
816
817                                 this.pass_distance = vlen((('1 0 0' * this.enemy.origin_x) + ('0 1 0' * this.enemy.origin_y)) - (('1 0 0' *  this.origin_x) + ('0 1 0' *  this.origin_y)));
818                                 Monster_Sound(this, monstersound_sight, 0, false, CH_VOICE);
819                         }
820                 }
821
822                 this.last_enemycheck = time + 1; // check for enemies every second
823         }
824
825         if(this.state == MONSTER_ATTACK_RANGED && IS_ONGROUND(this))
826         {
827                 this.state = 0;
828                 settouch(this, Monster_Touch);
829         }
830
831         if(this.state && time >= this.attack_finished_single[0])
832                 this.state = 0; // attack is over
833
834         if(this.state != MONSTER_ATTACK_MELEE) // don't move if set
835         if(time >= this.last_trace || this.enemy) // update enemy or rider instantly
836                 this.moveto = Monster_Move_Target(this, targ);
837
838         if(!this.enemy)
839                 Monster_Sound(this, monstersound_idle, 7, true, CH_VOICE);
840
841         if(this.state == MONSTER_ATTACK_MELEE)
842                 this.moveto = this.origin;
843
844         if(this.enemy && this.enemy.vehicle)
845                 runspeed = 0;
846
847         if(!(this.spawnflags & MONSTERFLAG_FLY_VERTICAL) && !(this.flags & FL_SWIM))
848                 this.moveto_z = this.origin_z;
849
850         if(vdist(this.origin - this.moveto, >, 100))
851         {
852                 float do_run = (this.enemy || this.monster_moveto);
853                 if(IS_ONGROUND(this) || ((this.flags & FL_FLY) || (this.flags & FL_SWIM)))
854                         Monster_CalculateVelocity(this, this.moveto, this.origin, true, ((do_run) ? runspeed : walkspeed));
855
856                 if(time > this.pain_finished) // TODO: use anim_finished instead!
857                 if(!this.state)
858                 if(time > this.anim_finished)
859                 if(vdist(this.velocity, >, 10))
860                         setanim(this, ((do_run) ? this.anim_run : this.anim_walk), true, false, false);
861                 else
862                         setanim(this, this.anim_idle, true, false, false);
863         }
864         else
865         {
866                 entity e = find(NULL, targetname, this.target2);
867                 if(e.target2)
868                         this.target2 = e.target2;
869                 else if(e.target)
870                         this.target2 = e.target;
871
872                 movelib_brake_simple(this, stpspeed);
873                 if(time > this.anim_finished)
874                 if(time > this.pain_finished)
875                 if(!this.state)
876                 if(vdist(this.velocity, <=, 30))
877                         setanim(this, this.anim_idle, true, false, false);
878         }
879
880         this.steerto = steerlib_attract2(this, ((this.monster_face) ? this.monster_face : this.moveto), 0.5, 500, 0.95);
881
882         vector real_angle = vectoangles(this.steerto) - this.angles;
883         float turny = 25;
884         if(this.state == MONSTER_ATTACK_MELEE)
885                 turny = 0;
886         if(turny)
887         {
888                 turny = bound(turny * -1, shortangle_f(real_angle.y, this.angles.y), turny);
889                 this.angles_y += turny;
890         }
891
892         Monster_Attack_Check(this, this.enemy);
893 }
894
895 void Monster_Remove(entity this)
896 {
897         if(IS_CLIENT(this))
898                 return; // don't remove it?
899
900         .entity weaponentity = weaponentities[0];
901         if(!this) { return; }
902
903         if(!MUTATOR_CALLHOOK(MonsterRemove, this))
904                 Send_Effect(EFFECT_ITEM_PICKUP, this.origin, '0 0 0', 1);
905
906         if(this.(weaponentity)) { remove(this.(weaponentity)); }
907         if(this.iceblock) { remove(this.iceblock); }
908         WaypointSprite_Kill(this.sprite);
909         remove(this);
910 }
911
912 void Monster_Dead_Think(entity this)
913 {
914         this.nextthink = time + this.ticrate;
915
916         if(this.monster_lifetime != 0)
917         if(time >= this.monster_lifetime)
918         {
919                 Monster_Dead_Fade(this);
920                 return;
921         }
922 }
923
924 void Monster_Appear(entity this, entity actor, entity trigger)
925 {
926         this.enemy = actor;
927         this.spawnflags &= ~MONSTERFLAG_APPEAR; // otherwise, we get an endless loop
928         Monster_Spawn(this, this.monsterid);
929 }
930
931 bool Monster_Appear_Check(entity this, int monster_id)
932 {
933         if(!(this.spawnflags & MONSTERFLAG_APPEAR))
934                 return false;
935
936         setthink(this, func_null);
937         this.monsterid = monster_id; // set so this monster is properly registered (otherwise, normal initialization is used)
938         this.nextthink = 0;
939         this.use = Monster_Appear;
940         this.flags = FL_MONSTER; // set so this monster can get butchered
941
942         return true;
943 }
944
945 void Monster_Reset(entity this)
946 {
947         setorigin(this, this.pos1);
948         this.angles = this.pos2;
949
950         Unfreeze(this); // remove any icy remains
951
952         this.health = this.max_health;
953         this.velocity = '0 0 0';
954         this.enemy = NULL;
955         this.goalentity = NULL;
956         this.attack_finished_single[0] = 0;
957         this.moveto = this.origin;
958 }
959
960 void Monster_Dead_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
961 {
962         this.health -= damage;
963
964         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
965
966         if(this.health <= -50) // 100 health until gone?
967         {
968                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
969
970                 // number of monsters spawned with mobspawn command
971                 totalspawned -= 1;
972
973                 setthink(this, SUB_Remove);
974                 this.nextthink = time + 0.1;
975                 this.event_damage = func_null;
976         }
977 }
978
979 void Monster_Dead(entity this, entity attacker, float gibbed)
980 {
981         setthink(this, Monster_Dead_Think);
982         this.nextthink = time;
983         this.monster_lifetime = time + 5;
984
985         if(STAT(FROZEN, this))
986         {
987                 Unfreeze(this); // remove any icy remains
988                 this.health = 0; // reset by Unfreeze
989         }
990
991         monster_dropitem(this, attacker);
992
993         Monster_Sound(this, monstersound_death, 0, false, CH_VOICE);
994
995         if(!(this.spawnflags & MONSTERFLAG_SPAWNED) && !(this.spawnflags & MONSTERFLAG_RESPAWNED))
996                 monsters_killed += 1;
997
998         if(IS_PLAYER(attacker))
999         if(autocvar_g_monsters_score_spawned || !((this.spawnflags & MONSTERFLAG_SPAWNED) || (this.spawnflags & MONSTERFLAG_RESPAWNED)))
1000                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
1001
1002         if(gibbed)
1003         {
1004                 // number of monsters spawned with mobspawn command
1005                 totalspawned -= 1;
1006         }
1007
1008         this.event_damage       = ((gibbed) ? func_null : Monster_Dead_Damage);
1009         this.solid                      = SOLID_CORPSE;
1010         this.takedamage         = DAMAGE_AIM;
1011         this.deadflag           = DEAD_DEAD;
1012         this.enemy                      = NULL;
1013         this.movetype           = MOVETYPE_TOSS;
1014         this.moveto                     = this.origin;
1015         settouch(this, Monster_Touch); // reset incase monster was pouncing
1016         this.reset                      = func_null;
1017         this.state                      = 0;
1018         this.attack_finished_single[0] = 0;
1019         this.effects = 0;
1020
1021         if(!((this.flags & FL_FLY) || (this.flags & FL_SWIM)))
1022                 this.velocity = '0 0 0';
1023
1024         CSQCModel_UnlinkEntity(this);
1025
1026         Monster mon = get_monsterinfo(this.monsterid);
1027         mon.mr_death(mon, this);
1028
1029         if(this.candrop && this.weapon)
1030                 W_ThrowNewWeapon(this, this.weapon, 0, this.origin, randomvec() * 150 + '0 0 325');
1031 }
1032
1033 void Monster_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1034 {
1035         if((this.spawnflags & MONSTERFLAG_INVINCIBLE) && deathtype != DEATH_KILL.m_id && !ITEM_DAMAGE_NEEDKILL(deathtype))
1036                 return;
1037
1038         if(STAT(FROZEN, this) && deathtype != DEATH_KILL.m_id && deathtype != DEATH_NADE_ICE_FREEZE.m_id)
1039                 return;
1040
1041         //if(time < this.pain_finished && deathtype != DEATH_KILL.m_id)
1042                 //return;
1043
1044         if(time < this.spawnshieldtime && deathtype != DEATH_KILL.m_id)
1045                 return;
1046
1047         if(deathtype == DEATH_FALL.m_id && this.draggedby != NULL)
1048                 return;
1049
1050         vector v;
1051         float take, save;
1052
1053         v = healtharmor_applydamage(100, this.armorvalue / 100, deathtype, damage);
1054         take = v_x;
1055         save = v_y;
1056
1057         Monster mon = get_monsterinfo(this.monsterid);
1058         take = mon.mr_pain(mon, this, take, attacker, deathtype);
1059
1060         if(take)
1061         {
1062                 this.health -= take;
1063                 Monster_Sound(this, monstersound_pain, 1.2, true, CH_PAIN);
1064         }
1065
1066         if(this.sprite)
1067                 WaypointSprite_UpdateHealth(this.sprite, this.health);
1068
1069         this.dmg_time = time;
1070
1071         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN.m_id)
1072                 spamsound (this, CH_PAIN, SND(BODYIMPACT1), VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
1073
1074         this.velocity += force * this.damageforcescale;
1075
1076         if(deathtype != DEATH_DROWN.m_id && take)
1077         {
1078                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, this, attacker);
1079                 if (take > 50)
1080                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
1081                 if (take > 100)
1082                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
1083         }
1084
1085         if(this.health <= 0)
1086         {
1087                 if(deathtype == DEATH_KILL.m_id)
1088                         this.candrop = false; // killed by mobkill command
1089
1090                 // TODO: fix this?
1091                 SUB_UseTargets(this, attacker, this.enemy);
1092                 this.target2 = this.oldtarget2; // reset to original target on death, incase we respawn
1093
1094                 Monster_Dead(this, attacker, (this.health <= -100 || deathtype == DEATH_KILL.m_id));
1095
1096                 WaypointSprite_Kill(this.sprite);
1097
1098                 MUTATOR_CALLHOOK(MonsterDies, this, attacker, deathtype);
1099
1100                 if(this.health <= -100 || deathtype == DEATH_KILL.m_id) // check if we're already gibbed
1101                 {
1102                         Violence_GibSplash(this, 1, 0.5, attacker);
1103
1104                         setthink(this, SUB_Remove);
1105                         this.nextthink = time + 0.1;
1106                 }
1107         }
1108 }
1109
1110 // don't check for enemies, just keep walking in a straight line
1111 void Monster_Move_2D(entity this, float mspeed, bool allow_jumpoff)
1112 {
1113         if(gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || this.draggedby != NULL || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < this.spawn_time)
1114         {
1115                 mspeed = 0;
1116                 if(time >= this.spawn_time)
1117                         setanim(this, this.anim_idle, true, false, false);
1118                 movelib_brake_simple(this, 0.6);
1119                 return;
1120         }
1121
1122         float reverse = false;
1123         vector a, b;
1124
1125         makevectors(this.angles);
1126         a = this.origin + '0 0 16';
1127         b = this.origin + '0 0 16' + v_forward * 32;
1128
1129         traceline(a, b, MOVE_NORMAL, this);
1130
1131         if(trace_fraction != 1.0)
1132         {
1133                 reverse = true;
1134
1135                 if(trace_ent)
1136                 if(IS_PLAYER(trace_ent) && !(trace_ent.items & IT_STRENGTH))
1137                         reverse = false;
1138         }
1139
1140         // TODO: fix this... tracing is broken if the floor is thin
1141         /*
1142         if(!allow_jumpoff)
1143         {
1144                 a = b - '0 0 32';
1145                 traceline(b, a, MOVE_WORLDONLY, this);
1146                 if(trace_fraction == 1.0)
1147                         reverse = true;
1148         } */
1149
1150         if(reverse)
1151         {
1152                 this.angles_y = anglemods(this.angles_y - 180);
1153                 makevectors(this.angles);
1154         }
1155
1156         movelib_move_simple_gravity(this, v_forward, mspeed, 1);
1157
1158         if(time > this.pain_finished)
1159         if(time > this.attack_finished_single[0])
1160         if(vdist(this.velocity, >, 10))
1161                 setanim(this, this.anim_walk, true, false, false);
1162         else
1163                 setanim(this, this.anim_idle, true, false, false);
1164 }
1165
1166 void Monster_Anim(entity this)
1167 {
1168         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
1169         if(IS_DEAD(this))
1170         {
1171                 if (!deadbits)
1172                 {
1173                         // Decide on which death animation to use.
1174                         if(random() < 0.5)
1175                                 deadbits = ANIMSTATE_DEAD1;
1176                         else
1177                                 deadbits = ANIMSTATE_DEAD2;
1178                 }
1179         }
1180         else
1181         {
1182                 // Clear a previous death animation.
1183                 deadbits = 0;
1184         }
1185         int animbits = deadbits;
1186         if(STAT(FROZEN, this))
1187                 animbits |= ANIMSTATE_FROZEN;
1188         if(this.crouch)
1189                 animbits |= ANIMSTATE_DUCK; // not that monsters can crouch currently...
1190         animdecide_setstate(this, animbits, false);
1191         animdecide_setimplicitstate(this, (IS_ONGROUND(this)));
1192
1193         /* // weapon entities for monsters?
1194         if (this.weaponentity)
1195         {
1196                 updateanim(this.weaponentity);
1197                 if (!this.weaponentity.animstate_override)
1198                         setanim(this.weaponentity, this.weaponentity.anim_idle, true, false, false);
1199         }
1200         */
1201 }
1202
1203 void Monster_Think(entity this)
1204 {
1205         setthink(this, Monster_Think);
1206         this.nextthink = this.ticrate;
1207
1208         if(this.monster_lifetime)
1209         if(time >= this.monster_lifetime)
1210         {
1211                 Damage(this, this, this, this.health + this.max_health, DEATH_KILL.m_id, this.origin, this.origin);
1212                 return;
1213         }
1214
1215         Monster mon = get_monsterinfo(this.monsterid);
1216         if(mon.mr_think(mon, this))
1217                 Monster_Move(this, this.speed2, this.speed, this.stopspeed);
1218
1219         Monster_Anim(this);
1220
1221         CSQCMODEL_AUTOUPDATE(this);
1222 }
1223
1224 bool Monster_Spawn_Setup(entity this)
1225 {
1226         Monster mon = Monsters_from(this.monsterid);
1227         mon.mr_setup(mon, this);
1228
1229         // ensure some basic needs are met
1230         if(!this.health) { this.health = 100; }
1231         if(!this.armorvalue) { this.armorvalue = bound(0.2, 0.5 * MONSTER_SKILLMOD(this), 0.9); }
1232         if(!this.target_range) { this.target_range = autocvar_g_monsters_target_range; }
1233         if(!this.respawntime) { this.respawntime = autocvar_g_monsters_respawn_delay; }
1234         if(!this.monster_moveflags) { this.monster_moveflags = MONSTER_MOVE_WANDER; }
1235         if(!this.attack_range) { this.attack_range = autocvar_g_monsters_attack_range; }
1236         if(!this.damageforcescale) { this.damageforcescale = autocvar_g_monsters_damageforcescale; }
1237
1238         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1239         {
1240                 Monster_Miniboss_Check(this);
1241                 this.health *= MONSTER_SKILLMOD(this);
1242
1243                 if(!this.skin)
1244                         this.skin = rint(random() * 4);
1245         }
1246
1247         this.max_health = this.health;
1248         this.pain_finished = this.nextthink;
1249
1250         if(IS_PLAYER(this.monster_follow))
1251                 this.effects |= EF_DIMLIGHT;
1252
1253         if(!this.wander_delay) { this.wander_delay = 2; }
1254         if(!this.wander_distance) { this.wander_distance = 600; }
1255
1256         Monster_Sounds_Precache(this);
1257         Monster_Sounds_Update(this);
1258
1259         if(teamplay)
1260                 this.monster_attack = true; // we can have monster enemies in team games
1261
1262         Monster_Sound(this, monstersound_spawn, 0, false, CH_VOICE);
1263
1264         if(autocvar_g_monsters_healthbars)
1265         {
1266                 entity wp = WaypointSprite_Spawn(WP_Monster, 0, 1024, this, '0 0 1' * (this.maxs.z + 15), NULL, this.team, this, sprite, true, RADARICON_DANGER);
1267                 wp.wp_extra = this.monsterid;
1268                 wp.colormod = ((this.team) ? Team_ColorRGB(this.team) : '1 0 0');
1269                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE))
1270                 {
1271                         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
1272                         WaypointSprite_UpdateHealth(this.sprite, this.health);
1273                 }
1274         }
1275
1276         setthink(this, Monster_Think);
1277         this.nextthink = time + this.ticrate;
1278
1279         if(MUTATOR_CALLHOOK(MonsterSpawn, this))
1280                 return false;
1281
1282         return true;
1283 }
1284
1285 bool Monster_Spawn(entity this, int mon_id)
1286 {
1287         // setup the basic required properties for a monster
1288         entity mon = Monsters_from(mon_id);
1289         if(!mon.monsterid) { return false; } // invalid monster
1290
1291         if(!autocvar_g_monsters) { Monster_Remove(this); return false; }
1292
1293         if(Monster_Appear_Check(this, mon_id)) { return true; } // return true so the monster isn't removed
1294
1295         if(!this.monster_skill)
1296                 this.monster_skill = cvar("g_monsters_skill");
1297
1298         // support for quake style removing monsters based on skill
1299         if(this.monster_skill == MONSTER_SKILL_EASY) if(this.spawnflags & MONSTERSKILL_NOTEASY) { Monster_Remove(this); return false; }
1300         if(this.monster_skill == MONSTER_SKILL_MEDIUM) if(this.spawnflags & MONSTERSKILL_NOTMEDIUM) { Monster_Remove(this); return false; }
1301         if(this.monster_skill == MONSTER_SKILL_HARD) if(this.spawnflags & MONSTERSKILL_NOTHARD) { Monster_Remove(this); return false; }
1302
1303         if(this.team && !teamplay)
1304                 this.team = 0;
1305
1306         if(!(this.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1307         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED)) // don't count re-spawning monsters either
1308                 monsters_total += 1;
1309
1310         setmodel(this, mon.m_model);
1311         this.flags                              = FL_MONSTER;
1312         this.classname                  = "monster";
1313         this.takedamage                 = DAMAGE_AIM;
1314         this.bot_attack                 = true;
1315         this.iscreature                 = true;
1316         this.teleportable               = true;
1317         this.damagedbycontents  = true;
1318         this.monsterid                  = mon_id;
1319         this.event_damage               = Monster_Damage;
1320         settouch(this, Monster_Touch);
1321         this.use                                = Monster_Use;
1322         this.solid                              = SOLID_BBOX;
1323         this.movetype                   = MOVETYPE_WALK;
1324         this.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1325         this.enemy                              = NULL;
1326         this.velocity                   = '0 0 0';
1327         this.moveto                             = this.origin;
1328         this.pos1                               = this.origin;
1329         this.pos2                               = this.angles;
1330         this.reset                              = Monster_Reset;
1331         this.netname                    = mon.netname;
1332         this.monster_attackfunc = mon.monster_attackfunc;
1333         this.monster_name               = mon.monster_name;
1334         this.candrop                    = true;
1335         this.view_ofs                   = '0 0 0.7' * (this.maxs_z * 0.5);
1336         this.oldtarget2                 = this.target2;
1337         this.pass_distance              = 0;
1338         this.deadflag                   = DEAD_NO;
1339         this.noalign                    = ((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM));
1340         this.spawn_time                 = time;
1341         this.gravity                    = 1;
1342         this.monster_moveto             = '0 0 0';
1343         this.monster_face               = '0 0 0';
1344         this.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1345
1346         if(!this.scale) { this.scale = 1; }
1347         if(autocvar_g_monsters_edit) { this.grab = 1; }
1348         if(autocvar_g_fullbrightplayers) { this.effects |= EF_FULLBRIGHT; }
1349         if(autocvar_g_nodepthtestplayers) { this.effects |= EF_NODEPTHTEST; }
1350         if(mon.spawnflags & MONSTER_TYPE_SWIM) { this.flags |= FL_SWIM; }
1351
1352         if(autocvar_g_playerclip_collisions)
1353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1354
1355         if(mon.spawnflags & MONSTER_TYPE_FLY)
1356         {
1357                 this.flags |= FL_FLY;
1358                 this.movetype = MOVETYPE_FLY;
1359         }
1360
1361         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1362         {
1363                 if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1364                         this.scale *= 1.3;
1365
1366                 if(mon.spawnflags & MONSTER_SIZE_QUAKE)
1367                 if(autocvar_g_monsters_quake_resize)
1368                         this.scale *= 1.3;
1369         }
1370
1371         setsize(this, mon.mins * this.scale, mon.maxs * this.scale);
1372
1373         this.ticrate = bound(sys_frametime, ((!this.ticrate) ? autocvar_g_monsters_think_delay : this.ticrate), 60);
1374
1375         Monster_UpdateModel(this);
1376
1377         if(!Monster_Spawn_Setup(this))
1378         {
1379                 Monster_Remove(this);
1380                 return false;
1381         }
1382
1383         if(!this.noalign)
1384         {
1385                 setorigin(this, this.origin + '0 0 20');
1386                 tracebox(this.origin + '0 0 64', this.mins, this.maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1387                 setorigin(this, trace_endpos);
1388         }
1389
1390         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1391                 monster_setupcolors(this);
1392
1393         CSQCMODEL_AUTOINIT(this);
1394
1395         return true;
1396 }