qcsrc/common/monsters/sv_monsters.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4     #include "../../lib/warpzone/common.qh"
   5     #include "../constants.qh"
   6     #include "../teams.qh"
   7     #include "../util.qh"
   8     #include "all.qh"
   9     #include "sv_monsters.qh"
  10     #include "../weapons/all.qh"
  11     #include "../../server/autocvars.qh"
  12     #include "../../server/defs.qh"
  13     #include "../deathtypes/all.qh"
  14     #include "../../server/mutators/all.qh"
  15         #include "../../server/steerlib.qh"
  16         #include "../turrets/sv_turrets.qh"
  17         #include "../turrets/util.qh"
  18     #include "../vehicles/all.qh"
  19     #include "../../server/campaign.qh"
  20     #include "../../server/command/common.qh"
  21     #include "../../server/command/cmd.qh"
  22         #include "../triggers/triggers.qh"
  23     #include "../../lib/csqcmodel/sv_model.qh"
  24     #include "../../server/round_handler.qh"
  25 #endif
  26
  27 void monsters_setstatus()
  28 {SELFPARAM();
  29         self.stat_monsters_total = monsters_total;
  30         self.stat_monsters_killed = monsters_killed;
  31 }
  32
  33 void monster_dropitem()
  34 {SELFPARAM();
  35         if(!self.candrop || !self.monster_loot)
  36                 return;
  37
  38         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  39         entity e = new(droppedweapon); // use weapon handling to remove it on touch
  40         e.spawnfunc_checked = true;
  41
  42         e.monster_loot = self.monster_loot;
  43
  44         MUTATOR_CALLHOOK(MonsterDropItem, e);
  45         e = other;
  46
  47         if(e && e.monster_loot)
  48         {
  49                 setself(e);
  50                 e.noalign = true;
  51                 e.monster_loot(e);
  52                 e.gravity = 1;
  53                 e.movetype = MOVETYPE_TOSS;
  54                 e.reset = SUB_Remove;
  55                 setorigin(e, org);
  56                 e.velocity = randomvec() * 175 + '0 0 325';
  57                 e.item_spawnshieldtime = time + 0.7;
  58                 SUB_SetFade(e, time + autocvar_g_monsters_drop_time, 1);
  59                 setself(this);
  60         }
  61 }
  62
  63 void monster_makevectors(entity e)
  64 {SELFPARAM();
  65         if(IS_MONSTER(self))
  66         {
  67                 vector v;
  68
  69                 v = e.origin + (e.mins + e.maxs) * 0.5;
  70                 self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
  71                 self.v_angle_x = -self.v_angle_x;
  72         }
  73
  74         makevectors(self.v_angle);
  75 }
  76
  77 // ===============
  78 // Target handling
  79 // ===============
  80
  81 bool Monster_ValidTarget(entity mon, entity player)
  82 {SELFPARAM();
  83         // ensure we're not checking nonexistent monster/target
  84         if(!mon || !player) { return false; }
  85
  86         if((player == mon)
  87         || (autocvar_g_monsters_lineofsight && !checkpvs(mon.origin + mon.view_ofs, player)) // enemy cannot be seen
  88         || (IS_VEHICLE(player) && !((get_monsterinfo(mon.monsterid)).spawnflags & MON_FLAG_RANGED)) // melee vs vehicle is useless
  89         || (time < game_starttime) // monsters do nothing before match has started
  90         || (player.takedamage == DAMAGE_NO)
  91         || (player.items & IT_INVISIBILITY)
  92         || (IS_SPEC(player) || IS_OBSERVER(player)) // don't attack spectators
  93         || (!IS_VEHICLE(player) && (player.deadflag != DEAD_NO || mon.deadflag != DEAD_NO || player.health <= 0 || mon.health <= 0))
  94         || (mon.monster_follow == player || player.monster_follow == mon)
  95         || (!IS_VEHICLE(player) && (player.flags & FL_NOTARGET))
  96         || (!autocvar_g_monsters_typefrag && player.BUTTON_CHAT)
  97         || (SAME_TEAM(player, mon))
  98         || (player.frozen)
  99         || (player.alpha != 0 && player.alpha < 0.5)
 100         )
 101         {
 102                 // if any of the above checks fail, target is not valid
 103                 return false;
 104         }
 105
 106         traceline(mon.origin + self.view_ofs, player.origin, 0, mon);
 107
 108         if((trace_fraction < 1) && (trace_ent != player))
 109                 return false;
 110
 111         if(autocvar_g_monsters_target_infront || (mon.spawnflags & MONSTERFLAG_INFRONT))
 112         if(mon.enemy != player)
 113         {
 114                 float dot;
 115
 116                 makevectors (mon.angles);
 117                 dot = normalize (player.origin - mon.origin) * v_forward;
 118
 119                 if(dot <= autocvar_g_monsters_target_infront_range) { return false; }
 120         }
 121
 122         return true; // this target is valid!
 123 }
 124
 125 entity Monster_FindTarget(entity mon)
 126 {
 127         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return mon.enemy; } // Handled by a mutator
 128
 129         entity head, closest_target = world;
 130         head = findradius(mon.origin, mon.target_range);
 131
 132         while(head) // find the closest acceptable target to pass to
 133         {
 134                 if(head.monster_attack)
 135                 if(Monster_ValidTarget(mon, head))
 136                 {
 137                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 138                         vector head_center = CENTER_OR_VIEWOFS(head);
 139                         vector ent_center = CENTER_OR_VIEWOFS(mon);
 140
 141                         if(closest_target)
 142                         {
 143                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 144                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 145                                         { closest_target = head; }
 146                         }
 147                         else { closest_target = head; }
 148                 }
 149
 150                 head = head.chain;
 151         }
 152
 153         return closest_target;
 154 }
 155
 156 void monster_setupcolors(entity mon)
 157 {
 158         if(IS_PLAYER(mon.realowner))
 159                 mon.colormap = mon.realowner.colormap;
 160         else if(teamplay && mon.team)
 161                 mon.colormap = 1024 + (mon.team - 1) * 17;
 162         else
 163         {
 164                 if(mon.monster_skill <= MONSTER_SKILL_EASY)
 165                         mon.colormap = 1029;
 166                 else if(mon.monster_skill <= MONSTER_SKILL_MEDIUM)
 167                         mon.colormap = 1027;
 168                 else if(mon.monster_skill <= MONSTER_SKILL_HARD)
 169                         mon.colormap = 1038;
 170                 else if(mon.monster_skill <= MONSTER_SKILL_INSANE)
 171                         mon.colormap = 1028;
 172                 else if(mon.monster_skill <= MONSTER_SKILL_NIGHTMARE)
 173                         mon.colormap = 1032;
 174                 else
 175                         mon.colormap = 1024;
 176         }
 177 }
 178
 179 void monster_changeteam(entity ent, float newteam)
 180 {
 181         if(!teamplay) { return; }
 182
 183         ent.team = newteam;
 184         ent.monster_attack = true; // new team, activate attacking
 185         monster_setupcolors(ent);
 186
 187         if(ent.sprite)
 188         {
 189                 WaypointSprite_UpdateTeamRadar(ent.sprite, RADARICON_DANGER, ((newteam) ? Team_ColorRGB(newteam) : '1 0 0'));
 190
 191                 ent.sprite.team = newteam;
 192                 ent.sprite.SendFlags |= 1;
 193         }
 194 }
 195
 196 void Monster_Delay_Action()
 197 {SELFPARAM();
 198         entity oldself = self;
 199         setself(self.owner);
 200         if(Monster_ValidTarget(self, self.enemy)) { oldself.use(); }
 201
 202         if(oldself.cnt > 0)
 203         {
 204                 oldself.cnt -= 1;
 205                 oldself.think = Monster_Delay_Action;
 206                 oldself.nextthink = time + oldself.respawn_time;
 207         }
 208         else
 209         {
 210                 oldself.think = SUB_Remove_self;
 211                 oldself.nextthink = time;
 212         }
 213 }
 214
 215 void Monster_Delay(float repeat_count, float repeat_defer, float defer_amnt, void() func)
 216 {SELFPARAM();
 217         // deferred attacking, checks if monster is still alive and target is still valid before attacking
 218         entity e = spawn();
 219
 220         e.think = Monster_Delay_Action;
 221         e.nextthink = time + defer_amnt;
 222         e.count = defer_amnt;
 223         e.owner = self;
 224         e.use = func;
 225         e.cnt = repeat_count;
 226         e.respawn_time = repeat_defer;
 227 }
 228
 229
 230 // ==============
 231 // Monster sounds
 232 // ==============
 233
 234 string get_monster_model_datafilename(string m, float sk, string fil)
 235 {
 236         if(m)
 237                 m = strcat(m, "_");
 238         else
 239                 m = "models/monsters/*_";
 240         if(sk >= 0)
 241                 m = strcat(m, ftos(sk));
 242         else
 243                 m = strcat(m, "*");
 244         return strcat(m, ".", fil);
 245 }
 246
 247 void Monster_Sound_Precache(string f)
 248 {
 249         float fh;
 250         string s;
 251         fh = fopen(f, FILE_READ);
 252         if(fh < 0)
 253                 return;
 254         while((s = fgets(fh)))
 255         {
 256                 if(tokenize_console(s) != 3)
 257                 {
 258                         LOG_TRACE("Invalid sound info line: ", s, "\n");
 259                         continue;
 260                 }
 261                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 262         }
 263         fclose(fh);
 264 }
 265
 266 void Monster_Sounds_Precache()
 267 {SELFPARAM();
 268         string m = (get_monsterinfo(self.monsterid)).m_model.model_str();
 269         float globhandle, n, i;
 270         string f;
 271
 272         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
 273         if (globhandle < 0)
 274                 return;
 275         n = search_getsize(globhandle);
 276         for (i = 0; i < n; ++i)
 277         {
 278                 //print(search_getfilename(globhandle, i), "\n");
 279                 f = search_getfilename(globhandle, i);
 280                 Monster_Sound_Precache(f);
 281         }
 282         search_end(globhandle);
 283 }
 284
 285 void Monster_Sounds_Clear()
 286 {SELFPARAM();
 287 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 288         ALLMONSTERSOUNDS
 289 #undef _MSOUND
 290 }
 291
 292 .string Monster_Sound_SampleField(string type)
 293 {
 294         GetMonsterSoundSampleField_notFound = 0;
 295         switch(type)
 296         {
 297 #define _MSOUND(m) case #m: return monstersound_##m;
 298                 ALLMONSTERSOUNDS
 299 #undef _MSOUND
 300         }
 301         GetMonsterSoundSampleField_notFound = 1;
 302         return string_null;
 303 }
 304
 305 bool Monster_Sounds_Load(string f, int first)
 306 {SELFPARAM();
 307         float fh;
 308         string s;
 309         var .string field;
 310         fh = fopen(f, FILE_READ);
 311         if(fh < 0)
 312         {
 313                 LOG_TRACE("Monster sound file not found: ", f, "\n");
 314                 return false;
 315         }
 316         while((s = fgets(fh)))
 317         {
 318                 if(tokenize_console(s) != 3)
 319                         continue;
 320                 field = Monster_Sound_SampleField(argv(0));
 321                 if(GetMonsterSoundSampleField_notFound)
 322                         continue;
 323                 if (self.(field))
 324                         strunzone(self.(field));
 325                 self.(field) = strzone(strcat(argv(1), " ", argv(2)));
 326         }
 327         fclose(fh);
 328         return true;
 329 }
 330
 331 .int skin_for_monstersound;
 332 void Monster_Sounds_Update()
 333 {SELFPARAM();
 334         if(self.skin == self.skin_for_monstersound) { return; }
 335
 336         self.skin_for_monstersound = self.skin;
 337         Monster_Sounds_Clear();
 338         if(!Monster_Sounds_Load(get_monster_model_datafilename(self.model, self.skin, "sounds"), 0))
 339                 Monster_Sounds_Load(get_monster_model_datafilename(self.model, 0, "sounds"), 0);
 340 }
 341
 342 void Monster_Sound(.string samplefield, float sound_delay, float delaytoo, float chan)
 343 {SELFPARAM();
 344         if(!autocvar_g_monsters_sounds) { return; }
 345
 346         if(delaytoo)
 347         if(time < self.msound_delay)
 348                 return; // too early
 349         GlobalSound_string(self, self.(samplefield), chan, VOICETYPE_PLAYERSOUND);
 350
 351         self.msound_delay = time + sound_delay;
 352 }
 353
 354
 355 // =======================
 356 // Monster attack handlers
 357 // =======================
 358
 359 float Monster_Attack_Melee(entity targ, float damg, vector anim, float er, float animtime, int deathtype, float dostop)
 360 {SELFPARAM();
 361         if(dostop && (self.flags & FL_MONSTER)) { self.state = MONSTER_ATTACK_MELEE; }
 362
 363         setanim(self, anim, false, true, false);
 364
 365         if(self.animstate_endtime > time && (self.flags & FL_MONSTER))
 366                 self.attack_finished_single[0] = self.anim_finished = self.animstate_endtime;
 367         else
 368                 self.attack_finished_single[0] = self.anim_finished = time + animtime;
 369
 370         monster_makevectors(targ);
 371
 372         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 373
 374         if(trace_ent.takedamage)
 375                 Damage(trace_ent, self, self, damg * MONSTER_SKILLMOD(self), deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 376
 377         return true;
 378 }
 379
 380 float Monster_Attack_Leap_Check(vector vel)
 381 {SELFPARAM();
 382         if(self.state && (self.flags & FL_MONSTER))
 383                 return false; // already attacking
 384         if(!(self.flags & FL_ONGROUND))
 385                 return false; // not on the ground
 386         if(self.health <= 0)
 387                 return false; // called when dead?
 388         if(time < self.attack_finished_single[0])
 389                 return false; // still attacking
 390
 391         vector old = self.velocity;
 392
 393         self.velocity = vel;
 394         tracetoss(self, self);
 395         self.velocity = old;
 396         if (trace_ent != self.enemy)
 397                 return false;
 398
 399         return true;
 400 }
 401
 402 bool Monster_Attack_Leap(vector anm, void() touchfunc, vector vel, float animtime)
 403 {SELFPARAM();
 404         if(!Monster_Attack_Leap_Check(vel))
 405                 return false;
 406
 407         setanim(self, anm, false, true, false);
 408
 409         if(self.animstate_endtime > time && (self.flags & FL_MONSTER))
 410                 self.attack_finished_single[0] = self.anim_finished = self.animstate_endtime;
 411         else
 412                 self.attack_finished_single[0] = self.anim_finished = time + animtime;
 413
 414         if(self.flags & FL_MONSTER)
 415                 self.state = MONSTER_ATTACK_RANGED;
 416         self.touch = touchfunc;
 417         self.origin_z += 1;
 418         self.velocity = vel;
 419         self.flags &= ~FL_ONGROUND;
 420
 421         return true;
 422 }
 423
 424 void Monster_Attack_Check(entity e, entity targ)
 425 {
 426         if((e == world || targ == world)
 427         || (!e.monster_attackfunc)
 428         || (time < e.attack_finished_single[0])
 429         ) { return; }
 430
 431         float targ_vlen = vlen(targ.origin - e.origin);
 432
 433         if(targ_vlen <= e.attack_range)
 434         {
 435                 float attack_success = e.monster_attackfunc(MONSTER_ATTACK_MELEE, targ);
 436                 if(attack_success == 1)
 437                         Monster_Sound(monstersound_melee, 0, false, CH_VOICE);
 438                 else if(attack_success > 0)
 439                         return;
 440         }
 441
 442         if(targ_vlen > e.attack_range)
 443         {
 444                 float attack_success = e.monster_attackfunc(MONSTER_ATTACK_RANGED, targ);
 445                 if(attack_success == 1)
 446                         Monster_Sound(monstersound_melee, 0, false, CH_VOICE);
 447                 else if(attack_success > 0)
 448                         return;
 449         }
 450 }
 451
 452
 453 // ======================
 454 // Main monster functions
 455 // ======================
 456
 457 void Monster_UpdateModel()
 458 {SELFPARAM();
 459         // assume some defaults
 460         /*self.anim_idle   = animfixfps(self, '0 1 0.01', '0 0 0');
 461         self.anim_walk   = animfixfps(self, '1 1 0.01', '0 0 0');
 462         self.anim_run    = animfixfps(self, '2 1 0.01', '0 0 0');
 463         self.anim_fire1  = animfixfps(self, '3 1 0.01', '0 0 0');
 464         self.anim_fire2  = animfixfps(self, '4 1 0.01', '0 0 0');
 465         self.anim_melee  = animfixfps(self, '5 1 0.01', '0 0 0');
 466         self.anim_pain1  = animfixfps(self, '6 1 0.01', '0 0 0');
 467         self.anim_pain2  = animfixfps(self, '7 1 0.01', '0 0 0');
 468         self.anim_die1   = animfixfps(self, '8 1 0.01', '0 0 0');
 469         self.anim_die2   = animfixfps(self, '9 1 0.01', '0 0 0');*/
 470
 471         // then get the real values
 472         Monster mon = get_monsterinfo(self.monsterid);
 473         mon.mr_anim(mon);
 474 }
 475
 476 void Monster_Touch()
 477 {SELFPARAM();
 478         if(other == world) { return; }
 479
 480         if(other.monster_attack)
 481         if(self.enemy != other)
 482         if(!IS_MONSTER(other))
 483         if(Monster_ValidTarget(self, other))
 484                 self.enemy = other;
 485 }
 486
 487 void Monster_Miniboss_Check()
 488 {SELFPARAM();
 489         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 490                 return;
 491
 492         float chance = random() * 100;
 493
 494         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 495         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 496         {
 497                 self.health += autocvar_g_monsters_miniboss_healthboost;
 498                 self.effects |= EF_RED;
 499                 if(!self.weapon)
 500                         self.weapon = WEP_VORTEX.m_id;
 501         }
 502 }
 503
 504 bool Monster_Respawn_Check()
 505 {SELFPARAM();
 506         if(self.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 507         if(MUTATOR_CALLHOOK(MonsterRespawn, self))
 508                 return true; // enabled by a mutator
 509
 510         if(self.spawnflags & MONSTERFLAG_NORESPAWN)
 511                 return false;
 512
 513         if(!autocvar_g_monsters_respawn)
 514                 return false;
 515
 516         return true;
 517 }
 518
 519 void Monster_Respawn() { SELFPARAM(); Monster_Spawn(self.monsterid); }
 520
 521 void Monster_Dead_Fade()
 522 {SELFPARAM();
 523         if(Monster_Respawn_Check())
 524         {
 525                 self.spawnflags |= MONSTERFLAG_RESPAWNED;
 526                 self.think = Monster_Respawn;
 527                 self.nextthink = time + self.respawntime;
 528                 self.monster_lifetime = 0;
 529                 self.deadflag = DEAD_RESPAWNING;
 530                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 531                 {
 532                         self.pos1 = self.origin;
 533                         self.pos2 = self.angles;
 534                 }
 535                 self.event_damage = func_null;
 536                 self.takedamage = DAMAGE_NO;
 537                 setorigin(self, self.pos1);
 538                 self.angles = self.pos2;
 539                 self.health = self.max_health;
 540                 setmodel(self, MDL_Null);
 541         }
 542         else
 543         {
 544                 // number of monsters spawned with mobspawn command
 545                 totalspawned -= 1;
 546
 547                 SUB_SetFade(self, time + 3, 1);
 548         }
 549 }
 550
 551 void Monster_Use()
 552 {SELFPARAM();
 553         if(Monster_ValidTarget(self, activator)) { self.enemy = activator; }
 554 }
 555
 556 vector Monster_Move_Target(entity targ)
 557 {SELFPARAM();
 558         // enemy is always preferred target
 559         if(self.enemy)
 560         {
 561                 vector targ_origin = ((self.enemy.absmin + self.enemy.absmax) * 0.5);
 562                 targ_origin = WarpZone_RefSys_TransformOrigin(self.enemy, self, targ_origin); // origin of target as seen by the monster (us)
 563                 WarpZone_TraceLine(self.origin, targ_origin, MOVE_NOMONSTERS, self);
 564
 565                 if((self.enemy == world)
 566                         || (self.enemy.deadflag != DEAD_NO || self.enemy.health < 1)
 567                         || (self.enemy.frozen)
 568                         || (self.enemy.flags & FL_NOTARGET)
 569                         || (self.enemy.alpha < 0.5 && self.enemy.alpha != 0)
 570                         || (self.enemy.takedamage == DAMAGE_NO)
 571                         || (vlen(self.origin - targ_origin) > self.target_range)
 572                         || ((trace_fraction < 1) && (trace_ent != self.enemy)))
 573                 {
 574                         self.enemy = world;
 575                         self.pass_distance = 0;
 576                 }
 577
 578                 if(self.enemy)
 579                 {
 580                         /*WarpZone_TrailParticles(world, particleeffectnum(EFFECT_RED_PASS), self.origin, targ_origin);
 581                         print("Trace origin: ", vtos(targ_origin), "\n");
 582                         print("Target origin: ", vtos(self.enemy.origin), "\n");
 583                         print("My origin: ", vtos(self.origin), "\n"); */
 584
 585                         self.monster_movestate = MONSTER_MOVE_ENEMY;
 586                         self.last_trace = time + 1.2;
 587                         if(self.monster_moveto)
 588                                 return self.monster_moveto; // assumes code is properly setting this when monster has an enemy
 589                         else
 590                                 return targ_origin;
 591                 }
 592
 593                 /*makevectors(self.angles);
 594                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 595                 self.last_trace = time + 1.2;
 596                 return self.enemy.origin; */
 597         }
 598
 599         switch(self.monster_moveflags)
 600         {
 601                 case MONSTER_MOVE_FOLLOW:
 602                 {
 603                         self.monster_movestate = MONSTER_MOVE_FOLLOW;
 604                         self.last_trace = time + 0.3;
 605                         return (self.monster_follow) ? self.monster_follow.origin : self.origin;
 606                 }
 607                 case MONSTER_MOVE_SPAWNLOC:
 608                 {
 609                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 610                         self.last_trace = time + 2;
 611                         return self.pos1;
 612                 }
 613                 case MONSTER_MOVE_NOMOVE:
 614                 {
 615                         if(self.monster_moveto)
 616                         {
 617                                 self.last_trace = time + 0.5;
 618                                 return self.monster_moveto;
 619                         }
 620                         else
 621                         {
 622                                 self.monster_movestate = MONSTER_MOVE_NOMOVE;
 623                                 self.last_trace = time + 2;
 624                         }
 625                         return self.origin;
 626                 }
 627                 default:
 628                 case MONSTER_MOVE_WANDER:
 629                 {
 630                         vector pos;
 631                         self.monster_movestate = MONSTER_MOVE_WANDER;
 632
 633                         if(self.monster_moveto)
 634                         {
 635                                 self.last_trace = time + 0.5;
 636                                 pos = self.monster_moveto;
 637                         }
 638                         else if(targ)
 639                         {
 640                                 self.last_trace = time + 0.5;
 641                                 pos = targ.origin;
 642                         }
 643                         else
 644                         {
 645                                 self.last_trace = time + self.wander_delay;
 646
 647                                 self.angles_y = rint(random() * 500);
 648                                 makevectors(self.angles);
 649                                 pos = self.origin + v_forward * self.wander_distance;
 650
 651                                 if(((self.flags & FL_FLY) && (self.spawnflags & MONSTERFLAG_FLY_VERTICAL)) || (self.flags & FL_SWIM))
 652                                 {
 653                                         pos.z = random() * 200;
 654                                         if(random() >= 0.5)
 655                                                 pos.z *= -1;
 656                                 }
 657                         }
 658
 659                         return pos;
 660                 }
 661         }
 662 }
 663
 664 void Monster_CalculateVelocity(entity mon, vector to, vector from, float turnrate, float movespeed)
 665 {SELFPARAM();
 666         float current_distance = vlen((('1 0 0' * to.x) + ('0 1 0' * to.y)) - (('1 0 0' * from.x) + ('0 1 0' * from.y))); // for the sake of this check, exclude Z axis
 667         float initial_height = 0; //min(50, (targ_distance * tanh(20)));
 668         float current_height = (initial_height * min(1, (self.pass_distance) ? (current_distance / self.pass_distance) : current_distance));
 669         //print("current_height = ", ftos(current_height), ", initial_height = ", ftos(initial_height), ".\n");
 670
 671         vector targpos;
 672         if(current_height) // make sure we can actually do this arcing path
 673         {
 674                 targpos = (to + ('0 0 1' * current_height));
 675                 WarpZone_TraceLine(mon.origin, targpos, MOVE_NOMONSTERS, mon);
 676                 if(trace_fraction < 1)
 677                 {
 678                         //print("normal arc line failed, trying to find new pos...");
 679                         WarpZone_TraceLine(to, targpos, MOVE_NOMONSTERS, mon);
 680                         targpos = (trace_endpos + '0 0 -10');
 681                         WarpZone_TraceLine(mon.origin, targpos, MOVE_NOMONSTERS, mon);
 682                         if(trace_fraction < 1) { targpos = to; /* print(" ^1FAILURE^7, reverting to original direction.\n"); */ }
 683                         /*else { print(" ^3SUCCESS^7, using new arc line.\n"); } */
 684                 }
 685         }
 686         else { targpos = to; }
 687
 688         //mon.angles = normalize(('0 1 0' * to_y) - ('0 1 0' * from_y));
 689
 690         vector desired_direction = normalize(targpos - from);
 691         if(turnrate) { mon.velocity = (normalize(normalize(mon.velocity) + (desired_direction * 50)) * movespeed); }
 692         else { mon.velocity = (desired_direction * movespeed); }
 693
 694         //mon.steerto = steerlib_attract2(targpos, 0.5, 500, 0.95);
 695         //mon.angles = vectoangles(mon.velocity);
 696 }
 697
 698 void Monster_Move(float runspeed, float walkspeed, float stpspeed)
 699 {SELFPARAM();
 700         if(self.target2) { self.goalentity = find(world, targetname, self.target2); }
 701
 702         entity targ;
 703
 704         if(self.frozen == 2)
 705         {
 706                 self.revive_progress = bound(0, self.revive_progress + self.ticrate * self.revive_speed, 1);
 707                 self.health = max(1, self.revive_progress * self.max_health);
 708                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
 709
 710                 if(!(self.spawnflags & MONSTERFLAG_INVINCIBLE) && self.sprite)
 711                         WaypointSprite_UpdateHealth(self.sprite, self.health);
 712
 713                 movelib_beak_simple(stpspeed);
 714                 setanim(self, self.anim_idle, true, false, false);
 715
 716                 self.enemy = world;
 717                 self.nextthink = time + self.ticrate;
 718
 719                 if(self.revive_progress >= 1)
 720                         Unfreeze(self);
 721
 722                 return;
 723         }
 724         else if(self.frozen == 3)
 725         {
 726                 self.revive_progress = bound(0, self.revive_progress - self.ticrate * self.revive_speed, 1);
 727                 self.health = max(0, autocvar_g_nades_ice_health + (self.max_health-autocvar_g_nades_ice_health) * self.revive_progress );
 728
 729                 if(!(self.spawnflags & MONSTERFLAG_INVINCIBLE) && self.sprite)
 730                         WaypointSprite_UpdateHealth(self.sprite, self.health);
 731
 732                 movelib_beak_simple(stpspeed);
 733                 setanim(self, self.anim_idle, true, false, false);
 734
 735                 self.enemy = world;
 736                 self.nextthink = time + self.ticrate;
 737
 738                 if(self.health < 1)
 739                 {
 740                         Unfreeze(self);
 741                         self.health = 0;
 742                         if(self.event_damage)
 743                                 self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
 744                 }
 745
 746                 else if ( self.revive_progress <= 0 )
 747                         Unfreeze(self);
 748
 749                 return;
 750         }
 751
 752         if(self.flags & FL_SWIM)
 753         {
 754                 if(self.waterlevel < WATERLEVEL_WETFEET)
 755                 {
 756                         if(time >= self.last_trace)
 757                         {
 758                                 self.last_trace = time + 0.4;
 759
 760                                 Damage (self, world, world, 2, DEATH_DROWN.m_id, self.origin, '0 0 0');
 761                                 self.angles = '90 90 0';
 762                                 if(random() < 0.5)
 763                                 {
 764                                         self.velocity_y += random() * 50;
 765                                         self.velocity_x -= random() * 50;
 766                                 }
 767                                 else
 768                                 {
 769                                         self.velocity_y -= random() * 50;
 770                                         self.velocity_x += random() * 50;
 771                                 }
 772                                 self.velocity_z += random() * 150;
 773                         }
 774
 775
 776                         self.movetype = MOVETYPE_BOUNCE;
 777                         //self.velocity_z = -200;
 778
 779                         return;
 780                 }
 781                 else if(self.movetype == MOVETYPE_BOUNCE)
 782                 {
 783                         self.angles_x = 0;
 784                         self.movetype = MOVETYPE_WALK;
 785                 }
 786         }
 787
 788         targ = self.goalentity;
 789
 790         if (MUTATOR_CALLHOOK(MonsterMove, runspeed, walkspeed, targ)
 791                 || gameover
 792                 || self.draggedby != world
 793                 || (round_handler_IsActive() && !round_handler_IsRoundStarted())
 794                 || time < game_starttime
 795                 || (autocvar_g_campaign && !campaign_bots_may_start)
 796                 || time < self.spawn_time)
 797         {
 798                 runspeed = walkspeed = 0;
 799                 if(time >= self.spawn_time)
 800                         setanim(self, self.anim_idle, true, false, false);
 801                 movelib_beak_simple(stpspeed);
 802                 return;
 803         }
 804
 805         targ = monster_target;
 806         runspeed = bound(0, monster_speed_run * MONSTER_SKILLMOD(self), runspeed * 2.5); // limit maxspeed to prevent craziness
 807         walkspeed = bound(0, monster_speed_walk * MONSTER_SKILLMOD(self), walkspeed * 2.5); // limit maxspeed to prevent craziness
 808
 809         if(teamplay)
 810         if(autocvar_g_monsters_teams)
 811         if(DIFF_TEAM(self.monster_follow, self))
 812                 self.monster_follow = world;
 813
 814         if(time >= self.last_enemycheck)
 815         {
 816                 if(!self.enemy)
 817                 {
 818                         self.enemy = Monster_FindTarget(self);
 819                         if(self.enemy)
 820                         {
 821                                 WarpZone_RefSys_Copy(self.enemy, self);
 822                                 WarpZone_RefSys_AddInverse(self.enemy, self); // wz1^-1 ... wzn^-1 receiver
 823                                 self.moveto = WarpZone_RefSys_TransformOrigin(self.enemy, self, (0.5 * (self.enemy.absmin + self.enemy.absmax)));
 824                                 self.monster_moveto = '0 0 0';
 825                                 self.monster_face = '0 0 0';
 826
 827                                 self.pass_distance = vlen((('1 0 0' * self.enemy.origin_x) + ('0 1 0' * self.enemy.origin_y)) - (('1 0 0' *  self.origin_x) + ('0 1 0' *  self.origin_y)));
 828                                 Monster_Sound(monstersound_sight, 0, false, CH_VOICE);
 829                         }
 830                 }
 831
 832                 self.last_enemycheck = time + 1; // check for enemies every second
 833         }
 834
 835         if(self.state == MONSTER_ATTACK_RANGED && (self.flags & FL_ONGROUND))
 836         {
 837                 self.state = 0;
 838                 self.touch = Monster_Touch;
 839         }
 840
 841         if(self.state && time >= self.attack_finished_single[0])
 842                 self.state = 0; // attack is over
 843
 844         if(self.state != MONSTER_ATTACK_MELEE) // don't move if set
 845         if(time >= self.last_trace || self.enemy) // update enemy or rider instantly
 846                 self.moveto = Monster_Move_Target(targ);
 847
 848         if(!self.enemy)
 849                 Monster_Sound(monstersound_idle, 7, true, CH_VOICE);
 850
 851         if(self.state == MONSTER_ATTACK_MELEE)
 852                 self.moveto = self.origin;
 853
 854         if(self.enemy && self.enemy.vehicle)
 855                 runspeed = 0;
 856
 857         if(!(self.spawnflags & MONSTERFLAG_FLY_VERTICAL) && !(self.flags & FL_SWIM))
 858                 self.moveto_z = self.origin_z;
 859
 860         if(vlen(self.origin - self.moveto) > 100)
 861         {
 862                 float do_run = (self.enemy || self.monster_moveto);
 863                 if((self.flags & FL_ONGROUND) || ((self.flags & FL_FLY) || (self.flags & FL_SWIM)))
 864                         Monster_CalculateVelocity(self, self.moveto, self.origin, true, ((do_run) ? runspeed : walkspeed));
 865
 866                 if(time > self.pain_finished) // TODO: use anim_finished instead!
 867                 if(!self.state)
 868                 if(time > self.anim_finished)
 869                 if(vlen(self.velocity) > 10)
 870                         setanim(self, ((do_run) ? self.anim_run : self.anim_walk), true, false, false);
 871                 else
 872                         setanim(self, self.anim_idle, true, false, false);
 873         }
 874         else
 875         {
 876                 entity e = find(world, targetname, self.target2);
 877                 if(e.target2)
 878                         self.target2 = e.target2;
 879                 else if(e.target)
 880                         self.target2 = e.target;
 881
 882                 movelib_beak_simple(stpspeed);
 883                 if(time > self.anim_finished)
 884                 if(time > self.pain_finished)
 885                 if(!self.state)
 886                 if(vlen(self.velocity) <= 30)
 887                         setanim(self, self.anim_idle, true, false, false);
 888         }
 889
 890         self.steerto = steerlib_attract2(((self.monster_face) ? self.monster_face : self.moveto), 0.5, 500, 0.95);
 891
 892         vector real_angle = vectoangles(self.steerto) - self.angles;
 893         float turny = 25;
 894         if(self.state == MONSTER_ATTACK_MELEE)
 895                 turny = 0;
 896         if(turny)
 897         {
 898                 turny = bound(turny * -1, shortangle_f(real_angle.y, self.angles.y), turny);
 899                 self.angles_y += turny;
 900         }
 901
 902         Monster_Attack_Check(self, self.enemy);
 903 }
 904
 905 void Monster_Remove(entity mon)
 906 {
 907         .entity weaponentity = weaponentities[0];
 908         if(!mon) { return; }
 909
 910         if(!MUTATOR_CALLHOOK(MonsterRemove, mon))
 911                 Send_Effect(EFFECT_ITEM_PICKUP, mon.origin, '0 0 0', 1);
 912
 913         if(mon.(weaponentity)) { remove(mon.(weaponentity)); }
 914         if(mon.iceblock) { remove(mon.iceblock); }
 915         WaypointSprite_Kill(mon.sprite);
 916         remove(mon);
 917 }
 918
 919 void Monster_Dead_Think()
 920 {SELFPARAM();
 921         self.nextthink = time + self.ticrate;
 922
 923         if(self.monster_lifetime != 0)
 924         if(time >= self.monster_lifetime)
 925         {
 926                 Monster_Dead_Fade();
 927                 return;
 928         }
 929 }
 930
 931 void Monster_Appear()
 932 {SELFPARAM();
 933         self.enemy = activator;
 934         self.spawnflags &= ~MONSTERFLAG_APPEAR; // otherwise, we get an endless loop
 935         Monster_Spawn(self.monsterid);
 936 }
 937
 938 float Monster_Appear_Check(entity ent, float monster_id)
 939 {
 940         if(!(ent.spawnflags & MONSTERFLAG_APPEAR))
 941                 return false;
 942
 943         ent.think = func_null;
 944         ent.monsterid = monster_id; // set so this monster is properly registered (otherwise, normal initialization is used)
 945         ent.nextthink = 0;
 946         ent.use = Monster_Appear;
 947         ent.flags = FL_MONSTER; // set so this monster can get butchered
 948
 949         return true;
 950 }
 951
 952 void Monster_Reset(entity this)
 953 {
 954         setorigin(this, this.pos1);
 955         this.angles = this.pos2;
 956
 957         Unfreeze(this); // remove any icy remains
 958
 959         this.health = this.max_health;
 960         this.velocity = '0 0 0';
 961         this.enemy = world;
 962         this.goalentity = world;
 963         this.attack_finished_single[0] = 0;
 964         this.moveto = this.origin;
 965 }
 966
 967 void Monster_Dead_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 968 {SELFPARAM();
 969         self.health -= damage;
 970
 971         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 972
 973         if(self.health <= -100) // 100 health until gone?
 974         {
 975                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 976
 977                 // number of monsters spawned with mobspawn command
 978                 totalspawned -= 1;
 979
 980                 self.think = SUB_Remove_self;
 981                 self.nextthink = time + 0.1;
 982                 self.event_damage = func_null;
 983         }
 984 }
 985
 986 void Monster_Dead(entity attacker, float gibbed)
 987 {SELFPARAM();
 988         self.think = Monster_Dead_Think;
 989         self.nextthink = time;
 990         self.monster_lifetime = time + 5;
 991
 992         if(self.frozen)
 993         {
 994                 Unfreeze(self); // remove any icy remains
 995                 self.health = 0; // reset by Unfreeze
 996         }
 997
 998         monster_dropitem();
 999
1000         Monster_Sound(monstersound_death, 0, false, CH_VOICE);
1001
1002         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !(self.spawnflags & MONSTERFLAG_RESPAWNED))
1003                 monsters_killed += 1;
1004
1005         if(IS_PLAYER(attacker))
1006         if(autocvar_g_monsters_score_spawned || !((self.spawnflags & MONSTERFLAG_SPAWNED) || (self.spawnflags & MONSTERFLAG_RESPAWNED)))
1007                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
1008
1009         if(gibbed)
1010         {
1011                 // number of monsters spawned with mobspawn command
1012                 totalspawned -= 1;
1013         }
1014
1015         self.event_damage       = ((gibbed) ? func_null : Monster_Dead_Damage);
1016         self.solid                      = SOLID_CORPSE;
1017         self.takedamage         = DAMAGE_AIM;
1018         self.deadflag           = DEAD_DEAD;
1019         self.enemy                      = world;
1020         self.movetype           = MOVETYPE_TOSS;
1021         self.moveto                     = self.origin;
1022         self.touch                      = Monster_Touch; // reset incase monster was pouncing
1023         self.reset                      = func_null;
1024         self.state                      = 0;
1025         self.attack_finished_single[0] = 0;
1026         self.effects = 0;
1027
1028         if(!((self.flags & FL_FLY) || (self.flags & FL_SWIM)))
1029                 self.velocity = '0 0 0';
1030
1031         CSQCModel_UnlinkEntity(self);
1032
1033         Monster mon = get_monsterinfo(self.monsterid);
1034         mon.mr_death(mon);
1035
1036         if(self.candrop && self.weapon)
1037                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
1038 }
1039
1040 void Monster_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1041 {SELFPARAM();
1042         if((self.spawnflags & MONSTERFLAG_INVINCIBLE) && deathtype != DEATH_KILL.m_id && !ITEM_DAMAGE_NEEDKILL(deathtype))
1043                 return;
1044
1045         if(self.frozen && deathtype != DEATH_KILL.m_id && deathtype != DEATH_NADE_ICE_FREEZE.m_id)
1046                 return;
1047
1048         //if(time < self.pain_finished && deathtype != DEATH_KILL.m_id)
1049                 //return;
1050
1051         if(time < self.spawnshieldtime && deathtype != DEATH_KILL.m_id)
1052                 return;
1053
1054         if(deathtype == DEATH_FALL.m_id && self.draggedby != world)
1055                 return;
1056
1057         vector v;
1058         float take, save;
1059
1060         v = healtharmor_applydamage(100, self.armorvalue / 100, deathtype, damage);
1061         take = v_x;
1062         save = v_y;
1063
1064         damage_take = take;
1065         frag_attacker = attacker;
1066         frag_deathtype = deathtype;
1067         Monster mon = get_monsterinfo(self.monsterid);
1068         mon.mr_pain(mon);
1069         take = damage_take;
1070
1071         if(take)
1072         {
1073                 self.health -= take;
1074                 Monster_Sound(monstersound_pain, 1.2, true, CH_PAIN);
1075         }
1076
1077         if(self.sprite)
1078                 WaypointSprite_UpdateHealth(self.sprite, self.health);
1079
1080         self.dmg_time = time;
1081
1082         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN.m_id)
1083                 spamsound (self, CH_PAIN, SND(BODYIMPACT1), VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
1084
1085         self.velocity += force * self.damageforcescale;
1086
1087         if(deathtype != DEATH_DROWN.m_id && take)
1088         {
1089                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
1090                 if (take > 50)
1091                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
1092                 if (take > 100)
1093                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
1094         }
1095
1096         if(self.health <= 0)
1097         {
1098                 if(deathtype == DEATH_KILL.m_id)
1099                         self.candrop = false; // killed by mobkill command
1100
1101                 // TODO: fix this?
1102                 activator = attacker;
1103                 other = self.enemy;
1104                 SUB_UseTargets();
1105                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
1106
1107                 Monster_Dead(attacker, (self.health <= -100 || deathtype == DEATH_KILL.m_id));
1108
1109                 WaypointSprite_Kill(self.sprite);
1110
1111                 frag_target = self;
1112                 MUTATOR_CALLHOOK(MonsterDies, attacker);
1113
1114                 if(self.health <= -100 || deathtype == DEATH_KILL.m_id) // check if we're already gibbed
1115                 {
1116                         Violence_GibSplash(self, 1, 0.5, attacker);
1117
1118                         self.think = SUB_Remove_self;
1119                         self.nextthink = time + 0.1;
1120                 }
1121         }
1122 }
1123
1124 // don't check for enemies, just keep walking in a straight line
1125 void Monster_Move_2D(float mspeed, float allow_jumpoff)
1126 {SELFPARAM();
1127         if(gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || self.draggedby != world || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
1128         {
1129                 mspeed = 0;
1130                 if(time >= self.spawn_time)
1131                         setanim(self, self.anim_idle, true, false, false);
1132                 movelib_beak_simple(0.6);
1133                 return;
1134         }
1135
1136         float reverse = FALSE;
1137         vector a, b;
1138
1139         makevectors(self.angles);
1140         a = self.origin + '0 0 16';
1141         b = self.origin + '0 0 16' + v_forward * 32;
1142
1143         traceline(a, b, MOVE_NORMAL, self);
1144
1145         if(trace_fraction != 1.0)
1146         {
1147                 reverse = TRUE;
1148
1149                 if(trace_ent)
1150                 if(IS_PLAYER(trace_ent) && !(trace_ent.items & IT_STRENGTH))
1151                         reverse = FALSE;
1152         }
1153
1154         // TODO: fix this... tracing is broken if the floor is thin
1155         /*
1156         if(!allow_jumpoff)
1157         {
1158                 a = b - '0 0 32';
1159                 traceline(b, a, MOVE_WORLDONLY, self);
1160                 if(trace_fraction == 1.0)
1161                         reverse = TRUE;
1162         } */
1163
1164         if(reverse)
1165         {
1166                 self.angles_y = anglemods(self.angles_y - 180);
1167                 makevectors(self.angles);
1168         }
1169
1170         movelib_move_simple_gravity(v_forward, mspeed, 1);
1171
1172         if(time > self.pain_finished)
1173         if(time > self.attack_finished_single[0])
1174         if(vlen(self.velocity) > 10)
1175                 setanim(self, self.anim_walk, true, false, false);
1176         else
1177                 setanim(self, self.anim_idle, true, false, false);
1178 }
1179
1180 void Monster_Anim()
1181 {SELFPARAM();
1182         int deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
1183         if(self.deadflag)
1184         {
1185                 if (!deadbits)
1186                 {
1187                         // Decide on which death animation to use.
1188                         if(random() < 0.5)
1189                                 deadbits = ANIMSTATE_DEAD1;
1190                         else
1191                                 deadbits = ANIMSTATE_DEAD2;
1192                 }
1193         }
1194         else
1195         {
1196                 // Clear a previous death animation.
1197                 deadbits = 0;
1198         }
1199         int animbits = deadbits;
1200         if(self.frozen)
1201                 animbits |= ANIMSTATE_FROZEN;
1202         if(self.crouch)
1203                 animbits |= ANIMSTATE_DUCK; // not that monsters can crouch currently...
1204         animdecide_setstate(self, animbits, false);
1205         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
1206
1207         /* // weapon entities for monsters?
1208         if (self.weaponentity)
1209         {
1210                 updateanim(self.weaponentity);
1211                 if (!self.weaponentity.animstate_override)
1212                         setanim(self.weaponentity, self.weaponentity.anim_idle, true, false, false);
1213         }
1214         */
1215 }
1216
1217 void Monster_Think()
1218 {SELFPARAM();
1219         self.think = Monster_Think;
1220         self.nextthink = self.ticrate;
1221
1222         if(self.monster_lifetime)
1223         if(time >= self.monster_lifetime)
1224         {
1225                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL.m_id, self.origin, self.origin);
1226                 return;
1227         }
1228
1229         Monster mon = get_monsterinfo(self.monsterid);
1230         if(mon.mr_think(mon))
1231                 Monster_Move(self.speed2, self.speed, self.stopspeed);
1232
1233         Monster_Anim();
1234
1235         CSQCMODEL_AUTOUPDATE(self);
1236 }
1237
1238 float Monster_Spawn_Setup()
1239 {SELFPARAM();
1240         Monster mon = get_monsterinfo(self.monsterid);
1241         mon.mr_setup(mon);
1242
1243         // ensure some basic needs are met
1244         if(!self.health) { self.health = 100; }
1245         if(!self.armorvalue) { self.armorvalue = bound(0.2, 0.5 * MONSTER_SKILLMOD(self), 0.9); }
1246         if(!self.target_range) { self.target_range = autocvar_g_monsters_target_range; }
1247         if(!self.respawntime) { self.respawntime = autocvar_g_monsters_respawn_delay; }
1248         if(!self.monster_moveflags) { self.monster_moveflags = MONSTER_MOVE_WANDER; }
1249         if(!self.attack_range) { self.attack_range = autocvar_g_monsters_attack_range; }
1250         if(!self.damageforcescale) { self.damageforcescale = autocvar_g_monsters_damageforcescale; }
1251
1252         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1253         {
1254                 Monster_Miniboss_Check();
1255                 self.health *= MONSTER_SKILLMOD(self);
1256
1257                 if(!self.skin)
1258                         self.skin = rint(random() * 4);
1259         }
1260
1261         self.max_health = self.health;
1262         self.pain_finished = self.nextthink;
1263
1264         if(IS_PLAYER(self.monster_follow))
1265                 self.effects |= EF_DIMLIGHT;
1266
1267         if(!self.wander_delay) { self.wander_delay = 2; }
1268         if(!self.wander_distance) { self.wander_distance = 600; }
1269
1270         Monster_Sounds_Precache();
1271         Monster_Sounds_Update();
1272
1273         if(teamplay)
1274                 self.monster_attack = true; // we can have monster enemies in team games
1275
1276         Monster_Sound(monstersound_spawn, 0, false, CH_VOICE);
1277
1278         if(autocvar_g_monsters_healthbars)
1279         {
1280                 entity wp = WaypointSprite_Spawn(WP_Monster, 0, 1024, self, '0 0 1' * (self.maxs.z + 15), world, self.team, self, sprite, true, RADARICON_DANGER);
1281                 wp.wp_extra = self.monsterid;
1282                 wp.colormod = ((self.team) ? Team_ColorRGB(self.team) : '1 0 0');
1283                 if(!(self.spawnflags & MONSTERFLAG_INVINCIBLE))
1284                 {
1285                         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
1286                         WaypointSprite_UpdateHealth(self.sprite, self.health);
1287                 }
1288         }
1289
1290         self.think = Monster_Think;
1291         self.nextthink = time + self.ticrate;
1292
1293         if(MUTATOR_CALLHOOK(MonsterSpawn))
1294                 return false;
1295
1296         return true;
1297 }
1298
1299 bool Monster_Spawn(int mon_id)
1300 {SELFPARAM();
1301         // setup the basic required properties for a monster
1302         entity mon = get_monsterinfo(mon_id);
1303         if(!mon.monsterid) { return false; } // invalid monster
1304
1305         if(!autocvar_g_monsters) { Monster_Remove(self); return false; }
1306
1307         if(Monster_Appear_Check(self, mon_id)) { return true; } // return true so the monster isn't removed
1308
1309         if(!self.monster_skill)
1310                 self.monster_skill = cvar("g_monsters_skill");
1311
1312         // support for quake style removing monsters based on skill
1313         if(self.monster_skill == MONSTER_SKILL_EASY) if(self.spawnflags & MONSTERSKILL_NOTEASY) { Monster_Remove(self); return false; }
1314         if(self.monster_skill == MONSTER_SKILL_MEDIUM) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { Monster_Remove(self); return false; }
1315         if(self.monster_skill == MONSTER_SKILL_HARD) if(self.spawnflags & MONSTERSKILL_NOTHARD) { Monster_Remove(self); return false; }
1316
1317         if(self.team && !teamplay)
1318                 self.team = 0;
1319
1320         if(!(self.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1321         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED)) // don't count re-spawning monsters either
1322                 monsters_total += 1;
1323
1324         setmodel(self, mon.m_model);
1325         self.flags                              = FL_MONSTER;
1326         self.classname                  = "monster";
1327         self.takedamage                 = DAMAGE_AIM;
1328         self.bot_attack                 = true;
1329         self.iscreature                 = true;
1330         self.teleportable               = true;
1331         self.damagedbycontents  = true;
1332         self.monsterid                  = mon_id;
1333         self.event_damage               = Monster_Damage;
1334         self.touch                              = Monster_Touch;
1335         self.use                                = Monster_Use;
1336         self.solid                              = SOLID_BBOX;
1337         self.movetype                   = MOVETYPE_WALK;
1338         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1339         self.enemy                              = world;
1340         self.velocity                   = '0 0 0';
1341         self.moveto                             = self.origin;
1342         self.pos1                               = self.origin;
1343         self.pos2                               = self.angles;
1344         self.reset                              = Monster_Reset;
1345         self.netname                    = mon.netname;
1346         self.monster_attackfunc = mon.monster_attackfunc;
1347         self.monster_name               = mon.monster_name;
1348         self.candrop                    = true;
1349         self.view_ofs                   = '0 0 0.7' * (self.maxs_z * 0.5);
1350         self.oldtarget2                 = self.target2;
1351         self.pass_distance              = 0;
1352         self.deadflag                   = DEAD_NO;
1353         self.noalign                    = ((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM));
1354         self.spawn_time                 = time;
1355         self.gravity                    = 1;
1356         self.monster_moveto             = '0 0 0';
1357         self.monster_face               = '0 0 0';
1358         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1359
1360         if(!self.scale) { self.scale = 1; }
1361         if(autocvar_g_monsters_edit) { self.grab = 1; }
1362         if(autocvar_g_fullbrightplayers) { self.effects |= EF_FULLBRIGHT; }
1363         if(autocvar_g_nodepthtestplayers) { self.effects |= EF_NODEPTHTEST; }
1364         if(mon.spawnflags & MONSTER_TYPE_SWIM) { self.flags |= FL_SWIM; }
1365
1366         if(mon.spawnflags & MONSTER_TYPE_FLY)
1367         {
1368                 self.flags |= FL_FLY;
1369                 self.movetype = MOVETYPE_FLY;
1370         }
1371
1372         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1373         {
1374                 if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1375                         self.scale *= 1.3;
1376
1377                 if(mon.spawnflags & MONSTER_SIZE_QUAKE)
1378                 if(autocvar_g_monsters_quake_resize)
1379                         self.scale *= 1.3;
1380         }
1381
1382         setsize(self, mon.mins * self.scale, mon.maxs * self.scale);
1383
1384         self.ticrate = bound(sys_frametime, ((!self.ticrate) ? autocvar_g_monsters_think_delay : self.ticrate), 60);
1385
1386         Monster_UpdateModel();
1387
1388         if(!Monster_Spawn_Setup())
1389         {
1390                 Monster_Remove(self);
1391                 return false;
1392         }
1393
1394         if(!self.noalign)
1395         {
1396                 setorigin(self, self.origin + '0 0 20');
1397                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1398                 setorigin(self, trace_endpos);
1399         }
1400
1401         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1402                 monster_setupcolors(self);
1403
1404         CSQCMODEL_AUTOINIT(self);
1405
1406         return true;
1407 }