Fix a couple of wrong type fields
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / monsters / sv_monsters.qc
1 #include "sv_monsters.qh"
2
3 #include <lib/warpzone/common.qh>
4 #include "../constants.qh"
5 #include "../teams.qh"
6 #include "../util.qh"
7 #include "all.qh"
8 #include "../physics/movelib.qh"
9 #include "../weapons/_mod.qh"
10 #include <server/autocvars.qh>
11 #include <server/defs.qh>
12 #include "../deathtypes/all.qh"
13 #include <server/mutators/_mod.qh>
14 #include <server/steerlib.qh>
15 #include "../turrets/sv_turrets.qh"
16 #include "../turrets/util.qh"
17 #include "../vehicles/all.qh"
18 #include <server/campaign.qh>
19 #include <server/command/_mod.qh>
20 #include "../mapobjects/triggers.qh"
21 #include <lib/csqcmodel/sv_model.qh>
22 #include <server/round_handler.qh>
23 #include <server/weapons/_mod.qh>
24
25 void monsters_setstatus(entity this)
26 {
27         STAT(MONSTERS_TOTAL, this) = monsters_total;
28         STAT(MONSTERS_KILLED, this) = monsters_killed;
29 }
30
31 void monster_dropitem(entity this, entity attacker)
32 {
33         if(!this.candrop || !this.monster_loot)
34                 return;
35
36         vector org = CENTER_OR_VIEWOFS(this);
37         entity e = spawn();
38         Item_SetLoot(e, true);
39         e.spawnfunc_checked = true;
40
41         e.monster_loot = this.monster_loot;
42
43         MUTATOR_CALLHOOK(MonsterDropItem, this, e, attacker);
44         e = M_ARGV(1, entity);
45
46         if(e && e.monster_loot)
47         {
48                 e.noalign = true;
49                 StartItem(e, e.monster_loot);
50                 e.gravity = 1;
51                 setorigin(e, org);
52                 e.velocity = randomvec() * 175 + '0 0 325';
53                 e.item_spawnshieldtime = time + 0.7;
54                 SUB_SetFade(e, time + autocvar_g_monsters_drop_time, 1);
55         }
56 }
57
58 void monster_makevectors(entity this, entity targ)
59 {
60         if(IS_MONSTER(this))
61         {
62                 vector v = targ.origin + (targ.mins + targ.maxs) * 0.5;
63                 this.v_angle = vectoangles(v - (this.origin + this.view_ofs));
64                 this.v_angle_x = -this.v_angle_x;
65         }
66
67         makevectors(this.v_angle);
68 }
69
70 // ===============
71 // Target handling
72 // ===============
73
74 bool Monster_ValidTarget(entity this, entity targ)
75 {
76         // ensure we're not checking nonexistent monster/target
77         if(!this || !targ) { return false; }
78
79         if((targ == this)
80         || (autocvar_g_monsters_lineofsight && !checkpvs(this.origin + this.view_ofs, targ)) // enemy cannot be seen
81         || (IS_VEHICLE(targ) && !((Monsters_from(this.monsterid)).spawnflags & MON_FLAG_RANGED)) // melee vs vehicle is useless
82         || (time < game_starttime) // monsters do nothing before match has started
83         || (targ.takedamage == DAMAGE_NO)
84         || (game_stopped)
85         || (targ.items & IT_INVISIBILITY)
86         || (IS_SPEC(targ) || IS_OBSERVER(targ)) // don't attack spectators
87         || (!IS_VEHICLE(targ) && (IS_DEAD(targ) || IS_DEAD(this) || GetResourceAmount(targ, RESOURCE_HEALTH) <= 0 || GetResourceAmount(this, RESOURCE_HEALTH) <= 0))
88         || (this.monster_follow == targ || targ.monster_follow == this)
89         || (!IS_VEHICLE(targ) && (targ.flags & FL_NOTARGET))
90         || (!autocvar_g_monsters_typefrag && PHYS_INPUT_BUTTON_CHAT(targ))
91         || (SAME_TEAM(targ, this))
92         || (STAT(FROZEN, targ))
93         || (targ.alpha != 0 && targ.alpha < 0.5)
94         || (MUTATOR_CALLHOOK(MonsterValidTarget, this, targ))
95         )
96         {
97                 // if any of the above checks fail, target is not valid
98                 return false;
99         }
100
101         vector targ_origin = ((targ.absmin + targ.absmax) * 0.5);
102         traceline(this.origin + this.view_ofs, targ_origin, MOVE_NOMONSTERS, this);
103
104         if(trace_fraction < 1 && trace_ent != targ)
105                 return false; // solid
106
107         if(autocvar_g_monsters_target_infront || (this.spawnflags & MONSTERFLAG_INFRONT))
108         if(this.enemy != targ)
109         {
110                 makevectors (this.angles);
111                 float dot = normalize (targ.origin - this.origin) * v_forward;
112
113                 if(dot <= autocvar_g_monsters_target_infront_range) { return false; }
114         }
115
116         return true; // this target is valid!
117 }
118
119 entity Monster_FindTarget(entity this)
120 {
121         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return this.enemy; } // Handled by a mutator
122
123         entity closest_target = NULL;
124         vector my_center = CENTER_OR_VIEWOFS(this);
125
126         // find the closest acceptable target to pass to
127         IL_EACH(g_monster_targets, it.monster_attack && vdist(it.origin - this.origin, <, this.target_range),
128         {
129                 if(Monster_ValidTarget(this, it))
130                 {
131                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
132                         vector targ_center = CENTER_OR_VIEWOFS(it);
133
134                         if(closest_target)
135                         {
136                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
137                                 if(vlen2(my_center - targ_center) < vlen2(my_center - closest_target_center))
138                                         { closest_target = it; }
139                         }
140                         else { closest_target = it; }
141                 }
142         });
143
144         return closest_target;
145 }
146
147 void monster_setupcolors(entity this)
148 {
149         if(IS_PLAYER(this.realowner))
150                 this.colormap = this.realowner.colormap;
151         else if(teamplay && this.team)
152                 this.colormap = 1024 + (this.team - 1) * 17;
153         else
154         {
155                 if(this.monster_skill <= MONSTER_SKILL_EASY)
156                         this.colormap = 1029;
157                 else if(this.monster_skill <= MONSTER_SKILL_MEDIUM)
158                         this.colormap = 1027;
159                 else if(this.monster_skill <= MONSTER_SKILL_HARD)
160                         this.colormap = 1038;
161                 else if(this.monster_skill <= MONSTER_SKILL_INSANE)
162                         this.colormap = 1028;
163                 else if(this.monster_skill <= MONSTER_SKILL_NIGHTMARE)
164                         this.colormap = 1032;
165                 else
166                         this.colormap = 1024;
167         }
168 }
169
170 void monster_changeteam(entity this, int newteam)
171 {
172         if(!teamplay) { return; }
173
174         this.team = newteam;
175         if(!this.monster_attack)
176                 IL_PUSH(g_monster_targets, this);
177         this.monster_attack = true; // new team, activate attacking
178         monster_setupcolors(this);
179
180         if(this.sprite)
181         {
182                 WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DANGER, ((newteam) ? Team_ColorRGB(newteam) : '1 0 0'));
183
184                 this.sprite.team = newteam;
185                 this.sprite.SendFlags |= 1;
186         }
187 }
188
189 .void(entity) monster_delayedfunc;
190 void Monster_Delay_Action(entity this)
191 {
192         if(Monster_ValidTarget(this.owner, this.owner.enemy)) { this.monster_delayedfunc(this.owner); }
193
194         if(this.cnt > 1)
195         {
196                 this.cnt -= 1;
197                 setthink(this, Monster_Delay_Action);
198                 this.nextthink = time + this.count;
199         }
200         else
201         {
202                 setthink(this, SUB_Remove);
203                 this.nextthink = time;
204         }
205 }
206
207 void Monster_Delay(entity this, int repeat_count, float defer_amnt, void(entity) func)
208 {
209         // deferred attacking, checks if monster is still alive and target is still valid before attacking
210         entity e = spawn();
211
212         setthink(e, Monster_Delay_Action);
213         e.nextthink = time + defer_amnt;
214         e.count = defer_amnt;
215         e.owner = this;
216         e.monster_delayedfunc = func;
217         e.cnt = repeat_count;
218 }
219
220
221 // ==============
222 // Monster sounds
223 // ==============
224
225 string get_monster_model_datafilename(string m, float sk, string fil)
226 {
227         if(m)
228                 m = strcat(m, "_");
229         else
230                 m = "models/monsters/*_";
231         if(sk >= 0)
232                 m = strcat(m, ftos(sk));
233         else
234                 m = strcat(m, "*");
235         return strcat(m, ".", fil);
236 }
237
238 void Monster_Sound_Precache(string f)
239 {
240         float fh;
241         string s;
242         fh = fopen(f, FILE_READ);
243         if(fh < 0)
244                 return;
245         while((s = fgets(fh)))
246         {
247                 if(tokenize_console(s) != 3)
248                 {
249                         //LOG_DEBUG("Invalid sound info line: ", s); // probably a comment, no need to spam warnings
250                         continue;
251                 }
252                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
253         }
254         fclose(fh);
255 }
256
257 void Monster_Sounds_Precache(entity this)
258 {
259         string m = (Monsters_from(this.monsterid)).m_model.model_str();
260         float globhandle, n, i;
261         string f;
262
263         globhandle = search_begin(strcat(m, "_*.sounds"), true, false);
264         if (globhandle < 0)
265                 return;
266         n = search_getsize(globhandle);
267         for (i = 0; i < n; ++i)
268         {
269                 //print(search_getfilename(globhandle, i), "\n");
270                 f = search_getfilename(globhandle, i);
271                 Monster_Sound_Precache(f);
272         }
273         search_end(globhandle);
274 }
275
276 void Monster_Sounds_Clear(entity this)
277 {
278 #define _MSOUND(m) strfree(this.monstersound_##m);
279         ALLMONSTERSOUNDS
280 #undef _MSOUND
281 }
282
283 .string Monster_Sound_SampleField(string type)
284 {
285         GetMonsterSoundSampleField_notFound = 0;
286         switch(type)
287         {
288 #define _MSOUND(m) case #m: return monstersound_##m;
289                 ALLMONSTERSOUNDS
290 #undef _MSOUND
291         }
292         GetMonsterSoundSampleField_notFound = 1;
293         return string_null;
294 }
295
296 bool Monster_Sounds_Load(entity this, string f, int first)
297 {
298         string s;
299         var .string field;
300         float fh = fopen(f, FILE_READ);
301         if(fh < 0)
302         {
303                 //LOG_DEBUG("Monster sound file not found: ", f); // no biggie, monster has no sounds, let's not spam it
304                 return false;
305         }
306         while((s = fgets(fh)))
307         {
308                 if(tokenize_console(s) != 3)
309                         continue;
310                 field = Monster_Sound_SampleField(argv(0));
311                 if(GetMonsterSoundSampleField_notFound)
312                         continue;
313                 strcpy(this.(field), strcat(argv(1), " ", argv(2)));
314         }
315         fclose(fh);
316         return true;
317 }
318
319 .int skin_for_monstersound;
320 void Monster_Sounds_Update(entity this)
321 {
322         if(this.skin == this.skin_for_monstersound) { return; }
323
324         this.skin_for_monstersound = this.skin;
325         Monster_Sounds_Clear(this);
326         if(!Monster_Sounds_Load(this, get_monster_model_datafilename(this.model, this.skin, "sounds"), 0))
327                 Monster_Sounds_Load(this, get_monster_model_datafilename(this.model, 0, "sounds"), 0);
328 }
329
330 void Monster_Sound(entity this, .string samplefield, float sound_delay, bool delaytoo, float chan)
331 {
332         if(!autocvar_g_monsters_sounds) { return; }
333
334         if(delaytoo)
335         if(time < this.msound_delay)
336                 return; // too early
337         string sample = this.(samplefield);
338         if (sample != "") sample = GlobalSound_sample(sample, random());
339         float myscale = ((this.scale) ? this.scale : 1); // safety net
340         // TODO: change volume depending on size too?
341         sound7(this, chan, sample, VOL_BASE, ATTEN_NORM, 100 / myscale, 0);
342
343         this.msound_delay = time + sound_delay;
344 }
345
346
347 // =======================
348 // Monster attack handlers
349 // =======================
350
351 bool Monster_Attack_Melee(entity this, entity targ, float damg, vector anim, float er, float animtime, int deathtype, bool dostop)
352 {
353         if(dostop && IS_MONSTER(this)) { this.state = MONSTER_ATTACK_MELEE; }
354
355         setanim(this, anim, false, true, false);
356
357         if(this.animstate_endtime > time && IS_MONSTER(this))
358                 this.attack_finished_single[0] = this.anim_finished = this.animstate_endtime;
359         else
360                 this.attack_finished_single[0] = this.anim_finished = time + animtime;
361
362         monster_makevectors(this, targ);
363
364         traceline(this.origin + this.view_ofs, this.origin + v_forward * er, 0, this);
365
366         if(trace_ent.takedamage)
367                 Damage(trace_ent, this, this, damg * MONSTER_SKILLMOD(this), deathtype, DMG_NOWEP, trace_ent.origin, normalize(trace_ent.origin - this.origin));
368
369         return true;
370 }
371
372 bool Monster_Attack_Leap_Check(entity this, vector vel)
373 {
374         if(this.state && IS_MONSTER(this))
375                 return false; // already attacking
376         if(!IS_ONGROUND(this))
377                 return false; // not on the ground
378         if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0 || IS_DEAD(this))
379                 return false; // called when dead?
380         if(time < this.attack_finished_single[0])
381                 return false; // still attacking
382
383         vector old = this.velocity;
384
385         this.velocity = vel;
386         tracetoss(this, this);
387         this.velocity = old;
388         if(trace_ent != this.enemy)
389                 return false;
390
391         return true;
392 }
393
394 bool Monster_Attack_Leap(entity this, vector anm, void(entity this, entity toucher) touchfunc, vector vel, float animtime)
395 {
396         if(!Monster_Attack_Leap_Check(this, vel))
397                 return false;
398
399         setanim(this, anm, false, true, false);
400
401         if(this.animstate_endtime > time && IS_MONSTER(this))
402                 this.attack_finished_single[0] = this.anim_finished = this.animstate_endtime;
403         else
404                 this.attack_finished_single[0] = this.anim_finished = time + animtime;
405
406         if(IS_MONSTER(this))
407                 this.state = MONSTER_ATTACK_RANGED;
408         settouch(this, touchfunc);
409         this.origin_z += 1;
410         this.velocity = vel;
411         UNSET_ONGROUND(this);
412
413         return true;
414 }
415
416 void Monster_Attack_Check(entity this, entity targ, .entity weaponentity)
417 {
418         int slot = weaponslot(weaponentity);
419
420         if((!this || !targ)
421         || (!this.monster_attackfunc)
422         || (time < this.attack_finished_single[slot])
423         ) { return; }
424
425         if(vdist(targ.origin - this.origin, <=, this.attack_range))
426         {
427                 int attack_success = this.monster_attackfunc(MONSTER_ATTACK_MELEE, this, targ, weaponentity);
428                 if(attack_success == 1)
429                         Monster_Sound(this, monstersound_melee, 0, false, CH_VOICE);
430                 else if(attack_success > 0)
431                         return;
432         }
433
434         if(vdist(targ.origin - this.origin, >, this.attack_range))
435         {
436                 int attack_success = this.monster_attackfunc(MONSTER_ATTACK_RANGED, this, targ, weaponentity);
437                 if(attack_success == 1)
438                         Monster_Sound(this, monstersound_melee, 0, false, CH_VOICE);
439                 else if(attack_success > 0)
440                         return;
441         }
442 }
443
444
445 // ======================
446 // Main monster functions
447 // ======================
448
449 void Monster_UpdateModel(entity this)
450 {
451         // assume some defaults
452         /*this.anim_idle   = animfixfps(this, '0 1 0.01', '0 0 0');
453         this.anim_walk   = animfixfps(this, '1 1 0.01', '0 0 0');
454         this.anim_run    = animfixfps(this, '2 1 0.01', '0 0 0');
455         this.anim_fire1  = animfixfps(this, '3 1 0.01', '0 0 0');
456         this.anim_fire2  = animfixfps(this, '4 1 0.01', '0 0 0');
457         this.anim_melee  = animfixfps(this, '5 1 0.01', '0 0 0');
458         this.anim_pain1  = animfixfps(this, '6 1 0.01', '0 0 0');
459         this.anim_pain2  = animfixfps(this, '7 1 0.01', '0 0 0');
460         this.anim_die1   = animfixfps(this, '8 1 0.01', '0 0 0');
461         this.anim_die2   = animfixfps(this, '9 1 0.01', '0 0 0');*/
462
463         // then get the real values
464         Monster mon = Monsters_from(this.monsterid);
465         mon.mr_anim(mon, this);
466 }
467
468 void Monster_Touch(entity this, entity toucher)
469 {
470         if(toucher == NULL) { return; }
471
472         if(toucher.monster_attack)
473         if(this.enemy != toucher)
474         if(!IS_MONSTER(toucher))
475         if(Monster_ValidTarget(this, toucher))
476                 this.enemy = toucher;
477 }
478
479 void Monster_Miniboss_Check(entity this)
480 {
481         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag, this))
482                 return;
483
484         float chance = random() * 100;
485
486         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
487         if ((this.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
488         {
489                 GiveResource(this, RESOURCE_HEALTH, autocvar_g_monsters_miniboss_healthboost);
490                 this.effects |= EF_RED;
491                 if(!this.weapon)
492                         this.weapon = WEP_VORTEX.m_id;
493         }
494 }
495
496 bool Monster_Respawn_Check(entity this)
497 {
498         if(this.deadflag == DEAD_DEAD) // don't call when monster isn't dead
499         if(MUTATOR_CALLHOOK(MonsterRespawn, this))
500                 return true; // enabled by a mutator
501
502         if(this.spawnflags & MONSTERFLAG_NORESPAWN)
503                 return false;
504
505         if(!autocvar_g_monsters_respawn)
506                 return false;
507
508         return true;
509 }
510
511 void Monster_Respawn(entity this) { Monster_Spawn(this, true, this.monsterid); }
512
513 .vector pos1, pos2;
514
515 void Monster_Dead_Fade(entity this)
516 {
517         if(Monster_Respawn_Check(this))
518         {
519                 this.spawnflags |= MONSTERFLAG_RESPAWNED;
520                 setthink(this, Monster_Respawn);
521                 this.nextthink = time + this.respawntime;
522                 this.monster_lifetime = 0;
523                 this.deadflag = DEAD_RESPAWNING;
524                 if(this.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
525                 {
526                         this.pos1 = this.origin;
527                         this.pos2 = this.angles;
528                 }
529                 this.event_damage = func_null;
530                 this.event_heal = func_null;
531                 this.takedamage = DAMAGE_NO;
532                 setorigin(this, this.pos1);
533                 this.angles = this.pos2;
534                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, this.max_health);
535                 setmodel(this, MDL_Null);
536         }
537         else
538         {
539                 // number of monsters spawned with mobspawn command
540                 totalspawned -= 1;
541
542                 SUB_SetFade(this, time + 3, 1);
543         }
544 }
545
546 void Monster_Use(entity this, entity actor, entity trigger)
547 {
548         if(Monster_ValidTarget(this, actor)) { this.enemy = actor; }
549 }
550
551 .float pass_distance;
552 vector Monster_Move_Target(entity this, entity targ)
553 {
554         // enemy is always preferred target
555         if(this.enemy)
556         {
557                 vector targ_origin = ((this.enemy.absmin + this.enemy.absmax) * 0.5);
558                 targ_origin = WarpZone_RefSys_TransformOrigin(this.enemy, this, targ_origin); // origin of target as seen by the monster (us)
559                 WarpZone_TraceLine(this.origin, targ_origin, MOVE_NOMONSTERS, this);
560
561                 // cases where the enemy may have changed their state (don't need to check everything here)
562                 if((!this.enemy)
563                         || (IS_DEAD(this.enemy) || GetResourceAmount(this.enemy, RESOURCE_HEALTH) < 1)
564                         || (STAT(FROZEN, this.enemy))
565                         || (this.enemy.flags & FL_NOTARGET)
566                         || (this.enemy.alpha < 0.5 && this.enemy.alpha != 0)
567                         || (this.enemy.takedamage == DAMAGE_NO)
568                         || (vdist(this.origin - targ_origin, >, this.target_range))
569                         || ((trace_fraction < 1) && (trace_ent != this.enemy)))
570                 {
571                         this.enemy = NULL;
572                         //this.pass_distance = 0;
573                 }
574
575                 if(this.enemy)
576                 {
577                         /*WarpZone_TrailParticles(NULL, particleeffectnum(EFFECT_RED_PASS), this.origin, targ_origin);
578                         print("Trace origin: ", vtos(targ_origin), "\n");
579                         print("Target origin: ", vtos(this.enemy.origin), "\n");
580                         print("My origin: ", vtos(this.origin), "\n"); */
581
582                         this.monster_movestate = MONSTER_MOVE_ENEMY;
583                         this.last_trace = time + 1.2;
584                         if(this.monster_moveto)
585                                 return this.monster_moveto; // assumes code is properly setting this when monster has an enemy
586                         else
587                                 return targ_origin;
588                 }
589
590                 /*makevectors(this.angles);
591                 this.monster_movestate = MONSTER_MOVE_ENEMY;
592                 this.last_trace = time + 1.2;
593                 return this.enemy.origin; */
594         }
595
596         switch(this.monster_moveflags)
597         {
598                 case MONSTER_MOVE_FOLLOW:
599                 {
600                         this.monster_movestate = MONSTER_MOVE_FOLLOW;
601                         this.last_trace = time + 0.3;
602                         return (this.monster_follow) ? this.monster_follow.origin : this.origin;
603                 }
604                 case MONSTER_MOVE_SPAWNLOC:
605                 {
606                         this.monster_movestate = MONSTER_MOVE_SPAWNLOC;
607                         this.last_trace = time + 2;
608                         return this.pos1;
609                 }
610                 case MONSTER_MOVE_NOMOVE:
611                 {
612                         if(this.monster_moveto)
613                         {
614                                 this.last_trace = time + 0.5;
615                                 return this.monster_moveto;
616                         }
617                         else
618                         {
619                                 this.monster_movestate = MONSTER_MOVE_NOMOVE;
620                                 this.last_trace = time + 2;
621                         }
622                         return this.origin;
623                 }
624                 default:
625                 case MONSTER_MOVE_WANDER:
626                 {
627                         vector pos;
628                         this.monster_movestate = MONSTER_MOVE_WANDER;
629
630                         if(this.monster_moveto)
631                         {
632                                 this.last_trace = time + 0.5;
633                                 pos = this.monster_moveto;
634                         }
635                         else if(targ)
636                         {
637                                 this.last_trace = time + 0.5;
638                                 pos = targ.origin;
639                         }
640                         else
641                         {
642                                 this.last_trace = time + this.wander_delay;
643
644                                 this.angles_y = rint(random() * 500);
645                                 makevectors(this.angles);
646                                 pos = this.origin + v_forward * this.wander_distance;
647
648                                 if(((this.flags & FL_FLY) && (this.spawnflags & MONSTERFLAG_FLY_VERTICAL)) || (this.flags & FL_SWIM))
649                                 {
650                                         pos.z = random() * 200;
651                                         if(random() >= 0.5)
652                                                 pos.z *= -1;
653                                 }
654                         }
655
656                         return pos;
657                 }
658         }
659 }
660
661 void Monster_CalculateVelocity(entity this, vector to, vector from, float turnrate, float movespeed)
662 {
663         //float current_distance = vlen((('1 0 0' * to.x) + ('0 1 0' * to.y)) - (('1 0 0' * from.x) + ('0 1 0' * from.y))); // for the sake of this check, exclude Z axis
664         //float initial_height = 0; //min(50, (targ_distance * tanh(20)));
665         //float current_height = (initial_height * min(1, (this.pass_distance) ? (current_distance / this.pass_distance) : current_distance));
666         //print("current_height = ", ftos(current_height), ", initial_height = ", ftos(initial_height), ".\n");
667
668         vector targpos = to;
669 #if 0
670         if(current_height) // make sure we can actually do this arcing path
671         {
672                 targpos = (to + ('0 0 1' * current_height));
673                 WarpZone_TraceLine(this.origin, targpos, MOVE_NOMONSTERS, this);
674                 if(trace_fraction < 1)
675                 {
676                         //print("normal arc line failed, trying to find new pos...");
677                         WarpZone_TraceLine(to, targpos, MOVE_NOMONSTERS, this);
678                         targpos = (trace_endpos + '0 0 -10');
679                         WarpZone_TraceLine(this.origin, targpos, MOVE_NOMONSTERS, this);
680                         if(trace_fraction < 1) { targpos = to; /* print(" ^1FAILURE^7, reverting to original direction.\n"); */ }
681                         /*else { print(" ^3SUCCESS^7, using new arc line.\n"); } */
682                 }
683         }
684         else { targpos = to; }
685 #endif
686
687         //this.angles = normalize(('0 1 0' * to_y) - ('0 1 0' * from_y));
688
689         vector desired_direction = normalize(targpos - from);
690         if(turnrate) { this.velocity = (normalize(normalize(this.velocity) + (desired_direction * 50)) * movespeed); }
691         else { this.velocity = (desired_direction * movespeed); }
692
693         //this.steerto = steerlib_attract2(targpos, 0.5, 500, 0.95);
694         //this.angles = vectoangles(this.velocity);
695 }
696
697 .entity draggedby;
698
699 void Monster_Move(entity this, float runspeed, float walkspeed, float stpspeed)
700 {
701         // update goal entity if lost
702         if(this.target2 && this.target2 != "" && this.goalentity.targetname != this.target2)
703                 this.goalentity = find(NULL, targetname, this.target2);
704
705         if(STAT(FROZEN, this))
706         {
707                 movelib_brake_simple(this, stpspeed);
708                 setanim(this, this.anim_idle, true, false, false);
709                 return; // no physics while frozen!
710         }
711
712         if(this.flags & FL_SWIM)
713         {
714                 if(this.waterlevel < WATERLEVEL_WETFEET)
715                 {
716                         if(time >= this.last_trace)
717                         {
718                                 this.last_trace = time + 0.4;
719
720                                 Damage (this, NULL, NULL, 2, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
721                                 this.angles = '90 90 0';
722                                 if(random() < 0.5)
723                                 {
724                                         this.velocity_y += random() * 50;
725                                         this.velocity_x -= random() * 50;
726                                 }
727                                 else
728                                 {
729                                         this.velocity_y -= random() * 50;
730                                         this.velocity_x += random() * 50;
731                                 }
732                                 this.velocity_z += random() * 150;
733                         }
734
735
736                         set_movetype(this, MOVETYPE_BOUNCE);
737                         //this.velocity_z = -200;
738
739                         return;
740                 }
741                 else if(this.move_movetype == MOVETYPE_BOUNCE)
742                 {
743                         this.angles_x = 0;
744                         set_movetype(this, MOVETYPE_WALK);
745                 }
746         }
747
748         entity targ = this.goalentity;
749
750         if (MUTATOR_CALLHOOK(MonsterMove, this, runspeed, walkspeed, targ)
751                 || game_stopped
752                 || this.draggedby != NULL
753                 || (round_handler_IsActive() && !round_handler_IsRoundStarted())
754                 || time < game_starttime
755                 || (autocvar_g_campaign && !campaign_bots_may_start)
756                 || time < this.spawn_time)
757         {
758                 runspeed = walkspeed = 0;
759                 if(time >= this.spawn_time)
760                         setanim(this, this.anim_idle, true, false, false);
761                 movelib_brake_simple(this, stpspeed);
762                 return;
763         }
764
765         targ = M_ARGV(3, entity);
766         runspeed = bound(0, M_ARGV(1, float) * MONSTER_SKILLMOD(this), runspeed * 2.5); // limit maxspeed to prevent craziness
767         walkspeed = bound(0, M_ARGV(2, float) * MONSTER_SKILLMOD(this), walkspeed * 2.5); // limit maxspeed to prevent craziness
768
769         if(teamplay && autocvar_g_monsters_teams)
770         if(DIFF_TEAM(this.monster_follow, this))
771                 this.monster_follow = NULL;
772
773         if(this.state == MONSTER_ATTACK_RANGED && IS_ONGROUND(this))
774         {
775                 this.state = 0;
776                 settouch(this, Monster_Touch);
777         }
778
779         if(this.state && time >= this.attack_finished_single[0])
780                 this.state = 0; // attack is over
781
782         if(this.state != MONSTER_ATTACK_MELEE) // don't move if set
783         if(time >= this.last_trace || this.enemy) // update enemy or rider instantly
784                 this.moveto = Monster_Move_Target(this, targ);
785
786         if(!this.enemy)
787                 Monster_Sound(this, monstersound_idle, 7, true, CH_VOICE);
788
789         if(this.state == MONSTER_ATTACK_MELEE)
790                 this.moveto = this.origin;
791
792         if(this.enemy && this.enemy.vehicle)
793                 runspeed = 0;
794
795         if(!(this.spawnflags & MONSTERFLAG_FLY_VERTICAL) && !(this.flags & FL_SWIM))
796                 this.moveto_z = this.origin_z;
797
798         if(vdist(this.origin - this.moveto, >, 100))
799         {
800                 bool do_run = (this.enemy || this.monster_moveto);
801                 if(IS_ONGROUND(this) || ((this.flags & FL_FLY) || (this.flags & FL_SWIM)))
802                         Monster_CalculateVelocity(this, this.moveto, this.origin, true, ((do_run) ? runspeed : walkspeed));
803
804                 if(time > this.pain_finished && time > this.anim_finished) // TODO: use anim_finished instead!?
805                 if(!this.state)
806                 if(vdist(this.velocity, >, 10))
807                         setanim(this, ((do_run) ? this.anim_run : this.anim_walk), true, false, false);
808                 else
809                         setanim(this, this.anim_idle, true, false, false);
810         }
811         else
812         {
813                 entity e = this.goalentity; //find(NULL, targetname, this.target2);
814                 if(e.target2 && e.target2 != "")
815                         this.target2 = e.target2;
816                 else if(e.target && e.target != "") // compatibility
817                         this.target2 = e.target;
818
819                 movelib_brake_simple(this, stpspeed);
820                 if(time > this.anim_finished && time > this.pain_finished)
821                 if(!this.state)
822                 if(vdist(this.velocity, <=, 30))
823                         setanim(this, this.anim_idle, true, false, false);
824         }
825
826         this.steerto = steerlib_attract2(this, ((this.monster_face) ? this.monster_face : this.moveto), 0.5, 500, 0.95);
827
828         vector real_angle = vectoangles(this.steerto) - this.angles;
829         float turny = 25;
830         if(this.state == MONSTER_ATTACK_MELEE)
831                 turny = 0;
832         if(turny)
833         {
834                 turny = bound(turny * -1, shortangle_f(real_angle.y, this.angles.y), turny);
835                 this.angles_y += turny;
836         }
837 }
838
839 void Monster_Remove(entity this)
840 {
841         if(IS_CLIENT(this))
842                 return; // don't remove it?
843
844         if(!this) { return; }
845
846         if(!MUTATOR_CALLHOOK(MonsterRemove, this))
847                 Send_Effect(EFFECT_ITEM_PICKUP, this.origin, '0 0 0', 1);
848
849         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
850         {
851                 .entity weaponentity = weaponentities[slot];
852                 if(this.(weaponentity))
853                         delete(this.(weaponentity));
854         }
855         if(this.iceblock) { delete(this.iceblock); }
856         WaypointSprite_Kill(this.sprite);
857         delete(this);
858 }
859
860 void Monster_Dead_Think(entity this)
861 {
862         this.nextthink = time + this.ticrate;
863
864         if(this.monster_lifetime != 0)
865         if(time >= this.monster_lifetime)
866         {
867                 Monster_Dead_Fade(this);
868                 return;
869         }
870 }
871
872 void Monster_Appear(entity this, entity actor, entity trigger)
873 {
874         this.enemy = actor;
875         Monster_Spawn(this, false, this.monsterid);
876 }
877
878 bool Monster_Appear_Check(entity this, int monster_id)
879 {
880         if(!(this.spawnflags & MONSTERFLAG_APPEAR))
881                 return false;
882
883         setthink(this, func_null);
884         this.monsterid = monster_id; // set so this monster is properly registered (otherwise, normal initialization is used)
885         this.nextthink = 0;
886         this.use = Monster_Appear;
887         this.flags = FL_MONSTER; // set so this monster can get butchered
888
889         return true;
890 }
891
892 void Monster_Reset(entity this)
893 {
894         setorigin(this, this.pos1);
895         this.angles = this.pos2;
896
897         Unfreeze(this); // remove any icy remains
898
899         SetResourceAmountExplicit(this, RESOURCE_HEALTH, this.max_health);
900         this.velocity = '0 0 0';
901         this.enemy = NULL;
902         this.goalentity = NULL;
903         this.attack_finished_single[0] = 0;
904         this.moveto = this.origin;
905 }
906
907 void Monster_Dead_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
908 {
909         TakeResource(this, RESOURCE_HEALTH, damage);
910
911         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
912
913         if(GetResourceAmount(this, RESOURCE_HEALTH) <= -50) // 100 health until gone?
914         {
915                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
916
917                 // number of monsters spawned with mobspawn command
918                 totalspawned -= 1;
919
920                 setthink(this, SUB_Remove);
921                 this.nextthink = time + 0.1;
922                 this.event_damage = func_null;
923         }
924 }
925
926 void Monster_Dead(entity this, entity attacker, float gibbed)
927 {
928         setthink(this, Monster_Dead_Think);
929         this.nextthink = time;
930         this.monster_lifetime = time + 5;
931
932         if(STAT(FROZEN, this))
933         {
934                 Unfreeze(this); // remove any icy remains
935                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, 0); // reset by Unfreeze (TODO)
936         }
937
938         monster_dropitem(this, attacker);
939
940         Monster_Sound(this, monstersound_death, 0, false, CH_VOICE);
941
942         if(!(this.spawnflags & MONSTERFLAG_SPAWNED) && !(this.spawnflags & MONSTERFLAG_RESPAWNED))
943                 monsters_killed += 1;
944
945         if(IS_PLAYER(attacker))
946         if(autocvar_g_monsters_score_spawned || !((this.spawnflags & MONSTERFLAG_SPAWNED) || (this.spawnflags & MONSTERFLAG_RESPAWNED)))
947                 GameRules_scoring_add(attacker, SCORE, +autocvar_g_monsters_score_kill);
948
949         if(gibbed)
950         {
951                 // number of monsters spawned with mobspawn command
952                 totalspawned -= 1;
953         }
954
955         if(!gibbed && this.mdl_dead && this.mdl_dead != "")
956                 _setmodel(this, this.mdl_dead);
957
958         this.event_damage       = ((gibbed) ? func_null : Monster_Dead_Damage);
959         this.event_heal         = func_null;
960         this.solid                      = SOLID_CORPSE;
961         this.takedamage         = DAMAGE_AIM;
962         this.deadflag           = DEAD_DEAD;
963         this.enemy                      = NULL;
964         set_movetype(this, MOVETYPE_TOSS);
965         this.moveto                     = this.origin;
966         settouch(this, Monster_Touch); // reset incase monster was pouncing
967         this.reset                      = func_null;
968         this.state                      = 0;
969         this.attack_finished_single[0] = 0;
970         this.effects = 0;
971
972         if(!((this.flags & FL_FLY) || (this.flags & FL_SWIM)))
973                 this.velocity = '0 0 0';
974
975         CSQCModel_UnlinkEntity(this);
976
977         Monster mon = Monsters_from(this.monsterid);
978         mon.mr_death(mon, this);
979
980         if(this.candrop && this.weapon)
981         {
982                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
983                 W_ThrowNewWeapon(this, this.weapon, 0, this.origin, randomvec() * 150 + '0 0 325', weaponentity);
984         }
985 }
986
987 void Monster_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
988 {
989         if((this.spawnflags & MONSTERFLAG_INVINCIBLE) && deathtype != DEATH_KILL.m_id && !ITEM_DAMAGE_NEEDKILL(deathtype))
990                 return;
991
992         if(STAT(FROZEN, this) && deathtype != DEATH_KILL.m_id && deathtype != DEATH_NADE_ICE_FREEZE.m_id)
993                 return;
994
995         //if(time < this.pain_finished && deathtype != DEATH_KILL.m_id)
996                 //return;
997
998         if(time < this.spawnshieldtime && deathtype != DEATH_KILL.m_id)
999                 return;
1000
1001         if(deathtype == DEATH_FALL.m_id && this.draggedby != NULL)
1002                 return;
1003
1004         vector v = healtharmor_applydamage(100, GetResourceAmount(this, RESOURCE_ARMOR) / 100, deathtype, damage);
1005         float take = v.x;
1006         //float save = v.y;
1007
1008         Monster mon = Monsters_from(this.monsterid);
1009         take = mon.mr_pain(mon, this, take, attacker, deathtype);
1010
1011         if(take)
1012         {
1013                 TakeResource(this, RESOURCE_HEALTH, take);
1014                 Monster_Sound(this, monstersound_pain, 1.2, true, CH_PAIN);
1015         }
1016
1017         if(this.sprite)
1018                 WaypointSprite_UpdateHealth(this.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
1019
1020         this.dmg_time = time;
1021
1022         if(deathtype != DEATH_DROWN.m_id && deathtype != DEATH_FIRE.m_id && sound_allowed(MSG_BROADCAST, attacker))
1023                 spamsound (this, CH_PAIN, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
1024
1025         this.velocity += force * this.damageforcescale;
1026
1027         if(deathtype != DEATH_DROWN.m_id && take)
1028         {
1029                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, this, attacker);
1030                 if (take > 50)
1031                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
1032                 if (take > 100)
1033                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
1034         }
1035
1036         if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0)
1037         {
1038                 if(deathtype == DEATH_KILL.m_id)
1039                         this.candrop = false; // killed by mobkill command
1040
1041                 // TODO: fix this?
1042                 SUB_UseTargets(this, attacker, this.enemy);
1043                 this.target2 = this.oldtarget2; // reset to original target on death, incase we respawn
1044
1045                 Monster_Dead(this, attacker, (GetResourceAmount(this, RESOURCE_HEALTH) <= -100 || deathtype == DEATH_KILL.m_id));
1046
1047                 WaypointSprite_Kill(this.sprite);
1048
1049                 MUTATOR_CALLHOOK(MonsterDies, this, attacker, deathtype);
1050
1051                 if(GetResourceAmount(this, RESOURCE_HEALTH) <= -100 || deathtype == DEATH_KILL.m_id) // check if we're already gibbed
1052                 {
1053                         Violence_GibSplash(this, 1, 0.5, attacker);
1054
1055                         setthink(this, SUB_Remove);
1056                         this.nextthink = time + 0.1;
1057                 }
1058         }
1059 }
1060
1061 bool Monster_Heal(entity targ, entity inflictor, float amount, float limit)
1062 {
1063         float true_limit = ((limit != RESOURCE_LIMIT_NONE) ? limit : targ.max_health);
1064         if(GetResourceAmount(targ, RESOURCE_HEALTH) <= 0 || GetResourceAmount(targ, RESOURCE_HEALTH) >= true_limit)
1065                 return false;
1066
1067         GiveResourceWithLimit(targ, RESOURCE_HEALTH, amount, true_limit);
1068         if(targ.sprite)
1069                 WaypointSprite_UpdateHealth(targ.sprite, GetResourceAmount(targ, RESOURCE_HEALTH));
1070         return true;
1071 }
1072
1073 // don't check for enemies, just keep walking in a straight line
1074 void Monster_Move_2D(entity this, float mspeed, bool allow_jumpoff)
1075 {
1076         if(game_stopped || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || this.draggedby != NULL || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < this.spawn_time)
1077         {
1078                 mspeed = 0;
1079                 if(time >= this.spawn_time)
1080                         setanim(this, this.anim_idle, true, false, false);
1081                 movelib_brake_simple(this, 0.6);
1082                 return;
1083         }
1084
1085         makevectors(this.angles);
1086         vector a = CENTER_OR_VIEWOFS(this);
1087         vector b = CENTER_OR_VIEWOFS(this) + v_forward * 32;
1088
1089         traceline(a, b, MOVE_NORMAL, this);
1090
1091         bool reverse = false;
1092         if(trace_fraction != 1.0)
1093                 reverse = true;
1094         if(trace_ent && IS_PLAYER(trace_ent) && !(trace_ent.items & ITEM_Strength.m_itemid))
1095                 reverse = false;
1096         if(trace_ent && IS_MONSTER(trace_ent))
1097                 reverse = true;
1098
1099         // TODO: fix this... tracing is broken if the floor is thin
1100         /*
1101         if(!allow_jumpoff)
1102         {
1103                 a = b - '0 0 32';
1104                 traceline(b, a, MOVE_WORLDONLY, this);
1105                 if(trace_fraction == 1.0)
1106                         reverse = true;
1107         } */
1108
1109         if(reverse)
1110         {
1111                 this.angles_y = anglemods(this.angles_y - 180);
1112                 makevectors(this.angles);
1113         }
1114
1115         movelib_move_simple_gravity(this, v_forward, mspeed, 1);
1116
1117         if(time > this.pain_finished && time > this.attack_finished_single[0])
1118         if(vdist(this.velocity, >, 10))
1119                 setanim(this, this.anim_walk, true, false, false);
1120         else
1121                 setanim(this, this.anim_idle, true, false, false);
1122 }
1123
1124 void Monster_Anim(entity this)
1125 {
1126         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
1127         if(IS_DEAD(this))
1128         {
1129                 if (!deadbits)
1130                 {
1131                         // Decide on which death animation to use.
1132                         if(random() < 0.5)
1133                                 deadbits = ANIMSTATE_DEAD1;
1134                         else
1135                                 deadbits = ANIMSTATE_DEAD2;
1136                 }
1137         }
1138         else
1139         {
1140                 // Clear a previous death animation.
1141                 deadbits = 0;
1142         }
1143         int animbits = deadbits;
1144         if(STAT(FROZEN, this))
1145                 animbits |= ANIMSTATE_FROZEN;
1146         if(this.crouch)
1147                 animbits |= ANIMSTATE_DUCK; // not that monsters can crouch currently...
1148         animdecide_setstate(this, animbits, false);
1149         animdecide_setimplicitstate(this, (IS_ONGROUND(this)));
1150
1151         /* // weapon entities for monsters?
1152         if (this.weaponentity)
1153         {
1154                 updateanim(this.weaponentity);
1155                 if (!this.weaponentity.animstate_override)
1156                         setanim(this.weaponentity, this.weaponentity.anim_idle, true, false, false);
1157         }
1158         */
1159 }
1160
1161 void Monster_Frozen_Think(entity this)
1162 {
1163         if(STAT(FROZEN, this) == 2)
1164         {
1165                 STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + this.ticrate * this.revive_speed, 1);
1166                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * this.max_health));
1167                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
1168
1169                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE) && this.sprite)
1170                         WaypointSprite_UpdateHealth(this.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
1171
1172                 if(STAT(REVIVE_PROGRESS, this) >= 1)
1173                         Unfreeze(this);
1174         }
1175         else if(STAT(FROZEN, this) == 3)
1176         {
1177                 STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - this.ticrate * this.revive_speed, 1);
1178                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (this.max_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
1179
1180                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE) && this.sprite)
1181                         WaypointSprite_UpdateHealth(this.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
1182
1183                 if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1184                 {
1185                         Unfreeze(this);
1186                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, 0);
1187                         if(this.event_damage)
1188                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
1189                 }
1190
1191                 else if ( STAT(REVIVE_PROGRESS, this) <= 0 )
1192                         Unfreeze(this);
1193         }
1194         // otherwise, no revival!
1195
1196         this.enemy = NULL; // TODO: save enemy, and attack when revived?
1197 }
1198
1199 void Monster_Enemy_Check(entity this)
1200 {
1201         if(!this.enemy)
1202         {
1203                 this.enemy = Monster_FindTarget(this);
1204                 if(this.enemy)
1205                 {
1206                         WarpZone_RefSys_Copy(this.enemy, this);
1207                         WarpZone_RefSys_AddInverse(this.enemy, this); // wz1^-1 ... wzn^-1 receiver
1208                         // update move target immediately?
1209                         this.moveto = WarpZone_RefSys_TransformOrigin(this.enemy, this, (0.5 * (this.enemy.absmin + this.enemy.absmax)));
1210                         this.monster_moveto = '0 0 0';
1211                         this.monster_face = '0 0 0';
1212
1213                         //this.pass_distance = vlen((('1 0 0' * this.enemy.origin_x) + ('0 1 0' * this.enemy.origin_y)) - (('1 0 0' *  this.origin_x) + ('0 1 0' *  this.origin_y)));
1214                         Monster_Sound(this, monstersound_sight, 0, false, CH_VOICE);
1215                 }
1216         }
1217 }
1218
1219 void Monster_Think(entity this)
1220 {
1221         setthink(this, Monster_Think);
1222         this.nextthink = time + this.ticrate;
1223
1224         if(this.monster_lifetime && time >= this.monster_lifetime)
1225         {
1226                 Damage(this, this, this, GetResourceAmount(this, RESOURCE_HEALTH) + this.max_health, DEATH_KILL.m_id, DMG_NOWEP, this.origin, this.origin);
1227                 return;
1228         }
1229
1230         if(STAT(FROZEN, this))
1231                 Monster_Frozen_Think(this);
1232         else if(time >= this.last_enemycheck)
1233         {
1234                 Monster_Enemy_Check(this);
1235                 this.last_enemycheck = time + 1; // check for enemies every second
1236         }
1237
1238         Monster mon = Monsters_from(this.monsterid);
1239         if(mon.mr_think(mon, this))
1240         {
1241                 Monster_Move(this, this.speed2, this.speed, this.stopspeed);
1242
1243                 .entity weaponentity = weaponentities[0]; // TODO?
1244                 Monster_Attack_Check(this, this.enemy, weaponentity);
1245         }
1246
1247         Monster_Anim(this);
1248
1249         CSQCMODEL_AUTOUPDATE(this);
1250 }
1251
1252 bool Monster_Spawn_Setup(entity this)
1253 {
1254         Monster mon = Monsters_from(this.monsterid);
1255         mon.mr_setup(mon, this);
1256
1257         // ensure some basic needs are met
1258         if(!GetResourceAmount(this, RESOURCE_HEALTH)) { SetResourceAmountExplicit(this, RESOURCE_HEALTH, 100); }
1259         if(!GetResourceAmount(this, RESOURCE_ARMOR)) { SetResourceAmountExplicit(this, RESOURCE_ARMOR, bound(0.2, 0.5 * MONSTER_SKILLMOD(this), 0.9)); }
1260         if(!this.target_range) { this.target_range = autocvar_g_monsters_target_range; }
1261         if(!this.respawntime) { this.respawntime = autocvar_g_monsters_respawn_delay; }
1262         if(!this.monster_moveflags) { this.monster_moveflags = MONSTER_MOVE_WANDER; }
1263         if(!this.attack_range) { this.attack_range = autocvar_g_monsters_attack_range; }
1264         if(!this.damageforcescale) { this.damageforcescale = autocvar_g_monsters_damageforcescale; }
1265
1266         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1267         {
1268                 Monster_Miniboss_Check(this);
1269                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(this, RESOURCE_HEALTH) * MONSTER_SKILLMOD(this));
1270
1271                 if(!this.skin)
1272                         this.skin = rint(random() * 4);
1273         }
1274
1275         this.max_health = GetResourceAmount(this, RESOURCE_HEALTH);
1276         this.pain_finished = this.nextthink;
1277
1278         if(IS_PLAYER(this.monster_follow))
1279                 this.effects |= EF_DIMLIGHT;
1280
1281         if(!this.wander_delay) { this.wander_delay = 2; }
1282         if(!this.wander_distance) { this.wander_distance = 600; }
1283
1284         Monster_Sounds_Precache(this);
1285         Monster_Sounds_Update(this);
1286
1287         if(teamplay)
1288         {
1289                 if(!this.monster_attack)
1290                         IL_PUSH(g_monster_targets, this);
1291                 this.monster_attack = true; // we can have monster enemies in team games
1292         }
1293
1294         Monster_Sound(this, monstersound_spawn, 0, false, CH_VOICE);
1295
1296         if(autocvar_g_monsters_healthbars)
1297         {
1298                 entity wp = WaypointSprite_Spawn(WP_Monster, 0, 1024, this, '0 0 1' * (this.maxs.z + 15), NULL, this.team, this, sprite, true, RADARICON_DANGER);
1299                 wp.wp_extra = this.monsterid;
1300                 wp.colormod = ((this.team) ? Team_ColorRGB(this.team) : '1 0 0');
1301                 if(!(this.spawnflags & MONSTERFLAG_INVINCIBLE))
1302                 {
1303                         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
1304                         WaypointSprite_UpdateHealth(this.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
1305                 }
1306         }
1307
1308         setthink(this, Monster_Think);
1309         this.nextthink = time + this.ticrate;
1310
1311         if(MUTATOR_CALLHOOK(MonsterSpawn, this))
1312                 return false;
1313
1314         return true;
1315 }
1316
1317 bool Monster_Spawn(entity this, bool check_appear, int mon_id)
1318 {
1319         // setup the basic required properties for a monster
1320         entity mon = Monsters_from(mon_id);
1321         if(!mon.monsterid) { return false; } // invalid monster
1322
1323         if(!autocvar_g_monsters) { Monster_Remove(this); return false; }
1324
1325         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1326         {
1327                 IL_PUSH(g_monsters, this);
1328                 if(this.mdl && this.mdl != "")
1329                         precache_model(this.mdl);
1330                 if(this.mdl_dead && this.mdl_dead != "")
1331                         precache_model(this.mdl_dead);
1332         }
1333
1334         if(check_appear && Monster_Appear_Check(this, mon_id)) { return true; } // return true so the monster isn't removed
1335
1336         if(!this.monster_skill)
1337                 this.monster_skill = cvar("g_monsters_skill");
1338
1339         // support for quake style removing monsters based on skill
1340         if(this.monster_skill == MONSTER_SKILL_EASY) if(this.spawnflags & MONSTERSKILL_NOTEASY) { Monster_Remove(this); return false; }
1341         if(this.monster_skill == MONSTER_SKILL_MEDIUM) if(this.spawnflags & MONSTERSKILL_NOTMEDIUM) { Monster_Remove(this); return false; }
1342         if(this.monster_skill == MONSTER_SKILL_HARD) if(this.spawnflags & MONSTERSKILL_NOTHARD) { Monster_Remove(this); return false; }
1343
1344         if(this.team && !teamplay)
1345                 this.team = 0;
1346
1347         if(!(this.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1348         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED)) // don't count re-spawning monsters either
1349                 monsters_total += 1;
1350
1351         if(this.mdl && this.mdl != "")
1352                 _setmodel(this, this.mdl);
1353         else
1354                 setmodel(this, mon.m_model);
1355
1356         this.flags                              = FL_MONSTER;
1357         this.classname                  = "monster";
1358         this.takedamage                 = DAMAGE_AIM;
1359         if(!this.bot_attack)
1360                 IL_PUSH(g_bot_targets, this);
1361         this.bot_attack                 = true;
1362         this.iscreature                 = true;
1363         this.teleportable               = true;
1364         if(!this.damagedbycontents)
1365                 IL_PUSH(g_damagedbycontents, this);
1366         this.damagedbycontents  = true;
1367         this.monsterid                  = mon_id;
1368         this.event_damage               = Monster_Damage;
1369         this.event_heal                 = Monster_Heal;
1370         settouch(this, Monster_Touch);
1371         this.use                                = Monster_Use;
1372         this.solid                              = SOLID_BBOX;
1373         set_movetype(this, MOVETYPE_WALK);
1374         this.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1375         this.enemy                              = NULL;
1376         this.velocity                   = '0 0 0';
1377         this.moveto                             = this.origin;
1378         this.pos1                               = this.origin;
1379         this.pos2                               = this.angles;
1380         this.reset                              = Monster_Reset;
1381         this.netname                    = mon.netname;
1382         this.monster_attackfunc = mon.monster_attackfunc;
1383         this.monster_name               = mon.monster_name;
1384         this.candrop                    = true;
1385         this.view_ofs                   = '0 0 0.7' * (this.maxs_z * 0.5);
1386         this.oldtarget2                 = this.target2;
1387         //this.pass_distance            = 0;
1388         this.deadflag                   = DEAD_NO;
1389         this.spawn_time                 = time;
1390         this.gravity                    = 1;
1391         this.monster_moveto             = '0 0 0';
1392         this.monster_face               = '0 0 0';
1393         this.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1394
1395         if(!this.noalign) { this.noalign = ((mon.spawnflags & MONSTER_TYPE_FLY) || (mon.spawnflags & MONSTER_TYPE_SWIM)); }
1396         if(!this.scale) { this.scale = 1; }
1397         if(autocvar_g_monsters_edit) { this.grab = 1; }
1398         if(autocvar_g_fullbrightplayers) { this.effects |= EF_FULLBRIGHT; }
1399         if(autocvar_g_nodepthtestplayers) { this.effects |= EF_NODEPTHTEST; }
1400         if(mon.spawnflags & MONSTER_TYPE_SWIM) { this.flags |= FL_SWIM; }
1401
1402         if(autocvar_g_playerclip_collisions)
1403                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1404
1405         if(mon.spawnflags & MONSTER_TYPE_FLY)
1406         {
1407                 this.flags |= FL_FLY;
1408                 set_movetype(this, MOVETYPE_FLY);
1409         }
1410
1411         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1412         {
1413                 if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1414                         this.scale *= 1.3;
1415
1416                 if(mon.spawnflags & MONSTER_SIZE_QUAKE)
1417                 if(autocvar_g_monsters_quake_resize)
1418                         this.scale *= 1.3;
1419         }
1420
1421         setsize(this, mon.m_mins * this.scale, mon.m_maxs * this.scale);
1422
1423         this.ticrate = bound(sys_frametime, ((!this.ticrate) ? autocvar_g_monsters_think_delay : this.ticrate), 60);
1424
1425         Monster_UpdateModel(this);
1426
1427         if(!Monster_Spawn_Setup(this))
1428         {
1429                 Monster_Remove(this);
1430                 return false;
1431         }
1432
1433         if(!this.noalign)
1434         {
1435                 setorigin(this, this.origin + '0 0 20');
1436                 tracebox(this.origin + '0 0 64', this.mins, this.maxs, this.origin - '0 0 10000', MOVE_WORLDONLY, this);
1437                 setorigin(this, trace_endpos);
1438         }
1439
1440         if(!(this.spawnflags & MONSTERFLAG_RESPAWNED))
1441                 monster_setupcolors(this);
1442
1443         CSQCMODEL_AUTOINIT(this);
1444
1445         return true;
1446 }