qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void M_Item_Touch ()
   7 {
   8         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   9         {
  10                 Item_Touch();
  11                 self.think = SUB_Remove;
  12                 self.nextthink = time + 0.1;
  13         }
  14 }
  15
  16 void monster_item_spawn()
  17 {
  18         if(self.monster_loot)
  19                 self.monster_loot();
  20
  21         self.gravity = 1;
  22         self.velocity = randomvec() * 175 + '0 0 325';
  23         self.touch = M_Item_Touch;
  24
  25         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  26 }
  27
  28 void monster_dropitem()
  29 {
  30         if(!self.candrop || !self.monster_loot)
  31                 return;
  32
  33         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  34         entity e = spawn();
  35
  36         setorigin(e, org);
  37
  38         e.monster_loot = self.monster_loot;
  39
  40         other = e;
  41         MUTATOR_CALLHOOK(MonsterDropItem);
  42         e = other;
  43
  44         e.think = monster_item_spawn;
  45         e.nextthink = time + 0.3;
  46 }
  47
  48 void monsters_setframe(float _frame)
  49 {
  50         if(self.frame == _frame)
  51                 return;
  52
  53         self.anim_start_time = time;
  54         self.frame = _frame;
  55         self.SendFlags |= MSF_ANIM;
  56 }
  57
  58 float monster_isvalidtarget (entity targ, entity ent)
  59 {
  60         if(!targ || !ent)
  61                 return FALSE; // someone doesn't exist
  62
  63         if(targ == ent)
  64                 return FALSE; // don't attack ourselves
  65
  66         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  67
  68         if(trace_ent != targ)
  69         {
  70                 if(trace_ent != world)
  71                         targ = trace_ent;
  72                 else
  73                         return FALSE;
  74         }
  75
  76         if(targ.vehicle_flags & VHF_ISVEHICLE)
  77         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  78                 return FALSE; // melee attacks are useless against vehicles
  79
  80         if(time < game_starttime)
  81                 return FALSE; // monsters do nothing before the match has started
  82
  83         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  84                 return FALSE; // enemy is too far away
  85
  86         if(targ.takedamage == DAMAGE_NO)
  87                 return FALSE; // enemy can't be damaged
  88
  89         if(targ.items & IT_INVISIBILITY)
  90                 return FALSE; // enemy is invisible
  91
  92         if(substring(targ.classname, 0, 10) == "onslaught_")
  93                 return FALSE; // don't attack onslaught targets
  94
  95         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  96                 return FALSE; // enemy is a spectator
  97
  98         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  99         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 100                 return FALSE; // enemy/self is dead
 101
 102         if(ent.monster_owner == targ)
 103                 return FALSE; // don't attack our master
 104
 105         if(targ.monster_owner == ent)
 106                 return FALSE; // don't attack our pet
 107
 108         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 109         if(targ.flags & FL_NOTARGET)
 110                 return FALSE; // enemy can't be targeted
 111
 112         if not(autocvar_g_monsters_typefrag)
 113         if(targ.BUTTON_CHAT)
 114                 return FALSE; // no typefragging!
 115
 116         if not(IsDifferentTeam(targ, ent))
 117                 return FALSE; // enemy is on our team
 118
 119         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 120         if(ent.enemy != targ)
 121         {
 122                 float dot;
 123
 124                 makevectors (ent.angles);
 125                 dot = normalize (targ.origin - ent.origin) * v_forward;
 126
 127                 if(dot <= 0.3)
 128                         return FALSE;
 129         }
 130
 131         return TRUE;
 132 }
 133
 134 entity FindTarget (entity ent)
 135 {
 136         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 137
 138         entity head, closest_target = world;
 139         head = findradius(ent.origin, ent.target_range);
 140
 141         while(head) // find the closest acceptable target to pass to
 142         {
 143                 if(monster_isvalidtarget(head, ent))
 144                 {
 145                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 146                         vector head_center = CENTER_OR_VIEWOFS(head);
 147                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 148
 149                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 150                         if(closest_target)
 151                         {
 152                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 153                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 154                                         { closest_target = head; }
 155                         }
 156                         else { closest_target = head; }
 157                 }
 158
 159                 head = head.chain;
 160         }
 161
 162         return closest_target;
 163 }
 164
 165 void MonsterTouch ()
 166 {
 167         if(other == world)
 168                 return;
 169
 170         if(self.enemy != other)
 171         if not(other.flags & FL_MONSTER)
 172         if(monster_isvalidtarget(other, self))
 173                 self.enemy = other;
 174 }
 175
 176 void monster_sound(string msound, float sound_delay, float delaytoo)
 177 {
 178         if(delaytoo && time < self.msound_delay)
 179                 return; // too early
 180
 181         if(msound == "")
 182                 return; // sound doesn't exist
 183
 184         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTEN_NORM);
 185
 186         self.msound_delay = time + sound_delay;
 187 }
 188
 189 void monster_precachesounds(entity e)
 190 {
 191         precache_sound(e.msound_idle);
 192         precache_sound(e.msound_death);
 193         precache_sound(e.msound_attack_melee);
 194         precache_sound(e.msound_attack_ranged);
 195         precache_sound(e.msound_sight);
 196         precache_sound(e.msound_pain);
 197 }
 198
 199 void monster_setupsounds(string mon)
 200 {
 201         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 202         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 203         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 204         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 205         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 206         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 207 }
 208
 209 void monster_makevectors(entity e)
 210 {
 211         vector v;
 212
 213         v = CENTER_OR_VIEWOFS(e);
 214         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 215         self.v_angle_x = -self.v_angle_x;
 216
 217         makevectors(self.v_angle);
 218 }
 219
 220 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 221 {
 222         float rdmg = damg * random();
 223
 224         if (self.health <= 0)
 225                 return FALSE; // attacking while dead?!
 226
 227         if(dostop)
 228         {
 229                 self.velocity_x = 0;
 230                 self.velocity_y = 0;
 231                 self.state = MONSTER_STATE_ATTACK_MELEE;
 232                 self.SendFlags |= MSF_MOVE;
 233         }
 234
 235         monsters_setframe(anim);
 236
 237         if(anim_finished != 0)
 238                 self.attack_finished_single = time + anim_finished;
 239
 240         monster_makevectors(targ);
 241
 242         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 243
 244         if(trace_ent.takedamage)
 245                 Damage(trace_ent, self, self, rdmg * monster_skill, deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 246
 247         return TRUE;
 248 }
 249
 250 void Monster_CheckMinibossFlag ()
 251 {
 252         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 253                 return;
 254
 255         float chance = random() * 100;
 256
 257         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 258         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 259         {
 260                 self.health += autocvar_g_monsters_miniboss_healthboost;
 261                 if not(self.weapon)
 262                         self.weapon = WEP_NEX;
 263         }
 264 }
 265
 266 float Monster_CanRespawn(entity ent)
 267 {
 268         other = ent;
 269         if(MUTATOR_CALLHOOK(MonsterRespawn))
 270                 return TRUE; // enabled by a mutator
 271
 272         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 273                 return FALSE;
 274
 275         if not(autocvar_g_monsters_respawn)
 276                 return FALSE;
 277
 278         return TRUE;
 279 }
 280
 281 void Monster_Fade ()
 282 {
 283         if(Monster_CanRespawn(self))
 284         {
 285                 self.monster_respawned = TRUE;
 286                 self.think = self.monster_spawnfunc;
 287                 self.nextthink = time + self.respawntime;
 288                 self.deadflag = DEAD_RESPAWNING;
 289                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 290                 {
 291                         self.pos1 = self.origin;
 292                         self.pos2 = self.angles;
 293                 }
 294                 self.event_damage = func_null;
 295                 self.takedamage = DAMAGE_NO;
 296                 setorigin(self, self.pos1);
 297                 self.angles = self.pos2;
 298                 self.health = self.max_health;
 299
 300                 self.SendFlags |= MSF_MOVE;
 301                 self.SendFlags |= MSF_STATUS;
 302         }
 303         else
 304                 SUB_SetFade(self, time + 3, 1);
 305 }
 306
 307 float Monster_CanJump (vector vel)
 308 {
 309         if(self.state)
 310                 return FALSE; // already attacking
 311         if not(self.flags & FL_ONGROUND)
 312                 return FALSE; // not on the ground
 313         if(self.health <= 0)
 314                 return FALSE; // called when dead?
 315         if(time < self.attack_finished_single)
 316                 return FALSE; // still attacking
 317
 318         vector old = self.velocity;
 319
 320         self.velocity = vel;
 321         tracetoss(self, self);
 322         self.velocity = old;
 323         if (trace_ent != self.enemy)
 324                 return FALSE;
 325
 326         return TRUE;
 327 }
 328
 329 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 330 {
 331         if(!Monster_CanJump(vel))
 332                 return FALSE;
 333
 334         monsters_setframe(anm);
 335         self.state = MONSTER_STATE_ATTACK_LEAP;
 336         self.touch = touchfunc;
 337         self.origin_z += 1;
 338         self.velocity = vel;
 339         self.flags &= ~FL_ONGROUND;
 340
 341         self.attack_finished_single = time + anim_finished;
 342
 343         return TRUE;
 344 }
 345
 346 void monster_checkattack(entity e, entity targ)
 347 {
 348         if(e == world)
 349                 return;
 350         if(targ == world)
 351                 return;
 352
 353         if not(e.monster_attackfunc)
 354                 return;
 355
 356         if(time < e.attack_finished_single)
 357                 return;
 358
 359         if(vlen(targ.origin - e.origin) <= e.attack_range)
 360         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 361         {
 362                 monster_sound(e.msound_attack_melee, 0, FALSE);
 363                 return;
 364         }
 365
 366         if(vlen(targ.origin - e.origin) > e.attack_range)
 367         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 368         {
 369                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 370                 return;
 371         }
 372 }
 373
 374 void monster_use ()
 375 {
 376         if not(self.enemy)
 377         if(self.health > 0)
 378         if(monster_isvalidtarget(activator, self))
 379                 self.enemy = activator;
 380 }
 381
 382 .float last_trace;
 383 .float last_enemycheck; // for checking enemy
 384 vector monster_pickmovetarget(entity targ)
 385 {
 386         // enemy is always preferred target
 387         if(self.enemy)
 388         {
 389                 makevectors(self.angles);
 390                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 391                 self.last_trace = time + 1.2;
 392                 return self.enemy.origin;
 393         }
 394
 395         switch(self.monster_moveflags)
 396         {
 397                 case MONSTER_MOVE_OWNER:
 398                 {
 399                         self.monster_movestate = MONSTER_MOVE_OWNER;
 400                         self.last_trace = time + 0.3;
 401                         if(self.monster_owner)
 402                                 return self.monster_owner.origin;
 403                 }
 404                 case MONSTER_MOVE_SPAWNLOC:
 405                 {
 406                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 407                         self.last_trace = time + 2;
 408                         return self.pos1;
 409                 }
 410                 case MONSTER_MOVE_NOMOVE:
 411                 {
 412                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 413                         self.last_trace = time + 2;
 414                         return self.origin;
 415                 }
 416                 default:
 417                 case MONSTER_MOVE_WANDER:
 418                 {
 419                         vector pos;
 420                         self.monster_movestate = MONSTER_MOVE_WANDER;
 421                         self.last_trace = time + 2;
 422
 423                         self.angles_y = random() * 500;
 424                         makevectors(self.angles);
 425                         pos = self.origin + v_forward * 600;
 426
 427                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 428                         {
 429                                 pos_z = random() * 200;
 430                                 if(random() >= 0.5)
 431                                         pos_z *= -1;
 432                         }
 433
 434                         if(targ)
 435                         {
 436                                 self.last_trace = time + 0.5;
 437                                 pos = targ.origin;
 438                         }
 439
 440                         return pos;
 441                 }
 442         }
 443 }
 444
 445 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 446 {
 447         fixedmakevectors(self.angles);
 448
 449         if(self.target2)
 450                 self.goalentity = find(world, targetname, self.target2);
 451
 452         entity targ;
 453
 454         if(self.frozen)
 455         {
 456                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 457                 self.health = max(1, self.max_health * self.revive_progress);
 458
 459                 self.SendFlags |= MSF_STATUS;
 460
 461                 movelib_beak_simple(stopspeed);
 462
 463                 self.velocity = '0 0 0';
 464                 self.enemy = world;
 465                 self.nextthink = time + 0.1;
 466
 467                 if(self.revive_progress >= 1)
 468                         Unfreeze(self); // wait for next think before attacking
 469
 470                 // don't bother updating angles here?
 471                 if(self.origin != self.oldorigin)
 472                 {
 473                         self.oldorigin = self.origin;
 474                         self.SendFlags |= MSF_MOVE;
 475                 }
 476
 477                 return; // no moving while frozen
 478         }
 479
 480         if(self.flags & FL_SWIM)
 481         {
 482                 if(self.waterlevel < WATERLEVEL_WETFEET)
 483                 {
 484                         if(time >= self.last_trace)
 485                         {
 486                                 self.last_trace = time + 0.4;
 487
 488                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 489                                 self.angles = '90 90 0';
 490                                 if(random() < 0.5)
 491                                 {
 492                                         self.velocity_y += random() * 50;
 493                                         self.velocity_x -= random() * 50;
 494                                 }
 495                                 else
 496                                 {
 497                                         self.velocity_y -= random() * 50;
 498                                         self.velocity_x += random() * 50;
 499                                 }
 500                                 self.velocity_z += random() * 150;
 501                         }
 502
 503
 504                         self.movetype = MOVETYPE_BOUNCE;
 505                         //self.velocity_z = -200;
 506
 507                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 508
 509                         return;
 510                 }
 511                 else
 512                 {
 513                         self.angles = '0 0 0';
 514                         self.movetype = MOVETYPE_WALK;
 515                 }
 516         }
 517
 518         targ = self.goalentity;
 519
 520         monster_target = targ;
 521         monster_speed_run = runspeed;
 522         monster_speed_walk = walkspeed;
 523
 524         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 525         {
 526                 runspeed = walkspeed = 0;
 527                 if(time >= self.spawn_time)
 528                         monsters_setframe(manim_idle);
 529                 movelib_beak_simple(stopspeed);
 530                 if(self.oldorigin != self.origin)
 531                 {
 532                         self.oldorigin = self.origin;
 533                         self.SendFlags |= MSF_MOVE;
 534                 }
 535                 return;
 536         }
 537
 538         targ = monster_target;
 539         runspeed = monster_speed_run;
 540         walkspeed = monster_speed_walk;
 541
 542         if(teamplay)
 543         if(autocvar_g_monsters_teams)
 544         if(IsDifferentTeam(self.monster_owner, self))
 545                 self.monster_owner = world;
 546
 547         if(self.enemy && self.enemy.health < 1)
 548                 self.enemy = world; // enough!
 549
 550         if(time >= self.last_enemycheck)
 551         {
 552                 if not(monster_isvalidtarget(self.enemy, self))
 553                         self.enemy = world;
 554
 555                 if not(self.enemy)
 556                 {
 557                         self.enemy = FindTarget(self);
 558                         if(self.enemy)
 559                                 monster_sound(self.msound_sight, 0, FALSE);
 560                 }
 561
 562                 self.last_enemycheck = time + 2;
 563         }
 564
 565         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 566                 self.state = 0;
 567
 568         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 569         if(time >= self.last_trace || self.enemy) // update enemy instantly
 570                 self.moveto = monster_pickmovetarget(targ);
 571
 572         if not(self.enemy)
 573                 monster_sound(self.msound_idle, 5, TRUE);
 574
 575         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 576                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 577
 578         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 579         {
 580                 self.state = 0;
 581                 self.touch = MonsterTouch;
 582         }
 583
 584         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 585
 586         float turny = 0;
 587         vector real_angle = vectoangles(self.steerto) - self.angles;
 588
 589         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 590                 turny = 20;
 591
 592         if(self.flags & FL_SWIM)
 593                 turny = vlen(self.angles - self.moveto);
 594
 595         if(turny)
 596         {
 597                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 598                 self.angles_y += turny;
 599         }
 600
 601         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 602                 self.moveto = self.origin;
 603
 604         if(self.enemy && self.enemy.vehicle)
 605                 runspeed = 0;
 606
 607         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 608                 v_forward = normalize(self.moveto - self.origin);
 609         else
 610                 self.moveto_z = self.origin_z;
 611
 612         if(vlen(self.origin - self.moveto) > 64)
 613         {
 614                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 615                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 616                 else
 617                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 618
 619                 if(time > self.pain_finished)
 620                 if(time > self.attack_finished_single)
 621                 if(vlen(self.velocity) > 10)
 622                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 623                 else
 624                         monsters_setframe(manim_idle);
 625         }
 626         else
 627         {
 628                 entity e = find(world, targetname, self.target2);
 629                 if(e.target2)
 630                         self.target2 = e.target2;
 631                 else if(e.target)
 632                         self.target2 = e.target;
 633
 634                 movelib_beak_simple(stopspeed);
 635                 if(time > self.attack_finished_single)
 636                 if(time > self.pain_finished)
 637                 if (vlen(self.velocity) <= 30)
 638                         monsters_setframe(manim_idle);
 639         }
 640
 641         monster_checkattack(self, self.enemy);
 642
 643         if(self.angles != self.oldangles)
 644         {
 645                 self.oldangles = self.angles;
 646                 self.SendFlags |= MSF_ANG;
 647         }
 648
 649         if(self.origin != self.oldorigin)
 650         {
 651                 self.oldorigin = self.origin;
 652                 self.SendFlags |= MSF_MOVE;
 653         }
 654 }
 655
 656 void monster_dead_think()
 657 {
 658         self.think = monster_dead_think;
 659         self.nextthink = time + 0.3; // don't need to update so often now
 660
 661         self.deadflag = DEAD_DEAD;
 662
 663         if(self.ltime != 0)
 664         if(time >= self.ltime)
 665         {
 666                 Monster_Fade();
 667                 return;
 668         }
 669
 670         if(self.oldorigin != self.origin)
 671         {
 672                 self.oldorigin = self.origin;
 673                 self.SendFlags |= MSF_MOVE;
 674         }
 675 }
 676
 677 void monsters_setstatus()
 678 {
 679         self.stat_monsters_total = monsters_total;
 680         self.stat_monsters_killed = monsters_killed;
 681 }
 682
 683 void Monster_Appear()
 684 {
 685         self.enemy = activator;
 686         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 687         self.monster_spawnfunc();
 688 }
 689
 690 float Monster_CheckAppearFlags(entity ent)
 691 {
 692         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 693                 return FALSE;
 694
 695         ent.think = func_null;
 696         ent.nextthink = 0;
 697         ent.use = Monster_Appear;
 698         ent.flags = FL_MONSTER; // set so this monster can get butchered
 699
 700         return TRUE;
 701 }
 702
 703 void monsters_reset()
 704 {
 705         setorigin(self, self.pos1);
 706         self.angles = self.pos2;
 707
 708         self.health = self.max_health;
 709         self.velocity = '0 0 0';
 710         self.enemy = world;
 711         self.goalentity = world;
 712         self.attack_finished_single = 0;
 713         self.moveto = self.origin;
 714
 715         self.SendFlags |= MSF_STATUS;
 716 }
 717
 718 float monster_send(entity to, float sf)
 719 {
 720         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 721         WriteByte(MSG_ENTITY, sf);
 722         if(sf & MSF_SETUP)
 723         {
 724             WriteByte(MSG_ENTITY, self.monsterid);
 725
 726             WriteCoord(MSG_ENTITY, self.origin_x);
 727             WriteCoord(MSG_ENTITY, self.origin_y);
 728             WriteCoord(MSG_ENTITY, self.origin_z);
 729
 730             WriteAngle(MSG_ENTITY, self.angles_x);
 731             WriteAngle(MSG_ENTITY, self.angles_y);
 732
 733                 WriteByte(MSG_ENTITY, self.skin);
 734                 WriteByte(MSG_ENTITY, self.team);
 735     }
 736
 737     if(sf & MSF_ANG)
 738     {
 739         WriteShort(MSG_ENTITY, rint(self.angles_x));
 740         WriteShort(MSG_ENTITY, rint(self.angles_y));
 741     }
 742
 743     if(sf & MSF_MOVE)
 744     {
 745         WriteShort(MSG_ENTITY, rint(self.origin_x));
 746         WriteShort(MSG_ENTITY, rint(self.origin_y));
 747         WriteShort(MSG_ENTITY, rint(self.origin_z));
 748
 749         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 750         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 751         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 752
 753         WriteShort(MSG_ENTITY, rint(self.angles_y));
 754     }
 755
 756     if(sf & MSF_ANIM)
 757     {
 758         WriteCoord(MSG_ENTITY, self.anim_start_time);
 759         WriteByte(MSG_ENTITY, self.frame);
 760     }
 761
 762     if(sf & MSF_STATUS)
 763     {
 764                 WriteByte(MSG_ENTITY, self.skin);
 765
 766         WriteByte(MSG_ENTITY, self.team);
 767
 768                 WriteByte(MSG_ENTITY, self.deadflag);
 769
 770         if(self.health <= 0)
 771             WriteByte(MSG_ENTITY, 0);
 772         else
 773             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 774     }
 775
 776         return TRUE;
 777 }
 778
 779 void monster_link(void() spawnproc)
 780 {
 781     Net_LinkEntity(self, TRUE, 0, monster_send);
 782     self.think      = spawnproc;
 783     self.nextthink  = time;
 784 }
 785
 786 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 787 {
 788         self.health -= damage;
 789
 790         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 791
 792         if(self.health <= -100) // 100 health until gone?
 793         {
 794                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 795
 796                 self.think = SUB_Remove;
 797                 self.nextthink = time + 0.1;
 798         }
 799 }
 800
 801 void monster_die()
 802 {
 803         self.think = monster_dead_think;
 804         self.nextthink = self.ticrate;
 805         self.ltime = time + 5;
 806
 807         monster_dropitem();
 808
 809         if(self.weaponentity)
 810         {
 811                 remove(self.weaponentity);
 812                 self.weaponentity = world;
 813         }
 814
 815         monster_sound(self.msound_death, 0, FALSE);
 816
 817         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 818                 monsters_killed += 1;
 819
 820         if(self.candrop && self.weapon)
 821                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 822
 823         if(IS_CLIENT(self.realowner))
 824                 self.realowner.monstercount -= 1;
 825
 826         self.event_damage       = monsters_corpse_damage;
 827         self.solid                      = SOLID_CORPSE;
 828         self.takedamage         = DAMAGE_AIM;
 829         self.enemy                      = world;
 830         self.movetype           = MOVETYPE_TOSS;
 831         self.moveto                     = self.origin;
 832         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 833
 834         if not(self.flags & FL_FLY)
 835                 self.velocity = '0 0 0';
 836
 837         self.SendFlags |= MSF_MOVE;
 838
 839         // number of monsters spawned with mobspawn command
 840         totalspawned -= 1;
 841
 842         MON_ACTION(self.monsterid, MR_DEATH);
 843 }
 844
 845 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 846 {
 847         if(self.frozen && deathtype != DEATH_KILL)
 848                 return;
 849
 850         if(time < self.pain_finished && deathtype != DEATH_KILL)
 851                 return;
 852
 853         if(time < self.spawnshieldtime)
 854                 return;
 855
 856         if(deathtype != DEATH_KILL)
 857                 damage *= self.armorvalue;
 858
 859         if(self.weaponentity && self.weaponentity.classname == "shield")
 860                 self.weaponentity.health -= damage;
 861
 862         self.health -= damage;
 863
 864         self.dmg_time = time;
 865
 866         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 867                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 868
 869         self.velocity += force * self.damageforcescale;
 870
 871         if(deathtype != DEATH_DROWN)
 872         {
 873                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 874                 if (damage > 50)
 875                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 876                 if (damage > 100)
 877                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 878         }
 879
 880         if(self.health <= 0)
 881         {
 882                 if(deathtype == DEATH_KILL)
 883                         self.candrop = FALSE; // killed by mobkill command
 884
 885                 // TODO: fix this?
 886                 activator = attacker;
 887                 other = self.enemy;
 888                 SUB_UseTargets();
 889                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 890
 891                 monster_die();
 892
 893                 frag_attacker = attacker;
 894                 frag_target = self;
 895                 MUTATOR_CALLHOOK(MonsterDies);
 896
 897                 if(self.health <= -100) // check if we're already gibbed
 898                 {
 899                         Violence_GibSplash(self, 1, 0.5, attacker);
 900
 901                         self.think = SUB_Remove;
 902                         self.nextthink = time + 0.1;
 903                 }
 904         }
 905
 906         self.SendFlags |= MSF_STATUS;
 907 }
 908
 909 void monster_think()
 910 {
 911         self.think = monster_think;
 912         self.nextthink = self.ticrate;
 913
 914         MON_ACTION(self.monsterid, MR_THINK);
 915 }
 916
 917 void monster_spawn()
 918 {
 919         MON_ACTION(self.monsterid, MR_SETUP);
 920
 921         if not(self.monster_respawned)
 922                 Monster_CheckMinibossFlag();
 923
 924         self.max_health = self.health;
 925         self.pain_finished = self.nextthink;
 926         self.anim_start_time = time;
 927
 928         if not(self.noalign)
 929         {
 930                 setorigin(self, self.origin + '0 0 20');
 931                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 932                 setorigin(self, trace_endpos);
 933         }
 934
 935         if not(self.monster_respawned)
 936         if not(self.skin)
 937                 self.skin = rint(random() * 4);
 938
 939         if not(self.attack_range)
 940                 self.attack_range = autocvar_g_monsters_attack_range;
 941
 942         self.pos1 = self.origin;
 943
 944         monster_setupsounds(self.netname);
 945
 946         monster_precachesounds(self);
 947
 948         if(teamplay)
 949                 self.monster_attack = TRUE; // we can have monster enemies in team games
 950
 951         monster_sound(self.msound_spawn, 0, FALSE);
 952
 953         MUTATOR_CALLHOOK(MonsterSpawn);
 954
 955         self.think = monster_think;
 956         self.nextthink = time + self.ticrate;
 957
 958         self.SendFlags |= MSF_SETUP;
 959 }
 960
 961 float monster_initialize(float mon_id, float nodrop)
 962 {
 963         if not(autocvar_g_monsters)
 964                 return FALSE;
 965
 966         vector min_s, max_s;
 967         entity mon = get_monsterinfo(mon_id);
 968
 969         // support for quake style removing monsters based on skill
 970         switch(monster_skill)
 971         {
 972                 case 0:
 973                 case 1: if(self.spawnflags & MONSTERSKILL_NOTEASY)              return FALSE; break;
 974                 case 2: if(self.spawnflags & MONSTERSKILL_NOTMEDIUM)    return FALSE; break;
 975                 default:
 976                 case 3: if(self.spawnflags & MONSTERSKILL_NOTHARD)              return FALSE; break;
 977         }
 978
 979         if(self.team && !teamplay)
 980                 self.team = 0;
 981
 982         self.flags = FL_MONSTER;
 983
 984         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 985         if not(self.monster_respawned)
 986                 monsters_total += 1;
 987
 988         min_s = mon.mins;
 989         max_s = mon.maxs;
 990
 991         self.netname = mon.netname;
 992         self.monster_name = M_NAME(mon_id);
 993
 994         setsize(self, min_s, max_s);
 995         self.takedamage                 = DAMAGE_AIM;
 996         self.bot_attack                 = TRUE;
 997         self.iscreature                 = TRUE;
 998         self.teleportable               = TRUE;
 999         self.damagedbycontents  = TRUE;
1000         self.monsterid                  = mon_id;
1001         self.damageforcescale   = 0;
1002         self.event_damage               = monsters_damage;
1003         self.touch                              = MonsterTouch;
1004         self.use                                = monster_use;
1005         self.solid                              = SOLID_BBOX;
1006         self.movetype                   = MOVETYPE_WALK;
1007         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1008         monsters_spawned           += 1;
1009         self.enemy                              = world;
1010         self.velocity                   = '0 0 0';
1011         self.moveto                             = self.origin;
1012         self.pos2                               = self.angles;
1013         self.reset                              = monsters_reset;
1014         self.candrop                    = TRUE;
1015         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1016         self.oldtarget2                 = self.target2;
1017         self.deadflag                   = DEAD_NO;
1018         self.scale                              = 1;
1019         self.noalign                    = nodrop;
1020         self.spawn_time                 = time;
1021         self.gravity                    = 1;
1022         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1023
1024         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1025                 self.flags |= FL_SWIM;
1026
1027         if(mon.spawnflags & MONSTER_TYPE_FLY)
1028         {
1029                 self.flags |= FL_FLY;
1030                 self.movetype = MOVETYPE_FLY;
1031         }
1032
1033         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1034                 self.scale = 1.3;
1035
1036         if not(self.ticrate)
1037                 self.ticrate = autocvar_g_monsters_think_delay;
1038
1039         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1040
1041         if not(self.armorvalue)
1042                 self.armorvalue = 1; // multiplier
1043
1044         if not(self.target_range)
1045                 self.target_range = autocvar_g_monsters_target_range;
1046
1047         if not(self.respawntime)
1048                 self.respawntime = autocvar_g_monsters_respawn_delay;
1049
1050         if not(self.monster_moveflags)
1051                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1052
1053         monster_link(monster_spawn);
1054
1055         return TRUE;
1056 }