Minor monster code cleanup
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / monsters / sv_monsters.qc
1 #include "sv_monsters.qh"
2
3 #include <server/g_subs.qh>
4 #include <lib/warpzone/common.qh>
5 #include "../constants.qh"
6 #include "../teams.qh"
7 #include "../util.qh"
8 #include "all.qh"
9 #include "../physics/movelib.qh"
10 #include "../weapons/_mod.qh"
11 #include <server/autocvars.qh>
12 #include <server/defs.qh>
13 #include "../deathtypes/all.qh"
14 #include <server/mutators/_mod.qh>
15 #include <server/steerlib.qh>
16 #include "../turrets/sv_turrets.qh"
17 #include "../turrets/util.qh"
18 #include "../vehicles/all.qh"
19 #include <server/campaign.qh>
20 #include <server/command/_mod.qh>
21 #include "../triggers/triggers.qh"
22 #include <lib/csqcmodel/sv_model.qh>
23 #include <server/round_handler.qh>
24 #include <server/weapons/_mod.qh>
25
26 void monsters_setstatus(entity this)
27 {
28         this.stat_monsters_total = monsters_total;
29         this.stat_monsters_killed = monsters_killed;
30 }
31
32 void monster_dropitem(entity this, entity attacker)
33 {
34         if(!this.candrop || !this.monster_loot)
35                 return;
36
37         vector org = CENTER_OR_VIEWOFS(this);
38         entity e = new(droppedweapon); // use weapon handling to remove it on touch
39         e.spawnfunc_checked = true;
40
41         e.monster_loot = this.monster_loot;
42
43         MUTATOR_CALLHOOK(MonsterDropItem, this, e, attacker);
44         e = M_ARGV(1, entity);
45
46         if(e && e.monster_loot)
47         {
48                 e.noalign = true;
49                 e.monster_loot(e);
50                 e.gravity = 1;
51                 set_movetype(e, MOVETYPE_TOSS);
52                 e.reset = SUB_Remove;
53                 setorigin(e, org);
54                 e.velocity = randomvec() * 175 + '0 0 325';
55                 e.item_spawnshieldtime = time + 0.7;
56                 SUB_SetFade(e, time + autocvar_g_monsters_drop_time, 1);
57         }
58 }
59
60 void monster_makevectors(entity this, entity targ)
61 {
62         if(IS_MONSTER(this))
63         {
64                 vector v = targ.origin + (targ.mins + targ.maxs) * 0.5;
65                 this.v_angle = vectoangles(v - (this.origin + this.view_ofs));
66                 this.v_angle_x = -this.v_angle_x;
67         }
68
69         makevectors(this.v_angle);
70 }
71
72 // ===============
73 // Target handling
74 // ===============
75
76 bool Monster_ValidTarget(entity this, entity targ)
77 {
78         // ensure we're not checking nonexistent monster/target
79         if(!this || !targ) { return false; }
80
81         if((targ == this)
82         || (autocvar_g_monsters_lineofsight && !checkpvs(this.origin + this.view_ofs, targ)) // enemy cannot be seen
83         || (IS_VEHICLE(targ) && !((Monsters_from(this.monsterid)).spawnflags & MON_FLAG_RANGED)) // melee vs vehicle is useless
84         || (time < game_starttime) // monsters do nothing before match has started
85         || (targ.takedamage == DAMAGE_NO)
86         || (targ.items & IT_INVISIBILITY)
87         || (IS_SPEC(targ) || IS_OBSERVER(targ)) // don't attack spectators
88         || (!IS_VEHICLE(targ) && (IS_DEAD(targ) || IS_DEAD(this) || targ.health <= 0 || this.health <= 0))
89         || (this.monster_follow == targ || targ.monster_follow == this)
90         || (!IS_VEHICLE(targ) && (targ.flags & FL_NOTARGET))
91         || (!autocvar_g_monsters_typefrag && PHYS_INPUT_BUTTON_CHAT(targ))
92         || (SAME_TEAM(targ, this))
93         || (STAT(FROZEN, targ))
94         || (targ.alpha != 0 && targ.alpha < 0.5)
95         || (MUTATOR_CALLHOOK(MonsterValidTarget, this, targ))
96         )
97         {
98                 // if any of the above checks fail, target is not valid
99                 return false;
100         }
101
102         traceline(this.origin + this.view_ofs, targ.origin, MOVE_NOMONSTERS, this);
103
104         if(trace_fraction < 1)
105                 return false; // solid
106
107         if(autocvar_g_monsters_target_infront || (this.spawnflags & MONSTERFLAG_INFRONT))
108         if(this.enemy != targ)
109         {
110                 makevectors (this.angles);
111                 float dot = normalize (targ.origin - this.origin) * v_forward;
112
113                 if(dot <= autocvar_g_monsters_target_infront_range) { return false; }
114         }
115
116         return true; // this target is valid!
117 }
118
119 entity Monster_FindTarget(entity this)
120 {
121         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return this.enemy; } // Handled by a mutator
122
123         entity closest_target = NULL;
124         vector my_center = CENTER_OR_VIEWOFS(this);
125
126         // find the closest acceptable target to pass to
127         FOREACH_ENTITY_RADIUS(this.origin, this.target_range, it.monster_attack,
128         {
129                 if(Monster_ValidTarget(this, it))
130                 {
131                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
132                         vector targ_center = CENTER_OR_VIEWOFS(it);
133
134                         if(closest_target)
135                         {
136                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
137                                 if(vlen2(my_center - targ_center) < vlen2(my_center - closest_target_center))
138                                         { closest_target = it; }
139                         }
140                         else { closest_target = it; }
141                 }
142         });
143
144         return closest_target;
145 }
146
147 void monster_setupcolors(entity this)
148 {
149         if(IS_PLAYER(this.realowner))
150                 this.colormap = this.realowner.colormap;
151         else if(teamplay && this.team)
152                 this.colormap = 1024 + (this.team - 1) * 17;
153         else
154         {
155                 if(this.monster_skill <= MONSTER_SKILL_EASY)
156                         this.colormap = 1029;
157                 else if(this.monster_skill <= MONSTER_SKILL_MEDIUM)
158                         this.colormap = 1027;
159                 else if(this.monster_skill <= MONSTER_SKILL_HARD)
160                         this.colormap = 1038;
161                 else if(this.monster_skill <= MONSTER_SKILL_INSANE)
162                         this.colormap = 1028;
163                 else if(this.monster_skill <= MONSTER_SKILL_NIGHTMARE)
164                         this.colormap = 1032;
165                 else
166                         this.colormap = 1024;
167         }
168 }
169
170 void monster_changeteam(entity this, int newteam)
171 {
172         if(!teamplay) { return; }
173
174         this.team = newteam;
175         this.monster_attack = true; // new team, activate attacking
176         monster_setupcolors(this);
177
178         if(this.sprite)
179         {
180                 WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DANGER, ((newteam) ? Team_ColorRGB(newteam) : '1 0 0'));
181
182                 this.sprite.team = newteam;
183                 this.sprite.SendFlags |= 1;
184         }
185 }
186
187 .void(entity) monster_delayedfunc;
188 void Monster_Delay_Action(entity this)
189 {
190         if(Monster_ValidTarget(this.owner, this.owner.enemy)) { this.monster_delayedfunc(this.owner); }
191
192         if(this.cnt > 1)
193         {
194                 this.cnt -= 1;
195                 setthink(this, Monster_Delay_Action);
196                 this.nextthink = time + this.count;
197         }
198         else
199         {
200                 setthink(this, SUB_Remove);
201                 this.nextthink = time;
202         }
203 }
204
205 void Monster_Delay(entity this, int repeat_count, float defer_amnt, void(entity) func)
206 {
207         // deferred attacking, checks if monster is still alive and target is still valid before attacking
208         entity e = spawn();
209
210         setthink(e, Monster_Delay_Action);
211         e.nextthink = time + defer_amnt;
212         e.count = defer_amnt;
213         e.owner = this;
214         e.monster_delayedfunc = func;
215         e.cnt = repeat_count;
216 }
217
218
219 // ==============
220 // Monster sounds
221 // ==============
222
223 string get_monster_model_datafilename(string m, float sk, string fil)
224 {
225         if(m)
226                 m = strcat(m, "_");
227         else
228                 m = "models/monsters/*_";
229         if(sk >= 0)
230                 m = strcat(m, ftos(sk));
231         else
232                 m = strcat(m, "*");
233         return strcat(m, ".", fil);
234 }
235
236 void Monster_Sound_Precache(string f)
237 {
238         float fh;
239         string s;
240         fh = fopen(f, FILE_READ);
241         if(fh < 0)
242                 return;
243         while((s = fgets(fh)))
244         {
245                 if(tokenize_console(s) != 3)
246                 {
247                         LOG_TRACE("Invalid sound info line: ", s);
248                         continue;
249                 }
250                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
251         }
252         fclose(fh);
253 }
254
255 void Monster_Sounds_Precache(entity this)
256 {
257         string m = (Monsters_from(this.monsterid)).m_model.model_str();
258         float globhandle, n, i;
259         string f;
260
261         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
262         if (globhandle < 0)
263                 return;
264         n = search_getsize(globhandle);
265         for (i = 0; i < n; ++i)
266         {
267                 //print(search_getfilename(globhandle, i), "\n");
268                 f = search_getfilename(globhandle, i);
269                 Monster_Sound_Precache(f);
270         }
271         search_end(globhandle);
272 }
273
274 void Monster_Sounds_Clear(entity this)
275 {
276 #define _MSOUND(m) if(this.monstersound_##m) { strunzone(this.monstersound_##m); this.monstersound_##m = string_null; }
277         ALLMONSTERSOUNDS
278 #undef _MSOUND
279 }
280
281 .string Monster_Sound_SampleField(string type)
282 {
283         GetMonsterSoundSampleField_notFound = 0;
284         switch(type)
285         {
286 #define _MSOUND(m) case #m: return monstersound_##m;
287                 ALLMONSTERSOUNDS
288 #undef _MSOUND
289         }
290         GetMonsterSoundSampleField_notFound = 1;
291         return string_null;
292 }
293
294 bool Monster_Sounds_Load(entity this, string f, int first)
295 {
296         string s;
297         var .string field;
298         float fh = fopen(f, FILE_READ);
299         if(fh < 0)
300         {
301                 LOG_TRACE("Monster sound file not found: ", f);
302                 return false;
303         }
304         while((s = fgets(fh)))
305         {
306                 if(tokenize_console(s) != 3)
307                         continue;
308                 field = Monster_Sound_SampleField(argv(0));
309                 if(GetMonsterSoundSampleField_notFound)
310                         continue;
311                 if (this.(field))
312                         strunzone(this.(field));
313                 this.(field) = strzone(strcat(argv(1), " ", argv(2)));
314         }
315         fclose(fh);
316         return true;
317 }
318
319 .int skin_for_monstersound;
320 void Monster_Sounds_Update(entity this)
321 {
322         if(this.skin == this.skin_for_monstersound) { return; }
323
324         this.skin_for_monstersound = this.skin;
325         Monster_Sounds_Clear(this);
326         if(!Monster_Sounds_Load(this, get_monster_model_datafilename(this.model, this.skin, "sounds"), 0))
327                 Monster_Sounds_Load(this, get_monster_model_datafilename(this.model, 0, "sounds"), 0);
328 }
329
330 void Monster_Sound(entity this, .string samplefield, float sound_delay, bool delaytoo, float chan)
331 {
332         if(!autocvar_g_monsters_sounds) { return; }
333
334         if(delaytoo)
335         if(time < this.msound_delay)
336                 return; // too early
337         GlobalSound_string(this, this.(samplefield), chan, VOL_BASE, VOICETYPE_PLAYERSOUND);
338
339         this.msound_delay = time + sound_delay;
340 }
341
342
343 // =======================
344 // Monster attack handlers
345 // =======================
346
347 bool Monster_Attack_Melee(entity this, entity targ, float damg, vector anim, float er, float animtime, int deathtype, bool dostop)
348 {
349         if(dostop && IS_MONSTER(this)) { this.state = MONSTER_ATTACK_MELEE; }
350
351         setanim(this, anim, false, true, false);
352
353         if(this.animstate_endtime > time && IS_MONSTER(this))
354                 this.attack_finished_single[0] = this.anim_finished = this.animstate_endtime;
355         else
356                 this.attack_finished_single[0] = this.anim_finished = time + animtime;
357
358         monster_makevectors(this, targ);
359
360         traceline(this.origin + this.view_ofs, this.origin + v_forward * er, 0, this);
361
362         if(trace_ent.takedamage)
363                 Damage(trace_ent, this, this, damg * MONSTER_SKILLMOD(this), deathtype, trace_ent.origin, normalize(trace_ent.origin - this.origin));
364
365         return true;
366 }
367
368 bool Monster_Attack_Leap_Check(entity this, vector vel)
369 {
370         if(this.state && IS_MONSTER(this))
371                 return false; // already attacking
372         if(!IS_ONGROUND(this))
373                 return false; // not on the ground
374         if(this.health <= 0 || IS_DEAD(this))
375                 return false; // called when dead?
376         if(time < this.attack_finished_single[0])
377                 return false; // still attacking
378
379         vector old = this.velocity;
380
381         this.velocity = vel;
382         tracetoss(this, this);
383         this.velocity = old;
384         if(trace_ent != this.enemy)
385                 return false;
386
387         return true;
388 }
389
390 bool Monster_Attack_Leap(entity this, vector anm, void(entity this, entity toucher) touchfunc, vector vel, float animtime)
391 {
392         if(!Monster_Attack_Leap_Check(this, vel))
393                 return false;
394
395         setanim(this, anm, false, true, false);
396
397         if(this.animstate_endtime > time && IS_MONSTER(this))
398                 this.attack_finished_single[0] = this.anim_finished = this.animstate_endtime;
399         else
400                 this.attack_finished_single[0] = this.anim_finished = time + animtime;
401
402         if(IS_MONSTER(this))
403                 this.state = MONSTER_ATTACK_RANGED;
404         settouch(this, touchfunc);
405         this.origin_z += 1;
406         this.velocity = vel;
407         UNSET_ONGROUND(this);
408
409         return true;
410 }
411
412 void Monster_Attack_Check(entity this, entity targ)
413 {
414         if((!this || !targ)
415         || (!this.monster_attackfunc)
416         || (time < this.attack_finished_single[0])
417         ) { return; }
418
419         if(vdist(targ.origin - this.origin, <=, this.attack_range))
420         {
421                 int attack_success = this.monster_attackfunc(MONSTER_ATTACK_MELEE, this, targ);
422                 if(attack_success == 1)
423                         Monster_Sound(this, monstersound_melee, 0, false, CH_VOICE);
424                 else if(attack_success > 0)
425                         return;
426         }
427
428         if(vdist(targ.origin - this.origin, >, this.attack_range))
429         {
430                 int attack_success = this.monster_attackfunc(MONSTER_ATTACK_RANGED, this, targ);
431                 if(attack_success == 1)
432                         Monster_Sound(this, monstersound_melee, 0, false, CH_VOICE);
433                 else if(attack_success > 0)
434                         return;
435         }
436 }
437
438
439 // ======================
440 // Main monster functions
441 // ======================
442
443 void Monster_UpdateModel(entity this)
444 {
445         // assume some defaults
446         /*this.anim_idle   = animfixfps(this, '0 1 0.01', '0 0 0');
447         this.anim_walk   = animfixfps(this, '1 1 0.01', '0 0 0');
448         this.anim_run    = animfixfps(this, '2 1 0.01', '0 0 0');
449         this.anim_fire1  = animfixfps(this, '3 1 0.01', '0 0 0');
450         this.anim_fire2  = animfixfps(this, '4 1 0.01', '0 0 0');
451         this.anim_melee  = animfixfps(this, '5 1 0.01', '0 0 0');
452         this.anim_pain1  = animfixfps(this, '6 1 0.01', '0 0 0');
453         this.anim_pain2  = animfixfps(this, '7 1 0.01', '0 0 0');
454         this.anim_die1   = animfixfps(this, '8 1 0.01', '0 0 0');
455         this.anim_die2   = animfixfps(this, '9 1 0.01', '0 0 0');*/
456
457         // then get the real values
458         Monster mon = Monsters_from(this.monsterid);
459         mon.mr_anim(mon, this);
460 }
461
462 void Monster_Touch(entity this, entity toucher)
463 {
464         if(toucher == NULL) { return; }
465
466         if(toucher.monster_attack)
467         if(this.enemy != toucher)
468         if(!IS_MONSTER(toucher))
469         if(Monster_ValidTarget(this, toucher))
470                 this.enemy = toucher;
471 }
472
473 void Monster_Miniboss_Check(entity this)
474 {
475         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag, this))
476                 return;
477
478         float chance = random() * 100;
479
480         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
481         if ((this.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
482         {
483                 this.health += autocvar_g_monsters_miniboss_healthboost;
484                 this.effects |= EF_RED;
485                 if(!this.weapon)
486                         this.weapon = WEP_VORTEX.m_id;
487         }
488 }
489
490 bool Monster_Respawn_Check(entity this)
491 {
492         if(this.deadflag == DEAD_DEAD) // don't call when monster isn't dead
493         if(MUTATOR_CALLHOOK(MonsterRespawn, this))
494                 return true; // enabled by a mutator
495
496         if(this.spawnflags & MONSTERFLAG_NORESPAWN)
497                 return false;
498
499         if(!autocvar_g_monsters_respawn)
500                 return false;
501
502         return true;
503 }
504
505 void Monster_Respawn(entity this) { Monster_Spawn(this, true, this.monsterid); }
506
507 .vector pos1, pos2;
508
509 void Monster_Dead_Fade(entity this)
510 {
511         if(Monster_Respawn_Check(this))
512         {
513                 this.spawnflags |= MONSTERFLAG_RESPAWNED;
514                 setthink(this, Monster_Respawn);
515                 this.nextthink = time + this.respawntime;
516                 this.monster_lifetime = 0;
517                 this.deadflag = DEAD_RESPAWNING;
518                 if(this.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
519                 {
520                         this.pos1 = this.origin;
521                         this.pos2 = this.angles;
522                 }
523                 this.event_damage = func_null;
524                 this.takedamage = DAMAGE_NO;
525                 setorigin(this, this.pos1);
526                 this.angles = this.pos2;
527                 this.health = this.max_health;
528                 setmodel(this, MDL_Null);
529         }
530         else
531         {
532                 // number of monsters spawned with mobspawn command
533                 totalspawned -= 1;
534
535                 SUB_SetFade(this, time + 3, 1);
536         }
537 }
538
539 void Monster_Use(entity this, entity actor, entity trigger)
540 {
541         if(Monster_ValidTarget(this, actor)) { this.enemy = actor; }
542 }
543
544 .float pass_distance;
545 vector Monster_Move_Target(entity this, entity targ)
546 {
547         // enemy is always preferred target
548         if(this.enemy)
549         {
550                 vector targ_origin = ((this.enemy.absmin + this.enemy.absmax) * 0.5);
551                 targ_origin = WarpZone_RefSys_TransformOrigin(this.enemy, this, targ_origin); // origin of target as seen by the monster (us)
552                 WarpZone_TraceLine(this.origin, targ_origin, MOVE_NOMONSTERS, this);
553
554                 // cases where the enemy may have changed their state (don't need to check everything here)
555                 if((!this.enemy)
556                         || (IS_DEAD(this.enemy) || this.enemy.health < 1)
557                         || (STAT(FROZEN, this.enemy))
558                         || (this.enemy.flags & FL_NOTARGET)
559                         || (this.enemy.alpha < 0.5 && this.enemy.alpha != 0)
560                         || (this.enemy.takedamage == DAMAGE_NO)
561                         || (vdist(this.origin - targ_origin, >, this.target_range))
562                         || ((trace_fraction < 1) && (trace_ent != this.enemy)))
563                 {
564                         this.enemy = NULL;
565                         this.pass_distance = 0;
566                 }
567
568                 if(this.enemy)
569                 {
570                         /*WarpZone_TrailParticles(NULL, particleeffectnum(EFFECT_RED_PASS), this.origin, targ_origin);
571                         print("Trace origin: ", vtos(targ_origin), "\n");
572                         print("Target origin: ", vtos(this.enemy.origin), "\n");
573                         print("My origin: ", vtos(this.origin), "\n"); */
574
575                         this.monster_movestate = MONSTER_MOVE_ENEMY;
576                         this.last_trace = time + 1.2;
577                         if(this.monster_moveto)
578                                 return this.monster_moveto; // assumes code is properly setting this when monster has an enemy
579                         else
580                                 return targ_origin;
581                 }
582
583                 /*makevectors(this.angles);
584                 this.monster_movestate = MONSTER_MOVE_ENEMY;
585                 this.last_trace = time + 1.2;
586                 return this.enemy.origin; */
587         }
588
589         switch(this.monster_moveflags)
590         {
591                 case MONSTER_MOVE_FOLLOW:
592                 {
593                         this.monster_movestate = MONSTER_MOVE_FOLLOW;
594                         this.last_trace = time + 0.3;
595                         return (this.monster_follow) ? this.monster_follow.origin : this.origin;
596                 }
597                 case MONSTER_MOVE_SPAWNLOC:
598                 {
599                         this.monster_movestate = MONSTER_MOVE_SPAWNLOC;
600                         this.last_trace = time + 2;
601                         return this.pos1;
602                 }
603                 case MONSTER_MOVE_NOMOVE:
604                 {
605                         if(this.monster_moveto)
606                         {
607                                 this.last_trace = time + 0.5;
608                                 return this.monster_moveto;
609                         }
610                         else
611                         {
612                                 this.monster_movestate = MONSTER_MOVE_NOMOVE;
613                                 this.last_trace = time + 2;
614                         }
615                         return this.origin;
616                 }
617                 default:
618                 case MONSTER_MOVE_WANDER:
619                 {
620                         vector pos;
621                         this.monster_movestate = MONSTER_MOVE_WANDER;
622
623                         if(this.monster_moveto)
624                         {
625                                 this.last_trace = time + 0.5;
626                                 pos = this.monster_moveto;
627                         }
628                         else if(targ)
629                         {
630                                 this.last_trace = time + 0.5;
631                                 pos = targ.origin;
632                         }
633                         else
634                         {
635                                 this.last_trace = time + this.wander_delay;
636
637                                 this.angles_y = rint(random() * 500);
638                                 makevectors(this.angles);
639                                 pos = this.origin + v_forward * this.wander_distance;
640
641                                 if(((this.flags & FL_FLY) && (this.spawnflags & MONSTERFLAG_FLY_VERTICAL)) || (this.flags & FL_SWIM))
642                                 {
643                                         pos.z = random() * 200;
644                                         if(random() >= 0.5)
645                                                 pos.z *= -1;
646                                 }
647                         }
648
649                         return pos;
650                 }
651         }
652 }
653
654 void Monster_CalculateVelocity(entity this, vector to, vector from, float turnrate, float movespeed)
655 {
656         float current_distance = vlen((('1 0 0' * to.x) + ('0 1 0' * to.y)) - (('1 0 0' * from.x) + ('0 1 0' * from.y))); // for the sake of this check, exclude Z axis
657         float initial_height = 0; //min(50, (targ_distance * tanh(20)));
658         float current_height = (initial_height * min(1, (this.pass_distance) ? (current_distance / this.pass_distance) : current_distance));
659         //print("current_height = ", ftos(current_height), ", initial_height = ", ftos(initial_height), ".\n");
660
661         vector targpos;
662         if(current_height) // make sure we can actually do this arcing path
663         {
664                 targpos = (to + ('0 0 1' * current_height));
665                 WarpZone_TraceLine(this.origin, targpos, MOVE_NOMONSTERS, this);
666                 if(trace_fraction < 1)
667                 {
668                         //print("normal arc line failed, trying to find new pos...");
669                         WarpZone_TraceLine(to, targpos, MOVE_NOMONSTERS, this);
670                         targpos = (trace_endpos + '0 0 -10');
671                         WarpZone_TraceLine(this.origin, targpos, MOVE_NOMONSTERS, this);
672                         if(trace_fraction < 1) { targpos = to; /* print(" ^1FAILURE^7, reverting to original direction.\n"); */ }
673                         /*else { print(" ^3SUCCESS^7, using new arc line.\n"); } */
674                 }
675         }
676         else { targpos = to; }
677
678         //this.angles = normalize(('0 1 0' * to_y) - ('0 1 0' * from_y));
679
680         vector desired_direction = normalize(targpos - from);
681         if(turnrate) { this.velocity = (normalize(normalize(this.velocity) + (desired_direction * 50)) * movespeed); }
682         else { this.velocity = (desired_direction * movespeed); }
683
684         //this.steerto = steerlib_attract2(targpos, 0.5, 500, 0.95);
685         //this.angles = vectoangles(this.velocity);
686 }
687
688 .entity draggedby;
689 .entity target2;
690
691 void Monster_Move(entity this, float runspeed, float walkspeed, float stpspeed)
692 {
693         // update goal entity if lost
694         if(this.target2 && this.goalentity.targetname != this.target2) { this.goalentity = find(NULL, targetname, this.target2); }
695
696         if(STAT(FROZEN, this) == 2)
697         {
698                 this.revive_progress = bound(0, this.revive_progress + this.ticrate * this.revive_speed, 1);
699                 this.health = max(1, this.revive_progress * this.max_health);
700                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
701
702                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE) && this.sprite)
703                         WaypointSprite_UpdateHealth(this.sprite, this.health);
704
705                 movelib_brake_simple(this, stpspeed);
706                 setanim(this, this.anim_idle, true, false, false);
707
708                 this.enemy = NULL;
709                 this.nextthink = time + this.ticrate;
710
711                 if(this.revive_progress >= 1)
712                         Unfreeze(this);
713
714                 return;
715         }
716         else if(STAT(FROZEN, this) == 3)
717         {
718                 this.revive_progress = bound(0, this.revive_progress - this.ticrate * this.revive_speed, 1);
719                 this.health = max(0, autocvar_g_nades_ice_health + (this.max_health-autocvar_g_nades_ice_health) * this.revive_progress );
720
721                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE) && this.sprite)
722                         WaypointSprite_UpdateHealth(this.sprite, this.health);
723
724                 movelib_brake_simple(this, stpspeed);
725                 setanim(this, this.anim_idle, true, false, false);
726
727                 this.enemy = NULL;
728                 this.nextthink = time + this.ticrate;
729
730                 if(this.health < 1)
731                 {
732                         Unfreeze(this);
733                         this.health = 0;
734                         if(this.event_damage)
735                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
736                 }
737
738                 else if ( this.revive_progress <= 0 )
739                         Unfreeze(this);
740
741                 return;
742         }
743
744         if(this.flags & FL_SWIM)
745         {
746                 if(this.waterlevel < WATERLEVEL_WETFEET)
747                 {
748                         if(time >= this.last_trace)
749                         {
750                                 this.last_trace = time + 0.4;
751
752                                 Damage (this, NULL, NULL, 2, DEATH_DROWN.m_id, this.origin, '0 0 0');
753                                 this.angles = '90 90 0';
754                                 if(random() < 0.5)
755                                 {
756                                         this.velocity_y += random() * 50;
757                                         this.velocity_x -= random() * 50;
758                                 }
759                                 else
760                                 {
761                                         this.velocity_y -= random() * 50;
762                                         this.velocity_x += random() * 50;
763                                 }
764                                 this.velocity_z += random() * 150;
765                         }
766
767
768                         set_movetype(this, MOVETYPE_BOUNCE);
769                         //this.velocity_z = -200;
770
771                         return;
772                 }
773                 else if(this.move_movetype == MOVETYPE_BOUNCE)
774                 {
775                         this.angles_x = 0;
776                         set_movetype(this, MOVETYPE_WALK);
777                 }
778         }
779
780         entity targ = this.goalentity;
781
782         if (MUTATOR_CALLHOOK(MonsterMove, this, runspeed, walkspeed, targ)
783                 || gameover
784                 || this.draggedby != NULL
785                 || (round_handler_IsActive() && !round_handler_IsRoundStarted())
786                 || time < game_starttime
787                 || (autocvar_g_campaign && !campaign_bots_may_start)
788                 || time < this.spawn_time)
789         {
790                 runspeed = walkspeed = 0;
791                 if(time >= this.spawn_time)
792                         setanim(this, this.anim_idle, true, false, false);
793                 movelib_brake_simple(this, stpspeed);
794                 return;
795         }
796
797         targ = M_ARGV(3, entity);
798         runspeed = bound(0, M_ARGV(1, float) * MONSTER_SKILLMOD(this), runspeed * 2.5); // limit maxspeed to prevent craziness
799         walkspeed = bound(0, M_ARGV(2, float) * MONSTER_SKILLMOD(this), walkspeed * 2.5); // limit maxspeed to prevent craziness
800
801         if(teamplay && autocvar_g_monsters_teams)
802         if(DIFF_TEAM(this.monster_follow, this))
803                 this.monster_follow = NULL;
804
805         if(time >= this.last_enemycheck)
806         {
807                 if(!this.enemy)
808                 {
809                         this.enemy = Monster_FindTarget(this);
810                         if(this.enemy)
811                         {
812                                 WarpZone_RefSys_Copy(this.enemy, this);
813                                 WarpZone_RefSys_AddInverse(this.enemy, this); // wz1^-1 ... wzn^-1 receiver
814                                 this.moveto = WarpZone_RefSys_TransformOrigin(this.enemy, this, (0.5 * (this.enemy.absmin + this.enemy.absmax)));
815                                 this.monster_moveto = '0 0 0';
816                                 this.monster_face = '0 0 0';
817
818                                 this.pass_distance = vlen((('1 0 0' * this.enemy.origin_x) + ('0 1 0' * this.enemy.origin_y)) - (('1 0 0' *  this.origin_x) + ('0 1 0' *  this.origin_y)));
819                                 Monster_Sound(this, monstersound_sight, 0, false, CH_VOICE);
820                         }
821                 }
822
823                 this.last_enemycheck = time + 1; // check for enemies every second
824         }
825
826         if(this.state == MONSTER_ATTACK_RANGED && IS_ONGROUND(this))
827         {
828                 this.state = 0;
829                 settouch(this, Monster_Touch);
830         }
831
832         if(this.state && time >= this.attack_finished_single[0])
833                 this.state = 0; // attack is over
834
835         if(this.state != MONSTER_ATTACK_MELEE) // don't move if set
836         if(time >= this.last_trace || this.enemy) // update enemy or rider instantly
837                 this.moveto = Monster_Move_Target(this, targ);
838
839         if(!this.enemy)
840                 Monster_Sound(this, monstersound_idle, 7, true, CH_VOICE);
841
842         if(this.state == MONSTER_ATTACK_MELEE)
843                 this.moveto = this.origin;
844
845         if(this.enemy && this.enemy.vehicle)
846                 runspeed = 0;
847
848         if(!(this.spawnflags & MONSTERFLAG_FLY_VERTICAL) && !(this.flags & FL_SWIM))
849                 this.moveto_z = this.origin_z;
850
851         if(vdist(this.origin - this.moveto, >, 100))
852         {
853                 bool do_run = (this.enemy || this.monster_moveto);
854                 if(IS_ONGROUND(this) || ((this.flags & FL_FLY) || (this.flags & FL_SWIM)))
855                         Monster_CalculateVelocity(this, this.moveto, this.origin, true, ((do_run) ? runspeed : walkspeed));
856
857                 if(time > this.pain_finished && time > this.anim_finished) // TODO: use anim_finished instead!?
858                 if(!this.state)
859                 if(vdist(this.velocity, >, 10))
860                         setanim(this, ((do_run) ? this.anim_run : this.anim_walk), true, false, false);
861                 else
862                         setanim(this, this.anim_idle, true, false, false);
863         }
864         else
865         {
866                 entity e = this.goalentity; //find(NULL, targetname, this.target2);
867                 if(e.target2)
868                         this.target2 = e.target2;
869                 else if(e.target) // compatibility
870                         this.target2 = e.target;
871
872                 movelib_brake_simple(this, stpspeed);
873                 if(time > this.anim_finished && time > this.pain_finished)
874                 if(!this.state)
875                 if(vdist(this.velocity, <=, 30))
876                         setanim(this, this.anim_idle, true, false, false);
877         }
878
879         this.steerto = steerlib_attract2(this, ((this.monster_face) ? this.monster_face : this.moveto), 0.5, 500, 0.95);
880
881         vector real_angle = vectoangles(this.steerto) - this.angles;
882         float turny = 25;
883         if(this.state == MONSTER_ATTACK_MELEE)
884                 turny = 0;
885         if(turny)
886         {
887                 turny = bound(turny * -1, shortangle_f(real_angle.y, this.angles.y), turny);
888                 this.angles_y += turny;
889         }
890
891         Monster_Attack_Check(this, this.enemy);
892 }
893
894 void Monster_Remove(entity this)
895 {
896         if(IS_CLIENT(this))
897                 return; // don't remove it?
898
899         if(!this) { return; }
900
901         if(!MUTATOR_CALLHOOK(MonsterRemove, this))
902                 Send_Effect(EFFECT_ITEM_PICKUP, this.origin, '0 0 0', 1);
903
904         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
905         {
906                 .entity weaponentity = weaponentities[slot];
907                 if(this.(weaponentity))
908                         delete(this.(weaponentity));
909         }
910         if(this.iceblock) { delete(this.iceblock); }
911         WaypointSprite_Kill(this.sprite);
912         delete(this);
913 }
914
915 void Monster_Dead_Think(entity this)
916 {
917         this.nextthink = time + this.ticrate;
918
919         if(this.monster_lifetime != 0)
920         if(time >= this.monster_lifetime)
921         {
922                 Monster_Dead_Fade(this);
923                 return;
924         }
925 }
926
927 void Monster_Appear(entity this, entity actor, entity trigger)
928 {
929         this.enemy = actor;
930         Monster_Spawn(this, false, this.monsterid);
931 }
932
933 bool Monster_Appear_Check(entity this, int monster_id)
934 {
935         if(!(this.spawnflags & MONSTERFLAG_APPEAR))
936                 return false;
937
938         setthink(this, func_null);
939         this.monsterid = monster_id; // set so this monster is properly registered (otherwise, normal initialization is used)
940         this.nextthink = 0;
941         this.use = Monster_Appear;
942         this.flags = FL_MONSTER; // set so this monster can get butchered
943
944         return true;
945 }
946
947 void Monster_Reset(entity this)
948 {
949         setorigin(this, this.pos1);
950         this.angles = this.pos2;
951
952         Unfreeze(this); // remove any icy remains
953
954         this.health = this.max_health;
955         this.velocity = '0 0 0';
956         this.enemy = NULL;
957         this.goalentity = NULL;
958         this.attack_finished_single[0] = 0;
959         this.moveto = this.origin;
960 }
961
962 void Monster_Dead_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
963 {
964         this.health -= damage;
965
966         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
967
968         if(this.health <= -50) // 100 health until gone?
969         {
970                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
971
972                 // number of monsters spawned with mobspawn command
973                 totalspawned -= 1;
974
975                 setthink(this, SUB_Remove);
976                 this.nextthink = time + 0.1;
977                 this.event_damage = func_null;
978         }
979 }
980
981 void Monster_Dead(entity this, entity attacker, float gibbed)
982 {
983         setthink(this, Monster_Dead_Think);
984         this.nextthink = time;
985         this.monster_lifetime = time + 5;
986
987         if(STAT(FROZEN, this))
988         {
989                 Unfreeze(this); // remove any icy remains
990                 this.health = 0; // reset by Unfreeze
991         }
992
993         monster_dropitem(this, attacker);
994
995         Monster_Sound(this, monstersound_death, 0, false, CH_VOICE);
996
997         if(!(this.spawnflags & MONSTERFLAG_SPAWNED) && !(this.spawnflags & MONSTERFLAG_RESPAWNED))
998                 monsters_killed += 1;
999
1000         if(IS_PLAYER(attacker))
1001         if(autocvar_g_monsters_score_spawned || !((this.spawnflags & MONSTERFLAG_SPAWNED) || (this.spawnflags & MONSTERFLAG_RESPAWNED)))
1002                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
1003
1004         if(gibbed)
1005         {
1006                 // number of monsters spawned with mobspawn command
1007                 totalspawned -= 1;
1008         }
1009
1010         this.event_damage       = ((gibbed) ? func_null : Monster_Dead_Damage);
1011         this.solid                      = SOLID_CORPSE;
1012         this.takedamage         = DAMAGE_AIM;
1013         this.deadflag           = DEAD_DEAD;
1014         this.enemy                      = NULL;
1015         set_movetype(this, MOVETYPE_TOSS);
1016         this.moveto                     = this.origin;
1017         settouch(this, Monster_Touch); // reset incase monster was pouncing
1018         this.reset                      = func_null;
1019         this.state                      = 0;
1020         this.attack_finished_single[0] = 0;
1021         this.effects = 0;
1022
1023         if(!((this.flags & FL_FLY) || (this.flags & FL_SWIM)))
1024                 this.velocity = '0 0 0';
1025
1026         CSQCModel_UnlinkEntity(this);
1027
1028         Monster mon = Monsters_from(this.monsterid);
1029         mon.mr_death(mon, this);
1030
1031         if(this.candrop && this.weapon)
1032                 W_ThrowNewWeapon(this, this.weapon, 0, this.origin, randomvec() * 150 + '0 0 325');
1033 }
1034
1035 void Monster_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1036 {
1037         if((this.spawnflags & MONSTERFLAG_INVINCIBLE) && deathtype != DEATH_KILL.m_id && !ITEM_DAMAGE_NEEDKILL(deathtype))
1038                 return;
1039
1040         if(STAT(FROZEN, this) && deathtype != DEATH_KILL.m_id && deathtype != DEATH_NADE_ICE_FREEZE.m_id)
1041                 return;
1042
1043         //if(time < this.pain_finished && deathtype != DEATH_KILL.m_id)
1044                 //return;
1045
1046         if(time < this.spawnshieldtime && deathtype != DEATH_KILL.m_id)
1047                 return;
1048
1049         if(deathtype == DEATH_FALL.m_id && this.draggedby != NULL)
1050                 return;
1051
1052         vector v = healtharmor_applydamage(100, this.armorvalue / 100, deathtype, damage);
1053         float take = v.x;
1054         //float save = v.y;
1055
1056         Monster mon = Monsters_from(this.monsterid);
1057         take = mon.mr_pain(mon, this, take, attacker, deathtype);
1058
1059         if(take)
1060         {
1061                 this.health -= take;
1062                 Monster_Sound(this, monstersound_pain, 1.2, true, CH_PAIN);
1063         }
1064
1065         if(this.sprite)
1066                 WaypointSprite_UpdateHealth(this.sprite, this.health);
1067
1068         this.dmg_time = time;
1069
1070         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN.m_id)
1071                 spamsound (this, CH_PAIN, SND(BODYIMPACT1), VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
1072
1073         this.velocity += force * this.damageforcescale;
1074
1075         if(deathtype != DEATH_DROWN.m_id && take)
1076         {
1077                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, this, attacker);
1078                 if (take > 50)
1079                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
1080                 if (take > 100)
1081                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
1082         }
1083
1084         if(this.health <= 0)
1085         {
1086                 if(deathtype == DEATH_KILL.m_id)
1087                         this.candrop = false; // killed by mobkill command
1088
1089                 // TODO: fix this?
1090                 SUB_UseTargets(this, attacker, this.enemy);
1091                 this.target2 = this.oldtarget2; // reset to original target on death, incase we respawn
1092
1093                 Monster_Dead(this, attacker, (this.health <= -100 || deathtype == DEATH_KILL.m_id));
1094
1095                 WaypointSprite_Kill(this.sprite);
1096
1097                 MUTATOR_CALLHOOK(MonsterDies, this, attacker, deathtype);
1098
1099                 if(this.health <= -100 || deathtype == DEATH_KILL.m_id) // check if we're already gibbed
1100                 {
1101                         Violence_GibSplash(this, 1, 0.5, attacker);
1102
1103                         setthink(this, SUB_Remove);
1104                         this.nextthink = time + 0.1;
1105                 }
1106         }
1107 }
1108
1109 // don't check for enemies, just keep walking in a straight line
1110 void Monster_Move_2D(entity this, float mspeed, bool allow_jumpoff)
1111 {
1112         if(gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || this.draggedby != NULL || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < this.spawn_time)
1113         {
1114                 mspeed = 0;
1115                 if(time >= this.spawn_time)
1116                         setanim(this, this.anim_idle, true, false, false);
1117                 movelib_brake_simple(this, 0.6);
1118                 return;
1119         }
1120
1121         makevectors(this.angles);
1122         vector a = CENTER_OR_VIEWOFS(this);
1123         vector b = CENTER_OR_VIEWOFS(this) + v_forward * 32;
1124
1125         traceline(a, b, MOVE_NORMAL, this);
1126
1127         bool reverse = false;
1128         if(trace_fraction != 1.0)
1129                 reverse = true;
1130         if(trace_ent && IS_PLAYER(trace_ent) && !(trace_ent.items & ITEM_Strength.m_itemid))
1131                 reverse = false;
1132         if(trace_ent && IS_MONSTER(trace_ent))
1133                 reverse = true;
1134
1135         // TODO: fix this... tracing is broken if the floor is thin
1136         /*
1137         if(!allow_jumpoff)
1138         {
1139                 a = b - '0 0 32';
1140                 traceline(b, a, MOVE_WORLDONLY, this);
1141                 if(trace_fraction == 1.0)
1142                         reverse = true;
1143         } */
1144
1145         if(reverse)
1146         {
1147                 this.angles_y = anglemods(this.angles_y - 180);
1148                 makevectors(this.angles);
1149         }
1150
1151         movelib_move_simple_gravity(this, v_forward, mspeed, 1);
1152
1153         if(time > this.pain_finished && time > this.attack_finished_single[0])
1154         if(vdist(this.velocity, >, 10))
1155                 setanim(this, this.anim_walk, true, false, false);
1156         else
1157                 setanim(this, this.anim_idle, true, false, false);
1158 }
1159
1160 void Monster_Anim(entity this)
1161 {
1162         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
1163         if(IS_DEAD(this))
1164         {
1165                 if (!deadbits)
1166                 {
1167                         // Decide on which death animation to use.
1168                         if(random() < 0.5)
1169                                 deadbits = ANIMSTATE_DEAD1;
1170                         else
1171                                 deadbits = ANIMSTATE_DEAD2;
1172                 }
1173         }
1174         else
1175         {
1176                 // Clear a previous death animation.
1177                 deadbits = 0;
1178         }
1179         int animbits = deadbits;
1180         if(STAT(FROZEN, this))
1181                 animbits |= ANIMSTATE_FROZEN;
1182         if(this.crouch)
1183                 animbits |= ANIMSTATE_DUCK; // not that monsters can crouch currently...
1184         animdecide_setstate(this, animbits, false);
1185         animdecide_setimplicitstate(this, (IS_ONGROUND(this)));
1186
1187         /* // weapon entities for monsters?
1188         if (this.weaponentity)
1189         {
1190                 updateanim(this.weaponentity);
1191                 if (!this.weaponentity.animstate_override)
1192                         setanim(this.weaponentity, this.weaponentity.anim_idle, true, false, false);
1193         }
1194         */
1195 }
1196
1197 void Monster_Think(entity this)
1198 {
1199         setthink(this, Monster_Think);
1200         this.nextthink = time + this.ticrate;
1201
1202         if(this.monster_lifetime && time >= this.monster_lifetime)
1203         {
1204                 Damage(this, this, this, this.health + this.max_health, DEATH_KILL.m_id, this.origin, this.origin);
1205                 return;
1206         }
1207
1208         Monster mon = Monsters_from(this.monsterid);
1209         if(mon.mr_think(mon, this))
1210                 Monster_Move(this, this.speed2, this.speed, this.stopspeed);
1211
1212         Monster_Anim(this);
1213
1214         CSQCMODEL_AUTOUPDATE(this);
1215 }
1216
1217 bool Monster_Spawn_Setup(entity this)
1218 {
1219         Monster mon = Monsters_from(this.monsterid);
1220         mon.mr_setup(mon, this);
1221
1222         // ensure some basic needs are met
1223         if(!this.health) { this.health = 100; }
1224         if(!this.armorvalue) { this.armorvalue = bound(0.2, 0.5 * MONSTER_SKILLMOD(this), 0.9); }
1225         if(!this.target_range) { this.target_range = autocvar_g_monsters_target_range; }
1226         if(!this.respawntime) { this.respawntime = autocvar_g_monsters_respawn_delay; }
1227         if(!this.monster_moveflags) { this.monster_moveflags = MONSTER_MOVE_WANDER; }
1228         if(!this.attack_range) { this.attack_range = autocvar_g_monsters_attack_range; }
1229         if(!this.damageforcescale) { this.damageforcescale = autocvar_g_monsters_damageforcescale; }
1230
1231         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1232         {
1233                 Monster_Miniboss_Check(this);
1234                 this.health *= MONSTER_SKILLMOD(this);
1235
1236                 if(!this.skin)
1237                         this.skin = rint(random() * 4);
1238         }
1239
1240         this.max_health = this.health;
1241         this.pain_finished = this.nextthink;
1242
1243         if(IS_PLAYER(this.monster_follow))
1244                 this.effects |= EF_DIMLIGHT;
1245
1246         if(!this.wander_delay) { this.wander_delay = 2; }
1247         if(!this.wander_distance) { this.wander_distance = 600; }
1248
1249         Monster_Sounds_Precache(this);
1250         Monster_Sounds_Update(this);
1251
1252         if(teamplay)
1253                 this.monster_attack = true; // we can have monster enemies in team games
1254
1255         Monster_Sound(this, monstersound_spawn, 0, false, CH_VOICE);
1256
1257         if(autocvar_g_monsters_healthbars)
1258         {
1259                 entity wp = WaypointSprite_Spawn(WP_Monster, 0, 1024, this, '0 0 1' * (this.maxs.z + 15), NULL, this.team, this, sprite, true, RADARICON_DANGER);
1260                 wp.wp_extra = this.monsterid;
1261                 wp.colormod = ((this.team) ? Team_ColorRGB(this.team) : '1 0 0');
1262                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE))
1263                 {
1264                         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
1265                         WaypointSprite_UpdateHealth(this.sprite, this.health);
1266                 }
1267         }
1268
1269         setthink(this, Monster_Think);
1270         this.nextthink = time + this.ticrate;
1271
1272         if(MUTATOR_CALLHOOK(MonsterSpawn, this))
1273                 return false;
1274
1275         return true;
1276 }
1277
1278 bool Monster_Spawn(entity this, bool check_appear, int mon_id)
1279 {
1280         // setup the basic required properties for a monster
1281         entity mon = Monsters_from(mon_id);
1282         if(!mon.monsterid) { return false; } // invalid monster
1283
1284         if(!autocvar_g_monsters) { Monster_Remove(this); return false; }
1285
1286         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1287                 IL_PUSH(g_monsters, this);
1288
1289         if(check_appear && Monster_Appear_Check(this, mon_id)) { return true; } // return true so the monster isn't removed
1290
1291         if(!this.monster_skill)
1292                 this.monster_skill = cvar("g_monsters_skill");
1293
1294         // support for quake style removing monsters based on skill
1295         if(this.monster_skill == MONSTER_SKILL_EASY) if(this.spawnflags & MONSTERSKILL_NOTEASY) { Monster_Remove(this); return false; }
1296         if(this.monster_skill == MONSTER_SKILL_MEDIUM) if(this.spawnflags & MONSTERSKILL_NOTMEDIUM) { Monster_Remove(this); return false; }
1297         if(this.monster_skill == MONSTER_SKILL_HARD) if(this.spawnflags & MONSTERSKILL_NOTHARD) { Monster_Remove(this); return false; }
1298
1299         if(this.team && !teamplay)
1300                 this.team = 0;
1301
1302         if(!(this.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1303         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED)) // don't count re-spawning monsters either
1304                 monsters_total += 1;
1305
1306         setmodel(this, mon.m_model);
1307         this.flags                              = FL_MONSTER;
1308         this.classname                  = "monster";
1309         this.takedamage                 = DAMAGE_AIM;
1310         if(!this.bot_attack)
1311                 IL_PUSH(g_bot_targets, this);
1312         this.bot_attack                 = true;
1313         this.iscreature                 = true;
1314         this.teleportable               = true;
1315         if(!this.damagedbycontents)
1316                 IL_PUSH(g_damagedbycontents, this);
1317         this.damagedbycontents  = true;
1318         this.monsterid                  = mon_id;
1319         this.event_damage               = Monster_Damage;
1320         settouch(this, Monster_Touch);
1321         this.use                                = Monster_Use;
1322         this.solid                              = SOLID_BBOX;
1323         set_movetype(this, MOVETYPE_WALK);
1324         this.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1325         this.enemy                              = NULL;
1326         this.velocity                   = '0 0 0';
1327         this.moveto                             = this.origin;
1328         this.pos1                               = this.origin;
1329         this.pos2                               = this.angles;
1330         this.reset                              = Monster_Reset;
1331         this.netname                    = mon.netname;
1332         this.monster_attackfunc = mon.monster_attackfunc;
1333         this.monster_name               = mon.monster_name;
1334         this.candrop                    = true;
1335         this.view_ofs                   = '0 0 0.7' * (this.maxs_z * 0.5);
1336         this.oldtarget2                 = this.target2;
1337         this.pass_distance              = 0;
1338         this.deadflag                   = DEAD_NO;
1339         this.spawn_time                 = time;
1340         this.gravity                    = 1;
1341         this.monster_moveto             = '0 0 0';
1342         this.monster_face               = '0 0 0';
1343         this.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1344
1345         if(!this.noalign) { this.noalign = ((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM)); }
1346         if(!this.scale) { this.scale = 1; }
1347         if(autocvar_g_monsters_edit) { this.grab = 1; }
1348         if(autocvar_g_fullbrightplayers) { this.effects |= EF_FULLBRIGHT; }
1349         if(autocvar_g_nodepthtestplayers) { this.effects |= EF_NODEPTHTEST; }
1350         if(mon.spawnflags & MONSTER_TYPE_SWIM) { this.flags |= FL_SWIM; }
1351
1352         if(autocvar_g_playerclip_collisions)
1353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1354
1355         if(mon.spawnflags & MONSTER_TYPE_FLY)
1356         {
1357                 this.flags |= FL_FLY;
1358                 set_movetype(this, MOVETYPE_FLY);
1359         }
1360
1361         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1362         {
1363                 if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1364                         this.scale *= 1.3;
1365
1366                 if(mon.spawnflags & MONSTER_SIZE_QUAKE)
1367                 if(autocvar_g_monsters_quake_resize)
1368                         this.scale *= 1.3;
1369         }
1370
1371         setsize(this, mon.mins * this.scale, mon.maxs * this.scale);
1372
1373         this.ticrate = bound(sys_frametime, ((!this.ticrate) ? autocvar_g_monsters_think_delay : this.ticrate), 60);
1374
1375         Monster_UpdateModel(this);
1376
1377         if(!Monster_Spawn_Setup(this))
1378         {
1379                 Monster_Remove(this);
1380                 return false;
1381         }
1382
1383         if(!this.noalign)
1384         {
1385                 setorigin(this, this.origin + '0 0 20');
1386                 tracebox(this.origin + '0 0 64', this.mins, this.maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1387                 setorigin(this, trace_endpos);
1388         }
1389
1390         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1391                 monster_setupcolors(this);
1392
1393         CSQCMODEL_AUTOINIT(this);
1394
1395         return true;
1396 }