qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void monster_item_spawn()
   7 {
   8         if(self.monster_loot)
   9                 self.monster_loot();
  10
  11         self.gravity = 1;
  12         self.reset = SUB_Remove;
  13         self.noalign = TRUE;
  14         self.velocity = randomvec() * 175 + '0 0 325';
  15         self.classname = "droppedweapon"; // hax
  16         self.item_spawnshieldtime = time + 0.7;
  17
  18         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  19 }
  20
  21 void monster_dropitem()
  22 {
  23         if(!self.candrop || !self.monster_loot)
  24                 return;
  25
  26         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  27         entity e = spawn();
  28
  29         setorigin(e, org);
  30
  31         e.monster_loot = self.monster_loot;
  32
  33         other = e;
  34         MUTATOR_CALLHOOK(MonsterDropItem);
  35         e = other;
  36
  37         if(e)
  38         {
  39                 e.think = monster_item_spawn;
  40                 e.nextthink = time + 0.3;
  41         }
  42 }
  43
  44 float Monster_SkillModifier()
  45 {
  46         float t = 0.5+self.monster_skill*((1.2-0.3)/10);
  47
  48         return t;
  49 }
  50
  51 float monster_isvalidtarget (entity targ, entity ent)
  52 {
  53         if(!targ || !ent)
  54                 return FALSE; // someone doesn't exist
  55
  56         if(targ == ent)
  57                 return FALSE; // don't attack ourselves
  58
  59         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  60
  61         if(trace_ent != targ)
  62                 return FALSE;
  63
  64         if(targ.vehicle_flags & VHF_ISVEHICLE)
  65         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  66                 return FALSE; // melee attacks are useless against vehicles
  67
  68         if(time < game_starttime)
  69                 return FALSE; // monsters do nothing before the match has started
  70
  71         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  72                 return FALSE; // enemy is too far away
  73
  74         if(targ.takedamage == DAMAGE_NO)
  75                 return FALSE; // enemy can't be damaged
  76
  77         if(targ.items & IT_INVISIBILITY)
  78                 return FALSE; // enemy is invisible
  79
  80         if(substring(targ.classname, 0, 10) == "onslaught_")
  81                 return FALSE; // don't attack onslaught targets
  82
  83         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  84                 return FALSE; // enemy is a spectator
  85
  86         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  87         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  88                 return FALSE; // enemy/self is dead
  89
  90         if(ent.monster_owner == targ)
  91                 return FALSE; // don't attack our master
  92
  93         if(targ.monster_owner == ent)
  94                 return FALSE; // don't attack our pet
  95
  96         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  97         if(targ.flags & FL_NOTARGET)
  98                 return FALSE; // enemy can't be targeted
  99
 100         if not(autocvar_g_monsters_typefrag)
 101         if(targ.BUTTON_CHAT)
 102                 return FALSE; // no typefragging!
 103
 104         if(SAME_TEAM(targ, ent))
 105                 return FALSE; // enemy is on our team
 106
 107         if (targ.frozen == 1 || (targ.frozen == 2 && ent.monsterid != MON_SPIDER))
 108                 return FALSE; // ignore frozen
 109
 110         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 111         if(ent.enemy != targ)
 112         {
 113                 float dot;
 114
 115                 makevectors (ent.angles);
 116                 dot = normalize (targ.origin - ent.origin) * v_forward;
 117
 118                 if(dot <= 0.3)
 119                         return FALSE;
 120         }
 121
 122         return TRUE;
 123 }
 124
 125 entity FindTarget (entity ent)
 126 {
 127         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 128
 129         entity head, closest_target = world;
 130         head = findradius(ent.origin, ent.target_range);
 131
 132         while(head) // find the closest acceptable target to pass to
 133         {
 134                 if(head.monster_attack)
 135                 if(monster_isvalidtarget(head, ent))
 136                 {
 137                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 138                         vector head_center = CENTER_OR_VIEWOFS(head);
 139                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 140
 141                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 142                         if(closest_target)
 143                         {
 144                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 145                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 146                                         { closest_target = head; }
 147                         }
 148                         else { closest_target = head; }
 149                 }
 150
 151                 head = head.chain;
 152         }
 153
 154         return closest_target;
 155 }
 156
 157 void MonsterTouch ()
 158 {
 159         if(other == world)
 160                 return;
 161
 162         if(self.enemy != other)
 163         if not(other.flags & FL_MONSTER)
 164         if(monster_isvalidtarget(other, self))
 165                 self.enemy = other;
 166 }
 167
 168 string get_monster_model_datafilename(string m, float sk, string fil)
 169 {
 170         if(m)
 171                 m = strcat(m, "_");
 172         else
 173                 m = "models/monsters/*_";
 174         if(sk >= 0)
 175                 m = strcat(m, ftos(sk));
 176         else
 177                 m = strcat(m, "*");
 178         return strcat(m, ".", fil);
 179 }
 180
 181 void PrecacheMonsterSounds(string f)
 182 {
 183         float fh;
 184         string s;
 185         fh = fopen(f, FILE_READ);
 186         if(fh < 0)
 187                 return;
 188         while((s = fgets(fh)))
 189         {
 190                 if(tokenize_console(s) != 3)
 191                 {
 192                         dprint("Invalid sound info line: ", s, "\n");
 193                         continue;
 194                 }
 195                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 196         }
 197         fclose(fh);
 198 }
 199
 200 void precache_monstersounds()
 201 {
 202         string m = (get_monsterinfo(self.monsterid)).model;
 203         float globhandle, n, i;
 204         string f;
 205
 206         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 207         if (globhandle < 0)
 208                 return;
 209         n = search_getsize(globhandle);
 210         for (i = 0; i < n; ++i)
 211         {
 212                 //print(search_getfilename(globhandle, i), "\n");
 213                 f = search_getfilename(globhandle, i);
 214                 PrecacheMonsterSounds(f);
 215         }
 216         search_end(globhandle);
 217 }
 218
 219 void ClearMonsterSounds()
 220 {
 221 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 222         ALLMONSTERSOUNDS
 223 #undef _MSOUND
 224 }
 225
 226 .string GetMonsterSoundSampleField(string type)
 227 {
 228         GetMonsterSoundSampleField_notFound = 0;
 229         switch(type)
 230         {
 231 #define _MSOUND(m) case #m: return monstersound_##m;
 232                 ALLMONSTERSOUNDS
 233 #undef _MSOUND
 234         }
 235         GetMonsterSoundSampleField_notFound = 1;
 236         return string_null;
 237 }
 238
 239 float LoadMonsterSounds(string f, float first)
 240 {
 241         float fh;
 242         string s;
 243         var .string field;
 244         fh = fopen(f, FILE_READ);
 245         if(fh < 0)
 246         {
 247                 dprint("Monster sound file not found: ", f, "\n");
 248                 return 0;
 249         }
 250         while((s = fgets(fh)))
 251         {
 252                 if(tokenize_console(s) != 3)
 253                         continue;
 254                 field = GetMonsterSoundSampleField(argv(0));
 255                 if(GetMonsterSoundSampleField_notFound)
 256                         continue;
 257                 if(self.field)
 258                         strunzone(self.field);
 259                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 260         }
 261         fclose(fh);
 262         return 1;
 263 }
 264
 265 .float skin_for_monstersound;
 266 void UpdateMonsterSounds()
 267 {
 268         entity mon = get_monsterinfo(self.monsterid);
 269
 270         if(self.skin == self.skin_for_monstersound)
 271                 return;
 272         self.skin_for_monstersound = self.skin;
 273         ClearMonsterSounds();
 274         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 275         if(!autocvar_g_debug_defaultsounds)
 276         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 277                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 278 }
 279
 280 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 281 {
 282         if(delaytoo && time < self.msound_delay)
 283                 return; // too early
 284         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 285
 286         self.msound_delay = time + sound_delay;
 287 }
 288
 289 void monster_makevectors(entity e)
 290 {
 291         vector v;
 292
 293         v = e.origin + (e.mins + e.maxs) * 0.5;
 294         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 295         self.v_angle_x = -self.v_angle_x;
 296
 297         makevectors(self.v_angle);
 298 }
 299
 300 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 301 {
 302         if (self.health <= 0)
 303                 return FALSE; // attacking while dead?!
 304
 305         if(dostop)
 306         {
 307                 self.velocity_x = 0;
 308                 self.velocity_y = 0;
 309                 self.state = MONSTER_STATE_ATTACK_MELEE;
 310         }
 311
 312         self.frame = anim;
 313
 314         if(anim_finished != 0)
 315                 self.attack_finished_single = time + anim_finished;
 316
 317         monster_makevectors(targ);
 318
 319         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 320
 321         if(trace_ent.takedamage)
 322                 Damage(trace_ent, self, self, damg * Monster_SkillModifier(), deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 323
 324         return TRUE;
 325 }
 326
 327 void Monster_CheckMinibossFlag ()
 328 {
 329         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 330                 return;
 331
 332         float chance = random() * 100;
 333
 334         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 335         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 336         {
 337                 self.health += autocvar_g_monsters_miniboss_healthboost;
 338                 self.effects |= EF_RED;
 339                 if not(self.weapon)
 340                         self.weapon = WEP_NEX;
 341         }
 342 }
 343
 344 float Monster_CanRespawn(entity ent)
 345 {
 346         other = ent;
 347         if(ent.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 348         if(MUTATOR_CALLHOOK(MonsterRespawn))
 349                 return TRUE; // enabled by a mutator
 350
 351         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 352                 return FALSE;
 353
 354         if not(autocvar_g_monsters_respawn)
 355                 return FALSE;
 356
 357         return TRUE;
 358 }
 359
 360 void Monster_Fade ()
 361 {
 362         if(Monster_CanRespawn(self))
 363         {
 364                 self.monster_respawned = TRUE;
 365                 self.think = self.monster_spawnfunc;
 366                 self.nextthink = time + self.respawntime;
 367                 self.ltime = 0;
 368                 self.deadflag = DEAD_RESPAWNING;
 369                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 370                 {
 371                         self.pos1 = self.origin;
 372                         self.pos2 = self.angles;
 373                 }
 374                 self.event_damage = func_null;
 375                 self.takedamage = DAMAGE_NO;
 376                 setorigin(self, self.pos1);
 377                 self.angles = self.pos2;
 378                 self.health = self.max_health;
 379                 setmodel(self, "null");
 380         }
 381         else
 382                 SUB_SetFade(self, time + 3, 1);
 383 }
 384
 385 float Monster_CanJump (vector vel)
 386 {
 387         if(self.state)
 388                 return FALSE; // already attacking
 389         if not(self.flags & FL_ONGROUND)
 390                 return FALSE; // not on the ground
 391         if(self.health <= 0)
 392                 return FALSE; // called when dead?
 393         if(time < self.attack_finished_single)
 394                 return FALSE; // still attacking
 395
 396         vector old = self.velocity;
 397
 398         self.velocity = vel;
 399         tracetoss(self, self);
 400         self.velocity = old;
 401         if (trace_ent != self.enemy)
 402                 return FALSE;
 403
 404         return TRUE;
 405 }
 406
 407 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 408 {
 409         if(!Monster_CanJump(vel))
 410                 return FALSE;
 411
 412         self.frame = anm;
 413         self.state = MONSTER_STATE_ATTACK_LEAP;
 414         self.touch = touchfunc;
 415         self.origin_z += 1;
 416         self.velocity = vel;
 417         self.flags &= ~FL_ONGROUND;
 418
 419         self.attack_finished_single = time + anim_finished;
 420
 421         return TRUE;
 422 }
 423
 424 void monster_checkattack(entity e, entity targ)
 425 {
 426         if(e == world)
 427                 return;
 428         if(targ == world)
 429                 return;
 430
 431         if not(e.monster_attackfunc)
 432                 return;
 433
 434         if(time < e.attack_finished_single)
 435                 return;
 436
 437         if(vlen(targ.origin - e.origin) <= e.attack_range)
 438         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 439         {
 440                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 441                 return;
 442         }
 443
 444         if(vlen(targ.origin - e.origin) > e.attack_range)
 445         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 446         {
 447                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 448                 return;
 449         }
 450 }
 451
 452 void monster_use ()
 453 {
 454         if not(self.enemy)
 455         if(self.health > 0)
 456         if(monster_isvalidtarget(activator, self))
 457                 self.enemy = activator;
 458 }
 459
 460 .float last_trace;
 461 .float last_enemycheck; // for checking enemy
 462 vector monster_pickmovetarget(entity targ)
 463 {
 464         // enemy is always preferred target
 465         if(self.enemy)
 466         {
 467                 makevectors(self.angles);
 468                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 469                 self.last_trace = time + 1.2;
 470                 return self.enemy.origin;
 471         }
 472
 473         switch(self.monster_moveflags)
 474         {
 475                 case MONSTER_MOVE_OWNER:
 476                 {
 477                         self.monster_movestate = MONSTER_MOVE_OWNER;
 478                         self.last_trace = time + 0.3;
 479                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 480                 }
 481                 case MONSTER_MOVE_SPAWNLOC:
 482                 {
 483                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 484                         self.last_trace = time + 2;
 485                         return self.pos1;
 486                 }
 487                 case MONSTER_MOVE_NOMOVE:
 488                 {
 489                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 490                         self.last_trace = time + 2;
 491                         return self.origin;
 492                 }
 493                 default:
 494                 case MONSTER_MOVE_WANDER:
 495                 {
 496                         vector pos;
 497                         self.monster_movestate = MONSTER_MOVE_WANDER;
 498                         self.last_trace = time + 2;
 499
 500                         self.angles_y = rint(random() * 500);
 501                         makevectors(self.angles);
 502                         pos = self.origin + v_forward * 600;
 503
 504                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 505                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 506                         {
 507                                 pos_z = random() * 200;
 508                                 if(random() >= 0.5)
 509                                         pos_z *= -1;
 510                         }
 511
 512                         if(targ)
 513                         {
 514                                 self.last_trace = time + 0.5;
 515                                 pos = targ.origin;
 516                         }
 517
 518                         return pos;
 519                 }
 520         }
 521 }
 522
 523 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 524 {
 525         fixedmakevectors(self.angles);
 526
 527         if(self.target2)
 528                 self.goalentity = find(world, targetname, self.target2);
 529
 530         entity targ;
 531
 532         if(self.frozen)
 533         {
 534                 self.revive_progress = bound(0, self.revive_progress + self.ticrate * self.revive_speed, 1);
 535                 self.health = max(1, self.max_health * self.revive_progress);
 536
 537                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 538
 539                 movelib_beak_simple(stopspeed);
 540
 541                 self.frame = manim_idle;
 542
 543                 self.enemy = world;
 544                 self.nextthink = time + self.ticrate;
 545
 546                 if(self.revive_progress >= 1)
 547                         Unfreeze(self); // wait for next think before attacking
 548
 549                 return; // no moving while frozen
 550         }
 551
 552         if(self.flags & FL_SWIM)
 553         {
 554                 if(self.waterlevel < WATERLEVEL_WETFEET)
 555                 {
 556                         if(time >= self.last_trace)
 557                         {
 558                                 self.fish_wasdrowning = TRUE;
 559                                 self.last_trace = time + 0.4;
 560
 561                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 562                                 self.angles = '90 90 0';
 563                                 if(random() < 0.5)
 564                                 {
 565                                         self.velocity_y += random() * 50;
 566                                         self.velocity_x -= random() * 50;
 567                                 }
 568                                 else
 569                                 {
 570                                         self.velocity_y -= random() * 50;
 571                                         self.velocity_x += random() * 50;
 572                                 }
 573                                 self.velocity_z += random() * 150;
 574                         }
 575
 576
 577                         self.movetype = MOVETYPE_BOUNCE;
 578                         //self.velocity_z = -200;
 579
 580                         return;
 581                 }
 582                 else if(self.fish_wasdrowning)
 583                 {
 584                         self.fish_wasdrowning = FALSE;
 585                         self.angles_x = 0;
 586                         self.movetype = MOVETYPE_WALK;
 587                 }
 588         }
 589
 590         targ = self.goalentity;
 591
 592         monster_target = targ;
 593         monster_speed_run = runspeed;
 594         monster_speed_walk = walkspeed;
 595
 596         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 597         {
 598                 runspeed = walkspeed = 0;
 599                 if(time >= self.spawn_time)
 600                         self.frame = manim_idle;
 601                 movelib_beak_simple(stopspeed);
 602                 return;
 603         }
 604
 605         targ = monster_target;
 606         runspeed = bound(0, monster_speed_run * Monster_SkillModifier(), runspeed * 2); // limit maxspeed to prevent craziness
 607         walkspeed = bound(0, monster_speed_walk * Monster_SkillModifier(), walkspeed * 2); // limit maxspeed to prevent craziness
 608
 609         if(teamplay)
 610         if(autocvar_g_monsters_teams)
 611         if(DIFF_TEAM(self.monster_owner, self))
 612                 self.monster_owner = world;
 613
 614         if(self.enemy && self.enemy.health < 1)
 615                 self.enemy = world; // enough!
 616
 617         if(time >= self.last_enemycheck)
 618         {
 619                 if not(monster_isvalidtarget(self.enemy, self))
 620                         self.enemy = world;
 621
 622                 if not(self.enemy)
 623                 {
 624                         self.enemy = FindTarget(self);
 625                         if(self.enemy)
 626                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 627                 }
 628
 629                 self.last_enemycheck = time + 0.5;
 630         }
 631
 632         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 633                 self.state = 0;
 634
 635         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 636         if(time >= self.last_trace || self.enemy) // update enemy instantly
 637                 self.moveto = monster_pickmovetarget(targ);
 638
 639         if not(self.enemy)
 640                 MonsterSound(monstersound_idle, 7, TRUE, CH_VOICE);
 641
 642         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 643                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 644
 645         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 646         {
 647                 self.state = 0;
 648                 self.touch = MonsterTouch;
 649         }
 650
 651         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 652
 653         float turny = 0;
 654         vector real_angle = vectoangles(self.steerto) - self.angles;
 655
 656         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 657                 turny = 20;
 658
 659         if(self.flags & FL_SWIM)
 660                 turny = vlen(self.angles - self.moveto);
 661
 662         if(turny)
 663         {
 664                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 665                 self.angles_y += turny;
 666         }
 667
 668         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 669                 self.moveto = self.origin;
 670
 671         if(self.enemy && self.enemy.vehicle)
 672                 runspeed = 0;
 673
 674         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 675                 v_forward = normalize(self.moveto - self.origin);
 676         else
 677                 self.moveto_z = self.origin_z;
 678
 679         if(vlen(self.origin - self.moveto) > 64)
 680         {
 681                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 682                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 683                 else
 684                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 685
 686                 if(time > self.pain_finished)
 687                 if(time > self.attack_finished_single)
 688                 if(vlen(self.velocity) > 10)
 689                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 690                 else
 691                         self.frame = manim_idle;
 692         }
 693         else
 694         {
 695                 entity e = find(world, targetname, self.target2);
 696                 if(e.target2)
 697                         self.target2 = e.target2;
 698                 else if(e.target)
 699                         self.target2 = e.target;
 700
 701                 movelib_beak_simple(stopspeed);
 702                 if(time > self.attack_finished_single)
 703                 if(time > self.pain_finished)
 704                 if (vlen(self.velocity) <= 30)
 705                         self.frame = manim_idle;
 706         }
 707
 708         monster_checkattack(self, self.enemy);
 709 }
 710
 711 void monster_remove(entity mon)
 712 {
 713         if not(mon)
 714                 return; // nothing to remove
 715
 716         pointparticles(particleeffectnum("item_pickup"), mon.origin, '0 0 0', 1);
 717
 718         if(mon.weaponentity)
 719                 remove(mon.weaponentity);
 720
 721         if(mon.iceblock)
 722                 remove(mon.iceblock);
 723
 724         WaypointSprite_Kill(mon.sprite);
 725
 726         remove(mon);
 727 }
 728
 729 void monster_dead_think()
 730 {
 731         self.nextthink = time + self.ticrate;
 732
 733         CSQCMODEL_AUTOUPDATE();
 734
 735         if(self.ltime != 0)
 736         if(time >= self.ltime)
 737         {
 738                 Monster_Fade();
 739                 return;
 740         }
 741 }
 742
 743 void monsters_setstatus()
 744 {
 745         self.stat_monsters_total = monsters_total;
 746         self.stat_monsters_killed = monsters_killed;
 747 }
 748
 749 void Monster_Appear()
 750 {
 751         self.enemy = activator;
 752         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 753         self.monster_spawnfunc();
 754 }
 755
 756 float Monster_CheckAppearFlags(entity ent)
 757 {
 758         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 759                 return FALSE;
 760
 761         ent.think = func_null;
 762         ent.nextthink = 0;
 763         ent.use = Monster_Appear;
 764         ent.flags = FL_MONSTER; // set so this monster can get butchered
 765
 766         return TRUE;
 767 }
 768
 769 void monsters_reset()
 770 {
 771         setorigin(self, self.pos1);
 772         self.angles = self.pos2;
 773
 774         Unfreeze(self); // remove any icy remains
 775
 776         self.health = self.max_health;
 777         self.velocity = '0 0 0';
 778         self.enemy = world;
 779         self.goalentity = world;
 780         self.attack_finished_single = 0;
 781         self.moveto = self.origin;
 782 }
 783
 784 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 785 {
 786         self.health -= damage;
 787
 788         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 789
 790         if(self.health <= -100) // 100 health until gone?
 791         {
 792                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 793
 794                 if(IS_CLIENT(self.realowner))
 795                 if not(self.monster_respawned)
 796                         self.realowner.monstercount -= 1;
 797
 798                 self.think = SUB_Remove;
 799                 self.nextthink = time + 0.1;
 800         }
 801 }
 802
 803 void monster_die(entity attacker, float gibbed)
 804 {
 805         self.think = monster_dead_think;
 806         self.nextthink = time;
 807         self.ltime = time + 5;
 808
 809         if ( self.frozen )
 810         {
 811                 Unfreeze(self); // remove any icy remains
 812                 self.health = 0; // reset by Unfreeze
 813         }
 814
 815         monster_dropitem();
 816
 817         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 818
 819         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 820                 monsters_killed += 1;
 821
 822         if(IS_PLAYER(attacker))
 823         if( autocvar_g_monsters_score_spawned ||
 824                         ( !(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned) )
 825                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
 826
 827         if(!Monster_CanRespawn(self) || gibbed)
 828         {
 829                 // number of monsters spawned with mobspawn command
 830                 totalspawned -= 1;
 831
 832                 if(IS_CLIENT(self.realowner))
 833                 if not(self.monster_respawned)
 834                         self.realowner.monstercount -= 1;
 835         }
 836
 837         if(self.candrop && self.weapon)
 838                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 839
 840         self.event_damage       = monsters_corpse_damage;
 841         self.solid                      = SOLID_CORPSE;
 842         self.takedamage         = DAMAGE_AIM;
 843         self.deadflag           = DEAD_DEAD;
 844         self.enemy                      = world;
 845         self.movetype           = MOVETYPE_TOSS;
 846         self.moveto                     = self.origin;
 847         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 848         self.reset                      = func_null;
 849         self.state                      = 0;
 850         self.attack_finished_single = 0;
 851
 852         if not(self.flags & FL_FLY)
 853                 self.velocity = '0 0 0';
 854
 855         MON_ACTION(self.monsterid, MR_DEATH);
 856 }
 857
 858 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 859 {
 860
 861         if(self.frozen && deathtype != DEATH_KILL)
 862                 return;
 863
 864         if(time < self.pain_finished && deathtype != DEATH_KILL)
 865                 return;
 866
 867         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
 868                 return;
 869
 870         vector v;
 871         float take, save;
 872
 873         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, deathtype, damage);
 874         take = v_x;
 875         save = v_y;
 876
 877         self.health -= take;
 878
 879         WaypointSprite_UpdateHealth(self.sprite, self.health);
 880
 881         self.dmg_time = time;
 882
 883         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 884                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 885
 886         self.velocity += force * self.damageforcescale;
 887
 888         if(deathtype != DEATH_DROWN)
 889         {
 890                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 891                 if (take > 50)
 892                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 893                 if (take > 100)
 894                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 895         }
 896
 897         if(self.health <= 0)
 898         {
 899                 if(deathtype == DEATH_KILL)
 900                         self.candrop = FALSE; // killed by mobkill command
 901
 902                 // TODO: fix this?
 903                 activator = attacker;
 904                 other = self.enemy;
 905                 SUB_UseTargets();
 906                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 907
 908                 monster_die(attacker, (self.health <= -100 || deathtype == DEATH_KILL));
 909
 910                 WaypointSprite_Kill(self.sprite);
 911
 912                 frag_attacker = attacker;
 913                 frag_target = self;
 914                 MUTATOR_CALLHOOK(MonsterDies);
 915
 916                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
 917                 {
 918                         Violence_GibSplash(self, 1, 0.5, attacker);
 919
 920                         self.think = SUB_Remove;
 921                         self.nextthink = time + 0.1;
 922                 }
 923         }
 924 }
 925
 926 void monster_setupcolors()
 927 {
 928         if(IS_PLAYER(self.monster_owner))
 929                 self.colormap = self.monster_owner.colormap;
 930         else if(teamplay && self.team)
 931                 self.colormap = 1024 + (self.team - 1) * 17;
 932         else
 933         {
 934                 if(self.monster_skill <= MONSTER_SKILL_EASY)
 935                         self.colormap = 1029;
 936                 else if(self.monster_skill <= MONSTER_SKILL_MEDIUM)
 937                         self.colormap = 1027;
 938                 else if(self.monster_skill <= MONSTER_SKILL_HARD)
 939                         self.colormap = 1038;
 940                 else if(self.monster_skill <= MONSTER_SKILL_INSANE)
 941                         self.colormap = 1028;
 942                 else if(self.monster_skill <= MONSTER_SKILL_NIGHTMARE)
 943                         self.colormap = 1032;
 944                 else
 945                         self.colormap = 1024;
 946         }
 947 }
 948
 949 void monster_think()
 950 {
 951         self.think = monster_think;
 952         self.nextthink = self.ticrate;
 953
 954         if(self.ltime)
 955         if(time >= self.ltime)
 956         {
 957                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
 958                 return;
 959         }
 960
 961         MON_ACTION(self.monsterid, MR_THINK);
 962
 963         CSQCMODEL_AUTOUPDATE();
 964 }
 965
 966 float monster_spawn()
 967 {
 968         MON_ACTION(self.monsterid, MR_SETUP);
 969
 970         if not(self.monster_respawned)
 971         {
 972                 Monster_CheckMinibossFlag();
 973                 self.health *= Monster_SkillModifier();
 974         }
 975
 976         self.max_health = self.health;
 977         self.pain_finished = self.nextthink;
 978
 979         if(IS_PLAYER(self.monster_owner))
 980                 self.effects |= EF_DIMLIGHT;
 981
 982         if not(self.monster_respawned)
 983         if not(self.skin)
 984                 self.skin = rint(random() * 4);
 985
 986         if not(self.attack_range)
 987                 self.attack_range = autocvar_g_monsters_attack_range;
 988
 989         precache_monstersounds();
 990         UpdateMonsterSounds();
 991
 992         if(teamplay)
 993                 self.monster_attack = TRUE; // we can have monster enemies in team games
 994
 995         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
 996
 997         WaypointSprite_Spawn(M_NAME(self.monsterid), 0, 1024, self, '0 0 1' * (self.maxs_z + 15), world, self.team, self, sprite, TRUE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 998         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 999         WaypointSprite_UpdateHealth(self.sprite, self.health);
1000
1001         self.think = monster_think;
1002         self.nextthink = time + self.ticrate;
1003
1004         if(MUTATOR_CALLHOOK(MonsterSpawn))
1005                 return FALSE;
1006
1007         return TRUE;
1008 }
1009
1010 float monster_initialize(float mon_id, float nodrop)
1011 {
1012         if not(autocvar_g_monsters)
1013                 return FALSE;
1014
1015         entity mon = get_monsterinfo(mon_id);
1016
1017         if not(self.monster_skill)
1018                 self.monster_skill = cvar("g_monsters_skill");
1019
1020         // support for quake style removing monsters based on skill
1021         if(self.monster_skill == MONSTER_SKILL_EASY) if(self.spawnflags & MONSTERSKILL_NOTEASY) { return FALSE; }
1022         if(self.monster_skill == MONSTER_SKILL_MEDIUM) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { return FALSE; }
1023         if(self.monster_skill == MONSTER_SKILL_HARD) if(self.spawnflags & MONSTERSKILL_NOTHARD) { return FALSE; }
1024
1025         if(self.team && !teamplay)
1026                 self.team = 0;
1027
1028         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
1029         if not(self.monster_respawned)
1030                 monsters_total += 1;
1031
1032         setmodel(self, mon.model);
1033         setsize(self, mon.mins, mon.maxs);
1034         self.flags                              = FL_MONSTER;
1035         self.takedamage                 = DAMAGE_AIM;
1036         self.bot_attack                 = TRUE;
1037         self.iscreature                 = TRUE;
1038         self.teleportable               = TRUE;
1039         self.damagedbycontents  = TRUE;
1040         self.monsterid                  = mon_id;
1041         self.damageforcescale   = 0;
1042         self.event_damage               = monsters_damage;
1043         self.touch                              = MonsterTouch;
1044         self.use                                = monster_use;
1045         self.solid                              = SOLID_BBOX;
1046         self.movetype                   = MOVETYPE_WALK;
1047         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1048         self.enemy                              = world;
1049         self.velocity                   = '0 0 0';
1050         self.moveto                             = self.origin;
1051         self.pos1                               = self.origin;
1052         self.pos2                               = self.angles;
1053         self.reset                              = monsters_reset;
1054         self.netname                    = mon.netname;
1055         self.monster_name               = M_NAME(mon_id);
1056         self.candrop                    = TRUE;
1057         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1058         self.oldtarget2                 = self.target2;
1059         self.deadflag                   = DEAD_NO;
1060         self.scale                              = 1;
1061         self.noalign                    = nodrop;
1062         self.spawn_time                 = time;
1063         self.gravity                    = 1;
1064         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1065
1066         if(autocvar_g_fullbrightplayers)
1067                 self.effects |= EF_FULLBRIGHT;
1068
1069         if(autocvar_g_nodepthtestplayers)
1070                 self.effects |= EF_NODEPTHTEST;
1071
1072         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1073                 self.flags |= FL_SWIM;
1074
1075         if(mon.spawnflags & MONSTER_TYPE_FLY)
1076         {
1077                 self.flags |= FL_FLY;
1078                 self.movetype = MOVETYPE_FLY;
1079         }
1080
1081         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1082                 self.scale = 1.3;
1083
1084         if not(self.ticrate)
1085                 self.ticrate = autocvar_g_monsters_think_delay;
1086
1087         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1088
1089         if not(self.m_armor_blockpercent)
1090                 self.m_armor_blockpercent = 0.5;
1091
1092         if not(self.target_range)
1093                 self.target_range = autocvar_g_monsters_target_range;
1094
1095         if not(self.respawntime)
1096                 self.respawntime = autocvar_g_monsters_respawn_delay;
1097
1098         if not(self.monster_moveflags)
1099                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1100
1101         if not(self.noalign)
1102         {
1103                 setorigin(self, self.origin + '0 0 20');
1104                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1105                 setorigin(self, trace_endpos);
1106         }
1107
1108         if not(monster_spawn())
1109                 return FALSE;
1110
1111         if not(self.monster_respawned)
1112                 monster_setupcolors();
1113
1114         CSQCMODEL_AUTOINIT();
1115
1116         return TRUE;
1117 }